autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       CVS) ;;
 105       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 106       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 107       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 108       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 109       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 110       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 111       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 112       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 113       llvm-gcc)       ;;
 114       test-suite)     ;;
 115       llvm-test)      ;;
 116       poolalloc)      ;;
 117       llvm-poolalloc) ;;
 118       *)
 119         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 120         ;;
 121     esac
 122   fi
 123 done
 124
 125 dnl===-----------------------------------------------------------------------===
 126 dnl===
 127 dnl=== SECTION 2: Architecture, target, and host checks
 128 dnl===
 129 dnl===-----------------------------------------------------------------------===
 130
 131 dnl Check the target for which we're compiling and the host that will do the
 132 dnl compilations. This will tell us which LLVM compiler will be used for
 133 dnl compiling SSA into object code. This needs to be done early because
 134 dnl following tests depend on it.
 135 AC_CANONICAL_TARGET
 136
 137 dnl Determine the platform type and cache its value. This helps us configure
 138 dnl the System library to the correct build platform.
 139 AC_CACHE_CHECK([type of operating system we're going to host on],
 140                [llvm_cv_os_type],
 141 [case $host in
 142   *-*-aix*)
 143     llvm_cv_link_all_option="-Wl,--whole-archive"
 144     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 145     llvm_cv_os_type="AIX"
 146     llvm_cv_platform_type="Unix" ;;
 147   *-*-irix*)
 148     llvm_cv_link_all_option="-Wl,--whole-archive"
 149     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 150     llvm_cv_os_type="IRIX"
 151     llvm_cv_platform_type="Unix" ;;
 152   *-*-cygwin*)
 153     llvm_cv_link_all_option="-Wl,--whole-archive"
 154     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 155     llvm_cv_os_type="Cygwin"
 156     llvm_cv_platform_type="Unix" ;;
 157   *-*-darwin*)
 158     llvm_cv_link_all_option="-Wl,-all_load"
 159     llvm_cv_no_link_all_option="-Wl,-noall_load"
 160     llvm_cv_os_type="Darwin"
 161     llvm_cv_platform_type="Unix" ;;
 162   *-*-minix*)
 163     llvm_cv_link_all_option="-Wl,-all_load"
 164     llvm_cv_no_link_all_option="-Wl,-noall_load"
 165     llvm_cv_os_type="Minix"
 166     llvm_cv_platform_type="Unix" ;;
 167   *-*-freebsd*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="FreeBSD"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-openbsd*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="OpenBSD"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-netbsd*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="NetBSD"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-dragonfly*)
 183     llvm_cv_link_all_option="-Wl,--whole-archive"
 184     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 185     llvm_cv_os_type="DragonFly"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-hpux*)
 188     llvm_cv_link_all_option="-Wl,--whole-archive"
 189     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 190     llvm_cv_os_type="HP-UX"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-interix*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="Interix"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-linux*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="Linux"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-solaris*)
 203     llvm_cv_link_all_option="-Wl,-z,allextract"
 204     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 205     llvm_cv_os_type="SunOS"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-auroraux*)
 208     llvm_cv_link_all_option="-Wl,-z,allextract"
 209     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 210     llvm_cv_os_type="AuroraUX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-win32*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="Win32"
 216     llvm_cv_platform_type="Win32" ;;
 217   *-*-mingw*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="MingW"
 221     llvm_cv_platform_type="Win32" ;;
 222   *-*-haiku*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Haiku"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-unknown-eabi*)
 228     llvm_cv_link_all_option="-Wl,--whole-archive"
 229     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 230     llvm_cv_os_type="Freestanding"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-unknown-elf*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="Freestanding"
 236     llvm_cv_platform_type="Unix" ;;
 237   *)
 238     llvm_cv_link_all_option=""
 239     llvm_cv_no_link_all_option=""
 240     llvm_cv_os_type="Unknown"
 241     llvm_cv_platform_type="Unknown" ;;
 242 esac])
 243
 244 AC_CACHE_CHECK([type of operating system we're going to target],
 245                [llvm_cv_target_os_type],
 246 [case $target in
 247   *-*-aix*)
 248     llvm_cv_target_os_type="AIX" ;;
 249   *-*-irix*)
 250     llvm_cv_target_os_type="IRIX" ;;
 251   *-*-cygwin*)
 252     llvm_cv_target_os_type="Cygwin" ;;
 253   *-*-darwin*)
 254     llvm_cv_target_os_type="Darwin" ;;
 255   *-*-minix*)
 256     llvm_cv_target_os_type="Minix" ;;
 257   *-*-freebsd*)
 258     llvm_cv_target_os_type="FreeBSD" ;;
 259   *-*-openbsd*)
 260     llvm_cv_target_os_type="OpenBSD" ;;
 261   *-*-netbsd*)
 262     llvm_cv_target_os_type="NetBSD" ;;
 263   *-*-dragonfly*)
 264     llvm_cv_target_os_type="DragonFly" ;;
 265   *-*-hpux*)
 266     llvm_cv_target_os_type="HP-UX" ;;
 267   *-*-interix*)
 268     llvm_cv_target_os_type="Interix" ;;
 269   *-*-linux*)
 270     llvm_cv_target_os_type="Linux" ;;
 271   *-*-solaris*)
 272     llvm_cv_target_os_type="SunOS" ;;
 273   *-*-auroraux*)
 274     llvm_cv_target_os_type="AuroraUX" ;;
 275   *-*-win32*)
 276     llvm_cv_target_os_type="Win32" ;;
 277   *-*-mingw*)
 278     llvm_cv_target_os_type="MingW" ;;
 279   *-*-haiku*)
 280     llvm_cv_target_os_type="Haiku" ;;
 281   *-unknown-eabi*)
 282     llvm_cv_target_os_type="Freestanding" ;;
 283   *)
 284     llvm_cv_target_os_type="Unknown" ;;
 285 esac])
 286
 287 dnl Make sure we aren't attempting to configure for an unknown system
 288 if test "$llvm_cv_os_type" = "Unknown" ; then
 289   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 290 fi
 291
 292 dnl Set the "OS" Makefile variable based on the platform type so the
 293 dnl makefile can configure itself to specific build hosts
 294 AC_SUBST(OS,$llvm_cv_os_type)
 295 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 296 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 297
 298 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 299 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 300 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 301
 302 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 303 dnl This is used by lib/System to determine the basic kind of implementation
 304 dnl to use.
 305 case $llvm_cv_platform_type in
 306   Unix)
 307     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 308     AC_SUBST(LLVM_ON_UNIX,[1])
 309     AC_SUBST(LLVM_ON_WIN32,[0])
 310     ;;
 311   Win32)
 312     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 313     AC_SUBST(LLVM_ON_UNIX,[0])
 314     AC_SUBST(LLVM_ON_WIN32,[1])
 315     ;;
 316 esac
 317
 318 dnl Determine what our target architecture is and configure accordingly.
 319 dnl This will allow Makefiles to make a distinction between the hardware and
 320 dnl the OS.
 321 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 322 [case $target in
 323   i?86-*)                 llvm_cv_target_arch="x86" ;;
 324   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 325   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 326   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 327   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 328   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 329   mips-*)                 llvm_cv_target_arch="Mips" ;;
 330   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 331   xcore-*)                llvm_cv_target_arch="XCore" ;;
 332   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 333   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 334   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 335   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 336   *)                      llvm_cv_target_arch="Unknown" ;;
 337 esac])
 338
 339 if test "$llvm_cv_target_arch" = "Unknown" ; then
 340   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 341 fi
 342
 343 # Determine the LLVM native architecture for the target
 344 case "$llvm_cv_target_arch" in
 345     x86)     LLVM_NATIVE_ARCH="X86" ;;
 346     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 347     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 348 esac
 349
 350 dnl Define a substitution, ARCH, for the target architecture
 351 AC_SUBST(ARCH,$llvm_cv_target_arch)
 352
 353 dnl Check for the endianness of the target
 354 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 355
 356 dnl Check for build platform executable suffix if we're crosscompiling
 357 if test "$cross_compiling" = yes; then
 358   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 359   AC_BUILD_EXEEXT
 360   ac_build_prefix=${build_alias}-
 361   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 362   if test -z "$BUILD_CXX"; then
 363      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 364      if test -z "$BUILD_CXX"; then
 365        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 366      fi
 367   fi
 368 else
 369   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 370 fi
 371
 372 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 373 dnl that this build is being done from a checkout. This sets up several
 374 dnl defaults for the command line switches. When we build with a CVS directory,
 375 dnl we get a debug with assertions turned on. Without, we assume a source
 376 dnl release and we get an optimized build without assertions.
 377 dnl See --enable-optimized and --enable-assertions below
 378 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 379   cvsbuild="yes"
 380   optimize="no"
 381   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 382 else
 383   cvsbuild="no"
 384   optimize="yes"
 385 fi
 386
 387 dnl===-----------------------------------------------------------------------===
 388 dnl===
 389 dnl=== SECTION 3: Command line arguments for the configure script.
 390 dnl===
 391 dnl===-----------------------------------------------------------------------===
 392
 393 dnl --enable-optimized : check whether they want to do an optimized build:
 394 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 395  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 396 if test ${enableval} = "no" ; then
 397   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 398 else
 399   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 400 fi
 401
 402 dnl --enable-profiling : check whether they want to do a profile build:
 403 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 404  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 405 if test ${enableval} = "no" ; then
 406   AC_SUBST(ENABLE_PROFILING,[[]])
 407 else
 408   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 409 fi
 410
 411 dnl --enable-assertions : check whether they want to turn on assertions or not:
 412 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 413   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 414 if test ${enableval} = "yes" ; then
 415   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 416 else
 417   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 418 fi
 419
 420 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 421 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 422   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 423 if test ${enableval} = "yes" ; then
 424   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 425   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 426 else
 427   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 428   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 429 fi
 430
 431 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 432 AC_ARG_ENABLE(debug-runtime,
 433    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(DEBUG_RUNTIME,[[]])
 436 else
 437   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 438 fi
 439
 440 dnl --enable-debug-symbols : should even optimized compiler libraries
 441 dnl have debug symbols?
 442 AC_ARG_ENABLE(debug-symbols,
 443    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 444 if test ${enableval} = "no" ; then
 445   AC_SUBST(DEBUG_SYMBOLS,[[]])
 446 else
 447   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 448 fi
 449
 450 dnl --enable-jit: check whether they want to enable the jit
 451 AC_ARG_ENABLE(jit,
 452   AS_HELP_STRING(--enable-jit,
 453                  [Enable Just In Time Compiling (default is YES)]),,
 454   enableval=default)
 455 if test ${enableval} = "no"
 456 then
 457   AC_SUBST(JIT,[[]])
 458 else
 459   case "$llvm_cv_target_arch" in
 460     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 461     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 462     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 466     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 473     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 474   esac
 475 fi
 476
 477 dnl Allow enablement of doxygen generated documentation
 478 AC_ARG_ENABLE(doxygen,
 479               AS_HELP_STRING([--enable-doxygen],
 480                              [Build doxygen documentation (default is NO)]),,
 481                              enableval=default)
 482 case "$enableval" in
 483   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 484   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 486   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 487 esac
 488
 489 dnl Allow disablement of threads
 490 AC_ARG_ENABLE(threads,
 491               AS_HELP_STRING([--enable-threads],
 492                              [Use threads if available (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 497   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 499 esac
 500 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 501
 502 dnl Allow building without position independent code
 503 AC_ARG_ENABLE(pic,
 504   AS_HELP_STRING([--enable-pic],
 505                  [Build LLVM with Position Independent Code (default is YES)]),,
 506                  enableval=default)
 507 case "$enableval" in
 508   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 509   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 510   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 511   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 512 esac
 513 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 514                    [Define if position independent code is enabled])
 515
 516 dnl Allow building a shared library and linking tools against it.
 517 AC_ARG_ENABLE(shared,
 518   AS_HELP_STRING([--enable-shared],
 519                  [Build a shared library and link tools against it (default is NO)]),,
 520                  enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 523   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl Enable embedding timestamp information into build.
 529 AC_ARG_ENABLE(timestamps,
 530   AS_HELP_STRING([--enable-timestamps],
 531                  [Enable embedding timestamp information in build (default is YES)]),,
 532                  enableval=default)
 533 case "$enableval" in
 534   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 535   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 536   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 537   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 538 esac
 539 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 540                    [Define if timestamp information (e.g., __DATE___) is allowed])
 541
 542 dnl Allow specific targets to be specified for building (or not)
 543 TARGETS_TO_BUILD=""
 544 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 545     [Build specific host targets: all or target1,target2,... Valid targets are:
 546      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 547      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 548     enableval=all)
 549 if test "$enableval" = host-only ; then
 550   enableval=host
 551 fi
 552 case "$enableval" in
 553   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 554   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 555       case "$a_target" in
 556         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 557         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 558         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 559         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 560         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 561         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 562         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 563         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 564         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 565         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 566         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 567         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 568         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 569         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 570         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 571         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 572         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 573         host) case "$llvm_cv_target_arch" in
 574             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 575             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 576             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 577             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 578             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 579             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 580             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 581             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 582             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 583             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 584             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 585             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 586             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 587             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 588             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 589           esac ;;
 590         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 591       esac
 592   done
 593   ;;
 594 esac
 595 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 596
 597 # Determine whether we are building LLVM support for the native architecture.
 598 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 599 for a_target in $TARGETS_TO_BUILD; do
 600   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 601     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 602     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 603       [LLVM architecture name for the native architecture, if available])
 604   fi
 605 done
 606
 607 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 608 # target feature def files.
 609 LLVM_ENUM_TARGETS=""
 610 LLVM_ENUM_ASM_PRINTERS=""
 611 LLVM_ENUM_ASM_PARSERS=""
 612 LLVM_ENUM_DISASSEMBLERS=""
 613 for target_to_build in $TARGETS_TO_BUILD; do
 614   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 615   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 616     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 617   fi
 618   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 619     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 620   fi
 621   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 622     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 623   fi
 624 done
 625 AC_SUBST(LLVM_ENUM_TARGETS)
 626 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 627 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 628 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 629
 630 dnl Prevent the CBackend from using printf("%a") for floating point so older
 631 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 632 dnl can still compile the CBE's output
 633 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 634   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 635   enableval=default)
 636 case "$enableval" in
 637   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 638   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 639   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 640   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 641 esac
 642 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 643                    [Define if CBE is enabled for printf %a output])
 644
 645 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 646 AC_ARG_WITH(llvmgccdir,
 647   AS_HELP_STRING([--with-llvmgccdir],
 648     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 649     withval=default)
 650 case "$withval" in
 651   default) WITH_LLVMGCCDIR=default ;;
 652   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 653   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 654 esac
 655
 656 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 657 AC_ARG_WITH(llvmgcc,
 658   AS_HELP_STRING([--with-llvmgcc],
 659     [Specify location of llvm-gcc driver (default searches PATH)]),
 660     LLVMGCC=$with_llvmgcc
 661       WITH_LLVMGCCDIR="",)
 662
 663 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 664 AC_ARG_WITH(llvmgxx,
 665   AS_HELP_STRING([--with-llvmgxx],
 666     [Specify location of llvm-g++ driver (default searches PATH)]),
 667     LLVMGXX=$with_llvmgxx
 668     WITH_LLVMGCCDIR="",)
 669
 670 if test -n "$LLVMGCC"; then
 671    LLVMGCCCOMMAND="$LLVMGCC"
 672 fi
 673
 674 if test -n "$LLVMGXX"; then
 675    LLVMGXXCOMMAND="$LLVMGXX"
 676 fi
 677
 678 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 679    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 680 fi
 681
 682 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 683    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 684 fi
 685
 686 dnl Allow a specific Clang compiler to be used with this LLVM config.
 687 AC_ARG_WITH(clang,
 688   AS_HELP_STRING([--with-clang],
 689     [Specify location of clang compiler (default is --with-built-clang)]),
 690     [],[with_clang=default])
 691
 692 dnl Enable use of the built Clang.
 693 AC_ARG_WITH(built-clang,
 694   AS_HELP_STRING([--with-built-clang],
 695     [Use the compiled Clang as the LLVM compiler (default=check)]),
 696     [],[with_built_clang=check])
 697
 698 dnl Select the Clang compiler option.
 699 dnl
 700 dnl If --with-clang is given, always honor that; otherwise honor
 701 dnl --with-built-clang, or check if we have the clang sources.
 702 AC_MSG_CHECKING([clang compiler])
 703 WITH_CLANGPATH=""
 704 WITH_BUILT_CLANG=0
 705 if test "$with_clang" != "default"; then
 706    WITH_CLANGPATH="$with_clang"
 707    if ! test -x "$WITH_CLANGPATH"; then
 708      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 709    fi
 710 elif test "$with_built_clang" = "yes"; then
 711    WITH_BUILT_CLANG=1
 712 elif test "$with_built_clang" = "no"; then
 713    WITH_BUILT_CLANG=0
 714 else
 715    if test "$with_built_clang" != "check"; then
 716       AC_MSG_ERROR([invalid value for --with-built-clang.])
 717    fi
 718
 719    if test -f ${srcdir}/tools/clang/README.txt; then
 720      WITH_BUILT_CLANG=1
 721    fi
 722 fi
 723
 724 if ! test -z "$WITH_CLANGPATH"; then
 725    AC_MSG_RESULT([$WITH_CLANGPATH])
 726    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 727 elif test "$WITH_BUILT_CLANG" = "1"; then
 728    AC_MSG_RESULT([built])
 729 else
 730    AC_MSG_RESULT([none])
 731 fi
 732 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 733 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 734 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 735
 736 dnl Override the option to use for optimized builds.
 737 AC_ARG_WITH(optimize-option,
 738   AS_HELP_STRING([--with-optimize-option],
 739                  [Select the compiler options to use for optimized builds]),,
 740                  withval=default)
 741 AC_MSG_CHECKING([optimization flags])
 742 case "$withval" in
 743   default)
 744     case "$llvm_cv_os_type" in
 745     FreeBSD) optimize_option=-O2 ;;
 746     MingW) optimize_option=-O2 ;;
 747     *)     optimize_option=-O3 ;;
 748     esac ;;
 749   *) optimize_option="$withval" ;;
 750 esac
 751 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 752 AC_MSG_RESULT([$optimize_option])
 753
 754 dnl Specify extra build options
 755 AC_ARG_WITH(extra-options,
 756   AS_HELP_STRING([--with-extra-options],
 757                  [Specify additional options to compile LLVM with]),,
 758                  withval=default)
 759 case "$withval" in
 760   default) EXTRA_OPTIONS= ;;
 761   *) EXTRA_OPTIONS=$withval ;;
 762 esac
 763 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 764
 765 dnl Allow specific bindings to be specified for building (or not)
 766 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 767     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 768     enableval=default)
 769 BINDINGS_TO_BUILD=""
 770 case "$enableval" in
 771   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 772   all ) BINDINGS_TO_BUILD="ocaml" ;;
 773   none | no) BINDINGS_TO_BUILD="" ;;
 774   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 775       case "$a_binding" in
 776         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 777         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 778       esac
 779   done
 780   ;;
 781 esac
 782
 783 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 784 dnl script for bindings/ocaml/configure, except that its auto value depends on
 785 dnl OCAMLC, which is found here to support tests.
 786 AC_ARG_WITH([ocaml-libdir],
 787   [AS_HELP_STRING([--with-ocaml-libdir],
 788     [Specify install location for ocaml bindings (default is stdlib)])],
 789   [],
 790   [withval=auto])
 791 case "$withval" in
 792   auto) with_ocaml_libdir="$withval" ;;
 793   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 794   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 795 esac
 796
 797 AC_ARG_WITH(c-include-dirs,
 798   AS_HELP_STRING([--with-c-include-dirs],
 799     [Colon separated list of directories clang will search for headers]),,
 800     withval="")
 801 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 802                    [Directories clang will search for headers])
 803
 804 AC_ARG_WITH(cxx-include-root,
 805   AS_HELP_STRING([--with-cxx-include-root],
 806     [Directory with the libstdc++ headers.]),,
 807     withval="")
 808 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 809                    [Directory with the libstdc++ headers.])
 810
 811 AC_ARG_WITH(cxx-include-arch,
 812   AS_HELP_STRING([--with-cxx-include-arch],
 813     [Architecture of the libstdc++ headers.]),,
 814     withval="")
 815 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 816                    [Arch the libstdc++ headers.])
 817
 818 AC_ARG_WITH(cxx-include-32bit-dir,
 819   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 820     [32 bit multilib dir.]),,
 821     withval="")
 822 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 823                    [32 bit multilib directory.])
 824
 825 AC_ARG_WITH(cxx-include-64bit-dir,
 826   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 827     [64 bit multilib directory.]),,
 828     withval="")
 829 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 830                    [64 bit multilib directory.])
 831
 832 dnl Allow linking of LLVM with GPLv3 binutils code.
 833 AC_ARG_WITH(binutils-include,
 834   AS_HELP_STRING([--with-binutils-include],
 835     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 836   withval=default)
 837 case "$withval" in
 838   default) WITH_BINUTILS_INCDIR=default ;;
 839   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 840   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 841 esac
 842 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 843   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 844   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 845      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 846      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 847   fi
 848 fi
 849
 850 dnl --enable-libffi : check whether the user wants to turn off libffi:
 851 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 852   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 853   [case "$enableval" in
 854     yes) llvm_cv_enable_libffi="yes" ;;
 855     no)  llvm_cv_enable_libffi="no"  ;;
 856     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 857   esac],
 858   llvm_cv_enable_libffi=no)
 859
 860 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 861 if test "$llvm_cv_os_type" = "Win32" ; then
 862    llvmc_dynamic="yes"
 863 else
 864    llvmc_dynamic="no"
 865 fi
 866
 867 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 868 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 869 --enable-llvmc-dynamic,
 870 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 871 enableval=$llvmc_dynamic)
 872 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 873    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 874 else
 875    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 876 fi
 877
 878 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 879 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 880 --enable-llvmc-dynamic-plugins,
 881 [Enable dynamic LLVMC plugins (default is YES)]),,
 882 enableval=yes)
 883 if test ${enableval} = "yes" ; then
 884    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 885 else
 886    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 887 fi
 888
 889 dnl===-----------------------------------------------------------------------===
 890 dnl===
 891 dnl=== SECTION 4: Check for programs we need and that they are the right version
 892 dnl===
 893 dnl===-----------------------------------------------------------------------===
 894
 895 dnl Check for compilation tools
 896 AC_PROG_CPP
 897 AC_PROG_CC(gcc)
 898 AC_PROG_CXX(g++)
 899
 900 AC_PROG_NM
 901 AC_SUBST(NM)
 902
 903 dnl Check for the tools that the makefiles require
 904 AC_CHECK_GNU_MAKE
 905 AC_PROG_LN_S
 906 AC_PATH_PROG(CMP, [cmp], [cmp])
 907 AC_PATH_PROG(CP, [cp], [cp])
 908 AC_PATH_PROG(DATE, [date], [date])
 909 AC_PATH_PROG(FIND, [find], [find])
 910 AC_PATH_PROG(GREP, [grep], [grep])
 911 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 912 AC_PATH_PROG(MV,   [mv],   [mv])
 913 AC_PROG_RANLIB
 914 AC_CHECK_TOOL(AR, ar, false)
 915 AC_PATH_PROG(RM,   [rm],   [rm])
 916 AC_PATH_PROG(SED,  [sed],  [sed])
 917 AC_PATH_PROG(TAR,  [tar],  [gtar])
 918 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 919
 920 dnl Looking for misc. graph plotting software
 921 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 922 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 923   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 924   dnl If we're targeting for mingw we should emit windows paths, not msys
 925   if test "$llvm_cv_os_type" = "MingW" ; then
 926     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 927   fi
 928   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 929    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 930 fi
 931 AC_PATH_PROG(DOT, [dot], [echo dot])
 932 if test "$DOT" != "echo dot" ; then
 933   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 934   dnl If we're targeting for mingw we should emit windows paths, not msys
 935   if test "$llvm_cv_os_type" = "MingW" ; then
 936     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 937   fi
 938   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 939    [Define to path to dot program if found or 'echo dot' otherwise])
 940 fi
 941 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 942 if test "$FDP" != "echo fdp" ; then
 943   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 944   dnl If we're targeting for mingw we should emit windows paths, not msys
 945   if test "$llvm_cv_os_type" = "MingW" ; then
 946     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 947   fi
 948   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 949    [Define to path to fdp program if found or 'echo fdp' otherwise])
 950 fi
 951 AC_PATH_PROG(NEATO, [neato], [echo neato])
 952 if test "$NEATO" != "echo neato" ; then
 953   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 954   dnl If we're targeting for mingw we should emit windows paths, not msys
 955   if test "$llvm_cv_os_type" = "MingW" ; then
 956     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 957   fi
 958   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 959    [Define to path to neato program if found or 'echo neato' otherwise])
 960 fi
 961 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 962 if test "$TWOPI" != "echo twopi" ; then
 963   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 964   dnl If we're targeting for mingw we should emit windows paths, not msys
 965   if test "$llvm_cv_os_type" = "MingW" ; then
 966     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 967   fi
 968   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 969    [Define to path to twopi program if found or 'echo twopi' otherwise])
 970 fi
 971 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 972 if test "$CIRCO" != "echo circo" ; then
 973   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 974   dnl If we're targeting for mingw we should emit windows paths, not msys
 975   if test "$llvm_cv_os_type" = "MingW" ; then
 976     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 977   fi
 978   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 979    [Define to path to circo program if found or 'echo circo' otherwise])
 980 fi
 981 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 982 if test "$GV" != "echo gv" ; then
 983   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 984   dnl If we're targeting for mingw we should emit windows paths, not msys
 985   if test "$llvm_cv_os_type" = "MingW" ; then
 986     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 987   fi
 988   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 989    [Define to path to gv program if found or 'echo gv' otherwise])
 990 fi
 991 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 992 if test "$DOTTY" != "echo dotty" ; then
 993   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 994   dnl If we're targeting for mingw we should emit windows paths, not msys
 995   if test "$llvm_cv_os_type" = "MingW" ; then
 996     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 997   fi
 998   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 999    [Define to path to dotty program if found or 'echo dotty' otherwise])
