autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.4svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [4], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd* | *-*-kfreebsd-gnu)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-openbsd*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="OpenBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-netbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="NetBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-dragonfly*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="DragonFly"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-hpux*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="HP-UX"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-interix*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="Interix"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-linux*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Linux"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-gnu*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="GNU"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-solaris*)
 266     llvm_cv_link_all_option="-Wl,-z,allextract"
 267     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 268     llvm_cv_os_type="SunOS"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-auroraux*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="AuroraUX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-win32*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Win32"
 279     llvm_cv_platform_type="Win32" ;;
 280   *-*-mingw*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="MingW"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-haiku*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Haiku"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-unknown-eabi*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Freestanding"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-elf*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *)
 301     llvm_cv_link_all_option=""
 302     llvm_cv_no_link_all_option=""
 303     llvm_cv_os_type="Unknown"
 304     llvm_cv_platform_type="Unknown" ;;
 305 esac])
 306
 307 AC_CACHE_CHECK([type of operating system we're going to target],
 308                [llvm_cv_target_os_type],
 309 [case $target in
 310   *-*-aix*)
 311     llvm_cv_target_os_type="AIX" ;;
 312   *-*-irix*)
 313     llvm_cv_target_os_type="IRIX" ;;
 314   *-*-cygwin*)
 315     llvm_cv_target_os_type="Cygwin" ;;
 316   *-*-darwin*)
 317     llvm_cv_target_os_type="Darwin" ;;
 318   *-*-minix*)
 319     llvm_cv_target_os_type="Minix" ;;
 320   *-*-freebsd* | *-*-kfreebsd-gnu)
 321     llvm_cv_target_os_type="FreeBSD" ;;
 322   *-*-openbsd*)
 323     llvm_cv_target_os_type="OpenBSD" ;;
 324   *-*-netbsd*)
 325     llvm_cv_target_os_type="NetBSD" ;;
 326   *-*-dragonfly*)
 327     llvm_cv_target_os_type="DragonFly" ;;
 328   *-*-hpux*)
 329     llvm_cv_target_os_type="HP-UX" ;;
 330   *-*-interix*)
 331     llvm_cv_target_os_type="Interix" ;;
 332   *-*-linux*)
 333     llvm_cv_target_os_type="Linux" ;;
 334   *-*-gnu*)
 335     llvm_cv_target_os_type="GNU" ;;
 336   *-*-solaris*)
 337     llvm_cv_target_os_type="SunOS" ;;
 338   *-*-auroraux*)
 339     llvm_cv_target_os_type="AuroraUX" ;;
 340   *-*-win32*)
 341     llvm_cv_target_os_type="Win32" ;;
 342   *-*-mingw*)
 343     llvm_cv_target_os_type="MingW" ;;
 344   *-*-haiku*)
 345     llvm_cv_target_os_type="Haiku" ;;
 346   *-*-rtems*)
 347     llvm_cv_target_os_type="RTEMS" ;;
 348   *-*-nacl*)
 349     llvm_cv_target_os_type="NativeClient" ;;
 350   *-unknown-eabi*)
 351     llvm_cv_target_os_type="Freestanding" ;;
 352   *)
 353     llvm_cv_target_os_type="Unknown" ;;
 354 esac])
 355
 356 dnl Make sure we aren't attempting to configure for an unknown system
 357 if test "$llvm_cv_os_type" = "Unknown" ; then
 358   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 359 fi
 360
 361 dnl Set the "OS" Makefile variable based on the platform type so the
 362 dnl makefile can configure itself to specific build hosts
 363 AC_SUBST(OS,$llvm_cv_os_type)
 364 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 365 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 366
 367 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 368 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 369 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 370
 371 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 372 dnl This is used by lib/Support to determine the basic kind of implementation
 373 dnl to use.
 374 case $llvm_cv_platform_type in
 375   Unix)
 376     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 377     AC_SUBST(LLVM_ON_UNIX,[1])
 378     AC_SUBST(LLVM_ON_WIN32,[0])
 379     ;;
 380   Win32)
 381     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 382     AC_SUBST(LLVM_ON_UNIX,[0])
 383     AC_SUBST(LLVM_ON_WIN32,[1])
 384     ;;
 385 esac
 386
 387 dnl Determine what our target architecture is and configure accordingly.
 388 dnl This will allow Makefiles to make a distinction between the hardware and
 389 dnl the OS.
 390 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 391 [case $target in
 392   i?86-*)                 llvm_cv_target_arch="x86" ;;
 393   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 394   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 395   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 396   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 397   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 398   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 399   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 400   xcore-*)                llvm_cv_target_arch="XCore" ;;
 401   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 402   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 403   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 404   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 405   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 406   *)                      llvm_cv_target_arch="Unknown" ;;
 407 esac])
 408
 409 if test "$llvm_cv_target_arch" = "Unknown" ; then
 410   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 411 fi
 412
 413 dnl Determine the LLVM native architecture for the target
 414 case "$llvm_cv_target_arch" in
 415     x86)     LLVM_NATIVE_ARCH="X86" ;;
 416     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 417     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 418 esac
 419
 420 dnl Define a substitution, ARCH, for the target architecture
 421 AC_SUBST(ARCH,$llvm_cv_target_arch)
 422
 423 dnl Determine what our host architecture.
 424 dnl This will allow MCJIT regress tests runs only for supported
 425 dnl platforms.
 426 case $host in
 427   i?86-*)                 host_arch="x86" ;;
 428   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 429   sparc*-*)               host_arch="Sparc" ;;
 430   powerpc*-*)             host_arch="PowerPC" ;;
 431   arm*-*)                 host_arch="ARM" ;;
 432   aarch64*-*)             host_arch="AArch64" ;;
 433   mips-* | mips64-*)      host_arch="Mips" ;;
 434   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 435   xcore-*)                host_arch="XCore" ;;
 436   msp430-*)               host_arch="MSP430" ;;
 437   hexagon-*)              host_arch="Hexagon" ;;
 438   mblaze-*)               host_arch="MBlaze" ;;
 439   s390x-*)                host_arch="SystemZ" ;;
 440   *)                      host_arch="Unknown" ;;
 441 esac
 442
 443 if test "$host_arch" = "Unknown" ; then
 444   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 445 fi
 446
 447 AC_SUBST(HOST_ARCH,$host_arch)
 448
 449 dnl Check for the endianness of the target
 450 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 451
 452 dnl Check for build platform executable suffix if we're cross-compiling
 453 if test "$cross_compiling" = yes; then
 454   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 455   AC_BUILD_EXEEXT
 456   ac_build_prefix=${build_alias}-
 457   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 458   if test -z "$BUILD_CXX"; then
 459      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 460      if test -z "$BUILD_CXX"; then
 461        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 462      fi
 463   fi
 464 else
 465   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 466 fi
 467
 468 dnl Check to see if there's a .svn or .git directory indicating that this
 469 dnl build is being done from a checkout. This sets up several defaults for
 470 dnl the command line switches. When we build with a checkout directory,
 471 dnl we get a debug with assertions turned on. Without, we assume a source
 472 dnl release and we get an optimized build without assertions.
 473 dnl See --enable-optimized and --enable-assertions below
 474 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 475   cvsbuild="yes"
 476   optimize="no"
 477   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 478 else
 479   cvsbuild="no"
 480   optimize="yes"
 481 fi
 482
 483 dnl===-----------------------------------------------------------------------===
 484 dnl===
 485 dnl=== SECTION 3: Command line arguments for the configure script.
 486 dnl===
 487 dnl===-----------------------------------------------------------------------===
 488
 489 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 490 AC_ARG_ENABLE(libcpp,
 491               AS_HELP_STRING([--enable-libcpp],
 492                              [Use libc++ if available (default is NO)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 496   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 497   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 499 esac
 500
 501 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 502 AC_ARG_ENABLE(cxx11,
 503               AS_HELP_STRING([--enable-cxx11],
 504                              [Use c++11 if available (default is NO)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 508   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 509   default) AC_SUBST(ENABLE_CXX11,[0]);;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 514 clang_arcmt="yes"
 515 AC_ARG_ENABLE(clang-arcmt,
 516               AS_HELP_STRING([--enable-clang-arcmt],
 517                              [Enable building of clang ARCMT (default is YES)]),
 518                              clang_arcmt="$enableval",
 519                              enableval="yes")
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 522   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 523   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 528 clang_static_analyzer="yes"
 529 AC_ARG_ENABLE(clang-static-analyzer,
 530               AS_HELP_STRING([--enable-clang-static-analyzer],
 531                              [Enable building of clang Static Analyzer (default is YES)]),
 532                              clang_static_analyzer="$enableval",
 533                              enableval="yes")
 534 case "$enableval" in
 535   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 536   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 537   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 538   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 539 esac
 540
 541 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 542 AC_ARG_ENABLE(clang-rewriter,
 543               AS_HELP_STRING([--enable-clang-rewriter],
 544                              [Enable building of clang rewriter (default is YES)]),,
 545                              enableval="yes")
 546 case "$enableval" in
 547   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 548   no)
 549     if test ${clang_arcmt} != "no" ; then
 550       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 551     fi
 552     if test ${clang_static_analyzer} != "no" ; then
 553       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 554     fi
 555     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 556     ;;
 557   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 558   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 559 esac
 560
 561 dnl --enable-optimized : check whether they want to do an optimized build:
 562 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 563  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 564 if test ${enableval} = "no" ; then
 565   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 566 else
 567   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 568 fi
 569
 570 dnl --enable-profiling : check whether they want to do a profile build:
 571 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 572  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 573 if test ${enableval} = "no" ; then
 574   AC_SUBST(ENABLE_PROFILING,[[]])
 575 else
 576   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 577 fi
 578
 579 dnl --enable-assertions : check whether they want to turn on assertions or not:
 580 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 581   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 582 if test ${enableval} = "yes" ; then
 583   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 584 else
 585   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 586 fi
 587
 588 dnl --enable-werror : check whether we want Werror on by default
 589 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 590   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 593   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 594   default) AC_SUBST(ENABLE_WERROR,[0]);;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 599 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 600   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 601 if test ${enableval} = "yes" ; then
 602   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 603   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 604 else
 605   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 606   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 607 fi
 608
 609 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 610 AC_ARG_ENABLE(debug-runtime,
 611    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 612 if test ${enableval} = "no" ; then
 613   AC_SUBST(DEBUG_RUNTIME,[[]])
 614 else
 615   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 616 fi
 617
 618 dnl --enable-debug-symbols : should even optimized compiler libraries
 619 dnl have debug symbols?
 620 AC_ARG_ENABLE(debug-symbols,
 621    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 622 if test ${enableval} = "no" ; then
 623   AC_SUBST(DEBUG_SYMBOLS,[[]])
 624 else
 625   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 626 fi
 627
 628 dnl --enable-keep-symbols : do not strip installed executables
 629 AC_ARG_ENABLE(keep-symbols,
 630    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 631 if test ${enableval} = "no" ; then
 632   AC_SUBST(KEEP_SYMBOLS,[[]])
 633 else
 634   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 635 fi
 636
 637 dnl --enable-jit: check whether they want to enable the jit
 638 AC_ARG_ENABLE(jit,
 639   AS_HELP_STRING(--enable-jit,
 640                  [Enable Just In Time Compiling (default is YES)]),,
 641   enableval=default)
 642 if test ${enableval} = "no"
 643 then
 644   AC_SUBST(JIT,[[]])
 645 else
 646   case "$llvm_cv_target_arch" in
 647     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 648     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 649     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 650     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 651     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 652     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 653     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 654     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 655     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 656     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 657     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 658     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 659     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 660     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 661   esac
 662 fi
 663
 664 dnl Allow enablement of building and installing docs
 665 AC_ARG_ENABLE(docs,
 666               AS_HELP_STRING([--enable-docs],
 667                              [Build documents (default is YES)]),,
 668                              enableval=default)
 669 case "$enableval" in
 670   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 671   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 672   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 673   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 674 esac
 675
 676 dnl Allow enablement of doxygen generated documentation
 677 AC_ARG_ENABLE(doxygen,
 678               AS_HELP_STRING([--enable-doxygen],
 679                              [Build doxygen documentation (default is NO)]),,
 680                              enableval=default)
 681 case "$enableval" in
 682   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 683   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 684   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 685   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 686 esac
 687
 688 dnl Allow disablement of threads
 689 AC_ARG_ENABLE(threads,
 690               AS_HELP_STRING([--enable-threads],
 691                              [Use threads if available (default is YES)]),,
 692                              enableval=default)
 693 case "$enableval" in
 694   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 695   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 696   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 697   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 698 esac
 699 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 700                    [Define if threads enabled])
 701
 702 dnl Allow disablement of pthread.h
 703 AC_ARG_ENABLE(pthreads,
 704               AS_HELP_STRING([--enable-pthreads],
 705                              [Use pthreads if available (default is YES)]),,
 706                              enableval=default)
 707 case "$enableval" in
 708   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 709   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 710   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 711   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 712 esac
 713
 714 dnl Allow disablement of zlib
 715 AC_ARG_ENABLE(zlib,
 716               AS_HELP_STRING([--enable-zlib],
 717                              [Use zlib for compression/decompression if
 718                               available (default is YES)]),,
 719                               enableval=default)
 720 case "$enableval" in
 721   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 722   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 723   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 724   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 725 esac
 726 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 727                    [Define if zlib is enabled])
 728
 729 dnl Allow building without position independent code
 730 AC_ARG_ENABLE(pic,
 731   AS_HELP_STRING([--enable-pic],
 732                  [Build LLVM with Position Independent Code (default is YES)]),,
 733                  enableval=default)
 734 case "$enableval" in
 735   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 736   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 737   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 738   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 739 esac
 740 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 741                    [Define if position independent code is enabled])
 742
 743 dnl Allow building a shared library and linking tools against it.
 744 AC_ARG_ENABLE(shared,
 745   AS_HELP_STRING([--enable-shared],
 746                  [Build a shared library and link tools against it (default is NO)]),,
 747                  enableval=default)
 748 case "$enableval" in
 749   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 750   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 751   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 752   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 753 esac
 754
 755 dnl Allow libstdc++ is embedded in LLVM.dll.
 756 AC_ARG_ENABLE(embed-stdcxx,
 757   AS_HELP_STRING([--enable-embed-stdcxx],
 758                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 759                  enableval=default)
 760 case "$enableval" in
 761   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 762   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 763   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 764   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 765 esac
 766
 767 dnl Enable embedding timestamp information into build.
 768 AC_ARG_ENABLE(timestamps,
 769   AS_HELP_STRING([--enable-timestamps],
 770                  [Enable embedding timestamp information in build (default is YES)]),,
 771                  enableval=default)
 772 case "$enableval" in
 773   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 774   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 775   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 776   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 777 esac
 778 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 779                    [Define if timestamp information (e.g., __DATE__) is allowed])
 780
 781 dnl Enable embedding timestamp information into build.
 782
 783 AC_ARG_ENABLE(backtraces,
 784   AS_HELP_STRING([--enable-backtraces],
 785                  [Enable embedding backtraces on crash (default is YES)]),,
 786                  enableval=default)
 787 case "$enableval" in
 788   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 789   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 790   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 791   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 792 esac
 793 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 794                    [Define if you want backtraces on crash])
 795
 796 dnl Allow specific targets to be specified for building (or not)
 797 TARGETS_TO_BUILD=""
 798 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 799     [Build specific host targets: all or target1,target2,... Valid targets are:
 800      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 801      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 802     enableval=all)
 803 if test "$enableval" = host-only ; then
 804   enableval=host
 805 fi
 806 case "$enableval" in
 807   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend MBlaze NVPTX Hexagon SystemZ R600" ;;
 808   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 809       case "$a_target" in
 810         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 811         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 812         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 813         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 814         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 815         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 816         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 817         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 818         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 819         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 820         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 821         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 822         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 823         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 824         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 825         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 826         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 827         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 828         host) case "$llvm_cv_target_arch" in
 829             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 830             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 831             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 832             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 833             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 834             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 835             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 836             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 837             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 838             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 839             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 840             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 841             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 842             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 843           esac ;;
 844         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 845       esac
 846   done
 847   ;;
 848 esac
 849
 850 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 851     [Build experimental host targets: disable or target1,target2,...
 852      (default=disable)]),,
 853     enableval=disable)
 854
 855 if test ${enableval} != "disable"
 856 then
 857   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 858 fi
 859
 860 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 861
 862 dnl Determine whether we are building LLVM support for the native architecture.
 863 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 864 for a_target in $TARGETS_TO_BUILD; do
 865   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 866     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 867       [LLVM architecture name for the native architecture, if available])
 868     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 869     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 870     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 871     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 872     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 873       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 874     fi
 875     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 876       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 877     fi
 878     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 879       [LLVM name for the native Target init function, if available])
 880     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 881       [LLVM name for the native TargetInfo init function, if available])
 882     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 883       [LLVM name for the native target MC init function, if available])
 884     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 885       [LLVM name for the native AsmPrinter init function, if available])
 886     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 887       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 888        [LLVM name for the native AsmParser init function, if available])
 889     fi
 890     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 891       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 892        [LLVM name for the native Disassembler init function, if available])
 893     fi
 894   fi
 895 done
 896
 897 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 898 dnl target feature def files.
 899 LLVM_ENUM_TARGETS=""
 900 LLVM_ENUM_ASM_PRINTERS=""
 901 LLVM_ENUM_ASM_PARSERS=""
 902 LLVM_ENUM_DISASSEMBLERS=""
 903 for target_to_build in $TARGETS_TO_BUILD; do
 904   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 905   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 906     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 907   fi
 908   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 909     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 910   fi
 911   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 912     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 913   fi
 914 done
 915 AC_SUBST(LLVM_ENUM_TARGETS)
 916 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 917 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 918 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 919
 920 dnl Override the option to use for optimized builds.
 921 AC_ARG_WITH(optimize-option,
 922   AS_HELP_STRING([--with-optimize-option],
 923                  [Select the compiler options to use for optimized builds]),,
 924                  withval=default)
 925 AC_MSG_CHECKING([optimization flags])
 926 case "$withval" in
 927   default)
 928     case "$llvm_cv_os_type" in
 929     FreeBSD) optimize_option=-O2 ;;
 930     MingW) optimize_option=-O2 ;;
 931     *)     optimize_option=-O3 ;;
 932     esac ;;
 933   *) optimize_option="$withval" ;;
 934 esac
 935 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 936 AC_MSG_RESULT([$optimize_option])
 937
 938 dnl Specify extra build options
 939 AC_ARG_WITH(extra-options,
 940   AS_HELP_STRING([--with-extra-options],
 941                  [Specify additional options to compile LLVM with]),,
 942                  withval=default)
 943 case "$withval" in
 944   default) EXTRA_OPTIONS= ;;
 945   *) EXTRA_OPTIONS=$withval ;;
 946 esac
 947 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 948
 949 dnl Specify extra linker build options
 950 AC_ARG_WITH(extra-ld-options,
 951   AS_HELP_STRING([--with-extra-ld-options],
 952                  [Specify additional options to link LLVM with]),,
 953                  withval=default)
 954 case "$withval" in
 955   default) EXTRA_LD_OPTIONS= ;;
 956   *) EXTRA_LD_OPTIONS=$withval ;;
 957 esac
 958 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 959
 960 dnl Allow specific bindings to be specified for building (or not)
 961 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 962     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 963     enableval=default)
 964 BINDINGS_TO_BUILD=""
 965 case "$enableval" in
 966   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 967   all ) BINDINGS_TO_BUILD="ocaml" ;;
 968   none | no) BINDINGS_TO_BUILD="" ;;
 969   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 970       case "$a_binding" in
 971         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 972         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 973       esac
 974   done
 975   ;;
 976 esac
 977
 978 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 979 dnl script for bindings/ocaml/configure, except that its auto value depends on
 980 dnl OCAMLC, which is found here to support tests.
 981 AC_ARG_WITH([ocaml-libdir],
 982   [AS_HELP_STRING([--with-ocaml-libdir],
 983     [Specify install location for ocaml bindings (default is stdlib)])],
 984   [],
 985   [withval=auto])
 986 case "$withval" in
 987   auto) with_ocaml_libdir="$withval" ;;
 988   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 989   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 990 esac
 991
 992 AC_ARG_WITH(clang-srcdir,
 993   AS_HELP_STRING([--with-clang-srcdir],
 994     [Directory to the out-of-tree Clang source]),,
 995     withval="-")
 996 case "$withval" in
 997   -) clang_src_root="" ;;
 998   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 999   *) clang_src_root="$ac_pwd/$withval" ;;
