autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.2svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [2], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd* | *-*-kfreebsd-gnu)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-gnu*)
 304     llvm_cv_target_os_type="GNU" ;;
 305   *-*-solaris*)
 306     llvm_cv_target_os_type="SunOS" ;;
 307   *-*-auroraux*)
 308     llvm_cv_target_os_type="AuroraUX" ;;
 309   *-*-win32*)
 310     llvm_cv_target_os_type="Win32" ;;
 311   *-*-mingw*)
 312     llvm_cv_target_os_type="MingW" ;;
 313   *-*-haiku*)
 314     llvm_cv_target_os_type="Haiku" ;;
 315   *-*-rtems*)
 316     llvm_cv_target_os_type="RTEMS" ;;
 317   *-*-nacl*)
 318     llvm_cv_target_os_type="NativeClient" ;;
 319   *-unknown-eabi*)
 320     llvm_cv_target_os_type="Freestanding" ;;
 321   *)
 322     llvm_cv_target_os_type="Unknown" ;;
 323 esac])
 324
 325 dnl Make sure we aren't attempting to configure for an unknown system
 326 if test "$llvm_cv_os_type" = "Unknown" ; then
 327   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 328 fi
 329
 330 dnl Set the "OS" Makefile variable based on the platform type so the
 331 dnl makefile can configure itself to specific build hosts
 332 AC_SUBST(OS,$llvm_cv_os_type)
 333 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 334 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 335
 336 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 337 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 338 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 339
 340 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 341 dnl This is used by lib/Support to determine the basic kind of implementation
 342 dnl to use.
 343 case $llvm_cv_platform_type in
 344   Unix)
 345     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 346     AC_SUBST(LLVM_ON_UNIX,[1])
 347     AC_SUBST(LLVM_ON_WIN32,[0])
 348     ;;
 349   Win32)
 350     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 351     AC_SUBST(LLVM_ON_UNIX,[0])
 352     AC_SUBST(LLVM_ON_WIN32,[1])
 353     ;;
 354 esac
 355
 356 dnl Determine what our target architecture is and configure accordingly.
 357 dnl This will allow Makefiles to make a distinction between the hardware and
 358 dnl the OS.
 359 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 360 [case $target in
 361   i?86-*)                 llvm_cv_target_arch="x86" ;;
 362   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 363   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 364   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 365   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 366   mips-*)                 llvm_cv_target_arch="Mips" ;;
 367   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 368   xcore-*)                llvm_cv_target_arch="XCore" ;;
 369   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 370   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 371   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 372   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 373   *)                      llvm_cv_target_arch="Unknown" ;;
 374 esac])
 375
 376 if test "$llvm_cv_target_arch" = "Unknown" ; then
 377   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 378 fi
 379
 380 dnl Determine the LLVM native architecture for the target
 381 case "$llvm_cv_target_arch" in
 382     x86)     LLVM_NATIVE_ARCH="X86" ;;
 383     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 384     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 385 esac
 386
 387 dnl Define a substitution, ARCH, for the target architecture
 388 AC_SUBST(ARCH,$llvm_cv_target_arch)
 389
 390 dnl Determine what our host architecture.
 391 dnl This will allow MCJIT regress tests runs only for supported
 392 dnl platforms.
 393 case $host in
 394   i?86-*)                 host_arch="x86" ;;
 395   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 396   sparc*-*)               host_arch="Sparc" ;;
 397   powerpc*-*)             host_arch="PowerPC" ;;
 398   arm*-*)                 host_arch="ARM" ;;
 399   mips-*)                 host_arch="Mips" ;;
 400   mipsel-*)               host_arch="Mips" ;;
 401   xcore-*)                host_arch="XCore" ;;
 402   msp430-*)               host_arch="MSP430" ;;
 403   hexagon-*)              host_arch="Hexagon" ;;
 404   mblaze-*)               host_arch="MBlaze" ;;
 405   *)                      host_arch="Unknown" ;;
 406 esac
 407
 408 if test "$host_arch" = "Unknown" ; then
 409   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 410 fi
 411
 412 AC_SUBST(HOST_ARCH,$host_arch)
 413
 414 dnl Check for the endianness of the target
 415 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 416
 417 dnl Check for build platform executable suffix if we're cross-compiling
 418 if test "$cross_compiling" = yes; then
 419   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 420   AC_BUILD_EXEEXT
 421   ac_build_prefix=${build_alias}-
 422   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 423   if test -z "$BUILD_CXX"; then
 424      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 425      if test -z "$BUILD_CXX"; then
 426        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 427      fi
 428   fi
 429 else
 430   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 431 fi
 432
 433 dnl Check to see if there's a .svn or .git directory indicating that this
 434 dnl build is being done from a checkout. This sets up several defaults for
 435 dnl the command line switches. When we build with a checkout directory,
 436 dnl we get a debug with assertions turned on. Without, we assume a source
 437 dnl release and we get an optimized build without assertions.
 438 dnl See --enable-optimized and --enable-assertions below
 439 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 440   cvsbuild="yes"
 441   optimize="no"
 442   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 443 else
 444   cvsbuild="no"
 445   optimize="yes"
 446 fi
 447
 448 dnl===-----------------------------------------------------------------------===
 449 dnl===
 450 dnl=== SECTION 3: Command line arguments for the configure script.
 451 dnl===
 452 dnl===-----------------------------------------------------------------------===
 453
 454 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 455 AC_ARG_ENABLE(libcpp,
 456               AS_HELP_STRING([--enable-libcpp],
 457                              [Use libc++ if available (default is NO)]),,
 458                              enableval=default)
 459 case "$enableval" in
 460   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 461   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 462   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 463   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 464 esac
 465
 466 dnl --enable-optimized : check whether they want to do an optimized build:
 467 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 468  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 469 if test ${enableval} = "no" ; then
 470   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 471 else
 472   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 473 fi
 474
 475 dnl --enable-profiling : check whether they want to do a profile build:
 476 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 477  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 478 if test ${enableval} = "no" ; then
 479   AC_SUBST(ENABLE_PROFILING,[[]])
 480 else
 481   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 482 fi
 483
 484 dnl --enable-assertions : check whether they want to turn on assertions or not:
 485 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 486   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 487 if test ${enableval} = "yes" ; then
 488   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 489 else
 490   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 491 fi
 492
 493 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 494 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 495   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 496 if test ${enableval} = "yes" ; then
 497   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 498   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 499 else
 500   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 501   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 502 fi
 503
 504 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 505 AC_ARG_ENABLE(debug-runtime,
 506    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 507 if test ${enableval} = "no" ; then
 508   AC_SUBST(DEBUG_RUNTIME,[[]])
 509 else
 510   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 511 fi
 512
 513 dnl --enable-debug-symbols : should even optimized compiler libraries
 514 dnl have debug symbols?
 515 AC_ARG_ENABLE(debug-symbols,
 516    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 517 if test ${enableval} = "no" ; then
 518   AC_SUBST(DEBUG_SYMBOLS,[[]])
 519 else
 520   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 521 fi
 522
 523 dnl --enable-jit: check whether they want to enable the jit
 524 AC_ARG_ENABLE(jit,
 525   AS_HELP_STRING(--enable-jit,
 526                  [Enable Just In Time Compiling (default is YES)]),,
 527   enableval=default)
 528 if test ${enableval} = "no"
 529 then
 530   AC_SUBST(JIT,[[]])
 531 else
 532   case "$llvm_cv_target_arch" in
 533     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 534     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 535     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 536     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 537     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 538     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 539     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 540     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 541     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 542     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 543     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 544     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 545   esac
 546 fi
 547
 548 dnl Allow enablement of building and installing docs
 549 AC_ARG_ENABLE(docs,
 550               AS_HELP_STRING([--enable-docs],
 551                              [Build documents (default is YES)]),,
 552                              enableval=default)
 553 case "$enableval" in
 554   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 555   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 556   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 557   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 558 esac
 559
 560 dnl Allow enablement of doxygen generated documentation
 561 AC_ARG_ENABLE(doxygen,
 562               AS_HELP_STRING([--enable-doxygen],
 563                              [Build doxygen documentation (default is NO)]),,
 564                              enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 567   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 568   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 570 esac
 571
 572 dnl Allow disablement of threads
 573 AC_ARG_ENABLE(threads,
 574               AS_HELP_STRING([--enable-threads],
 575                              [Use threads if available (default is YES)]),,
 576                              enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 579   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 580   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 582 esac
 583 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 584                    [Define if threads enabled])
 585
 586 dnl Allow disablement of pthread.h
 587 AC_ARG_ENABLE(pthreads,
 588               AS_HELP_STRING([--enable-pthreads],
 589                              [Use pthreads if available (default is YES)]),,
 590                              enableval=default)
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 593   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 594   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl Allow building without position independent code
 599 AC_ARG_ENABLE(pic,
 600   AS_HELP_STRING([--enable-pic],
 601                  [Build LLVM with Position Independent Code (default is YES)]),,
 602                  enableval=default)
 603 case "$enableval" in
 604   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 605   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 606   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 607   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 608 esac
 609 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 610                    [Define if position independent code is enabled])
 611
 612 dnl Allow building a shared library and linking tools against it.
 613 AC_ARG_ENABLE(shared,
 614   AS_HELP_STRING([--enable-shared],
 615                  [Build a shared library and link tools against it (default is NO)]),,
 616                  enableval=default)
 617 case "$enableval" in
 618   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 619   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 620   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 621   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 622 esac
 623
 624 dnl Allow libstdc++ is embedded in LLVM.dll.
 625 AC_ARG_ENABLE(embed-stdcxx,
 626   AS_HELP_STRING([--enable-embed-stdcxx],
 627                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 628                  enableval=default)
 629 case "$enableval" in
 630   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 631   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 632   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 633   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 634 esac
 635
 636 dnl Enable embedding timestamp information into build.
 637 AC_ARG_ENABLE(timestamps,
 638   AS_HELP_STRING([--enable-timestamps],
 639                  [Enable embedding timestamp information in build (default is YES)]),,
 640                  enableval=default)
 641 case "$enableval" in
 642   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 643   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 644   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 645   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 646 esac
 647 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 648                    [Define if timestamp information (e.g., __DATE__) is allowed])
 649
 650 dnl Allow specific targets to be specified for building (or not)
 651 TARGETS_TO_BUILD=""
 652 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 653     [Build specific host targets: all or target1,target2,... Valid targets are:
 654      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 655      xcore, msp430, nvptx, and cpp (default=all)]),,
 656     enableval=all)
 657 if test "$enableval" = host-only ; then
 658   enableval=host
 659 fi
 660 case "$enableval" in
 661   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze NVPTX Hexagon" ;;
 662   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 663       case "$a_target" in
 664         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 665         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 666         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 667         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 668         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 669         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 670         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 671         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 672         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 673         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 674         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 675         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 676         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 677         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 678         host) case "$llvm_cv_target_arch" in
 679             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 680             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 681             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 682             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 683             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 684             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 685             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 686             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 687             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 688             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 689             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 690             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 691             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 692           esac ;;
 693         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 694       esac
 695   done
 696   ;;
 697 esac
 698 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 699
 700 dnl Determine whether we are building LLVM support for the native architecture.
 701 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 702 for a_target in $TARGETS_TO_BUILD; do
 703   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 704     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 705       [LLVM architecture name for the native architecture, if available])
 706     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 707     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 708     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 709     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 710     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 711       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 712     fi
 713     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 714       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 715     fi
 716     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 717       [LLVM name for the native Target init function, if available])
 718     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 719       [LLVM name for the native TargetInfo init function, if available])
 720     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 721       [LLVM name for the native target MC init function, if available])
 722     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 723       [LLVM name for the native AsmPrinter init function, if available])
 724     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 725       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 726        [LLVM name for the native AsmParser init function, if available])
 727     fi
 728     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 729       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 730        [LLVM name for the native Disassembler init function, if available])
 731     fi
 732   fi
 733 done
 734
 735 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 736 dnl target feature def files.
 737 LLVM_ENUM_TARGETS=""
 738 LLVM_ENUM_ASM_PRINTERS=""
 739 LLVM_ENUM_ASM_PARSERS=""
 740 LLVM_ENUM_DISASSEMBLERS=""
 741 for target_to_build in $TARGETS_TO_BUILD; do
 742   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 743   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 744     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 745   fi
 746   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 747     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 748   fi
 749   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 750     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 751   fi
 752 done
 753 AC_SUBST(LLVM_ENUM_TARGETS)
 754 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 755 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 756 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 757
 758 dnl Override the option to use for optimized builds.
 759 AC_ARG_WITH(optimize-option,
 760   AS_HELP_STRING([--with-optimize-option],
 761                  [Select the compiler options to use for optimized builds]),,
 762                  withval=default)
 763 AC_MSG_CHECKING([optimization flags])
 764 case "$withval" in
 765   default)
 766     case "$llvm_cv_os_type" in
 767     FreeBSD) optimize_option=-O2 ;;
 768     MingW) optimize_option=-O2 ;;
 769     *)     optimize_option=-O3 ;;
 770     esac ;;
 771   *) optimize_option="$withval" ;;
 772 esac
 773 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 774 AC_MSG_RESULT([$optimize_option])
 775
 776 dnl Specify extra build options
 777 AC_ARG_WITH(extra-options,
 778   AS_HELP_STRING([--with-extra-options],
 779                  [Specify additional options to compile LLVM with]),,
 780                  withval=default)
 781 case "$withval" in
 782   default) EXTRA_OPTIONS= ;;
 783   *) EXTRA_OPTIONS=$withval ;;
 784 esac
 785 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 786
 787 dnl Specify extra linker build options
 788 AC_ARG_WITH(extra-ld-options,
 789   AS_HELP_STRING([--with-extra-ld-options],
 790                  [Specify additional options to link LLVM with]),,
 791                  withval=default)
 792 case "$withval" in
 793   default) EXTRA_LD_OPTIONS= ;;
 794   *) EXTRA_LD_OPTIONS=$withval ;;
 795 esac
 796 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 797
 798 dnl Allow specific bindings to be specified for building (or not)
 799 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 800     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 801     enableval=default)
 802 BINDINGS_TO_BUILD=""
 803 case "$enableval" in
 804   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 805   all ) BINDINGS_TO_BUILD="ocaml" ;;
 806   none | no) BINDINGS_TO_BUILD="" ;;
 807   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 808       case "$a_binding" in
 809         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 810         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 811       esac
 812   done
 813   ;;
 814 esac
 815
 816 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 817 dnl script for bindings/ocaml/configure, except that its auto value depends on
 818 dnl OCAMLC, which is found here to support tests.
 819 AC_ARG_WITH([ocaml-libdir],
 820   [AS_HELP_STRING([--with-ocaml-libdir],
 821     [Specify install location for ocaml bindings (default is stdlib)])],
 822   [],
 823   [withval=auto])
 824 case "$withval" in
 825   auto) with_ocaml_libdir="$withval" ;;
 826   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 827   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 828 esac
 829
 830 AC_ARG_WITH(clang-srcdir,
 831   AS_HELP_STRING([--with-clang-srcdir],
 832     [Directory to the out-of-tree Clang source]),,
 833     withval="-")
 834 case "$withval" in
 835   -) clang_src_root="" ;;
 836   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 837   *) clang_src_root="$ac_pwd/$withval" ;;
 838 esac
 839 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 840
 841 AC_ARG_WITH(clang-resource-dir,
 842   AS_HELP_STRING([--with-clang-resource-dir],
 843     [Relative directory from the Clang binary for resource files]),,
 844     withval="")
 845 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 846                    [Relative directory for resource files])
 847
 848 AC_ARG_WITH(c-include-dirs,
 849   AS_HELP_STRING([--with-c-include-dirs],
 850     [Colon separated list of directories clang will search for headers]),,
 851     withval="")
 852 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 853                    [Directories clang will search for headers])
 854
 855 # Clang normally uses the system c++ headers and libraries. With this option,
 856 # clang will use the ones provided by a gcc installation instead. This option should
 857 # be passed the same value that was used with --prefix when configuring gcc.
 858 AC_ARG_WITH(gcc-toolchain,
 859   AS_HELP_STRING([--with-gcc-toolchain],
 860     [Directory where gcc is installed.]),,
 861     withval="")
 862 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 863                    [Directory where gcc is installed.])
 864
 865 AC_ARG_WITH(default-sysroot,
 866   AS_HELP_STRING([--with-default-sysroot],
 867     [Add --sysroot=<path> to all compiler invocations.]),,
 868     withval="")
 869 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
 870                    [Default <path> to all compiler invocations for --sysroot=<path>.])
 871
 872 dnl Allow linking of LLVM with GPLv3 binutils code.
 873 AC_ARG_WITH(binutils-include,
 874   AS_HELP_STRING([--with-binutils-include],
 875     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 876   withval=default)
 877 case "$withval" in
 878   default) WITH_BINUTILS_INCDIR=default ;;
 879   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 880   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 881 esac
 882 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 883   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 884   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 885      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 886      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 887   fi
 888 fi
 889
 890 dnl Specify the URL where bug reports should be submitted.
 891 AC_ARG_WITH(bug-report-url,
 892   AS_HELP_STRING([--with-bug-report-url],
 893     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 894     withval="http://llvm.org/bugs/")
 895 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 896                    [Bug report URL.])
 897
 898 dnl --enable-libffi : check whether the user wants to turn off libffi:
 899 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 900   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 901   [case "$enableval" in
 902     yes) llvm_cv_enable_libffi="yes" ;;
 903     no)  llvm_cv_enable_libffi="no"  ;;
 904     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 905   esac],
 906   llvm_cv_enable_libffi=no)
 907
 908 AC_ARG_WITH(internal-prefix,
 909   AS_HELP_STRING([--with-internal-prefix],
 910     [Installation directory for internal files]),,
 911     withval="")
 912 AC_SUBST(INTERNAL_PREFIX,[$withval])
 913
 914 dnl===-----------------------------------------------------------------------===
 915 dnl===
 916 dnl=== SECTION 4: Check for programs we need and that they are the right version
 917 dnl===
 918 dnl===-----------------------------------------------------------------------===
 919
 920 AC_PROG_NM
 921 AC_SUBST(NM)
 922
 923 dnl Check for the tools that the makefiles require
 924 AC_CHECK_GNU_MAKE
 925 AC_PROG_LN_S
 926 AC_PATH_PROG(CMP, [cmp], [cmp])
 927 AC_PATH_PROG(CP, [cp], [cp])
 928 AC_PATH_PROG(DATE, [date], [date])
 929 AC_PATH_PROG(FIND, [find], [find])
 930 AC_PATH_PROG(GREP, [grep], [grep])
 931 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 932 AC_PATH_PROG(MV,   [mv],   [mv])
 933 AC_PROG_RANLIB
 934 AC_CHECK_TOOL(AR, ar, false)
 935 AC_PATH_PROG(RM,   [rm],   [rm])
 936 AC_PATH_PROG(SED,  [sed],  [sed])
 937 AC_PATH_PROG(TAR,  [tar],  [gtar])
 938 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 939
 940 dnl Looking for misc. graph plotting software
 941 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 942 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 943   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 944   dnl If we're targeting for mingw we should emit windows paths, not msys
 945   if test "$llvm_cv_os_type" = "MingW" ; then
 946     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 947   fi
 948   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 949    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 950 fi
 951 AC_PATH_PROG(DOT, [dot], [echo dot])
 952 if test "$DOT" != "echo dot" ; then
 953   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 954   dnl If we're targeting for mingw we should emit windows paths, not msys
 955   if test "$llvm_cv_os_type" = "MingW" ; then
 956     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 957   fi
 958   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 959    [Define to path to dot program if found or 'echo dot' otherwise])
 960 fi
 961 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 962 if test "$FDP" != "echo fdp" ; then
 963   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 964   dnl If we're targeting for mingw we should emit windows paths, not msys
 965   if test "$llvm_cv_os_type" = "MingW" ; then
 966     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 967   fi
 968   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 969    [Define to path to fdp program if found or 'echo fdp' otherwise])
 970 fi
 971 AC_PATH_PROG(NEATO, [neato], [echo neato])
 972 if test "$NEATO" != "echo neato" ; then
 973   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 974   dnl If we're targeting for mingw we should emit windows paths, not msys
 975   if test "$llvm_cv_os_type" = "MingW" ; then
 976     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 977   fi
 978   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 979    [Define to path to neato program if found or 'echo neato' otherwise])
 980 fi
 981 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 982 if test "$TWOPI" != "echo twopi" ; then
 983   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 984   dnl If we're targeting for mingw we should emit windows paths, not msys
 985   if test "$llvm_cv_os_type" = "MingW" ; then
 986     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 987   fi
 988   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 989    [Define to path to twopi program if found or 'echo twopi' otherwise])
 990 fi
 991 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 992 if test "$CIRCO" != "echo circo" ; then
 993   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 994   dnl If we're targeting for mingw we should emit windows paths, not msys
 995   if test "$llvm_cv_os_type" = "MingW" ; then
 996     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 997   fi
 998   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 999    [Define to path to circo program if found or 'echo circo' otherwise])