1000 fi
1001
1002 dnl Look for a sufficiently recent version of Perl.
1003 LLVM_PROG_PERL([5.006])
1004 AC_SUBST(PERL)
1005 if test x"$PERL" = xnone; then
1006    AC_SUBST(HAVE_PERL,0)
1007    AC_MSG_ERROR([perl is required but was not found, please install it])
1008 else
1009    AC_SUBST(HAVE_PERL,1)
1010 fi
1011
1012 dnl Find the install program
1013 AC_PROG_INSTALL
1014 dnl Prepend src dir to install path dir if it's a relative path
1015 dnl This is a hack for installs that take place in something other
1016 dnl than the top level.
1017 case "$INSTALL" in
1018  [[\\/$]]* | ?:[[\\/]]* ) ;;
1019  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1020 esac
1021
1022 dnl Checks for documentation and testing tools that we can do without. If these
1023 dnl are not found then they are set to "true" which always succeeds but does
1024 dnl nothing. This just lets the build output show that we could have done
1025 dnl something if the tool was available.
1026 AC_PATH_PROG(BZIP2, [bzip2])
1027 AC_PATH_PROG(CAT, [cat])
1028 AC_PATH_PROG(DOXYGEN, [doxygen])
1029 AC_PATH_PROG(GROFF, [groff])
1030 AC_PATH_PROG(GZIP, [gzip])
1031 AC_PATH_PROG(POD2HTML, [pod2html])
1032 AC_PATH_PROG(POD2MAN, [pod2man])
1033 AC_PATH_PROG(PDFROFF, [pdfroff])
1034 AC_PATH_PROG(RUNTEST, [runtest])
1035 DJ_AC_PATH_TCLSH
1036 AC_PATH_PROG(ZIP, [zip])
1037 AC_PATH_PROGS(OCAMLC, [ocamlc])
1038 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1039 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1040 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1041 AC_PATH_PROGS(GAS, [gas as])
1042
1043 dnl Determine whether the linker supports the -R option.
1044 AC_LINK_USE_R
1045
1046 dnl Determine whether the linker supports the -export-dynamic option.
1047 AC_LINK_EXPORT_DYNAMIC
1048
1049 dnl Determine whether the linker supports the --version-script option.
1050 AC_LINK_VERSION_SCRIPT
1051
1052 dnl Check for libtool and the library that has dlopen function (which must come
1053 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1054 dnl libtool).
1055 AC_LIBTOOL_DLOPEN
1056 AC_LIB_LTDL
1057
1058 if test "$WITH_LLVMGCCDIR" = "default" ; then
1059   LLVMGCC="llvm-gcc${EXEEXT}"
1060   LLVMGXX="llvm-g++${EXEEXT}"
1061   LLVMGCCCOMMAND="$LLVMGCC"
1062   LLVMGXXCOMMAND="$LLVMGXX"
1063   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1064   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1065   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1066   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1067 else
1068   if test -z "$LLVMGCC"; then
1069     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1070     LLVMGCCCOMMAND="$LLVMGCC"
1071   fi
1072   if test -z "$LLVMGXX"; then
1073     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1074     LLVMGXXCOMMAND="$LLVMGXX"
1075   fi
1076
1077   AC_SUBST(LLVMGCC,$LLVMGCC)
1078   AC_SUBST(LLVMGXX,$LLVMGXX)
1079   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1080   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1081 fi
1082
1083 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1084 dnl found, otherwise clang if available.
1085 AC_ARG_WITH(llvmcc,
1086   AS_HELP_STRING([--with-llvmcc=<name>],
1087     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1088     [],[with_llvmcc=check])
1089 AC_MSG_CHECKING([LLVM capable compiler])
1090 if test "$with_llvmcc" != "check"; then
1091    if (test "$with_llvmcc" != "llvm-gcc" &&
1092        test "$with_llvmcc" != "clang" &&
1093        test "$with_llvmcc" != "none"); then
1094       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1095    fi
1096    WITH_LLVMCC="$with_llvmcc"
1097 elif test -n "$LLVMGCC"; then
1098    WITH_LLVMCC=llvm-gcc
1099 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1100    WITH_LLVMCC=clang
1101 else
1102    WITH_LLVMCC=none
1103 fi
1104 AC_MSG_RESULT([$WITH_LLVMCC])
1105 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1106
1107 AC_MSG_CHECKING([tool compatibility])
1108
1109 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1110 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1111 dnl to support those options.
1112 dnl "icc" emits gcc signatures
1113 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1114 ICC=no
1115 IXX=no
1116 case $CC in
1117   icc*|icpc*)
1118     ICC=yes
1119     IXX=yes
1120     ;;
1121    *)
1122     ;;
1123 esac
1124
1125 if test "$GCC" != "yes" && test "$ICC" != "yes"
1126 then
1127   AC_MSG_ERROR([gcc|icc required but not found])
1128 fi
1129
1130 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1131 if test "$GXX" != "yes" && test "$IXX" != "yes"
1132 then
1133   AC_MSG_ERROR([g++|icc required but not found])
1134 fi
1135
1136 dnl Verify that GCC is version 3.0 or higher
1137 if test "$GCC" = "yes"
1138 then
1139   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1140 #error Unsupported GCC version
1141 #endif
1142 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1143 fi
1144
1145 dnl Check for GNU Make.  We use its extensions, so don't build without it
1146 if test -z "$llvm_cv_gnu_make_command"
1147 then
1148   AC_MSG_ERROR([GNU Make required but not found])
1149 fi
1150
1151 dnl Tool compatibility is okay if we make it here.
1152 AC_MSG_RESULT([ok])
1153
1154 dnl Check optional compiler flags.
1155 AC_MSG_CHECKING([optional compiler flags])
1156 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1157 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1158 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1159
1160 dnl===-----------------------------------------------------------------------===
1161 dnl===
1162 dnl=== SECTION 5: Check for libraries
1163 dnl===
1164 dnl===-----------------------------------------------------------------------===
1165
1166 AC_CHECK_LIB(m,sin)
1167 if test "$llvm_cv_os_type" = "MingW" ; then
1168   AC_CHECK_LIB(imagehlp, main)
1169   AC_CHECK_LIB(psapi, main)
1170 fi
1171
1172 dnl dlopen() is required for plugin support.
1173 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1174                [Define if dlopen() is available on this platform.]),
1175                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1176
1177 dnl libffi is optional; used to call external functions from the interpreter
1178 if test "$llvm_cv_enable_libffi" = "yes" ; then
1179   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1180                  [Define if libffi is available on this platform.]),
1181                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1182 fi
1183
1184 dnl mallinfo is optional; the code can compile (minus features) without it
1185 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1186                [Define if mallinfo() is available on this platform.]))
1187
1188 dnl pthread locking functions are optional - but llvm will not be thread-safe
1189 dnl without locks.
1190 if test "$ENABLE_THREADS" -eq 1 ; then
1191   AC_CHECK_LIB(pthread, pthread_mutex_init)
1192   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1193                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1194                            [Have pthread_mutex_lock]))
1195   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1196                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1197                  [Have pthread_rwlock_init]))
1198   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1199                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1200                  [Have pthread_getspecific]))
1201 fi
1202
1203 dnl Allow extra x86-disassembler library
1204 AC_ARG_WITH(udis86,
1205   AS_HELP_STRING([--with-udis86=<path>],
1206     [Use udis86 external x86 disassembler library]),
1207     [
1208       AC_SUBST(USE_UDIS86, [1])
1209       case "$withval" in
1210         /usr/lib|yes) ;;
1211         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1212       esac
1213       AC_CHECK_LIB(udis86, ud_init, [], [
1214         echo "Error! You need to have libudis86 around."
1215         exit -1
1216       ])
1217     ],
1218     AC_SUBST(USE_UDIS86, [0]))
1219 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1220                    [Define if use udis86 library])
1221
1222 dnl Allow OProfile support for JIT output.
1223 AC_ARG_WITH(oprofile,
1224   AS_HELP_STRING([--with-oprofile=<prefix>],
1225     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1226     [
1227       AC_SUBST(USE_OPROFILE, [1])
1228       case "$withval" in
1229         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1230         no) llvm_cv_oppath=
1231             AC_SUBST(USE_OPROFILE, [0]) ;;
1232         *) llvm_cv_oppath="${withval}/lib/oprofile"
1233            CPPFLAGS="-I${withval}/include";;
1234       esac
1235       if test -n "$llvm_cv_oppath" ; then
1236         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1237         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1238         dnl libbfd is not included properly in libopagent in some Debian
1239         dnl versions.  If libbfd isn't found at all, we assume opagent works
1240         dnl anyway.
1241         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1242         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1243           echo "Error! You need to have libopagent around."
1244           exit -1
1245         ])
1246         AC_CHECK_HEADER([opagent.h], [], [
1247           echo "Error! You need to have opagent.h around."
1248           exit -1
1249           ])
1250       fi
1251     ],
1252     [
1253       AC_SUBST(USE_OPROFILE, [0])
1254     ])
1255 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1256                    [Define if we have the oprofile JIT-support library])
1257
1258 dnl===-----------------------------------------------------------------------===
1259 dnl===
1260 dnl=== SECTION 6: Check for header files
1261 dnl===
1262 dnl===-----------------------------------------------------------------------===
1263
1264 dnl First, use autoconf provided macros for specific headers that we need
1265 dnl We don't check for ancient stuff or things that are guaranteed to be there
1266 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1267 dnl Generally we're looking for POSIX headers.
1268 AC_HEADER_DIRENT
1269 AC_HEADER_MMAP_ANONYMOUS
1270 AC_HEADER_STAT
1271 AC_HEADER_STDC
1272 AC_HEADER_SYS_WAIT
1273 AC_HEADER_TIME
1274
1275 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1276 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1277 AC_CHECK_HEADERS([utime.h windows.h])
1278 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1279 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1280 AC_CHECK_HEADERS([valgrind/valgrind.h])
1281 if test "$ENABLE_THREADS" -eq 1 ; then
1282   AC_CHECK_HEADERS(pthread.h,
1283                    AC_SUBST(HAVE_PTHREAD, 1),
1284                    AC_SUBST(HAVE_PTHREAD, 0))
1285 else
1286   AC_SUBST(HAVE_PTHREAD, 0)
1287 fi
1288
1289 dnl Try to find ffi.h.
1290 if test "$llvm_cv_enable_libffi" = "yes" ; then
1291   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1292 fi
1293
1294 dnl Try to find Darwin specific crash reporting library.
1295 AC_CHECK_HEADERS([CrashReporterClient.h])
1296
1297 dnl Try to find Darwin specific linker-section library.
1298 AC_CHECK_HEADERS([mach-o/getsect.h])
1299
1300 dnl===-----------------------------------------------------------------------===
1301 dnl===
1302 dnl=== SECTION 7: Check for types and structures
1303 dnl===
1304 dnl===-----------------------------------------------------------------------===
1305
1306 AC_HUGE_VAL_CHECK
1307 AC_TYPE_PID_T
1308 AC_TYPE_SIZE_T
1309 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1310 AC_STRUCT_TM
1311 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1312 AC_CHECK_TYPES([uint64_t],,
1313          AC_CHECK_TYPES([u_int64_t],,
1314          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1315
1316 dnl===-----------------------------------------------------------------------===
1317 dnl===
1318 dnl=== SECTION 8: Check for specific functions needed
1319 dnl===
1320 dnl===-----------------------------------------------------------------------===
1321
1322 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1323 AC_CHECK_FUNCS([powf fmodf strtof round ])
1324 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1325 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1326 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1327 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1328 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1329 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1330 AC_C_PRINTF_A
1331 AC_FUNC_RAND48
1332
1333 dnl Check for variations in the Standard C++ library and STL. These macros are
1334 dnl provided by LLVM in the autoconf/m4 directory.
1335 AC_FUNC_ISNAN
1336 AC_FUNC_ISINF
1337
1338 dnl Check for mmap support.We also need to know if /dev/zero is required to
1339 dnl be opened for allocating RWX memory.
1340 dnl Make sure we aren't attempting to configure for an unknown system
1341 if test "$llvm_cv_platform_type" = "Unix" ; then
1342   AC_FUNC_MMAP
1343   AC_FUNC_MMAP_FILE
1344   AC_NEED_DEV_ZERO_FOR_MMAP
1345
1346   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1347   then
1348     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1349   fi
1350   if test "$ac_cv_func_mmap_file" = "no"
1351   then
1352     AC_MSG_WARN([mmap() of files required but not found])
1353   fi
1354 fi
1355
1356 dnl atomic builtins are required for threading support.
1357 AC_MSG_CHECKING(for GCC atomic builtins)
1358 AC_LINK_IFELSE(
1359   AC_LANG_SOURCE(
1360     [[int main() {
1361         volatile unsigned long val = 1;
1362         __sync_synchronize();
1363         __sync_val_compare_and_swap(&val, 1, 0);
1364         __sync_add_and_fetch(&val, 1);
1365         __sync_sub_and_fetch(&val, 1);
1366         return 0;
1367       }
1368     ]]),
1369   AC_MSG_RESULT(yes)
1370   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1371   AC_MSG_RESULT(no)
1372   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1373   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1374
1375 dnl Check for Darwin-specific getsect().
1376 AC_MSG_CHECKING(for getsect())
1377 AC_COMPILE_IFELSE(
1378   AC_LANG_SOURCE(
1379     [[#include <mach-o/getsect.h>
1380       int main() {
1381         unsigned long p;
1382         return (int)getsect("__DATA","__pass_info", &p);
1383       }
1384     ]]),
1385   AC_MSG_RESULT(yes)
1386     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support),
1387   AC_MSG_RESULT(no)
1388     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support)
1389 )
1390
1391
1392 dnl===-----------------------------------------------------------------------===
1393 dnl===
1394 dnl=== SECTION 9: Additional checks, variables, etc.
1395 dnl===
1396 dnl===-----------------------------------------------------------------------===
1397
1398 dnl Handle 32-bit linux systems running a 64-bit kernel.
1399 dnl This has to come after section 4 because it invokes the compiler.
1400 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1401   AC_IS_LINUX_MIXED
1402   if test "$llvm_cv_linux_mixed" = "yes"; then
1403     llvm_cv_target_arch="x86"
1404     ARCH="x86"
1405   fi
1406 fi
1407
1408 dnl Check, whether __dso_handle is present
1409 AC_CHECK_FUNCS([__dso_handle])
1410
1411 dnl See if the llvm-gcc executable can compile to LLVM assembly
1412 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1413 [llvm_cv_llvmgcc_sanity="no"
1414 if test -x "$LLVMGCC" ; then
1415   cp /dev/null conftest.c
1416   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1417       grep 'target datalayout =' > /dev/null 2>&1
1418   if test $? -eq 0 ; then
1419     llvm_cv_llvmgcc_sanity="yes"
1420   fi
1421   rm conftest.c
1422 fi])
1423
1424 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1425 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1426   AC_MSG_CHECKING([llvm-gcc component support])
1427   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1428   AC_SUBST(LLVMCC1,$llvmcc1path)
1429   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1430   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1431   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1432   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1433   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1434   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1435   AC_MSG_RESULT([ok])
1436 fi
1437
1438 dnl Propagate the shared library extension that the libltdl checks did to
1439 dnl the Makefiles so we can use it there too
1440 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1441
1442 dnl Propagate the run-time library path variable that the libltdl
1443 dnl checks found to the Makefiles so we can use it there too
1444 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1445
1446 # Translate the various configuration directories and other basic
1447 # information into substitutions that will end up in Makefile.config.in
1448 # that these configured values can be used by the makefiles
1449 if test "${prefix}" = "NONE" ; then
1450   prefix="/usr/local"
1451 fi
1452 eval LLVM_PREFIX="${prefix}";
1453 eval LLVM_BINDIR="${prefix}/bin";
1454 eval LLVM_LIBDIR="${prefix}/lib";
1455 eval LLVM_DATADIR="${prefix}/share/llvm";
1456 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1457 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1458 eval LLVM_INCLUDEDIR="${prefix}/include";
1459 eval LLVM_INFODIR="${prefix}/info";
1460 eval LLVM_MANDIR="${prefix}/man";
1461 LLVM_CONFIGTIME=`date`
1462 AC_SUBST(LLVM_PREFIX)
1463 AC_SUBST(LLVM_BINDIR)
1464 AC_SUBST(LLVM_LIBDIR)
1465 AC_SUBST(LLVM_DATADIR)
1466 AC_SUBST(LLVM_DOCSDIR)
1467 AC_SUBST(LLVM_ETCDIR)
1468 AC_SUBST(LLVM_INCLUDEDIR)
1469 AC_SUBST(LLVM_INFODIR)
1470 AC_SUBST(LLVM_MANDIR)
1471 AC_SUBST(LLVM_CONFIGTIME)
1472
1473 # Place the various directores into the config.h file as #defines so that we
1474 # can know about the installation paths within LLVM.
1475 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1476                    [Installation prefix directory])
1477 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1478                    [Installation directory for binary executables])
1479 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1480                    [Installation directory for libraries])
1481 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1482                    [Installation directory for data files])
1483 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1484                    [Installation directory for documentation])
1485 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1486                    [Installation directory for config files])
1487 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1488                    [Installation directory for include files])
1489 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1490                    [Installation directory for .info files])
1491 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1492                    [Installation directory for man pages])
1493 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1494                    [Time at which LLVM was configured])
1495 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1496                    [Host triple we were built on])
1497
1498 # Determine which bindings to build.
1499 if test "$BINDINGS_TO_BUILD" = auto ; then
1500   BINDINGS_TO_BUILD=""
1501   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1502     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1503   fi
1504 fi
1505 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1506
1507 # This isn't really configurey, but it avoids having to repeat the list in
1508 # other files.
1509 AC_SUBST(ALL_BINDINGS,ocaml)
1510
1511 # Do any work necessary to ensure that bindings have what they need.
1512 binding_prereqs_failed=0
1513 for a_binding in $BINDINGS_TO_BUILD ; do
1514   case "$a_binding" in
1515   ocaml)
1516     if test "x$OCAMLC" = x ; then
1517       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1518       binding_prereqs_failed=1
1519     fi
1520     if test "x$OCAMLDEP" = x ; then
1521       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1522       binding_prereqs_failed=1
1523     fi
1524     if test "x$OCAMLOPT" = x ; then
1525       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1526       dnl ocamlopt is optional!
1527     fi
1528     if test "x$with_ocaml_libdir" != xauto ; then
1529       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1530     else
1531       ocaml_stdlib="`"$OCAMLC" -where`"
1532       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1533       then
1534         # ocaml stdlib is beneath our prefix; use stdlib
1535         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1536       else
1537         # ocaml stdlib is outside our prefix; use libdir/ocaml
1538         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1539       fi
1540     fi
1541     ;;
1542   esac
1543 done
1544 if test "$binding_prereqs_failed" = 1 ; then
1545   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1546 fi
1547
1548 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1549 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1550
1551 dnl Determine linker rpath flag
1552 if test "$llvm_cv_link_use_r" = "yes" ; then
1553   RPATH="-Wl,-R"
1554 else
1555   RPATH="-Wl,-rpath"
1556 fi
1557 AC_SUBST(RPATH)
1558
1559 dnl Determine linker rdynamic flag
1560 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1561   RDYNAMIC="-Wl,-export-dynamic"
1562 else
1563   RDYNAMIC=""
1564 fi
1565 AC_SUBST(RDYNAMIC)
1566
1567 dnl===-----------------------------------------------------------------------===
1568 dnl===
1569 dnl=== SECTION 10: Specify the output files and generate it
1570 dnl===
1571 dnl===-----------------------------------------------------------------------===
1572
1573 dnl Configure header files
1574 dnl WARNING: dnl If you add or remove any of the following config headers, then
1575 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1576 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1577 dnl files can be updated automatically when their *.in sources change.
1578 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1579 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1580 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1581 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1582 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1583 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1584
1585 dnl Configure the makefile's configuration data
1586 AC_CONFIG_FILES([Makefile.config])
1587
1588 dnl Configure the RPM spec file for LLVM
1589 AC_CONFIG_FILES([llvm.spec])
1590
1591 dnl Configure llvmc's Base plugin
1592 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1593
1594 dnl Do the first stage of configuration for llvm-config.in.
1595 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1596
1597 dnl Do special configuration of Makefiles
1598 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1599 AC_CONFIG_MAKEFILE(Makefile)
1600 AC_CONFIG_MAKEFILE(Makefile.common)
1601 AC_CONFIG_MAKEFILE(examples/Makefile)
1602 AC_CONFIG_MAKEFILE(lib/Makefile)
1603 AC_CONFIG_MAKEFILE(runtime/Makefile)
1604 AC_CONFIG_MAKEFILE(test/Makefile)
1605 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1606 AC_CONFIG_MAKEFILE(unittests/Makefile)
1607 AC_CONFIG_MAKEFILE(tools/Makefile)
1608 AC_CONFIG_MAKEFILE(utils/Makefile)
1609 AC_CONFIG_MAKEFILE(projects/Makefile)
1610 AC_CONFIG_MAKEFILE(bindings/Makefile)
1611 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1612
1613 dnl Finally, crank out the output
1614 AC_OUTPUT