autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.7.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=7
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Quit if it is an in-source build
  77 if test ${srcdir} == "." ; then
  78   AC_MSG_WARN([**************************************************************************************])
  79   AC_MSG_WARN([*                                                                                    *])
  80   AC_MSG_WARN([*                                   WARNING                                          *])
  81   AC_MSG_WARN([*                                                                                    *])
  82   AC_MSG_WARN([*                        In-source builds are deprecated.                            *])
  83   AC_MSG_WARN([*                                                                                    *])
  84   AC_MSG_WARN([*               Please configure from a separate build directory!                    *])
  85   AC_MSG_WARN([*                                                                                    *])
  86   AC_MSG_WARN([**************************************************************************************])
  87 fi
  88
  89 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  90 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  91 : ${CFLAGS=}
  92 : ${CXXFLAGS=}
  93
  94 dnl We need to check for the compiler up here to avoid anything else
  95 dnl starting with a different one.
  96 AC_PROG_CC(clang gcc)
  97 AC_PROG_CXX(clang++ g++)
  98 AC_PROG_CPP
  99
 100 dnl If CXX is Clang, check that it can find and parse C++ standard library
 101 dnl headers.
 102 if test "$CXX" = "clang++" ; then
 103   AC_MSG_CHECKING([whether clang works])
 104   AC_LANG_PUSH([C++])
 105   dnl Note that space between 'include' and '(' is required.  There's a broken
 106   dnl regex in aclocal that otherwise will think that we call m4's include
 107   dnl builtin.
 108   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
 109 #if __has_include (<cxxabi.h>)
 110 #include <cxxabi.h>
 111 #endif
 112 #if __has_include (<unwind.h>)
 113 #include <unwind.h>
 114 #endif
 115 ]])],
 116 [
 117   AC_MSG_RESULT([yes])
 118 ],
 119 [
 120   AC_MSG_RESULT([no])
 121   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler LLVM_SRC_DIR/configure ...])
 122 ])
 123   AC_LANG_POP([C++])
 124 fi
 125
 126 dnl Set up variables that track whether the host compiler is GCC or Clang where
 127 dnl we can effectively sanity check them. We don't try to sanity check all the
 128 dnl other possible compilers.
 129 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 130 AC_LANG_PUSH([C++])
 131 llvm_cv_cxx_compiler=unknown
 132 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 133                                     #error
 134                                     #endif
 135                                     ]])],
 136                   llvm_cv_cxx_compiler=clang,
 137                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 138                                                        #error
 139                                                        #endif
 140                                                        ]])],
 141                                      llvm_cv_cxx_compiler=gcc, [])])
 142 AC_LANG_POP([C++])
 143 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 144
 145 dnl Configure all of the projects present in our source tree. While we could
 146 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 147 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 148 dnl Instead we match on the known projects.
 149
 150 dnl
 151 dnl One tricky part of doing this is that some projects depend upon other
 152 dnl projects.  For example, several projects rely upon the LLVM test suite.
 153 dnl We want to configure those projects first so that their object trees are
 154 dnl created before running the configure scripts of projects that depend upon
 155 dnl them.
 156 dnl
 157
 158 dnl Several projects use the LLVM test suite, so configure it next.
 159 if test -d ${srcdir}/projects/test-suite ; then
 160   AC_CONFIG_SUBDIRS([projects/test-suite])
 161 fi
 162
 163 dnl llvm-test is the old name of the test-suite, kept here for backwards
 164 dnl compatibility
 165 if test -d ${srcdir}/projects/llvm-test ; then
 166   AC_CONFIG_SUBDIRS([projects/llvm-test])
 167 fi
 168
 169 dnl Some projects use poolalloc; configure that next
 170 if test -d ${srcdir}/projects/poolalloc ; then
 171   AC_CONFIG_SUBDIRS([projects/poolalloc])
 172 fi
 173
 174 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 175   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 176 fi
 177
 178 dnl Check for all other projects
 179 for i in `ls ${srcdir}/projects`
 180 do
 181   if test -d ${srcdir}/projects/${i} ; then
 182     case ${i} in
 183       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 184       compiler-rt)       ;;
 185       test-suite)     ;;
 186       llvm-test)      ;;
 187       poolalloc)      ;;
 188       llvm-poolalloc) ;;
 189       *)
 190         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 191         ;;
 192     esac
 193   fi
 194 done
 195
 196 dnl Disable the build of polly, even if it is checked out into tools/polly.
 197 AC_ARG_ENABLE(polly,
 198               AS_HELP_STRING([--enable-polly],
 199                              [Use polly if available (default is YES)]),,
 200                              enableval=default)
 201 case "$enableval" in
 202   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 203   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 204   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 205   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 206 esac
 207
 208
 209 dnl Check if polly is checked out into tools/polly and configure it if
 210 dnl available.
 211 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 212   AC_SUBST(LLVM_HAS_POLLY,1)
 213   AC_CONFIG_SUBDIRS([tools/polly])
 214 fi
 215
 216 dnl===-----------------------------------------------------------------------===
 217 dnl===
 218 dnl=== SECTION 2: Architecture, target, and host checks
 219 dnl===
 220 dnl===-----------------------------------------------------------------------===
 221
 222 dnl Check the target for which we're compiling and the host that will do the
 223 dnl compilations. This will tell us which LLVM compiler will be used for
 224 dnl compiling SSA into object code. This needs to be done early because
 225 dnl following tests depend on it.
 226 AC_CANONICAL_TARGET
 227
 228 dnl Determine the platform type and cache its value. This helps us configure
 229 dnl the System library to the correct build platform.
 230 AC_CACHE_CHECK([type of operating system we're going to host on],
 231                [llvm_cv_os_type],
 232 [case $host in
 233   *-*-aix*)
 234     llvm_cv_link_all_option="-Wl,--whole-archive"
 235     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 236     llvm_cv_os_type="AIX"
 237     llvm_cv_platform_type="Unix" ;;
 238   *-*-irix*)
 239     llvm_cv_link_all_option="-Wl,--whole-archive"
 240     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 241     llvm_cv_os_type="IRIX"
 242     llvm_cv_platform_type="Unix" ;;
 243   *-*-cygwin*)
 244     llvm_cv_link_all_option="-Wl,--whole-archive"
 245     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 246     llvm_cv_os_type="Cygwin"
 247     llvm_cv_platform_type="Unix" ;;
 248   *-*-darwin*)
 249     llvm_cv_link_all_option="-Wl,-all_load"
 250     llvm_cv_no_link_all_option="-Wl,-noall_load"
 251     llvm_cv_os_type="Darwin"
 252     llvm_cv_platform_type="Unix" ;;
 253   *-*-minix*)
 254     llvm_cv_link_all_option="-Wl,-all_load"
 255     llvm_cv_no_link_all_option="-Wl,-noall_load"
 256     llvm_cv_os_type="Minix"
 257     llvm_cv_platform_type="Unix" ;;
 258   *-*-freebsd*)
 259     llvm_cv_link_all_option="-Wl,--whole-archive"
 260     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 261     llvm_cv_os_type="FreeBSD"
 262     llvm_cv_platform_type="Unix" ;;
 263   *-*-kfreebsd-gnu)
 264     llvm_cv_link_all_option="-Wl,--whole-archive"
 265     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 266     llvm_cv_os_type="GNU/kFreeBSD"
 267     llvm_cv_platform_type="Unix" ;;
 268   *-*-openbsd*)
 269     llvm_cv_link_all_option="-Wl,--whole-archive"
 270     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 271     llvm_cv_os_type="OpenBSD"
 272     llvm_cv_platform_type="Unix" ;;
 273   *-*-netbsd*)
 274     llvm_cv_link_all_option="-Wl,--whole-archive"
 275     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 276     llvm_cv_os_type="NetBSD"
 277     llvm_cv_platform_type="Unix" ;;
 278   *-*-dragonfly*)
 279     llvm_cv_link_all_option="-Wl,--whole-archive"
 280     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 281     llvm_cv_os_type="DragonFly"
 282     llvm_cv_platform_type="Unix" ;;
 283   *-*-bitrig*)
 284     llvm_cv_link_all_option="-Wl,--whole-archive"
 285     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 286     llvm_cv_os_type="Bitrig"
 287     llvm_cv_platform_type="Unix" ;;
 288   *-*-hpux*)
 289     llvm_cv_link_all_option="-Wl,--whole-archive"
 290     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 291     llvm_cv_os_type="HP-UX"
 292     llvm_cv_platform_type="Unix" ;;
 293   *-*-interix*)
 294     llvm_cv_link_all_option="-Wl,--whole-archive"
 295     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 296     llvm_cv_os_type="Interix"
 297     llvm_cv_platform_type="Unix" ;;
 298   *-*-linux*)
 299     llvm_cv_link_all_option="-Wl,--whole-archive"
 300     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 301     llvm_cv_os_type="Linux"
 302     llvm_cv_platform_type="Unix" ;;
 303   *-*-gnu*)
 304     llvm_cv_link_all_option="-Wl,--whole-archive"
 305     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 306     llvm_cv_os_type="GNU"
 307     llvm_cv_platform_type="Unix" ;;
 308   *-*-solaris*)
 309     llvm_cv_link_all_option="-Wl,-z,allextract"
 310     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 311     llvm_cv_os_type="SunOS"
 312     llvm_cv_platform_type="Unix" ;;
 313   *-*-win32*)
 314     llvm_cv_link_all_option="-Wl,--whole-archive"
 315     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 316     llvm_cv_os_type="Win32"
 317     llvm_cv_platform_type="Win32" ;;
 318   *-*-mingw*)
 319     llvm_cv_link_all_option="-Wl,--whole-archive"
 320     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 321     llvm_cv_os_type="MingW"
 322     llvm_cv_platform_type="Win32" ;;
 323   *-*-haiku*)
 324     llvm_cv_link_all_option="-Wl,--whole-archive"
 325     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 326     llvm_cv_os_type="Haiku"
 327     llvm_cv_platform_type="Unix" ;;
 328   *-unknown-eabi*)
 329     llvm_cv_link_all_option="-Wl,--whole-archive"
 330     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 331     llvm_cv_os_type="Freestanding"
 332     llvm_cv_platform_type="Unix" ;;
 333   *-unknown-elf*)
 334     llvm_cv_link_all_option="-Wl,--whole-archive"
 335     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 336     llvm_cv_os_type="Freestanding"
 337     llvm_cv_platform_type="Unix" ;;
 338   *)
 339     llvm_cv_link_all_option=""
 340     llvm_cv_no_link_all_option=""
 341     llvm_cv_os_type="Unknown"
 342     llvm_cv_platform_type="Unknown" ;;
 343 esac])
 344
 345 AC_CACHE_CHECK([type of operating system we're going to target],
 346                [llvm_cv_target_os_type],
 347 [case $target in
 348   *-*-aix*)
 349     llvm_cv_target_os_type="AIX" ;;
 350   *-*-irix*)
 351     llvm_cv_target_os_type="IRIX" ;;
 352   *-*-cygwin*)
 353     llvm_cv_target_os_type="Cygwin" ;;
 354   *-*-darwin*)
 355     llvm_cv_target_os_type="Darwin" ;;
 356   *-*-minix*)
 357     llvm_cv_target_os_type="Minix" ;;
 358   *-*-freebsd*)
 359     llvm_cv_target_os_type="FreeBSD" ;;
 360   *-*-kfreebsd-gnu)
 361     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 362   *-*-openbsd*)
 363     llvm_cv_target_os_type="OpenBSD" ;;
 364   *-*-netbsd*)
 365     llvm_cv_target_os_type="NetBSD" ;;
 366   *-*-dragonfly*)
 367     llvm_cv_target_os_type="DragonFly" ;;
 368   *-*-bitrig*)
 369     llvm_cv_target_os_type="Bitrig" ;;
 370   *-*-hpux*)
 371     llvm_cv_target_os_type="HP-UX" ;;
 372   *-*-interix*)
 373     llvm_cv_target_os_type="Interix" ;;
 374   *-*-linux*)
 375     llvm_cv_target_os_type="Linux" ;;
 376   *-*-gnu*)
 377     llvm_cv_target_os_type="GNU" ;;
 378   *-*-solaris*)
 379     llvm_cv_target_os_type="SunOS" ;;
 380   *-*-win32*)
 381     llvm_cv_target_os_type="Win32" ;;
 382   *-*-mingw*)
 383     llvm_cv_target_os_type="MingW" ;;
 384   *-*-haiku*)
 385     llvm_cv_target_os_type="Haiku" ;;
 386   *-*-rtems*)
 387     llvm_cv_target_os_type="RTEMS" ;;
 388   *-*-nacl*)
 389     llvm_cv_target_os_type="NativeClient" ;;
 390   *-unknown-eabi*)
 391     llvm_cv_target_os_type="Freestanding" ;;
 392   *-*-ps4)
 393     llvm_cv_target_os_type="PS4" ;;
 394   *)
 395     llvm_cv_target_os_type="Unknown" ;;
 396 esac])
 397
 398 dnl Make sure we aren't attempting to configure for an unknown system
 399 if test "$llvm_cv_os_type" = "Unknown" ; then
 400   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 401 fi
 402
 403 dnl Set the "OS" Makefile variable based on the platform type so the
 404 dnl makefile can configure itself to specific build hosts
 405 AC_SUBST(OS,$llvm_cv_os_type)
 406 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 407 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 408
 409 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 410 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 411 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 412
 413 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 414 dnl This is used by lib/Support to determine the basic kind of implementation
 415 dnl to use.
 416 case $llvm_cv_platform_type in
 417   Unix)
 418     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 419     AC_SUBST(LLVM_ON_UNIX,[1])
 420     AC_SUBST(LLVM_ON_WIN32,[0])
 421     ;;
 422   Win32)
 423     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 424     AC_SUBST(LLVM_ON_UNIX,[0])
 425     AC_SUBST(LLVM_ON_WIN32,[1])
 426     ;;
 427 esac
 428
 429 dnl Determine what our target architecture is and configure accordingly.
 430 dnl This will allow Makefiles to make a distinction between the hardware and
 431 dnl the OS.
 432 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 433 [case $target in
 434   i?86-*)                 llvm_cv_target_arch="x86" ;;
 435   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 436   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 437   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 438   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 439   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 440   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 441   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 442   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 443   xcore-*)                llvm_cv_target_arch="XCore" ;;
 444   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 445   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 446   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 447   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 448   wasm*-*)                llvm_cv_target_arch="WebAssembly" ;;
 449   *)                      llvm_cv_target_arch="Unknown" ;;
 450 esac])
 451
 452 if test "$llvm_cv_target_arch" = "Unknown" ; then
 453   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 454 fi
 455
 456 dnl Determine the LLVM native architecture for the target
 457 case "$llvm_cv_target_arch" in
 458     x86)     LLVM_NATIVE_ARCH="X86" ;;
 459     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 460     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 461 esac
 462
 463 dnl Define a substitution, ARCH, for the target architecture
 464 AC_SUBST(ARCH,$llvm_cv_target_arch)
 465 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 466
 467 dnl Determine what our host architecture.
 468 dnl This will allow MCJIT regress tests runs only for supported
 469 dnl platforms.
 470 case $host in
 471   i?86-*)                 host_arch="x86" ;;
 472   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 473   sparc*-*)               host_arch="Sparc" ;;
 474   powerpc*-*)             host_arch="PowerPC" ;;
 475   arm64*-*)               host_arch="AArch64" ;;
 476   arm*-*)                 host_arch="ARM" ;;
 477   aarch64*-*)             host_arch="AArch64" ;;
 478   mips-* | mips64-*)      host_arch="Mips" ;;
 479   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 480   xcore-*)                host_arch="XCore" ;;
 481   msp430-*)               host_arch="MSP430" ;;
 482   hexagon-*)              host_arch="Hexagon" ;;
 483   s390x-*)                host_arch="SystemZ" ;;
 484   wasm*-*)                host_arch="WebAssembly" ;;
 485   *)                      host_arch="Unknown" ;;
 486 esac
 487
 488 if test "$host_arch" = "Unknown" ; then
 489   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 490 fi
 491
 492 AC_SUBST(HOST_ARCH,$host_arch)
 493
 494 dnl Check for build platform executable suffix if we're cross-compiling
 495 if test "$cross_compiling" = yes; then
 496   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 497   AC_BUILD_EXEEXT
 498   ac_build_prefix=${build_alias}-
 499   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 500   if test -z "$BUILD_CXX"; then
 501      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 502      if test -z "$BUILD_CXX"; then
 503        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 504      fi
 505   fi
 506 else
 507   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 508 fi
 509
 510 dnl Check to see if there's a .svn or .git directory indicating that this
 511 dnl build is being done from a checkout. This sets up several defaults for
 512 dnl the command line switches. When we build with a checkout directory,
 513 dnl we get a debug with assertions turned on. Without, we assume a source
 514 dnl release and we get an optimized build without assertions.
 515 dnl See --enable-optimized and --enable-assertions below
 516 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 517   cvsbuild="yes"
 518   optimize="no"
 519   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 520 else
 521   cvsbuild="no"
 522   optimize="yes"
 523 fi
 524
 525 dnl===-----------------------------------------------------------------------===
 526 dnl===
 527 dnl=== SECTION 3: Command line arguments for the configure script.
 528 dnl===
 529 dnl===-----------------------------------------------------------------------===
 530
 531 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 532 AC_ARG_ENABLE(libcpp,
 533               AS_HELP_STRING([--enable-libcpp],
 534                              [Use libc++ if available (default is NO)]),,
 535                              enableval=default)
 536 case "$enableval" in
 537   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 538   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 539   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 540   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 541 esac
 542
 543 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 544 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 545 dnl these checks here so that we have the configuration of the standard C++
 546 dnl library finished.
 547 AC_ARG_ENABLE(compiler-version-checks,
 548               AS_HELP_STRING([--enable-compiler-version-checks],
 549                              [Check the version of the host compiler (default is YES)]),,
 550                              enableval=default)
 551 case "$enableval" in
 552   no)
 553     ;;
 554   yes|default)
 555     AC_LANG_PUSH([C++])
 556     case "$llvm_cv_cxx_compiler" in
 557     clang)
 558       AC_MSG_CHECKING([whether Clang is new enough])
 559       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 560 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 561 #error This version of Clang is too old to build LLVM
 562 #endif
 563 ]])],
 564           [AC_MSG_RESULT([yes])],
 565           [AC_MSG_RESULT([no])
 566            AC_MSG_ERROR([
 567 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 568 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 569 bypass these sanity checks.])])
 570
 571       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 572       dnl are sometimes deeply confusing though. Here we test for an obvious
 573       dnl incomplete feature in 4.6's standard library that was completed in
 574       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 575       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 576       dnl that happening in the Makefile.
 577       if test "$ENABLE_LIBCPP" -eq 0 ; then
 578         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 579         llvm_cv_old_cxxflags="$CXXFLAGS"
 580         CXXFLAGS="$CXXFLAGS -std=c++0x"
 581         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 582 #include <atomic>
 583 std::atomic<float> x(0.0f);
 584 int main() { return (float)x; }
 585 ]])],
 586             [AC_MSG_RESULT([yes])],
 587             [AC_MSG_RESULT([no])
 588              AC_MSG_ERROR([
 589 We detected a missing feature in the standard C++ library that was known to be
 590 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 591 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 592 than 4.7. You will need to update your system and ensure Clang uses the newer
 593 standard library.
 594
 595 If this error is incorrect or you need to force things to work, you may pass
 596 '--disable-compiler-version-checks' to configure to bypass this test.])])
 597         CXXFLAGS="$llvm_cv_old_cxxflags"
 598       fi
 599       ;;
 600     gcc)
 601       AC_MSG_CHECKING([whether GCC is new enough])
 602       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 603 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 604 #error This version of GCC is too old to build LLVM
 605 #endif
 606 ]])],
 607           [AC_MSG_RESULT([yes])],
 608           [AC_MSG_RESULT([no])
 609            AC_MSG_ERROR([
 610 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 611 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 612 bypass these sanity checks.])])
 613       ;;
 614     unknown)
 615       ;;
 616     esac
 617     AC_LANG_POP([C++])
 618     ;;
 619   *)
 620     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 621     ;;
 622 esac
 623
 624 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 625 AC_ARG_ENABLE(cxx1y,
 626               AS_HELP_STRING([--enable-cxx1y],
 627                              [Use c++1y if available (default is NO)]),,
 628                              enableval=default)
 629 case "$enableval" in
 630   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 631   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 632   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 633   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 634 esac
 635
 636 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 637 dnl line
 638 AC_ARG_ENABLE(split-dwarf,
 639               AS_HELP_STRING([--enable-split-dwarf],
 640                              [Use split-dwarf if available (default is NO)]),,
 641                              enableval=default)
 642 case "$enableval" in
 643   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 644   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 645   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 646   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 647 esac
 648
 649 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 650 clang_arcmt="yes"
 651 AC_ARG_ENABLE(clang-arcmt,
 652               AS_HELP_STRING([--enable-clang-arcmt],
 653                              [Enable building of clang ARCMT (default is YES)]),
 654                              clang_arcmt="$enableval",
 655                              enableval="yes")
 656 case "$enableval" in
 657   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 658   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 659   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 660   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 661 esac
 662
 663 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 664 clang_plugin_support="yes"
 665 AC_ARG_ENABLE(clang-plugin-support,
 666               AS_HELP_STRING([--enable-clang-plugin-support],
 667                              [Enable plugin support in clang (default is YES)]),
 668                              clang_plugin_support="$enableval",
 669                              enableval="yes")
 670 case "$enableval" in
 671   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 672   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 673   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 674   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 675 esac
 676
 677 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 678 clang_static_analyzer="yes"
 679 AC_ARG_ENABLE(clang-static-analyzer,
 680               AS_HELP_STRING([--enable-clang-static-analyzer],
 681                              [Enable building of clang Static Analyzer (default is YES)]),
 682                              clang_static_analyzer="$enableval",
 683                              enableval="yes")
 684 case "$enableval" in
 685   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 686   no)
 687     if test ${clang_arcmt} != "no" ; then
 688       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 689     fi
 690     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 691     ;;
 692   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 693   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 694 esac
 695
 696 dnl --enable-optimized : check whether they want to do an optimized build:
 697 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 698  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 699 if test ${enableval} = "no" ; then
 700   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 701 else
 702   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 703 fi
 704
 705 dnl --enable-profiling : check whether they want to do a profile build:
 706 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 707  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 708 if test ${enableval} = "no" ; then
 709   AC_SUBST(ENABLE_PROFILING,[[]])
 710 else
 711   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 712 fi
 713
 714 dnl --enable-assertions : check whether they want to turn on assertions or not:
 715 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 716   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 717 if test ${enableval} = "yes" ; then
 718   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 719   assertions_enabled="yes"
 720 else
 721   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 722   assertions_enabled="no"
 723 fi
 724
 725 dnl --enable-werror : check whether we want Werror on by default
 726 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 727   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 728 case "$enableval" in
 729   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 730   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 731   default) AC_SUBST(ENABLE_WERROR,[0]);;
 732   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 733 esac
 734
 735 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 736 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 737   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 738 if test ${enableval} = "yes" ; then
 739   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 740   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 741 else
 742   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 743   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 744 fi
 745
 746 dnl --enable-abi-breaking-checks : decide whether we should compile in asserts and
 747 dnl checks that make the build ABI incompatible with an llvm built without these
 748 dnl checks enabled.
 749 AC_ARG_ENABLE(abi-breaking-checks,AS_HELP_STRING(
 750   --enable-abi-breaking-checks,[Compile with abi-breaking asserts support (default is with-asserts)]),, enableval="with-asserts")
 751 case "$enableval" in
 752   with-asserts)  if test ${assertions_enabled} = "yes" ; then
 753                    AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 754                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 755                  else
 756                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 757                  fi ;;
 758   yes)
 759                  AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 760                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 761                  ;;
 762   no)
 763                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 764                  ;;
 765   *) AC_MSG_ERROR([Invalid setting for --enable-abi-breaking-checks.  Use "with-asserts", "yes" or "no"])
 766 esac
 767
 768 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 769 AC_ARG_ENABLE(debug-runtime,
 770    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 771 if test ${enableval} = "no" ; then
 772   AC_SUBST(DEBUG_RUNTIME,[[]])
 773 else
 774   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 775 fi
 776
 777 dnl --enable-debug-symbols : should even optimized compiler libraries
 778 dnl have debug symbols?
 779 AC_ARG_ENABLE(debug-symbols,
 780    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 781 if test ${enableval} = "no" ; then
 782   AC_SUBST(DEBUG_SYMBOLS,[[]])
 783 else
 784   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 785 fi
 786
 787 dnl --enable-keep-symbols : do not strip installed executables
 788 AC_ARG_ENABLE(keep-symbols,
 789    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 790 if test ${enableval} = "no" ; then
 791   AC_SUBST(KEEP_SYMBOLS,[[]])
 792 else
 793   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 794 fi
 795
 796 dnl --enable-jit: check whether they want to enable the jit
 797 AC_ARG_ENABLE(jit,
 798   AS_HELP_STRING(--enable-jit,
 799                  [Enable Just In Time Compiling (default is YES)]),,
 800   enableval=default)
 801 if test ${enableval} = "no"
 802 then
 803   AC_SUBST(JIT,[[]])
 804 else
 805   case "$llvm_cv_target_arch" in
 806     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 807     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 808     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 809     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 810     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 811     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 812     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 813     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 814     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 815     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 816     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 817     WebAssembly) AC_SUBST(TARGET_HAS_JIT,0) ;;
 818     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 819   esac
 820 fi
 821
 822 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 823 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 824
 825 dnl Allow enablement of building and installing docs
 826 AC_ARG_ENABLE(docs,
 827               AS_HELP_STRING([--enable-docs],
 828                              [Build documents (default is YES)]),,
 829                              enableval=default)
 830 case "$enableval" in
 831   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 832   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 833   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 834   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 835 esac
 836
 837 dnl Allow enablement of doxygen generated documentation
 838 AC_ARG_ENABLE(doxygen,
 839               AS_HELP_STRING([--enable-doxygen],
 840                              [Build doxygen documentation (default is NO)]),,
 841                              enableval=default)
 842 case "$enableval" in
 843   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 844   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 845   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 846 esac
 847
 848 dnl Allow enablement of doxygen search engine
 849 AC_ARG_ENABLE(doxygen-search,
 850               AS_HELP_STRING([--enable-doxygen-search],
 851                              [Enable doxygen search support (default is NO)]),,
 852                              enableval=default)
 853 ENABLE_DOXYGEN_SEARCH="$enableval"
 854
 855 case "$enableval" in
 856   yes|no|default) ;;
 857   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 858 esac
 859
 860 AC_ARG_ENABLE(doxygen-external-search,
 861               AS_HELP_STRING([--enable-doxygen-external-search],
 862                              [Enable doxygen exteranl search (default is NO)]),,
 863                              enableval=default)
 864 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 865
 866 case "$enableval" in
 867   yes)
 868     dnl To match with the CMake behavior, enable doxygen when
 869     dnl --enable-doxygen-external-search is enabled.
 870     case "$ENABLE_DOXYGEN_SEARCH" in
 871       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 872       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 873     esac
 874     ;;
 875   no|default) ;;
 876   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 877 esac
 878
 879 AC_ARG_WITH(doxygen-search-engine-url,
 880             AS_HELP_STRING([--with-doxygen-search-engine-url],
 881                            [Specify the external search engine for doxygen]),,)
 882 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 883
 884 AC_ARG_WITH(doxygen-search-mappings,
 885             AS_HELP_STRING([--with-doxygen-search-mappings],
 886                            [Specify the extra search mapping for doxygen]),,)
 887 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 888
 889 case "$ENABLE_DOXYGEN_SEARCH" in
 890   yes)
 891     if test "$ENABLE_DOXYGEN" = "0" ; then
 892       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 893     fi
 894
 895     AC_SUBST(enable_searchengine,[YES])
 896
 897     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 898       yes)
 899         AC_SUBST(enable_external_search,[YES])
 900         AC_SUBST(enable_server_based_search,[YES])
 901         AC_SUBST(searchengine_url,["$WITH_DOXYGEN_SEARCH_ENGINE_URL"])
 902         AC_SUBST(extra_search_mappings,["$WITH_DOXYGEN_SEARCH_MAPPINGS"])
 903         ;;
 904
 905       no|default)
 906         AC_SUBST(enable_external_search,[NO])
 907         AC_SUBST(enable_server_based_search,[NO])
 908         AC_SUBST(searchengine_url,[])
 909         AC_SUBST(extra_search_mappings,[])
 910         ;;
 911     esac
 912     ;;
 913
 914   no|default)
 915     AC_SUBST(enable_searchengine,[NO])
 916     AC_SUBST(searchengine_url,[])
 917     AC_SUBST(enable_server_based_search,[NO])
 918     AC_SUBST(enable_external_search,[NO])
 919     AC_SUBST(extra_search_mappings,[])
 920     ;;
 921
 922   *)
 923     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 924     ;;
 925 esac
 926
 927 dnl Allow enablement of doxygen generated Qt help files
 928 AC_ARG_ENABLE(doxygen-qt-help,
 929               AS_HELP_STRING([--enable-doxygen-qt-help],
 930                              [Build Qt help files (default is NO)]),,
 931                              enableval=default)
 932 case "$enableval" in
 933   yes)
 934     if test "$ENABLE_DOXYGEN" = "0" ; then
 935       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 936     fi
 937
 938     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 939
 940     dnl Qt help file for llvm doxygen documentation
 941     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 942     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 943     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 944     AC_SUBST(llvm_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 945     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,["$PACKAGE_STRING"])
 946     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,["$PACKAGE_NAME,$PACKAGE_VERSION"])
 947
 948     dnl Qt help file for clang doxygen documentation
 949     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 950     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 951     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 952     AC_SUBST(clang_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 953     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 954     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 955     ;;
 956
 957   no|default)
 958     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 959     AC_SUBST(llvm_doxygen_qch_filename,[])
 960     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 961     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 962     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 963     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 964
 965     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 966     AC_SUBST(clang_doxygen_qch_filename,[])
 967     AC_SUBST(clang_doxygen_qhp_namespace,[])
 968     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 969     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 970     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 971     ;;
 972
 973   *)
 974     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 975 esac
 976
 977 dnl Allow disablement of threads
 978 AC_ARG_ENABLE(threads,
 979               AS_HELP_STRING([--enable-threads],
 980                              [Use threads if available (default is YES)]),,
 981                              enableval=default)
 982 case "$enableval" in
 983   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 984   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 985   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 986   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 987 esac
 988 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 989                    [Define if threads enabled])
 990
 991 dnl Allow disablement of pthread.h
 992 AC_ARG_ENABLE(pthreads,
 993               AS_HELP_STRING([--enable-pthreads],
 994                              [Use pthreads if available (default is YES)]),,
 995                              enableval=default)
 996 case "$enableval" in
 997   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 998   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 999   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