1000 fi
1001 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1002 if test "$GV" != "echo gv" ; then
1003   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1004   dnl If we're targeting for mingw we should emit windows paths, not msys
1005   if test "$llvm_cv_os_type" = "MingW" ; then
1006     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1007   fi
1008   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1009    [Define to path to gv program if found or 'echo gv' otherwise])
1010 fi
1011 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1012 if test "$DOTTY" != "echo dotty" ; then
1013   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1014   dnl If we're targeting for mingw we should emit windows paths, not msys
1015   if test "$llvm_cv_os_type" = "MingW" ; then
1016     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1017   fi
1018   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1019    [Define to path to dotty program if found or 'echo dotty' otherwise])
1020 fi
1021 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1022 if test "$XDOT_PY" != "echo xdot.py" ; then
1023   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1024   dnl If we're targeting for mingw we should emit windows paths, not msys
1025   if test "$llvm_cv_os_type" = "MingW" ; then
1026     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1027   fi
1028   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1029    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1030 fi
1031
1032 dnl Find the install program
1033 AC_PROG_INSTALL
1034 dnl Prepend src dir to install path dir if it's a relative path
1035 dnl This is a hack for installs that take place in something other
1036 dnl than the top level.
1037 case "$INSTALL" in
1038  [[\\/$]]* | ?:[[\\/]]* ) ;;
1039  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1040 esac
1041
1042 dnl Checks for documentation and testing tools that we can do without. If these
1043 dnl are not found then they are set to "true" which always succeeds but does
1044 dnl nothing. This just lets the build output show that we could have done
1045 dnl something if the tool was available.
1046 AC_PATH_PROG(BZIP2, [bzip2])
1047 AC_PATH_PROG(CAT, [cat])
1048 AC_PATH_PROG(DOXYGEN, [doxygen])
1049 AC_PATH_PROG(GROFF, [groff])
1050 AC_PATH_PROG(GZIPBIN, [gzip])
1051 AC_PATH_PROG(PDFROFF, [pdfroff])
1052 AC_PATH_PROG(ZIP, [zip])
1053 AC_PATH_PROGS(OCAMLC, [ocamlc])
1054 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1055 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1056 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1057 AC_PATH_PROGS(GAS, [gas as])
1058
1059 dnl Get the version of the linker in use.
1060 AC_LINK_GET_VERSION
1061
1062 dnl Determine whether the linker supports the -R option.
1063 AC_LINK_USE_R
1064
1065 dnl Determine whether the linker supports the -export-dynamic option.
1066 AC_LINK_EXPORT_DYNAMIC
1067
1068 dnl Determine whether the linker supports the --version-script option.
1069 AC_LINK_VERSION_SCRIPT
1070
1071 dnl Check for libtool and the library that has dlopen function (which must come
1072 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1073 dnl libtool).
1074 AC_LIBTOOL_DLOPEN
1075 AC_LIB_LTDL
1076
1077 AC_MSG_CHECKING([tool compatibility])
1078
1079 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1080 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1081 dnl to support those options.
1082 dnl "icc" emits gcc signatures
1083 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1084 ICC=no
1085 IXX=no
1086 case $CC in
1087   icc*|icpc*)
1088     ICC=yes
1089     IXX=yes
1090     ;;
1091    *)
1092     ;;
1093 esac
1094
1095 if test "$GCC" != "yes" && test "$ICC" != "yes"
1096 then
1097   AC_MSG_ERROR([gcc|icc required but not found])
1098 fi
1099
1100 dnl Ensure that compilation tools are compatible with GCC extensions
1101 if test "$GXX" != "yes" && test "$IXX" != "yes"
1102 then
1103   AC_MSG_ERROR([g++|clang++|icc required but not found])
1104 fi
1105
1106 dnl Verify that GCC is version 3.0 or higher
1107 if test "$GCC" = "yes"
1108 then
1109   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1110 #error Unsupported GCC version
1111 #endif
1112 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1113 fi
1114
1115 dnl Check for GNU Make.  We use its extensions, so don't build without it
1116 if test -z "$llvm_cv_gnu_make_command"
1117 then
1118   AC_MSG_ERROR([GNU Make required but not found])
1119 fi
1120
1121 dnl Tool compatibility is okay if we make it here.
1122 AC_MSG_RESULT([ok])
1123
1124 dnl Check optional compiler flags.
1125 AC_MSG_CHECKING([optional compiler flags])
1126 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1127 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1128 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1129 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1130
1131 dnl===-----------------------------------------------------------------------===
1132 dnl===
1133 dnl=== SECTION 5: Check for libraries
1134 dnl===
1135 dnl===-----------------------------------------------------------------------===
1136
1137 AC_CHECK_LIB(m,sin)
1138 if test "$llvm_cv_os_type" = "MingW" ; then
1139   AC_CHECK_LIB(imagehlp, main)
1140   AC_CHECK_LIB(psapi, main)
1141 fi
1142
1143 dnl dlopen() is required for plugin support.
1144 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1145                [Define if dlopen() is available on this platform.]),
1146                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1147
1148 dnl libffi is optional; used to call external functions from the interpreter
1149 if test "$llvm_cv_enable_libffi" = "yes" ; then
1150   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1151                  [Define if libffi is available on this platform.]),
1152                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1153 fi
1154
1155 dnl mallinfo is optional; the code can compile (minus features) without it
1156 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1157                [Define if mallinfo() is available on this platform.]))
1158
1159 dnl pthread locking functions are optional - but llvm will not be thread-safe
1160 dnl without locks.
1161 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1162   AC_CHECK_LIB(pthread, pthread_mutex_init)
1163   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1164                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1165                            [Have pthread_mutex_lock]))
1166   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1167                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1168                  [Have pthread_rwlock_init]))
1169   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1170                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1171                  [Have pthread_getspecific]))
1172 fi
1173
1174 dnl Allow extra x86-disassembler library
1175 AC_ARG_WITH(udis86,
1176   AS_HELP_STRING([--with-udis86=<path>],
1177     [Use udis86 external x86 disassembler library]),
1178     [
1179       AC_SUBST(USE_UDIS86, [1])
1180       case "$withval" in
1181         /usr/lib|yes) ;;
1182         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1183       esac
1184       AC_CHECK_LIB(udis86, ud_init, [], [
1185         echo "Error! You need to have libudis86 around."
1186         exit -1
1187       ])
1188     ],
1189     AC_SUBST(USE_UDIS86, [0]))
1190 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1191                    [Define if use udis86 library])
1192
1193 dnl Allow OProfile support for JIT output.
1194 AC_ARG_WITH(oprofile,
1195   AS_HELP_STRING([--with-oprofile=<prefix>],
1196     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1197     [
1198       AC_SUBST(USE_OPROFILE, [1])
1199       case "$withval" in
1200         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1201         no) llvm_cv_oppath=
1202             AC_SUBST(USE_OPROFILE, [0]) ;;
1203         *) llvm_cv_oppath="${withval}/lib/oprofile"
1204            CPPFLAGS="-I${withval}/include";;
1205       esac
1206       case $llvm_cv_os_type in
1207         Linux)
1208           if test -n "$llvm_cv_oppath" ; then
1209             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1210             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1211             dnl libbfd is not included properly in libopagent in some Debian
1212             dnl versions.  If libbfd isn't found at all, we assume opagent works
1213             dnl anyway.
1214             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1215             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1216               echo "Error! You need to have libopagent around."
1217               exit -1
1218             ])
1219             AC_CHECK_HEADER([opagent.h], [], [
1220               echo "Error! You need to have opagent.h around."
1221               exit -1
1222               ])
1223           fi ;;
1224         *)
1225           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1226       esac
1227     ],
1228     [
1229       AC_SUBST(USE_OPROFILE, [0])
1230     ])
1231 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1232                    [Define if we have the oprofile JIT-support library])
1233
1234 dnl Enable support for Intel JIT Events API.
1235 AC_ARG_WITH(intel-jitevents,
1236   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1237     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1238     [
1239       case $llvm_cv_os_type in
1240         Linux|Win32|Cygwin|MingW) ;;
1241         *)
1242           AC_MSG_ERROR([
1243             Intel JIT API support is available on Linux and Windows only."]) ;;
1244       esac
1245
1246       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1247       case "$llvm_cv_target_arch" in
1248         x86)    llvm_intel_jitevents_archdir="lib32";;
1249         x86_64) llvm_intel_jitevents_archdir="lib64";;
1250         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1251                 exit -1;;
1252       esac
1253       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1254       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1255       case "$withval" in
1256         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1257                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1258         *) ;;
1259       esac
1260
1261       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1262       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1263
1264       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1265       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1266
1267       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1268         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1269         exit -1
1270       ])
1271       AC_CHECK_HEADER([jitprofiling.h], [], [
1272         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1273         exit -1
1274       ])
1275
1276     ],
1277     [
1278       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1279     ])
1280 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1281                    [Define if we have the Intel JIT API runtime support library])
1282
1283 dnl===-----------------------------------------------------------------------===
1284 dnl===
1285 dnl=== SECTION 6: Check for header files
1286 dnl===
1287 dnl===-----------------------------------------------------------------------===
1288
1289 dnl First, use autoconf provided macros for specific headers that we need
1290 dnl We don't check for ancient stuff or things that are guaranteed to be there
1291 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1292 dnl Generally we're looking for POSIX headers.
1293 AC_HEADER_DIRENT
1294 AC_HEADER_MMAP_ANONYMOUS
1295 AC_HEADER_STAT
1296 AC_HEADER_SYS_WAIT
1297 AC_HEADER_TIME
1298
1299 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1300 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1301 AC_CHECK_HEADERS([utime.h windows.h])
1302 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1303 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1304 AC_CHECK_HEADERS([valgrind/valgrind.h])
1305 AC_CHECK_HEADERS([fenv.h])
1306 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1307   AC_CHECK_HEADERS(pthread.h,
1308                    AC_SUBST(HAVE_PTHREAD, 1),
1309                    AC_SUBST(HAVE_PTHREAD, 0))
1310 else
1311   AC_SUBST(HAVE_PTHREAD, 0)
1312 fi
1313
1314 dnl Try to find ffi.h.
1315 if test "$llvm_cv_enable_libffi" = "yes" ; then
1316   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1317 fi
1318
1319 dnl Try to find Darwin specific crash reporting libraries.
1320 AC_CHECK_HEADERS([CrashReporterClient.h])
1321
1322 dnl Try to find Darwin specific crash reporting global.
1323 AC_MSG_CHECKING([__crashreporter_info__])
1324 AC_LINK_IFELSE(
1325   AC_LANG_SOURCE(
1326     [[extern const char *__crashreporter_info__;
1327       int main() {
1328         __crashreporter_info__ = "test";
1329         return 0;
1330       }
1331     ]]),
1332   AC_MSG_RESULT(yes)
1333   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1334   AC_MSG_RESULT(no)
1335   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1336             Define if __crashreporter_info__ exists.))
1337
1338 dnl===-----------------------------------------------------------------------===
1339 dnl===
1340 dnl=== SECTION 7: Check for types and structures
1341 dnl===
1342 dnl===-----------------------------------------------------------------------===
1343
1344 AC_HUGE_VAL_CHECK
1345 AC_TYPE_PID_T
1346 AC_TYPE_SIZE_T
1347 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1348 AC_STRUCT_TM
1349 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1350 AC_CHECK_TYPES([uint64_t],,
1351          AC_CHECK_TYPES([u_int64_t],,
1352          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1353
1354 dnl===-----------------------------------------------------------------------===
1355 dnl===
1356 dnl=== SECTION 8: Check for specific functions needed
1357 dnl===
1358 dnl===-----------------------------------------------------------------------===
1359
1360 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1361 AC_CHECK_FUNCS([powf fmodf strtof round ])
1362 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1363 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1364 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1365 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1366 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1367 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1368 AC_C_PRINTF_A
1369 AC_FUNC_RAND48
1370
1371 dnl Check the declaration "Secure API" on Windows environments.
1372 AC_CHECK_DECLS([strerror_s])
1373
1374 dnl Check symbols in libgcc.a for JIT on Mingw.
1375 if test "$llvm_cv_os_type" = "MingW" ; then
1376   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1377   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1378   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1379   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1380
1381   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1382   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1383   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1384   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1385   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1386   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1387   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1388   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1389   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1390   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1391
1392   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1393   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1394 fi
1395
1396 dnl Check Win32 API EnumerateLoadedModules.
1397 if test "$llvm_cv_os_type" = "MingW" ; then
1398   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1399   AC_COMPILE_IFELSE([[#include <windows.h>
1400 #include <imagehlp.h>
1401 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1402 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1403 [
1404   AC_MSG_RESULT([yes])
1405   llvm_cv_win32_elmcb_pcstr="PCSTR"
1406 ],
1407 [
1408   AC_MSG_RESULT([no])
1409   llvm_cv_win32_elmcb_pcstr="PSTR"
1410 ])
1411   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1412 fi
1413
1414 dnl Check for variations in the Standard C++ library and STL. These macros are
1415 dnl provided by LLVM in the autoconf/m4 directory.
1416 AC_FUNC_ISNAN
1417 AC_FUNC_ISINF
1418
1419 dnl Check for mmap support.We also need to know if /dev/zero is required to
1420 dnl be opened for allocating RWX memory.
1421 dnl Make sure we aren't attempting to configure for an unknown system
1422 if test "$llvm_cv_platform_type" = "Unix" ; then
1423   AC_FUNC_MMAP
1424   AC_FUNC_MMAP_FILE
1425   AC_NEED_DEV_ZERO_FOR_MMAP
1426
1427   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1428   then
1429     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1430   fi
1431   if test "$ac_cv_func_mmap_file" = "no"
1432   then
1433     AC_MSG_WARN([mmap() of files required but not found])
1434   fi
1435 fi
1436
1437 dnl atomic builtins are required for threading support.
1438 AC_MSG_CHECKING(for GCC atomic builtins)
1439 dnl Since we'll be using these atomic builtins in C++ files we should test
1440 dnl the C++ compiler.
1441 AC_LANG_PUSH([C++])
1442 AC_LINK_IFELSE(
1443   AC_LANG_SOURCE(
1444     [[int main() {
1445         volatile unsigned long val = 1;
1446         __sync_synchronize();
1447         __sync_val_compare_and_swap(&val, 1, 0);
1448         __sync_add_and_fetch(&val, 1);
1449         __sync_sub_and_fetch(&val, 1);
1450         return 0;
1451       }
1452     ]]),
1453   AC_LANG_POP([C++])
1454   AC_MSG_RESULT(yes)
1455   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1456   AC_MSG_RESULT(no)
1457   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1458   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1459
1460 dnl===-----------------------------------------------------------------------===
1461 dnl===
1462 dnl=== SECTION 9: Additional checks, variables, etc.
1463 dnl===
1464 dnl===-----------------------------------------------------------------------===
1465
1466 dnl Handle 32-bit linux systems running a 64-bit kernel.
1467 dnl This has to come after section 4 because it invokes the compiler.
1468 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1469   AC_IS_LINUX_MIXED
1470   if test "$llvm_cv_linux_mixed" = "yes"; then
1471     llvm_cv_target_arch="x86"
1472     ARCH="x86"
1473   fi
1474 fi
1475
1476 dnl Check whether __dso_handle is present
1477 AC_CHECK_FUNCS([__dso_handle])
1478
1479 dnl Propagate the shared library extension that the libltdl checks did to
1480 dnl the Makefiles so we can use it there too
1481 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1482
1483 dnl Propagate the run-time library path variable that the libltdl
1484 dnl checks found to the Makefiles so we can use it there too
1485 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1486
1487 dnl Translate the various configuration directories and other basic
1488 dnl information into substitutions that will end up in Makefile.config.in
1489 dnl that these configured values can be used by the makefiles
1490 if test "${prefix}" = "NONE" ; then
1491   prefix="/usr/local"
1492 fi
1493 eval LLVM_PREFIX="${prefix}";
1494 eval LLVM_BINDIR="${prefix}/bin";
1495 eval LLVM_LIBDIR="${prefix}/lib";
1496 eval LLVM_DATADIR="${prefix}/share/llvm";
1497 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1498 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1499 eval LLVM_INCLUDEDIR="${prefix}/include";
1500 eval LLVM_INFODIR="${prefix}/info";
1501 eval LLVM_MANDIR="${prefix}/man";
1502 LLVM_CONFIGTIME=`date`
1503 AC_SUBST(LLVM_PREFIX)
1504 AC_SUBST(LLVM_BINDIR)
1505 AC_SUBST(LLVM_LIBDIR)
1506 AC_SUBST(LLVM_DATADIR)
1507 AC_SUBST(LLVM_DOCSDIR)
1508 AC_SUBST(LLVM_ETCDIR)
1509 AC_SUBST(LLVM_INCLUDEDIR)
1510 AC_SUBST(LLVM_INFODIR)
1511 AC_SUBST(LLVM_MANDIR)
1512 AC_SUBST(LLVM_CONFIGTIME)
1513
1514 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1515 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1516   LLVM_CONFIGTIME="(timestamp not enabled)"
1517 fi
1518
1519 dnl Place the various directories into the config.h file as #defines so that we
1520 dnl can know about the installation paths within LLVM.
1521 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1522                    [Installation prefix directory])
1523 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1524                    [Installation directory for binary executables])
1525 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1526                    [Installation directory for libraries])
1527 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1528                    [Installation directory for data files])
1529 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1530                    [Installation directory for documentation])
1531 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1532                    [Installation directory for config files])
1533 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1534                    [Installation directory for include files])
1535 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1536                    [Installation directory for .info files])
1537 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1538                    [Installation directory for man pages])
1539 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1540                    [Time at which LLVM was configured])
1541 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1542                    [Host triple LLVM will be executed on])
1543 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1544                    [Target triple LLVM will generate code for by default])
1545
1546 dnl Determine which bindings to build.
1547 if test "$BINDINGS_TO_BUILD" = auto ; then
1548   BINDINGS_TO_BUILD=""
1549   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1550     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1551   fi
1552 fi
1553 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1554
1555 dnl This isn't really configurey, but it avoids having to repeat the list in
1556 dnl other files.
1557 AC_SUBST(ALL_BINDINGS,ocaml)
1558
1559 dnl Do any work necessary to ensure that bindings have what they need.
1560 binding_prereqs_failed=0
1561 for a_binding in $BINDINGS_TO_BUILD ; do
1562   case "$a_binding" in
1563   ocaml)
1564     if test "x$OCAMLC" = x ; then
1565       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1566       binding_prereqs_failed=1
1567     fi
1568     if test "x$OCAMLDEP" = x ; then
1569       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1570       binding_prereqs_failed=1
1571     fi
1572     if test "x$OCAMLOPT" = x ; then
1573       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1574       dnl ocamlopt is optional!
1575     fi
1576     if test "x$with_ocaml_libdir" != xauto ; then
1577       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1578     else
1579       ocaml_stdlib="`"$OCAMLC" -where`"
1580       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1581       then
1582         # ocaml stdlib is beneath our prefix; use stdlib
1583         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1584       else
1585         # ocaml stdlib is outside our prefix; use libdir/ocaml
1586         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1587       fi
1588     fi
1589     ;;
1590   esac
1591 done
1592 if test "$binding_prereqs_failed" = 1 ; then
1593   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1594 fi
1595
1596 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1597 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1598
1599 dnl Determine linker rpath flag
1600 if test "$llvm_cv_link_use_r" = "yes" ; then
1601   RPATH="-Wl,-R"
1602 else
1603   RPATH="-Wl,-rpath"
1604 fi
1605 AC_SUBST(RPATH)
1606
1607 dnl Determine linker rdynamic flag
1608 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1609   RDYNAMIC="-Wl,-export-dynamic"
1610 else
1611   RDYNAMIC=""
1612 fi
1613 AC_SUBST(RDYNAMIC)
1614
1615 dnl===-----------------------------------------------------------------------===
1616 dnl===
1617 dnl=== SECTION 10: Specify the output files and generate it
1618 dnl===
1619 dnl===-----------------------------------------------------------------------===
1620
1621 dnl Configure header files
1622 dnl WARNING: dnl If you add or remove any of the following config headers, then
1623 dnl you MUST also update Makefile so that the variable FilesToConfig
1624 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1625 dnl files can be updated automatically when their *.in sources change.
1626 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1627 AH_TOP([#ifndef CONFIG_H
1628 #define CONFIG_H])
1629 AH_BOTTOM([#endif])
1630
1631 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1632 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1633 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1634 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1635 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1636
1637 dnl Configure the makefile's configuration data
1638 AC_CONFIG_FILES([Makefile.config])
1639
1640 dnl Configure the RPM spec file for LLVM
1641 AC_CONFIG_FILES([llvm.spec])
1642
1643 dnl Configure doxygen's configuration file
1644 AC_CONFIG_FILES([docs/doxygen.cfg])
1645
1646 dnl Configure clang, if present
1647 if test "${clang_src_root}" = ""; then
1648   clang_src_root="$srcdir/tools/clang"
1649 fi
1650 if test -f ${clang_src_root}/README.txt; then
1651   dnl Use variables to stay under 80 columns.
1652   configh="include/clang/Config/config.h"
1653   doxy="docs/doxygen.cfg"
1654   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1655   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1656 fi
1657
1658 dnl OCaml findlib META file
1659 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1660
1661 dnl Do special configuration of Makefiles
1662 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1663 AC_CONFIG_MAKEFILE(Makefile)
1664 AC_CONFIG_MAKEFILE(Makefile.common)
1665 AC_CONFIG_MAKEFILE(examples/Makefile)
1666 AC_CONFIG_MAKEFILE(lib/Makefile)
1667 AC_CONFIG_MAKEFILE(runtime/Makefile)
1668 AC_CONFIG_MAKEFILE(test/Makefile)
1669 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1670 AC_CONFIG_MAKEFILE(unittests/Makefile)
1671 AC_CONFIG_MAKEFILE(tools/Makefile)
1672 AC_CONFIG_MAKEFILE(utils/Makefile)
1673 AC_CONFIG_MAKEFILE(projects/Makefile)
1674 AC_CONFIG_MAKEFILE(bindings/Makefile)
1675 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1676
1677 dnl Finally, crank out the output
1678 AC_OUTPUT