1000 esac
1001 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1002
1003 AC_ARG_WITH(clang-resource-dir,
1004   AS_HELP_STRING([--with-clang-resource-dir],
1005     [Relative directory from the Clang binary for resource files]),,
1006     withval="")
1007 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1008                    [Relative directory for resource files])
1009
1010 AC_ARG_WITH(c-include-dirs,
1011   AS_HELP_STRING([--with-c-include-dirs],
1012     [Colon separated list of directories clang will search for headers]),,
1013     withval="")
1014 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1015                    [Directories clang will search for headers])
1016
1017 # Clang normally uses the system c++ headers and libraries. With this option,
1018 # clang will use the ones provided by a gcc installation instead. This option should
1019 # be passed the same value that was used with --prefix when configuring gcc.
1020 AC_ARG_WITH(gcc-toolchain,
1021   AS_HELP_STRING([--with-gcc-toolchain],
1022     [Directory where gcc is installed.]),,
1023     withval="")
1024 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1025                    [Directory where gcc is installed.])
1026
1027 AC_ARG_WITH(default-sysroot,
1028   AS_HELP_STRING([--with-default-sysroot],
1029     [Add --sysroot=<path> to all compiler invocations.]),,
1030     withval="")
1031 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1032                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1033
1034 dnl Allow linking of LLVM with GPLv3 binutils code.
1035 AC_ARG_WITH(binutils-include,
1036   AS_HELP_STRING([--with-binutils-include],
1037     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1038   withval=default)
1039 case "$withval" in
1040   default) WITH_BINUTILS_INCDIR=default ;;
1041   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1042   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1043 esac
1044 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1045   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1046   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1047      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1048      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1049   fi
1050 fi
1051
1052 dnl Specify the URL where bug reports should be submitted.
1053 AC_ARG_WITH(bug-report-url,
1054   AS_HELP_STRING([--with-bug-report-url],
1055     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1056     withval="http://llvm.org/bugs/")
1057 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1058                    [Bug report URL.])
1059
1060 dnl --enable-libffi : check whether the user wants to turn off libffi:
1061 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1062   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1063   [case "$enableval" in
1064     yes) llvm_cv_enable_libffi="yes" ;;
1065     no)  llvm_cv_enable_libffi="no"  ;;
1066     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1067   esac],
1068   llvm_cv_enable_libffi=no)
1069
1070 AC_ARG_WITH(internal-prefix,
1071   AS_HELP_STRING([--with-internal-prefix],
1072     [Installation directory for internal files]),,
1073     withval="")
1074 AC_SUBST(INTERNAL_PREFIX,[$withval])
1075
1076 dnl===-----------------------------------------------------------------------===
1077 dnl===
1078 dnl=== SECTION 4: Check for programs we need and that they are the right version
1079 dnl===
1080 dnl===-----------------------------------------------------------------------===
1081
1082 AC_PROG_NM
1083 AC_SUBST(NM)
1084
1085 dnl Check for the tools that the makefiles require
1086 AC_CHECK_GNU_MAKE
1087 AC_PROG_LN_S
1088 AC_PATH_PROG(CMP, [cmp], [cmp])
1089 AC_PATH_PROG(CP, [cp], [cp])
1090 AC_PATH_PROG(DATE, [date], [date])
1091 AC_PATH_PROG(FIND, [find], [find])
1092 AC_PATH_PROG(GREP, [grep], [grep])
1093 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1094 AC_PATH_PROG(MV,   [mv],   [mv])
1095 AC_PROG_RANLIB
1096 AC_CHECK_TOOL(AR, ar, false)
1097 AC_PATH_PROG(RM,   [rm],   [rm])
1098 AC_PATH_PROG(SED,  [sed],  [sed])
1099 AC_PATH_PROG(TAR,  [tar],  [gtar])
1100 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1101
1102 dnl Looking for misc. graph plotting software
1103 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1104 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1105   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1106   dnl If we're targeting for mingw we should emit windows paths, not msys
1107   if test "$llvm_cv_os_type" = "MingW" ; then
1108     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1109   fi
1110   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1111    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1112 fi
1113 AC_PATH_PROG(DOT, [dot], [echo dot])
1114 if test "$DOT" != "echo dot" ; then
1115   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1116   dnl If we're targeting for mingw we should emit windows paths, not msys
1117   if test "$llvm_cv_os_type" = "MingW" ; then
1118     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1119   fi
1120   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1121    [Define to path to dot program if found or 'echo dot' otherwise])
1122 fi
1123 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1124 if test "$FDP" != "echo fdp" ; then
1125   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1126   dnl If we're targeting for mingw we should emit windows paths, not msys
1127   if test "$llvm_cv_os_type" = "MingW" ; then
1128     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1129   fi
1130   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1131    [Define to path to fdp program if found or 'echo fdp' otherwise])
1132 fi
1133 AC_PATH_PROG(NEATO, [neato], [echo neato])
1134 if test "$NEATO" != "echo neato" ; then
1135   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1136   dnl If we're targeting for mingw we should emit windows paths, not msys
1137   if test "$llvm_cv_os_type" = "MingW" ; then
1138     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1139   fi
1140   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1141    [Define to path to neato program if found or 'echo neato' otherwise])
1142 fi
1143 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1144 if test "$TWOPI" != "echo twopi" ; then
1145   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1146   dnl If we're targeting for mingw we should emit windows paths, not msys
1147   if test "$llvm_cv_os_type" = "MingW" ; then
1148     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1149   fi
1150   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1151    [Define to path to twopi program if found or 'echo twopi' otherwise])
1152 fi
1153 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1154 if test "$CIRCO" != "echo circo" ; then
1155   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1156   dnl If we're targeting for mingw we should emit windows paths, not msys
1157   if test "$llvm_cv_os_type" = "MingW" ; then
1158     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1159   fi
1160   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1161    [Define to path to circo program if found or 'echo circo' otherwise])
1162 fi
1163 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1164 if test "$GV" != "echo gv" ; then
1165   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1166   dnl If we're targeting for mingw we should emit windows paths, not msys
1167   if test "$llvm_cv_os_type" = "MingW" ; then
1168     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1169   fi
1170   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1171    [Define to path to gv program if found or 'echo gv' otherwise])
1172 fi
1173 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1174 if test "$DOTTY" != "echo dotty" ; then
1175   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1176   dnl If we're targeting for mingw we should emit windows paths, not msys
1177   if test "$llvm_cv_os_type" = "MingW" ; then
1178     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1179   fi
1180   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1181    [Define to path to dotty program if found or 'echo dotty' otherwise])
1182 fi
1183 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1184 if test "$XDOT_PY" != "echo xdot.py" ; then
1185   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1186   dnl If we're targeting for mingw we should emit windows paths, not msys
1187   if test "$llvm_cv_os_type" = "MingW" ; then
1188     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1189   fi
1190   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1191    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1192 fi
1193
1194 dnl Find the install program
1195 AC_PROG_INSTALL
1196 dnl Prepend src dir to install path dir if it's a relative path
1197 dnl This is a hack for installs that take place in something other
1198 dnl than the top level.
1199 case "$INSTALL" in
1200  [[\\/$]]* | ?:[[\\/]]* ) ;;
1201  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1202 esac
1203
1204 dnl Checks for documentation and testing tools that we can do without. If these
1205 dnl are not found then they are set to "true" which always succeeds but does
1206 dnl nothing. This just lets the build output show that we could have done
1207 dnl something if the tool was available.
1208 AC_PATH_PROG(BZIP2, [bzip2])
1209 AC_PATH_PROG(CAT, [cat])
1210 AC_PATH_PROG(DOXYGEN, [doxygen])
1211 AC_PATH_PROG(GROFF, [groff])
1212 AC_PATH_PROG(GZIPBIN, [gzip])
1213 AC_PATH_PROG(PDFROFF, [pdfroff])
1214 AC_PATH_PROG(ZIP, [zip])
1215 AC_PATH_PROGS(OCAMLC, [ocamlc])
1216 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1217 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1218 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1219 AC_PATH_PROGS(GAS, [gas as])
1220
1221 dnl Get the version of the linker in use.
1222 AC_LINK_GET_VERSION
1223
1224 dnl Determine whether the linker supports the -R option.
1225 AC_LINK_USE_R
1226
1227 dnl Determine whether the linker supports the -export-dynamic option.
1228 AC_LINK_EXPORT_DYNAMIC
1229
1230 dnl Determine whether the linker supports the --version-script option.
1231 AC_LINK_VERSION_SCRIPT
1232
1233 dnl Check for libtool and the library that has dlopen function (which must come
1234 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1235 dnl libtool).
1236 AC_LIBTOOL_DLOPEN
1237 AC_LIB_LTDL
1238
1239 AC_MSG_CHECKING([tool compatibility])
1240
1241 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1242 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1243 dnl to support those options.
1244 dnl "icc" emits gcc signatures
1245 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1246 ICC=no
1247 IXX=no
1248 case $CC in
1249   icc*|icpc*)
1250     ICC=yes
1251     IXX=yes
1252     ;;
1253    *)
1254     ;;
1255 esac
1256
1257 if test "$GCC" != "yes" && test "$ICC" != "yes"
1258 then
1259   AC_MSG_ERROR([gcc|icc required but not found])
1260 fi
1261
1262 dnl Ensure that compilation tools are compatible with GCC extensions
1263 if test "$GXX" != "yes" && test "$IXX" != "yes"
1264 then
1265   AC_MSG_ERROR([g++|clang++|icc required but not found])
1266 fi
1267
1268 dnl Verify that GCC is version 3.0 or higher
1269 if test "$GCC" = "yes"
1270 then
1271   AC_COMPILE_IFELSE(
1272 [
1273   AC_LANG_SOURCE([[
1274     #if !defined(__GNUC__) || __GNUC__ < 3
1275     #error Unsupported GCC version
1276     #endif
1277   ]])
1278 ],
1279 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1280 fi
1281
1282 dnl Check for GNU Make.  We use its extensions, so don't build without it
1283 if test -z "$llvm_cv_gnu_make_command"
1284 then
1285   AC_MSG_ERROR([GNU Make required but not found])
1286 fi
1287
1288 dnl Tool compatibility is okay if we make it here.
1289 AC_MSG_RESULT([ok])
1290
1291 dnl Check optional compiler flags.
1292 AC_MSG_CHECKING([optional compiler flags])
1293 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1294 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1295 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1296
1297 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1298 dnl false positives, so disable it.
1299 NO_UNINITIALIZED=
1300 NO_MAYBE_UNINITIALIZED=
1301 if test "$GXX" = "yes"
1302 then
1303   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1304   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1305   dnl known to be uninitialized from cases which might be uninitialized.  We
1306   dnl still want to catch the first kind of errors.
1307   if test -z "$NO_MAYBE_UNINITIALIZED"
1308   then
1309     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1310   fi
1311 fi
1312 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1313
1314 AC_ARG_WITH([python],
1315             [AS_HELP_STRING([--with-python], [path to python])],
1316             [PYTHON="$withval"])
1317
1318 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1319   AC_MSG_CHECKING([for python])
1320   AC_MSG_RESULT([user defined: $with_python])
1321 else
1322   if test -n "$PYTHON" ; then
1323     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1324   fi
1325
1326   AC_PATH_PROG([PYTHON], [python python2 python26],
1327                [AC_MSG_RESULT([not found])
1328                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1329 fi
1330
1331 AC_MSG_CHECKING([for python >= 2.5])
1332 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1333 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1334 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1335 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1336 if   test "$ac_python_version_major" -eq "2" \
1337    && test "$ac_python_version_minor" -ge "5" ; then
1338   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1339 else
1340   AC_MSG_RESULT([not found])
1341   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1342 fi
1343
1344 dnl===-----------------------------------------------------------------------===
1345 dnl===
1346 dnl=== SECTION 5: Check for libraries
1347 dnl===
1348 dnl===-----------------------------------------------------------------------===
1349
1350 AC_CHECK_LIB(m,sin)
1351 if test "$llvm_cv_os_type" = "MingW" ; then
1352   AC_CHECK_LIB(imagehlp, main)
1353   AC_CHECK_LIB(psapi, main)
1354 fi
1355
1356 dnl dlopen() is required for plugin support.
1357 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1358                [Define if dlopen() is available on this platform.]),
1359                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1360
1361 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1362 dnl macros to detect whether clock_gettime is available, this just finds the
1363 dnl right libraries to link with.
1364 AC_SEARCH_LIBS(clock_gettime,rt)
1365
1366 dnl libffi is optional; used to call external functions from the interpreter
1367 if test "$llvm_cv_enable_libffi" = "yes" ; then
1368   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1369                  [Define if libffi is available on this platform.]),
1370                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1371 fi
1372
1373 dnl mallinfo is optional; the code can compile (minus features) without it
1374 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1375                [Define if mallinfo() is available on this platform.]))
1376
1377 dnl pthread locking functions are optional - but llvm will not be thread-safe
1378 dnl without locks.
1379 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1380   AC_CHECK_LIB(pthread, pthread_mutex_init)
1381   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1382                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1383                            [Have pthread_mutex_lock]))
1384   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1385                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1386                  [Have pthread_rwlock_init]))
1387   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1388                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1389                  [Have pthread_getspecific]))
1390 fi
1391
1392 dnl zlib is optional; used for compression/uncompression
1393 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1394   AC_CHECK_LIB(z, compress2)
1395 fi
1396
1397 dnl Allow extra x86-disassembler library
1398 AC_ARG_WITH(udis86,
1399   AS_HELP_STRING([--with-udis86=<path>],
1400     [Use udis86 external x86 disassembler library]),
1401     [
1402       AC_SUBST(USE_UDIS86, [1])
1403       case "$withval" in
1404         /usr/lib|yes) ;;
1405         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1406       esac
1407       AC_CHECK_LIB(udis86, ud_init, [], [
1408         echo "Error! You need to have libudis86 around."
1409         exit -1
1410       ])
1411     ],
1412     AC_SUBST(USE_UDIS86, [0]))
1413 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1414                    [Define if use udis86 library])
1415
1416 dnl Allow OProfile support for JIT output.
1417 AC_ARG_WITH(oprofile,
1418   AS_HELP_STRING([--with-oprofile=<prefix>],
1419     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1420     [
1421       AC_SUBST(USE_OPROFILE, [1])
1422       case "$withval" in
1423         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1424         no) llvm_cv_oppath=
1425             AC_SUBST(USE_OPROFILE, [0]) ;;
1426         *) llvm_cv_oppath="${withval}/lib/oprofile"
1427            CPPFLAGS="-I${withval}/include";;
1428       esac
1429       case $llvm_cv_os_type in
1430         Linux)
1431           if test -n "$llvm_cv_oppath" ; then
1432             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1433             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1434             dnl libbfd is not included properly in libopagent in some Debian
1435             dnl versions.  If libbfd isn't found at all, we assume opagent works
1436             dnl anyway.
1437             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1438             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1439               echo "Error! You need to have libopagent around."
1440               exit -1
1441             ])
1442             AC_CHECK_HEADER([opagent.h], [], [
1443               echo "Error! You need to have opagent.h around."
1444               exit -1
1445               ])
1446           fi ;;
1447         *)
1448           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1449       esac
1450     ],
1451     [
1452       AC_SUBST(USE_OPROFILE, [0])
1453     ])
1454 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1455                    [Define if we have the oprofile JIT-support library])
1456
1457 dnl Enable support for Intel JIT Events API.
1458 AC_ARG_WITH(intel-jitevents,
1459   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1460     [
1461        case "$withval" in
1462           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1463           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1464           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1465        esac
1466
1467       case $llvm_cv_os_type in
1468         Linux|Win32|Cygwin|MingW) ;;
1469         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1470       esac
1471
1472       case "$llvm_cv_target_arch" in
1473         x86|x86_64) ;;
1474         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1475       esac
1476     ],
1477     [
1478       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1479     ])
1480 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1481                    [Define if we have the Intel JIT API runtime support library])
1482
1483 dnl Check for libxml2
1484 dnl Right now we're just checking for the existence, we could also check for a
1485 dnl particular version via --version on xml2-config
1486 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1487
1488 AC_MSG_CHECKING(for libxml2 includes)
1489 if test "x$XML2CONFIG" = "x"; then
1490  AC_MSG_RESULT(xml2-config not found)
1491 else
1492  LIBXML2_INC=`$XML2CONFIG --cflags`
1493  AC_MSG_RESULT($LIBXML2_INC)
1494  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1495                                 LIBXML2_LIBS="-lxml2"])
1496 fi
1497 AC_SUBST(LIBXML2_LIBS)
1498 AC_SUBST(LIBXML2_INC)
1499
1500 dnl===-----------------------------------------------------------------------===
1501 dnl===
1502 dnl=== SECTION 6: Check for header files
1503 dnl===
1504 dnl===-----------------------------------------------------------------------===
1505
1506 dnl First, use autoconf provided macros for specific headers that we need
1507 dnl We don't check for ancient stuff or things that are guaranteed to be there
1508 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1509 dnl Generally we're looking for POSIX headers.
1510 AC_HEADER_DIRENT
1511 AC_HEADER_MMAP_ANONYMOUS
1512 AC_HEADER_STAT
1513 AC_HEADER_SYS_WAIT
1514 AC_HEADER_TIME
1515
1516 AC_LANG_PUSH([C++])
1517 AC_CHECK_HEADERS([cxxabi.h])
1518 AC_LANG_POP([C++])
1519 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1520 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1521 AC_CHECK_HEADERS([utime.h windows.h])
1522 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1523 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1524 AC_CHECK_HEADERS([valgrind/valgrind.h])
1525 AC_CHECK_HEADERS([fenv.h])
1526 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1527 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1528   AC_CHECK_HEADERS(pthread.h,
1529                    AC_SUBST(HAVE_PTHREAD, 1),
1530                    AC_SUBST(HAVE_PTHREAD, 0))
1531 else
1532   AC_SUBST(HAVE_PTHREAD, 0)
1533 fi
1534 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1535   AC_CHECK_HEADERS(zlib.h,
1536                    AC_SUBST(HAVE_LIBZ, 1),
1537                    AC_SUBST(HAVE_LIBZ, 0))
1538 else
1539   AC_SUBST(HAVE_LIBZ, 0)
1540 fi
1541
1542 dnl Try to find ffi.h.
1543 if test "$llvm_cv_enable_libffi" = "yes" ; then
1544   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1545 fi
1546
1547 dnl Try to find Darwin specific crash reporting libraries.
1548 AC_CHECK_HEADERS([CrashReporterClient.h])
1549
1550 dnl Try to find Darwin specific crash reporting global.
1551 AC_MSG_CHECKING([__crashreporter_info__])
1552 AC_LINK_IFELSE(
1553 [
1554   AC_LANG_SOURCE([[
1555     extern const char *__crashreporter_info__;
1556     int main() {
1557       __crashreporter_info__ = "test";
1558       return 0;
1559     }
1560   ]])
1561 ],
1562 [
1563   AC_MSG_RESULT([yes])
1564   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1565 ],
1566 [
1567   AC_MSG_RESULT([no])
1568   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1569 ])
1570
1571 dnl===-----------------------------------------------------------------------===
1572 dnl===
1573 dnl=== SECTION 7: Check for types and structures
1574 dnl===
1575 dnl===-----------------------------------------------------------------------===
1576
1577 AC_HUGE_VAL_CHECK
1578 AC_TYPE_PID_T
1579 AC_TYPE_SIZE_T
1580 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1581 AC_STRUCT_TM
1582 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1583 AC_CHECK_TYPES([uint64_t],,
1584          AC_CHECK_TYPES([u_int64_t],,
1585          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1586
1587 dnl===-----------------------------------------------------------------------===
1588 dnl===
1589 dnl=== SECTION 8: Check for specific functions needed
1590 dnl===
1591 dnl===-----------------------------------------------------------------------===
1592
1593 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1594 AC_CHECK_FUNCS([powf fmodf strtof round ])
1595 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1596 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1597 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1598 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1599 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1600 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1601 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1602 AC_C_PRINTF_A
1603 AC_FUNC_RAND48
1604
1605 dnl Check the declaration "Secure API" on Windows environments.
1606 AC_CHECK_DECLS([strerror_s])
1607
1608 dnl Check symbols in libgcc.a for JIT on Mingw.
1609 if test "$llvm_cv_os_type" = "MingW" ; then
1610   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1611   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1612   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1613   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1614
1615   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1616   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1617   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1618   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1619   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1620   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1621   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1622   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1623   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1624   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1625
1626   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1627   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1628 fi
1629
1630 dnl Check Win32 API EnumerateLoadedModules.
1631 if test "$llvm_cv_os_type" = "MingW" ; then
1632   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1633   AC_COMPILE_IFELSE(
1634 [
1635   AC_LANG_SOURCE([[
1636     #include <windows.h>
1637     #include <imagehlp.h>
1638     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1639     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1640   ]])
1641 ],
1642 [
1643   AC_MSG_RESULT([yes])
1644   llvm_cv_win32_elmcb_pcstr="PCSTR"
1645 ],
1646 [
1647   AC_MSG_RESULT([no])
1648   llvm_cv_win32_elmcb_pcstr="PSTR"
1649 ])
1650   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1651 fi
1652
1653 dnl Check for variations in the Standard C++ library and STL. These macros are
1654 dnl provided by LLVM in the autoconf/m4 directory.
1655 AC_FUNC_ISNAN
1656 AC_FUNC_ISINF
1657
1658 dnl Check for mmap support.We also need to know if /dev/zero is required to
1659 dnl be opened for allocating RWX memory.
1660 dnl Make sure we aren't attempting to configure for an unknown system
1661 if test "$llvm_cv_platform_type" = "Unix" ; then
1662   AC_FUNC_MMAP
1663   AC_FUNC_MMAP_FILE
1664   AC_NEED_DEV_ZERO_FOR_MMAP
1665
1666   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1667   then
1668     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1669   fi
1670   if test "$ac_cv_func_mmap_file" = "no"
1671   then
1672     AC_MSG_WARN([mmap() of files required but not found])
1673   fi
1674 fi
1675
1676 dnl atomic builtins are required for threading support.
1677 AC_MSG_CHECKING(for GCC atomic builtins)
1678 dnl Since we'll be using these atomic builtins in C++ files we should test
1679 dnl the C++ compiler.
1680 AC_LANG_PUSH([C++])
1681 AC_LINK_IFELSE(
1682 [
1683   AC_LANG_SOURCE([[
1684     int main() {
1685       volatile unsigned long val = 1;
1686       __sync_synchronize();
1687       __sync_val_compare_and_swap(&val, 1, 0);
1688       __sync_add_and_fetch(&val, 1);
1689       __sync_sub_and_fetch(&val, 1);
1690       return 0;
1691     }
1692   ]])
1693 ],
1694 [
1695   AC_MSG_RESULT([yes])
1696   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1697 ],
1698 [
1699   AC_MSG_RESULT([no])
1700   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1701   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1702 ])
1703 AC_LANG_POP([C++])
1704
1705 dnl===-----------------------------------------------------------------------===
1706 dnl===
1707 dnl=== SECTION 9: Additional checks, variables, etc.
1708 dnl===
1709 dnl===-----------------------------------------------------------------------===
1710
1711 dnl Handle 32-bit linux systems running a 64-bit kernel.
1712 dnl This has to come after section 4 because it invokes the compiler.
1713 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1714   AC_IS_LINUX_MIXED
1715   if test "$llvm_cv_linux_mixed" = "yes"; then
1716     llvm_cv_target_arch="x86"
1717     ARCH="x86"
1718   fi
1719 fi
1720
1721 dnl Check whether __dso_handle is present
1722 AC_CHECK_FUNCS([__dso_handle])
1723
1724 dnl Propagate the shared library extension that the libltdl checks did to
1725 dnl the Makefiles so we can use it there too
1726 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1727
1728 dnl Propagate the run-time library path variable that the libltdl
1729 dnl checks found to the Makefiles so we can use it there too
1730 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1731
1732 dnl Translate the various configuration directories and other basic
1733 dnl information into substitutions that will end up in Makefile.config.in
1734 dnl that these configured values can be used by the makefiles
1735 if test "${prefix}" = "NONE" ; then
1736   prefix="/usr/local"
1737 fi
1738 eval LLVM_PREFIX="${prefix}";
1739 eval LLVM_BINDIR="${prefix}/bin";
1740 eval LLVM_LIBDIR="${prefix}/lib";
1741 eval LLVM_DATADIR="${prefix}/share/llvm";
1742 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1743 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1744 eval LLVM_INCLUDEDIR="${prefix}/include";
1745 eval LLVM_INFODIR="${prefix}/info";
1746 eval LLVM_MANDIR="${prefix}/man";
1747 LLVM_CONFIGTIME=`date`
1748 AC_SUBST(LLVM_PREFIX)
1749 AC_SUBST(LLVM_BINDIR)
1750 AC_SUBST(LLVM_LIBDIR)
1751 AC_SUBST(LLVM_DATADIR)
1752 AC_SUBST(LLVM_DOCSDIR)
1753 AC_SUBST(LLVM_ETCDIR)
1754 AC_SUBST(LLVM_INCLUDEDIR)
1755 AC_SUBST(LLVM_INFODIR)
1756 AC_SUBST(LLVM_MANDIR)
1757 AC_SUBST(LLVM_CONFIGTIME)
1758
1759 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1760 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1761   LLVM_CONFIGTIME="(timestamp not enabled)"
1762 fi
1763
1764 dnl Place the various directories into the config.h file as #defines so that we
1765 dnl can know about the installation paths within LLVM.
1766 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1767                    [Installation prefix directory])
1768 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1769                    [Installation directory for binary executables])
1770 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1771                    [Installation directory for libraries])
1772 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1773                    [Installation directory for data files])
1774 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1775                    [Installation directory for documentation])
1776 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1777                    [Installation directory for config files])
1778 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1779                    [Installation directory for include files])
1780 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1781                    [Installation directory for .info files])
1782 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1783                    [Installation directory for man pages])
1784 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1785                    [Time at which LLVM was configured])
1786 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1787                    [Host triple LLVM will be executed on])
1788 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1789                    [Target triple LLVM will generate code for by default])
1790
1791 dnl Determine which bindings to build.
1792 if test "$BINDINGS_TO_BUILD" = auto ; then
1793   BINDINGS_TO_BUILD=""
1794   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1795     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1796   fi
1797 fi
1798 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1799
1800 dnl This isn't really configurey, but it avoids having to repeat the list in
1801 dnl other files.
1802 AC_SUBST(ALL_BINDINGS,ocaml)
1803
1804 dnl Do any work necessary to ensure that bindings have what they need.
1805 binding_prereqs_failed=0
1806 for a_binding in $BINDINGS_TO_BUILD ; do
1807   case "$a_binding" in
1808   ocaml)
1809     if test "x$OCAMLC" = x ; then
1810       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1811       binding_prereqs_failed=1
1812     fi
1813     if test "x$OCAMLDEP" = x ; then
1814       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1815       binding_prereqs_failed=1
1816     fi
1817     if test "x$OCAMLOPT" = x ; then
1818       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1819       dnl ocamlopt is optional!
1820     fi
1821     if test "x$with_ocaml_libdir" != xauto ; then
1822       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1823     else
1824       ocaml_stdlib="`"$OCAMLC" -where`"
1825       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1826       then
1827         # ocaml stdlib is beneath our prefix; use stdlib
1828         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1829       else
1830         # ocaml stdlib is outside our prefix; use libdir/ocaml
1831         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1832       fi
1833     fi
1834     ;;
1835   esac
1836 done
1837 if test "$binding_prereqs_failed" = 1 ; then
1838   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1839 fi
1840
1841 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1842 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1843
1844 dnl Determine linker rpath flag
1845 if test "$llvm_cv_link_use_r" = "yes" ; then
1846   RPATH="-Wl,-R"
1847 else
1848   RPATH="-Wl,-rpath"
1849 fi
1850 AC_SUBST(RPATH)
1851
1852 dnl Determine linker rdynamic flag
1853 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1854   RDYNAMIC="-Wl,-export-dynamic"
1855 else
1856   RDYNAMIC=""
1857 fi
1858 AC_SUBST(RDYNAMIC)
1859
1860 dnl===-----------------------------------------------------------------------===
1861 dnl===
1862 dnl=== SECTION 10: Specify the output files and generate it
1863 dnl===
1864 dnl===-----------------------------------------------------------------------===
1865
1866 dnl Configure header files
1867 dnl WARNING: dnl If you add or remove any of the following config headers, then
1868 dnl you MUST also update Makefile so that the variable FilesToConfig
1869 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1870 dnl files can be updated automatically when their *.in sources change.
1871 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1872 AH_TOP([#ifndef CONFIG_H
1873 #define CONFIG_H])
1874 AH_BOTTOM([#endif])
1875
1876 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1877 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1878 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1879 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1880 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1881
1882 dnl Configure the makefile's configuration data
1883 AC_CONFIG_FILES([Makefile.config])
1884
1885 dnl Configure the RPM spec file for LLVM
1886 AC_CONFIG_FILES([llvm.spec])
1887
1888 dnl Configure doxygen's configuration file
1889 AC_CONFIG_FILES([docs/doxygen.cfg])
1890
1891 dnl Configure clang, if present
1892 if test "${clang_src_root}" = ""; then
1893   clang_src_root="$srcdir/tools/clang"
1894 fi
1895 if test -f ${clang_src_root}/README.txt; then
1896   dnl Use variables to stay under 80 columns.
1897   configh="include/clang/Config/config.h"
1898   doxy="docs/doxygen.cfg"
1899   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1900   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1901 fi
1902
1903 dnl OCaml findlib META file
1904 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1905
1906 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1907 test "x$program_prefix" = "xNONE" && program_prefix=""
1908 AC_SUBST([program_prefix])
1909
1910
1911 dnl Do special configuration of Makefiles
1912 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1913 AC_CONFIG_MAKEFILE(Makefile)
1914 AC_CONFIG_MAKEFILE(Makefile.common)
1915 AC_CONFIG_MAKEFILE(examples/Makefile)
1916 AC_CONFIG_MAKEFILE(lib/Makefile)
1917 AC_CONFIG_MAKEFILE(runtime/Makefile)
1918 AC_CONFIG_MAKEFILE(test/Makefile)
1919 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1920 AC_CONFIG_MAKEFILE(unittests/Makefile)
1921 AC_CONFIG_MAKEFILE(tools/Makefile)
1922 AC_CONFIG_MAKEFILE(utils/Makefile)
1923 AC_CONFIG_MAKEFILE(projects/Makefile)
1924 AC_CONFIG_MAKEFILE(bindings/Makefile)
1925 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1926
1927 dnl Finally, crank out the output
1928 AC_OUTPUT