1000   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
1001 esac
1002
1003 dnl Allow disablement of zlib
1004 AC_ARG_ENABLE(zlib,
1005               AS_HELP_STRING([--enable-zlib],
1006                              [Use zlib for compression/decompression if
1007                               available (default is YES)]),,
1008                               enableval=default)
1009 case "$enableval" in
1010   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1011   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
1012   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1013   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
1014 esac
1015 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
1016                    [Define if zlib is enabled])
1017
1018 dnl Allow building without position independent code
1019 AC_ARG_ENABLE(pic,
1020   AS_HELP_STRING([--enable-pic],
1021                  [Build LLVM with Position Independent Code (default is YES)]),,
1022                  enableval=default)
1023 case "$enableval" in
1024   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
1025   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
1026   default) AC_SUBST(ENABLE_PIC,[1]) ;;
1027   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
1028 esac
1029 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
1030                    [Define if position independent code is enabled])
1031
1032 dnl Allow building a shared library and linking tools against it.
1033 AC_ARG_ENABLE(shared,
1034   AS_HELP_STRING([--enable-shared],
1035                  [Build a shared library and link tools against it (default is NO)]),,
1036                  enableval=default)
1037 case "$enableval" in
1038   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
1039   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1040   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1041   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1042 esac
1043
1044 dnl Allow libstdc++ is embedded in LLVM.dll.
1045 AC_ARG_ENABLE(embed-stdcxx,
1046   AS_HELP_STRING([--enable-embed-stdcxx],
1047                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1048                  enableval=default)
1049 case "$enableval" in
1050   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1051   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1052   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1053   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1054 esac
1055
1056 dnl Enable embedding timestamp information into build.
1057 AC_ARG_ENABLE(timestamps,
1058   AS_HELP_STRING([--enable-timestamps],
1059                  [Enable embedding timestamp information in build (default is YES)]),,
1060                  enableval=default)
1061 case "$enableval" in
1062   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1063   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1064   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1065   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1066 esac
1067 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1068                    [Define if timestamp information (e.g., __DATE__) is allowed])
1069
1070 dnl Enable support for showing backtraces.
1071 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1072   [--enable-backtraces],
1073   [Enable embedding backtraces on crash (default is YES)]),
1074   [case "$enableval" in
1075     yes) llvm_cv_enable_backtraces="yes" ;;
1076     no)  llvm_cv_enable_backtraces="no"  ;;
1077     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1078   esac],
1079   llvm_cv_enable_backtraces="yes")
1080 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1081   AC_DEFINE([ENABLE_BACKTRACES],[1],
1082             [Define if you want backtraces on crash])
1083 fi
1084
1085 dnl Enable installing platform specific signal handling overrides, for improved
1086 dnl CrashRecovery support or interaction with crash reporting software. This
1087 dnl support may be inappropriate for some clients embedding LLVM as a library.
1088 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1089   [--enable-crash-overrides],
1090   [Enable crash handling overrides (default is YES)]),
1091   [case "$enableval" in
1092     yes) llvm_cv_enable_crash_overrides="yes" ;;
1093     no)  llvm_cv_enable_crash_overrides="no"  ;;
1094     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1095   esac],
1096   llvm_cv_enable_crash_overrides="yes")
1097 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1098   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1099             [Define to enable crash handling overrides])
1100 fi
1101
1102 dnl List all possible targets
1103 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ AMDGPU BPF"
1104 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1105
1106 dnl Allow specific targets to be specified for building (or not)
1107 TARGETS_TO_BUILD=""
1108 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1109     [Build specific host targets: all or target1,target2,... Valid targets are:
1110      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1111      xcore, msp430, nvptx, systemz, r600, bpf, wasm, and cpp (default=all)]),,
1112     enableval=all)
1113 if test "$enableval" = host-only ; then
1114   enableval=host
1115 fi
1116 case "$enableval" in
1117   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1118   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1119       case "$a_target" in
1120         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1121         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1122         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1123         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1124         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1125         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1126         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1127         bpf)      TARGETS_TO_BUILD="BPF $TARGETS_TO_BUILD" ;;
1128         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1129         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1130         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1131         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1132         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1133         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1134         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1135         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1136         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1137         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1138         amdgpu)   TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1139         r600)     TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1140         wasm)     TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1141         host) case "$llvm_cv_target_arch" in
1142             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1143             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1144             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1145             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1146             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1147             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1148             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1149             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1150             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1151             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1152             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1153             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1154             WebAssembly) TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1155             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1156           esac ;;
1157         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1158       esac
1159   done
1160   ;;
1161 esac
1162
1163 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1164     [Build experimental host targets: disable or target1,target2,...
1165      (default=disable)]),,
1166     enableval=disable)
1167
1168 if test ${enableval} != "disable"
1169 then
1170   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1171 fi
1172
1173 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1174
1175 dnl Determine whether we are building LLVM support for the native architecture.
1176 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1177 for a_target in $TARGETS_TO_BUILD; do
1178   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1179     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1180       [LLVM architecture name for the native architecture, if available])
1181     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1182     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1183     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1184     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1185     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1186       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1187     fi
1188     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1189       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1190     fi
1191     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1192       [LLVM name for the native Target init function, if available])
1193     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1194       [LLVM name for the native TargetInfo init function, if available])
1195     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1196       [LLVM name for the native target MC init function, if available])
1197     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1198       [LLVM name for the native AsmPrinter init function, if available])
1199     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1200       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1201        [LLVM name for the native AsmParser init function, if available])
1202     fi
1203     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1204       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1205        [LLVM name for the native Disassembler init function, if available])
1206     fi
1207   fi
1208 done
1209
1210 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1211 dnl target feature def files.
1212 LLVM_ENUM_TARGETS=""
1213 LLVM_ENUM_ASM_PRINTERS=""
1214 LLVM_ENUM_ASM_PARSERS=""
1215 LLVM_ENUM_DISASSEMBLERS=""
1216 for target_to_build in $TARGETS_TO_BUILD; do
1217   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1218   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1219     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1220   fi
1221   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1222     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1223   fi
1224   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1225     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1226   fi
1227 done
1228 AC_SUBST(LLVM_ENUM_TARGETS)
1229 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1230 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1231 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1232
1233 dnl Override the option to use for optimized builds.
1234 AC_ARG_WITH(optimize-option,
1235   AS_HELP_STRING([--with-optimize-option],
1236                  [Select the compiler options to use for optimized builds]),,
1237                  withval=default)
1238 AC_MSG_CHECKING([optimization flags])
1239 case "$withval" in
1240   default)
1241     case "$llvm_cv_os_type" in
1242     FreeBSD) optimize_option=-O2 ;;
1243     MingW) optimize_option=-O2 ;;
1244     *)     optimize_option=-O3 ;;
1245     esac ;;
1246   *) optimize_option="$withval" ;;
1247 esac
1248 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1249 AC_MSG_RESULT([$optimize_option])
1250
1251 dnl Specify extra build options
1252 AC_ARG_WITH(extra-options,
1253   AS_HELP_STRING([--with-extra-options],
1254                  [Specify additional options to compile LLVM with]),,
1255                  withval=default)
1256 case "$withval" in
1257   default) EXTRA_OPTIONS= ;;
1258   *) EXTRA_OPTIONS=$withval ;;
1259 esac
1260 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1261
1262 dnl Specify extra linker build options
1263 AC_ARG_WITH(extra-ld-options,
1264   AS_HELP_STRING([--with-extra-ld-options],
1265                  [Specify additional options to link LLVM with]),,
1266                  withval=default)
1267 case "$withval" in
1268   default) EXTRA_LD_OPTIONS= ;;
1269   *) EXTRA_LD_OPTIONS=$withval ;;
1270 esac
1271 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1272
1273 dnl Allow specific bindings to be specified for building (or not)
1274 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1275     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1276     enableval=default)
1277 BINDINGS_TO_BUILD=""
1278 case "$enableval" in
1279   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1280   all ) BINDINGS_TO_BUILD="ocaml" ;;
1281   none | no) BINDINGS_TO_BUILD="" ;;
1282   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1283       case "$a_binding" in
1284         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1285         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1286       esac
1287   done
1288   ;;
1289 esac
1290
1291 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1292 dnl script for bindings/ocaml/configure, except that its auto value depends on
1293 dnl OCAMLC, which is found here to support tests.
1294 AC_ARG_WITH([ocaml-libdir],
1295   [AS_HELP_STRING([--with-ocaml-libdir],
1296     [Specify install location for ocaml bindings (default is stdlib)])],
1297   [],
1298   [withval=auto])
1299 case "$withval" in
1300   auto) with_ocaml_libdir="$withval" ;;
1301   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1302   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1303 esac
1304
1305 AC_ARG_WITH(clang-srcdir,
1306   AS_HELP_STRING([--with-clang-srcdir],
1307     [Directory to the out-of-tree Clang source]),,
1308     withval="-")
1309 case "$withval" in
1310   -) clang_src_root="" ;;
1311   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1312   *) clang_src_root="$ac_pwd/$withval" ;;
1313 esac
1314 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1315
1316 AC_ARG_WITH(clang-resource-dir,
1317   AS_HELP_STRING([--with-clang-resource-dir],
1318     [Relative directory from the Clang binary for resource files]),,
1319     withval="")
1320 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1321                    [Relative directory for resource files])
1322
1323 AC_ARG_WITH(c-include-dirs,
1324   AS_HELP_STRING([--with-c-include-dirs],
1325     [Colon separated list of directories clang will search for headers]),,
1326     withval="")
1327 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1328                    [Directories clang will search for headers])
1329
1330 # Clang normally uses the system c++ headers and libraries. With this option,
1331 # clang will use the ones provided by a gcc installation instead. This option should
1332 # be passed the same value that was used with --prefix when configuring gcc.
1333 AC_ARG_WITH(gcc-toolchain,
1334   AS_HELP_STRING([--with-gcc-toolchain],
1335     [Directory where gcc is installed.]),,
1336     withval="")
1337 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1338                    [Directory where gcc is installed.])
1339
1340 AC_ARG_WITH(default-sysroot,
1341   AS_HELP_STRING([--with-default-sysroot],
1342     [Add --sysroot=<path> to all compiler invocations.]),,
1343     withval="")
1344 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1345                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1346
1347 AC_ARG_WITH(clang-default-openmp-runtime,
1348   AS_HELP_STRING([--with-clang-default-openmp-runtime],
1349     [The default OpenMP runtime for Clang.]),,
1350     withval="libgomp")
1351 AC_DEFINE_UNQUOTED(CLANG_DEFAULT_OPENMP_RUNTIME,"$withval",
1352                    [Default OpenMP runtime used by -fopenmp.])
1353
1354 dnl Allow linking of LLVM with GPLv3 binutils code.
1355 AC_ARG_WITH(binutils-include,
1356   AS_HELP_STRING([--with-binutils-include],
1357     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1358   withval=default)
1359 case "$withval" in
1360   default) WITH_BINUTILS_INCDIR=default ;;
1361   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1362   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1363 esac
1364 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1365   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1366   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1367      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1368      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1369   fi
1370 fi
1371
1372 dnl Specify the URL where bug reports should be submitted.
1373 AC_ARG_WITH(bug-report-url,
1374   AS_HELP_STRING([--with-bug-report-url],
1375     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1376     withval="http://llvm.org/bugs/")
1377 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1378                    [Bug report URL.])
1379
1380 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1381 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1382   [--enable-terminfo],
1383   [Query the terminfo database if available (default is YES)]),
1384   [case "$enableval" in
1385     yes) llvm_cv_enable_terminfo="yes" ;;
1386     no)  llvm_cv_enable_terminfo="no"  ;;
1387     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1388   esac],
1389   llvm_cv_enable_terminfo="yes")
1390 case "$llvm_cv_enable_terminfo" in
1391   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1392   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1393 esac
1394
1395 dnl --enable-libedit: check whether the user wants to turn off libedit.
1396 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1397   [--enable-libedit],
1398   [Use libedit if available (default is YES)]),
1399   [case "$enableval" in
1400     yes) llvm_cv_enable_libedit="yes" ;;
1401     no)  llvm_cv_enable_libedit="no"  ;;
1402     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1403   esac],
1404   llvm_cv_enable_libedit="yes")
1405
1406 dnl --enable-libffi : check whether the user wants to turn off libffi:
1407 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1408   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1409   [case "$enableval" in
1410     yes) llvm_cv_enable_libffi="yes" ;;
1411     no)  llvm_cv_enable_libffi="no"  ;;
1412     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1413   esac],
1414   llvm_cv_enable_libffi=no)
1415
1416 AC_ARG_WITH(internal-prefix,
1417   AS_HELP_STRING([--with-internal-prefix],
1418     [Installation directory for internal files]),,
1419     withval="")
1420 AC_SUBST(INTERNAL_PREFIX,[$withval])
1421
1422 dnl===-----------------------------------------------------------------------===
1423 dnl===
1424 dnl=== SECTION 4: Check for programs we need and that they are the right version
1425 dnl===
1426 dnl===-----------------------------------------------------------------------===
1427
1428 dnl Check for the tools that the makefiles require
1429 AC_CHECK_GNU_MAKE
1430 AC_PROG_LN_S
1431 AC_PATH_PROG(NM, [nm], [nm])
1432 AC_PATH_PROG(CMP, [cmp], [cmp])
1433 AC_PATH_PROG(CP, [cp], [cp])
1434 AC_PATH_PROG(DATE, [date], [date])
1435 AC_PATH_PROG(FIND, [find], [find])
1436 AC_PATH_PROG(GREP, [grep], [grep])
1437 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1438 AC_PATH_PROG(MV,   [mv],   [mv])
1439 AC_PROG_RANLIB
1440 AC_CHECK_TOOL(AR, ar, false)
1441 AC_PATH_PROG(RM,   [rm],   [rm])
1442 AC_PATH_PROG(SED,  [sed],  [sed])
1443 AC_PATH_PROG(TAR,  [tar],  [gtar])
1444 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1445
1446 dnl Looking for misc. graph plotting software
1447 AC_PATH_PROG(DOT, [dot], [echo dot])
1448 if test "$DOT" != "echo dot" ; then
1449   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1450   dnl If we're targeting for mingw we should emit windows paths, not msys
1451   if test "$llvm_cv_os_type" = "MingW" ; then
1452     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1453   fi
1454   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1455    [Define to path to dot program if found or 'echo dot' otherwise])
1456 fi
1457
1458 dnl Find the install program
1459 AC_PROG_INSTALL
1460 dnl Prepend src dir to install path dir if it's a relative path
1461 dnl This is a hack for installs that take place in something other
1462 dnl than the top level.
1463 case "$INSTALL" in
1464  [[\\/$]]* | ?:[[\\/]]* ) ;;
1465  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1466 esac
1467
1468 dnl Checks for documentation and testing tools that we can do without. If these
1469 dnl are not found then they are set to "true" which always succeeds but does
1470 dnl nothing. This just lets the build output show that we could have done
1471 dnl something if the tool was available.
1472 AC_PATH_PROG(BZIP2, [bzip2])
1473 AC_PATH_PROG(CAT, [cat])
1474 AC_PATH_PROG(DOXYGEN, [doxygen])
1475 AC_PATH_PROG(GROFF, [groff])
1476 AC_PATH_PROG(GZIPBIN, [gzip])
1477 AC_PATH_PROG(PDFROFF, [pdfroff])
1478 AC_PATH_PROG(ZIP, [zip])
1479 AC_PATH_PROG(GO, [go])
1480 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1481 AC_PATH_PROGS(GAS, [gas as])
1482
1483 dnl Get the version of the linker in use.
1484 AC_LINK_GET_VERSION
1485
1486 dnl Determine whether the linker supports the -R option.
1487 AC_LINK_USE_R
1488
1489 dnl Determine whether the compiler supports the -rdynamic option.
1490 AC_LINK_EXPORT_DYNAMIC
1491
1492 dnl Determine whether the linker supports the --version-script option.
1493 AC_LINK_VERSION_SCRIPT
1494
1495 AC_CHECK_HEADERS([errno.h])
1496
1497 case "$llvm_cv_os_type" in
1498   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1499   Darwin) llvm_shlib_ext=.dylib ;;
1500   *) llvm_shlib_ext=.so ;;
1501 esac
1502
1503 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1504
1505 AC_MSG_CHECKING([tool compatibility])
1506
1507 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1508 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1509 dnl to support those options.
1510 dnl "icc" emits gcc signatures
1511 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1512 ICC=no
1513 IXX=no
1514 case $CC in
1515   icc*|icpc*)
1516     ICC=yes
1517     IXX=yes
1518     ;;
1519    *)
1520     ;;
1521 esac
1522
1523 if test "$GCC" != "yes" && test "$ICC" != "yes"
1524 then
1525   AC_MSG_ERROR([gcc|icc required but not found])
1526 fi
1527
1528 dnl Ensure that compilation tools are compatible with GCC extensions
1529 if test "$GXX" != "yes" && test "$IXX" != "yes"
1530 then
1531   AC_MSG_ERROR([g++|clang++|icc required but not found])
1532 fi
1533
1534 dnl Verify that GCC is version 3.0 or higher
1535 if test "$GCC" = "yes"
1536 then
1537   AC_COMPILE_IFELSE(
1538 [
1539   AC_LANG_SOURCE([[
1540     #if !defined(__GNUC__) || __GNUC__ < 3
1541     #error Unsupported GCC version
1542     #endif
1543   ]])
1544 ],
1545 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1546 fi
1547
1548 dnl Check for GNU Make.  We use its extensions, so don't build without it
1549 if test -z "$llvm_cv_gnu_make_command"
1550 then
1551   AC_MSG_ERROR([GNU Make required but not found])
1552 fi
1553
1554 dnl Tool compatibility is okay if we make it here.
1555 AC_MSG_RESULT([ok])
1556
1557 dnl Check optional compiler flags.
1558 AC_MSG_CHECKING([optional compiler flags])
1559 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1560 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1561 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1562
1563 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1564 dnl false positives, so disable it.
1565 NO_UNINITIALIZED=
1566 NO_MAYBE_UNINITIALIZED=
1567 if test "$GXX" = "yes"
1568 then
1569   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1570   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1571   dnl known to be uninitialized from cases which might be uninitialized.  We
1572   dnl still want to catch the first kind of errors.
1573   if test -z "$NO_MAYBE_UNINITIALIZED"
1574   then
1575     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1576   fi
1577 fi
1578
1579 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1580 dnl -Wno-comment to the flags.
1581 no_comment=
1582 llvm_cv_old_cxxflags="$CXXFLAGS"
1583 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1584 AC_COMPILE_IFELSE(
1585 [
1586   AC_LANG_SOURCE([[// Comment \o\
1587 // Another comment
1588 int main() { return 0; }
1589   ]])
1590 ],
1591 [
1592   no_comment=-Wno-comment
1593 ],
1594 [])
1595 AC_SUBST(NO_COMMENT, [$no_comment])
1596 CXXFLAGS="$llvm_cv_old_cxxflags"
1597
1598 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1599
1600 AC_ARG_WITH([python],
1601             [AS_HELP_STRING([--with-python], [path to python])],
1602             [PYTHON="$withval"])
1603
1604 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1605   AC_MSG_CHECKING([for python])
1606   AC_MSG_RESULT([user defined: $with_python])
1607 else
1608   if test -n "$PYTHON" ; then
1609     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1610   fi
1611
1612   AC_PATH_PROG([PYTHON], [python python2 python27],
1613                [AC_MSG_RESULT([not found])
1614                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1615 fi
1616
1617 AC_MSG_CHECKING([for python >= 2.7])
1618 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1619 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1620 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1621 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1622 if test "$ac_python_version_major" -gt "2" || \
1623    (test "$ac_python_version_major" -eq "2" && \
1624     test "$ac_python_version_minor" -ge "7") ; then
1625   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1626 else
1627   AC_MSG_RESULT([not found])
1628   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1629 fi
1630
1631 dnl===-----------------------------------------------------------------------===
1632 dnl===
1633 dnl=== SECTION 5: Check for libraries
1634 dnl===
1635 dnl===-----------------------------------------------------------------------===
1636
1637 AC_CHECK_LIB(m,sin)
1638 if test "$llvm_cv_os_type" = "MingW" ; then
1639   AC_CHECK_LIB(imagehlp, main)
1640   AC_CHECK_LIB(ole32, main)
1641   AC_CHECK_LIB(psapi, main)
1642   AC_CHECK_LIB(shell32, main)
1643 fi
1644
1645 dnl dlopen() is required for plugin support.
1646 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1647                [Define if dlopen() is available on this platform.]),
1648                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1649
1650 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1651 dnl macros to detect whether clock_gettime is available, this just finds the
1652 dnl right libraries to link with.
1653 AC_SEARCH_LIBS(clock_gettime,rt)
1654
1655 dnl The curses library is optional; used for querying terminal info
1656 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1657   dnl We need the has_color functionality in curses for it to be useful.
1658   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1659                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1660                                    [Define if the setupterm() function is supported this platform.]))
1661 fi
1662
1663 dnl The libedit library is optional; used by lib/LineEditor
1664 if test "$llvm_cv_enable_libedit" = "yes" ; then
1665   AC_SEARCH_LIBS(el_init,edit,
1666                  AC_DEFINE([HAVE_LIBEDIT],[1],
1667                            [Define if libedit is available on this platform.]))
1668 fi
1669
1670 dnl libffi is optional; used to call external functions from the interpreter
1671 if test "$llvm_cv_enable_libffi" = "yes" ; then
1672   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1673                  [Define if libffi is available on this platform.]),
1674                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1675 fi
1676
1677 dnl mallinfo is optional; the code can compile (minus features) without it
1678 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1679                [Define if mallinfo() is available on this platform.]))
1680
1681 dnl pthread locking functions are optional - but llvm will not be thread-safe
1682 dnl without locks.
1683 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1684   AC_CHECK_LIB(pthread, pthread_mutex_init)
1685   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1686                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1687                            [Have pthread_mutex_lock]))
1688   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1689                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1690                  [Have pthread_rwlock_init]))
1691   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1692                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1693                  [Have pthread_getspecific]))
1694 fi
1695
1696 dnl zlib is optional; used for compression/uncompression
1697 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1698   AC_CHECK_LIB(z, compress2)
1699 fi
1700
1701 dnl Allow OProfile support for JIT output.
1702 AC_ARG_WITH(oprofile,
1703   AS_HELP_STRING([--with-oprofile=<prefix>],
1704     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1705     [
1706       AC_SUBST(USE_OPROFILE, [1])
1707       case "$withval" in
1708         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1709         no) llvm_cv_oppath=
1710             AC_SUBST(USE_OPROFILE, [0]) ;;
1711         *) llvm_cv_oppath="${withval}/lib/oprofile"
1712            CPPFLAGS="-I${withval}/include";;
1713       esac
1714       case $llvm_cv_os_type in
1715         Linux)
1716           if test -n "$llvm_cv_oppath" ; then
1717             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1718             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1719             dnl libbfd is not included properly in libopagent in some Debian
1720             dnl versions.  If libbfd isn't found at all, we assume opagent works
1721             dnl anyway.
1722             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1723             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1724               echo "Error! You need to have libopagent around."
1725               exit 1
1726             ])
1727             AC_CHECK_HEADER([opagent.h], [], [
1728               echo "Error! You need to have opagent.h around."
1729               exit 1
1730               ])
1731           fi ;;
1732         *)
1733           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1734       esac
1735     ],
1736     [
1737       AC_SUBST(USE_OPROFILE, [0])
1738     ])
1739 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1740                    [Define if we have the oprofile JIT-support library])
1741
1742 dnl Enable support for Intel JIT Events API.
1743 AC_ARG_WITH(intel-jitevents,
1744   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1745     [
1746        case "$withval" in
1747           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1748           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1749           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1750        esac
1751
1752       case $llvm_cv_os_type in
1753         Linux|Win32|Cygwin|MingW) ;;
1754         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1755       esac
1756
1757       case "$llvm_cv_target_arch" in
1758         x86|x86_64) ;;
1759         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1760       esac
1761     ],
1762     [
1763       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1764     ])
1765 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1766                    [Define if we have the Intel JIT API runtime support library])
1767
1768 dnl Check for libxml2
1769 dnl Right now we're just checking for the existence, we could also check for a
1770 dnl particular version via --version on xml2-config
1771 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1772
1773 AC_MSG_CHECKING(for libxml2 includes)
1774 if test "x$XML2CONFIG" = "x"; then
1775  AC_MSG_RESULT(xml2-config not found)
1776 else
1777  LIBXML2_INC=`$XML2CONFIG --cflags`
1778  AC_MSG_RESULT($LIBXML2_INC)
1779  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1780                                 LIBXML2_LIBS="-lxml2"])
1781 fi
1782 AC_SUBST(LIBXML2_LIBS)
1783 AC_SUBST(LIBXML2_INC)
1784
1785 dnl===-----------------------------------------------------------------------===
1786 dnl===
1787 dnl=== SECTION 6: Check for header files
1788 dnl===
1789 dnl===-----------------------------------------------------------------------===
1790
1791 dnl First, use autoconf provided macros for specific headers that we need
1792 dnl We don't check for ancient stuff or things that are guaranteed to be there
1793 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1794 dnl Generally we're looking for POSIX headers.
1795 AC_HEADER_DIRENT
1796 AC_HEADER_MMAP_ANONYMOUS
1797 AC_HEADER_STAT
1798 AC_HEADER_SYS_WAIT
1799 AC_HEADER_TIME
1800
1801 AC_LANG_PUSH([C++])
1802 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1803 AC_CHECK_HEADERS([cxxabi.h], [], [],
1804 [#include <stddef.h>
1805 ])
1806 AC_LANG_POP([C++])
1807
1808 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1809 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1810 AC_CHECK_HEADERS([utime.h])
1811 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1812 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1813 AC_CHECK_HEADERS([valgrind/valgrind.h])
1814 AC_CHECK_HEADERS([fenv.h])
1815 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1816 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1817   AC_CHECK_HEADERS(pthread.h,
1818                    AC_SUBST(HAVE_PTHREAD, 1),
1819                    AC_SUBST(HAVE_PTHREAD, 0))
1820 else
1821   AC_SUBST(HAVE_PTHREAD, 0)
1822 fi
1823 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1824   AC_CHECK_HEADERS(zlib.h,
1825                    AC_SUBST(HAVE_LIBZ, 1),
1826                    AC_SUBST(HAVE_LIBZ, 0))
1827 else
1828   AC_SUBST(HAVE_LIBZ, 0)
1829 fi
1830
1831 dnl Try to find ffi.h.
1832 if test "$llvm_cv_enable_libffi" = "yes" ; then
1833   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1834 fi
1835
1836 dnl Try to find Darwin specific crash reporting libraries.
1837 AC_CHECK_HEADERS([CrashReporterClient.h])
1838
1839 dnl Try to find Darwin specific crash reporting global.
1840 AC_MSG_CHECKING([__crashreporter_info__])
1841 AC_LINK_IFELSE(
1842 [
1843   AC_LANG_SOURCE([[
1844     extern const char *__crashreporter_info__;
1845     int main() {
1846       __crashreporter_info__ = "test";
1847       return 0;
1848     }
1849   ]])
1850 ],
1851 [
1852   AC_MSG_RESULT([yes])
1853   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1854 ],
1855 [
1856   AC_MSG_RESULT([no])
1857   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1858 ])
1859
1860 dnl===-----------------------------------------------------------------------===
1861 dnl===
1862 dnl=== SECTION 7: Check for types and structures
1863 dnl===
1864 dnl===-----------------------------------------------------------------------===
1865
1866 AC_HUGE_VAL_CHECK
1867 AC_TYPE_PID_T
1868 AC_TYPE_SIZE_T
1869 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1870 AC_STRUCT_TM
1871 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1872 AC_CHECK_TYPES([uint64_t],,
1873          AC_CHECK_TYPES([u_int64_t],,
1874          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1875
1876 dnl===-----------------------------------------------------------------------===
1877 dnl===
1878 dnl=== SECTION 8: Check for specific functions needed
1879 dnl===
1880 dnl===-----------------------------------------------------------------------===
1881
1882 AC_CHECK_FUNCS([backtrace getcwd ])
1883 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1884 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1885 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1886 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1887 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1888 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1889 AC_CHECK_FUNCS([futimes futimens])
1890 AC_C_PRINTF_A
1891 AC_FUNC_RAND48
1892
1893 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1894 AC_CHECK_DECLS([arc4random])
1895
1896 dnl Check the declaration "Secure API" on Windows environments.
1897 AC_CHECK_DECLS([strerror_s])
1898
1899 dnl Check symbols in libgcc.a for JIT on Mingw.
1900 if test "$llvm_cv_os_type" = "MingW" ; then
1901   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1902   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1903   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1904   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1905   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1906   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1907
1908   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1909   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1910   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1911   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1912   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1913   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1914   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1915   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1916   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1917   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1918
1919   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1920   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1921 fi
1922
1923 dnl Check Win32 API EnumerateLoadedModules.
1924 if test "$llvm_cv_os_type" = "MingW" ; then
1925   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1926   AC_COMPILE_IFELSE(
1927 [
1928   AC_LANG_SOURCE([[
1929     #include <windows.h>
1930     #include <imagehlp.h>
1931     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1932     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1933   ]])
1934 ],
1935 [
1936   AC_MSG_RESULT([yes])
1937   llvm_cv_win32_elmcb_pcstr="PCSTR"
1938 ],
1939 [
1940   AC_MSG_RESULT([no])
1941   llvm_cv_win32_elmcb_pcstr="PSTR"
1942 ])
1943   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1944 fi
1945
1946 dnl Check for mmap support.We also need to know if /dev/zero is required to
1947 dnl be opened for allocating RWX memory.
1948 dnl Make sure we aren't attempting to configure for an unknown system
1949 if test "$llvm_cv_platform_type" = "Unix" ; then
1950   AC_FUNC_MMAP
1951   AC_FUNC_MMAP_FILE
1952   AC_NEED_DEV_ZERO_FOR_MMAP
1953
1954   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1955   then
1956     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1957   fi
1958   if test "$ac_cv_func_mmap_file" = "no"
1959   then
1960     AC_MSG_WARN([mmap() of files required but not found])
1961   fi
1962 fi
1963
1964 dnl atomic builtins are required for threading support.
1965 AC_MSG_CHECKING(for GCC atomic builtins)
1966 dnl Since we'll be using these atomic builtins in C++ files we should test
1967 dnl the C++ compiler.
1968 AC_LANG_PUSH([C++])
1969 AC_LINK_IFELSE(
1970 [
1971   AC_LANG_SOURCE([[
1972     int main() {
1973       volatile unsigned long val = 1;
1974       __sync_synchronize();
1975       __sync_val_compare_and_swap(&val, 1, 0);
1976       __sync_add_and_fetch(&val, 1);
1977       __sync_sub_and_fetch(&val, 1);
1978       return 0;
1979     }
1980   ]])
1981 ],
1982 [
1983   AC_MSG_RESULT([yes])
1984   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1985 ],
1986 [
1987   AC_MSG_RESULT([no])
1988   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1989   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1990 ])
1991 AC_LANG_POP([C++])
1992
1993 dnl===-----------------------------------------------------------------------===
1994 dnl===
1995 dnl=== SECTION 9: Additional checks, variables, etc.
1996 dnl===
1997 dnl===-----------------------------------------------------------------------===
1998
1999 dnl Handle 32-bit linux systems running a 64-bit kernel.
2000 dnl This has to come after section 4 because it invokes the compiler.
2001 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
2002   AC_IS_LINUX_MIXED
2003   if test "$llvm_cv_linux_mixed" = "yes"; then
2004     llvm_cv_target_arch="x86"
2005     ARCH="x86"
2006   fi
2007 fi
2008
2009 dnl Check whether __dso_handle is present
2010 AC_CHECK_FUNCS([__dso_handle])
2011
2012 dnl Propagate the shared library extension that the libltdl checks did to
2013 dnl the Makefiles so we can use it there too
2014 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
2015
2016 dnl Translate the various configuration directories and other basic
2017 dnl information into substitutions that will end up in Makefile.config.in
2018 dnl that these configured values can be used by the makefiles
2019 if test "${prefix}" = "NONE" ; then
2020   prefix="/usr/local"
2021 fi
2022 eval LLVM_PREFIX="${prefix}";
2023 eval LLVM_BINDIR="${prefix}/bin";
2024 eval LLVM_DATADIR="${prefix}/share/llvm";
2025 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
2026 eval LLVM_ETCDIR="${prefix}/etc/llvm";
2027 eval LLVM_INCLUDEDIR="${prefix}/include";
2028 eval LLVM_INFODIR="${prefix}/info";
2029 eval LLVM_MANDIR="${prefix}/man";
2030 LLVM_CONFIGTIME=`date`
2031 AC_SUBST(LLVM_PREFIX)
2032 AC_SUBST(LLVM_BINDIR)
2033 AC_SUBST(LLVM_DATADIR)
2034 AC_SUBST(LLVM_DOCSDIR)
2035 AC_SUBST(LLVM_ETCDIR)
2036 AC_SUBST(LLVM_INCLUDEDIR)
2037 AC_SUBST(LLVM_INFODIR)
2038 AC_SUBST(LLVM_MANDIR)
2039 AC_SUBST(LLVM_CONFIGTIME)
2040
2041 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
2042 if test "${ENABLE_TIMESTAMPS}" = "0"; then
2043   LLVM_CONFIGTIME="(timestamp not enabled)"
2044 fi
2045
2046 dnl Place the various directories into the config.h file as #defines so that we
2047 dnl can know about the installation paths within LLVM.
2048 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
2049                    [Installation prefix directory])
2050 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
2051                    [Installation directory for binary executables])
2052 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2053                    [Installation directory for data files])
2054 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2055                    [Installation directory for documentation])
2056 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2057                    [Installation directory for config files])
2058 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2059                    [Installation directory for include files])
2060 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2061                    [Installation directory for .info files])
2062 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2063                    [Installation directory for man pages])
2064 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2065                    [Time at which LLVM was configured])
2066 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2067                    [Host triple LLVM will be executed on])
2068 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2069                    [Target triple LLVM will generate code for by default])
2070
2071 dnl Determine which bindings to build.
2072 if test "$BINDINGS_TO_BUILD" = auto ; then
2073   BINDINGS_TO_BUILD=""
2074   if test "x$OCAMLFIND" != x ; then
2075     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2076   fi
2077   if test "x$GO" != x ; then
2078     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2079       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2080     fi
2081   fi
2082 fi
2083 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2084
2085 dnl Do any work necessary to ensure that bindings have what they need.
2086 binding_prereqs_failed=0
2087 for a_binding in $BINDINGS_TO_BUILD ; do
2088   case "$a_binding" in
2089   ocaml)
2090     if test "x$OCAMLFIND" = x ; then
2091       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2092       binding_prereqs_failed=1
2093     fi
2094
2095     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2096       HAVE_OCAMLOPT=1
2097     else
2098       HAVE_OCAMLOPT=0
2099     fi
2100     AC_SUBST(HAVE_OCAMLOPT)
2101
2102     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2103       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2104       binding_prereqs_failed=1
2105     fi
2106
2107     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2108       HAVE_OCAML_OUNIT=1
2109     else
2110       HAVE_OCAML_OUNIT=0
2111       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2112       dnl oUnit is optional!
2113     fi
2114     AC_SUBST(HAVE_OCAML_OUNIT)
2115
2116     if test "x$with_ocaml_libdir" != xauto ; then
2117       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2118     else
2119       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2120       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2121       then
2122         # ocaml stdlib is beneath our prefix; use stdlib
2123         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2124       else
2125         # ocaml stdlib is outside our prefix; use libdir/ocaml
2126         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2127       fi
2128     fi
2129     ;;
2130   go)
2131     if test "x$GO" = x ; then
2132       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2133       binding_prereqs_failed=1
2134     else
2135       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2136         :
2137       else
2138         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2139         binding_prereqs_failed=1
2140       fi
2141     fi
2142     ;;
2143   esac
2144 done
2145 if test "$binding_prereqs_failed" = 1 ; then
2146   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2147 fi
2148
2149 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2150 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2151
2152 dnl Determine linker rpath flag
2153 if test "$llvm_cv_link_use_r" = "yes" ; then
2154   RPATH="-Wl,-R"
2155 else
2156   RPATH="-Wl,-rpath"
2157 fi
2158 AC_SUBST(RPATH)
2159
2160 dnl Determine linker rdynamic flag
2161 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2162   RDYNAMIC="-rdynamic"
2163 else
2164   RDYNAMIC=""
2165 fi
2166 AC_SUBST(RDYNAMIC)
2167
2168 dnl===-----------------------------------------------------------------------===
2169 dnl===
2170 dnl=== SECTION 10: Specify the output files and generate it
2171 dnl===
2172 dnl===-----------------------------------------------------------------------===
2173
2174 dnl Configure header files
2175 dnl WARNING: dnl If you add or remove any of the following config headers, then
2176 dnl you MUST also update Makefile so that the variable FilesToConfig
2177 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2178 dnl files can be updated automatically when their *.in sources change.
2179 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2180 AH_TOP([#ifndef CONFIG_H
2181 #define CONFIG_H
2182
2183 /* Exported configuration */
2184 #include "llvm/Config/llvm-config.h"])
2185 AH_BOTTOM([#endif])
2186
2187 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2188 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2189 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2190 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2191 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2192
2193 dnl Configure the makefile's configuration data
2194 AC_CONFIG_FILES([Makefile.config])
2195
2196 dnl Configure the RPM spec file for LLVM
2197 AC_CONFIG_FILES([llvm.spec])
2198
2199 dnl Configure doxygen's configuration file
2200 AC_CONFIG_FILES([docs/doxygen.cfg])
2201
2202 dnl Configure clang, if present
2203 if test "${clang_src_root}" = ""; then
2204   clang_src_root="$srcdir/tools/clang"
2205 fi
2206 if test -f ${clang_src_root}/README.txt; then
2207   dnl Clang supports build systems which use the multilib libdir suffix.
2208   dnl The autoconf system doesn't support this so stub out that variable.
2209   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2210                      [Multilib suffix for libdir.])
2211
2212   dnl Use variables to stay under 80 columns.
2213   configh="include/clang/Config/config.h"
2214   doxy="docs/doxygen.cfg"
2215   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2216   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2217 fi
2218
2219 dnl OCaml findlib META file
2220 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2221
2222 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2223 test "x$program_prefix" = "xNONE" && program_prefix=""
2224 AC_SUBST([program_prefix])
2225
2226
2227 dnl Do special configuration of Makefiles
2228 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2229 AC_CONFIG_MAKEFILE(Makefile)
2230 AC_CONFIG_MAKEFILE(Makefile.common)
2231 AC_CONFIG_MAKEFILE(examples/Makefile)
2232 AC_CONFIG_MAKEFILE(lib/Makefile)
2233 AC_CONFIG_MAKEFILE(test/Makefile)
2234 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2235 AC_CONFIG_MAKEFILE(unittests/Makefile)
2236 AC_CONFIG_MAKEFILE(tools/Makefile)
2237 AC_CONFIG_MAKEFILE(utils/Makefile)
2238 AC_CONFIG_MAKEFILE(projects/Makefile)
2239 AC_CONFIG_MAKEFILE(bindings/Makefile)
2240 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2241
2242 dnl Finally, crank out the output
2243 AC_OUTPUT