autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.8.0],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=8
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Quit if it is an in-source build
  77 if test ${srcdir} = "." ; then
  78   AC_MSG_ERROR([In-source builds are not allowed. Please configure from a separate build directory!])
  79 fi
  80
  81 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  82 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  83 : ${CFLAGS=}
  84 : ${CXXFLAGS=}
  85
  86 dnl We need to check for the compiler up here to avoid anything else
  87 dnl starting with a different one.
  88 AC_PROG_CC(clang gcc)
  89 AC_PROG_CXX(clang++ g++)
  90 AC_PROG_CPP
  91
  92 dnl If CXX is Clang, check that it can find and parse C++ standard library
  93 dnl headers.
  94 if test "$CXX" = "clang++" ; then
  95   AC_MSG_CHECKING([whether clang works])
  96   AC_LANG_PUSH([C++])
  97   dnl Note that space between 'include' and '(' is required.  There's a broken
  98   dnl regex in aclocal that otherwise will think that we call m4's include
  99   dnl builtin.
 100   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
 101 #if __has_include (<cxxabi.h>)
 102 #include <cxxabi.h>
 103 #endif
 104 #if __has_include (<unwind.h>)
 105 #include <unwind.h>
 106 #endif
 107 ]])],
 108 [
 109   AC_MSG_RESULT([yes])
 110 ],
 111 [
 112   AC_MSG_RESULT([no])
 113   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler LLVM_SRC_DIR/configure ...])
 114 ])
 115   AC_LANG_POP([C++])
 116 fi
 117
 118 dnl Set up variables that track whether the host compiler is GCC or Clang where
 119 dnl we can effectively sanity check them. We don't try to sanity check all the
 120 dnl other possible compilers.
 121 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 122 AC_LANG_PUSH([C++])
 123 llvm_cv_cxx_compiler=unknown
 124 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 125                                     #error
 126                                     #endif
 127                                     ]])],
 128                   llvm_cv_cxx_compiler=clang,
 129                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 130                                                        #error
 131                                                        #endif
 132                                                        ]])],
 133                                      llvm_cv_cxx_compiler=gcc, [])])
 134 AC_LANG_POP([C++])
 135 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 136 AC_SUBST(CXX_COMPILER,$llvm_cv_cxx_compiler)
 137
 138 dnl Configure all of the projects present in our source tree. While we could
 139 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 140 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 141 dnl Instead we match on the known projects.
 142
 143 dnl
 144 dnl One tricky part of doing this is that some projects depend upon other
 145 dnl projects.  For example, several projects rely upon the LLVM test suite.
 146 dnl We want to configure those projects first so that their object trees are
 147 dnl created before running the configure scripts of projects that depend upon
 148 dnl them.
 149 dnl
 150
 151 dnl Several projects use the LLVM test suite, so configure it next.
 152 if test -d ${srcdir}/projects/test-suite ; then
 153   AC_CONFIG_SUBDIRS([projects/test-suite])
 154 fi
 155
 156 dnl llvm-test is the old name of the test-suite, kept here for backwards
 157 dnl compatibility
 158 if test -d ${srcdir}/projects/llvm-test ; then
 159   AC_CONFIG_SUBDIRS([projects/llvm-test])
 160 fi
 161
 162 dnl Some projects use poolalloc; configure that next
 163 if test -d ${srcdir}/projects/poolalloc ; then
 164   AC_CONFIG_SUBDIRS([projects/poolalloc])
 165 fi
 166
 167 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 168   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 169 fi
 170
 171 dnl Check for all other projects
 172 for i in `ls ${srcdir}/projects`
 173 do
 174   if test -d ${srcdir}/projects/${i} ; then
 175     case ${i} in
 176       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 177       compiler-rt)       ;;
 178       test-suite)     ;;
 179       llvm-test)      ;;
 180       poolalloc)      ;;
 181       llvm-poolalloc) ;;
 182       *)
 183         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 184         ;;
 185     esac
 186   fi
 187 done
 188
 189 dnl Disable the build of polly, even if it is checked out into tools/polly.
 190 AC_ARG_ENABLE(polly,
 191               AS_HELP_STRING([--enable-polly],
 192                              [Use polly if available (default is YES)]),,
 193                              enableval=default)
 194 case "$enableval" in
 195   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 196   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 197   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 198   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 199 esac
 200
 201
 202 dnl Check if polly is checked out into tools/polly and configure it if
 203 dnl available.
 204 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 205   AC_SUBST(LLVM_HAS_POLLY,1)
 206   AC_CONFIG_SUBDIRS([tools/polly])
 207 fi
 208
 209 dnl===-----------------------------------------------------------------------===
 210 dnl===
 211 dnl=== SECTION 2: Architecture, target, and host checks
 212 dnl===
 213 dnl===-----------------------------------------------------------------------===
 214
 215 dnl Check the target for which we're compiling and the host that will do the
 216 dnl compilations. This will tell us which LLVM compiler will be used for
 217 dnl compiling SSA into object code. This needs to be done early because
 218 dnl following tests depend on it.
 219 AC_CANONICAL_TARGET
 220
 221 dnl Determine the platform type and cache its value. This helps us configure
 222 dnl the System library to the correct build platform.
 223 AC_CACHE_CHECK([type of operating system we're going to host on],
 224                [llvm_cv_os_type],
 225 [case $host in
 226   *-*-aix*)
 227     llvm_cv_link_all_option="-Wl,--whole-archive"
 228     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 229     llvm_cv_os_type="AIX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-irix*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="IRIX"
 235     llvm_cv_platform_type="Unix" ;;
 236   *-*-cygwin*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="Cygwin"
 240     llvm_cv_platform_type="Unix" ;;
 241   *-*-darwin*)
 242     llvm_cv_link_all_option="-Wl,-all_load"
 243     llvm_cv_no_link_all_option="-Wl,-noall_load"
 244     llvm_cv_os_type="Darwin"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-*-minix*)
 247     llvm_cv_link_all_option="-Wl,-all_load"
 248     llvm_cv_no_link_all_option="-Wl,-noall_load"
 249     llvm_cv_os_type="Minix"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-*-freebsd*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="FreeBSD"
 255     llvm_cv_platform_type="Unix" ;;
 256   *-*-kfreebsd-gnu)
 257     llvm_cv_link_all_option="-Wl,--whole-archive"
 258     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 259     llvm_cv_os_type="GNU/kFreeBSD"
 260     llvm_cv_platform_type="Unix" ;;
 261   *-*-openbsd*)
 262     llvm_cv_link_all_option="-Wl,--whole-archive"
 263     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 264     llvm_cv_os_type="OpenBSD"
 265     llvm_cv_platform_type="Unix" ;;
 266   *-*-netbsd*)
 267     llvm_cv_link_all_option="-Wl,--whole-archive"
 268     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 269     llvm_cv_os_type="NetBSD"
 270     llvm_cv_platform_type="Unix" ;;
 271   *-*-dragonfly*)
 272     llvm_cv_link_all_option="-Wl,--whole-archive"
 273     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 274     llvm_cv_os_type="DragonFly"
 275     llvm_cv_platform_type="Unix" ;;
 276   *-*-bitrig*)
 277     llvm_cv_link_all_option="-Wl,--whole-archive"
 278     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 279     llvm_cv_os_type="Bitrig"
 280     llvm_cv_platform_type="Unix" ;;
 281   *-*-hpux*)
 282     llvm_cv_link_all_option="-Wl,--whole-archive"
 283     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 284     llvm_cv_os_type="HP-UX"
 285     llvm_cv_platform_type="Unix" ;;
 286   *-*-interix*)
 287     llvm_cv_link_all_option="-Wl,--whole-archive"
 288     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 289     llvm_cv_os_type="Interix"
 290     llvm_cv_platform_type="Unix" ;;
 291   *-*-linux*)
 292     llvm_cv_link_all_option="-Wl,--whole-archive"
 293     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 294     llvm_cv_os_type="Linux"
 295     llvm_cv_platform_type="Unix" ;;
 296   *-*-gnu*)
 297     llvm_cv_link_all_option="-Wl,--whole-archive"
 298     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 299     llvm_cv_os_type="GNU"
 300     llvm_cv_platform_type="Unix" ;;
 301   *-*-solaris*)
 302     llvm_cv_link_all_option="-Wl,-z,allextract"
 303     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 304     llvm_cv_os_type="SunOS"
 305     llvm_cv_platform_type="Unix" ;;
 306   *-*-win32*)
 307     llvm_cv_link_all_option="-Wl,--whole-archive"
 308     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 309     llvm_cv_os_type="Win32"
 310     llvm_cv_platform_type="Win32" ;;
 311   *-*-mingw*)
 312     llvm_cv_link_all_option="-Wl,--whole-archive"
 313     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 314     llvm_cv_os_type="MingW"
 315     llvm_cv_platform_type="Win32" ;;
 316   *-*-haiku*)
 317     llvm_cv_link_all_option="-Wl,--whole-archive"
 318     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 319     llvm_cv_os_type="Haiku"
 320     llvm_cv_platform_type="Unix" ;;
 321   *-unknown-eabi*)
 322     llvm_cv_link_all_option="-Wl,--whole-archive"
 323     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 324     llvm_cv_os_type="Freestanding"
 325     llvm_cv_platform_type="Unix" ;;
 326   *-unknown-elf*)
 327     llvm_cv_link_all_option="-Wl,--whole-archive"
 328     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 329     llvm_cv_os_type="Freestanding"
 330     llvm_cv_platform_type="Unix" ;;
 331   *)
 332     llvm_cv_link_all_option=""
 333     llvm_cv_no_link_all_option=""
 334     llvm_cv_os_type="Unknown"
 335     llvm_cv_platform_type="Unknown" ;;
 336 esac])
 337
 338 AC_CACHE_CHECK([type of operating system we're going to target],
 339                [llvm_cv_target_os_type],
 340 [case $target in
 341   *-*-aix*)
 342     llvm_cv_target_os_type="AIX" ;;
 343   *-*-irix*)
 344     llvm_cv_target_os_type="IRIX" ;;
 345   *-*-cygwin*)
 346     llvm_cv_target_os_type="Cygwin" ;;
 347   *-*-darwin*)
 348     llvm_cv_target_os_type="Darwin" ;;
 349   *-*-minix*)
 350     llvm_cv_target_os_type="Minix" ;;
 351   *-*-freebsd*)
 352     llvm_cv_target_os_type="FreeBSD" ;;
 353   *-*-kfreebsd-gnu)
 354     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 355   *-*-openbsd*)
 356     llvm_cv_target_os_type="OpenBSD" ;;
 357   *-*-netbsd*)
 358     llvm_cv_target_os_type="NetBSD" ;;
 359   *-*-dragonfly*)
 360     llvm_cv_target_os_type="DragonFly" ;;
 361   *-*-bitrig*)
 362     llvm_cv_target_os_type="Bitrig" ;;
 363   *-*-hpux*)
 364     llvm_cv_target_os_type="HP-UX" ;;
 365   *-*-interix*)
 366     llvm_cv_target_os_type="Interix" ;;
 367   *-*-linux*)
 368     llvm_cv_target_os_type="Linux" ;;
 369   *-*-gnu*)
 370     llvm_cv_target_os_type="GNU" ;;
 371   *-*-solaris*)
 372     llvm_cv_target_os_type="SunOS" ;;
 373   *-*-win32*)
 374     llvm_cv_target_os_type="Win32" ;;
 375   *-*-mingw*)
 376     llvm_cv_target_os_type="MingW" ;;
 377   *-*-haiku*)
 378     llvm_cv_target_os_type="Haiku" ;;
 379   *-*-rtems*)
 380     llvm_cv_target_os_type="RTEMS" ;;
 381   *-*-nacl*)
 382     llvm_cv_target_os_type="NativeClient" ;;
 383   *-unknown-eabi*)
 384     llvm_cv_target_os_type="Freestanding" ;;
 385   *-*-ps4)
 386     llvm_cv_target_os_type="PS4" ;;
 387   *)
 388     llvm_cv_target_os_type="Unknown" ;;
 389 esac])
 390
 391 dnl Make sure we aren't attempting to configure for an unknown system
 392 if test "$llvm_cv_os_type" = "Unknown" ; then
 393   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 394 fi
 395
 396 dnl Set the "OS" Makefile variable based on the platform type so the
 397 dnl makefile can configure itself to specific build hosts
 398 AC_SUBST(OS,$llvm_cv_os_type)
 399 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 400 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 401
 402 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 403 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 404 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 405
 406 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 407 dnl This is used by lib/Support to determine the basic kind of implementation
 408 dnl to use.
 409 case $llvm_cv_platform_type in
 410   Unix)
 411     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 412     AC_SUBST(LLVM_ON_UNIX,[1])
 413     AC_SUBST(LLVM_ON_WIN32,[0])
 414     ;;
 415   Win32)
 416     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 417     AC_SUBST(LLVM_ON_UNIX,[0])
 418     AC_SUBST(LLVM_ON_WIN32,[1])
 419     ;;
 420 esac
 421
 422 dnl Determine what our target architecture is and configure accordingly.
 423 dnl This will allow Makefiles to make a distinction between the hardware and
 424 dnl the OS.
 425 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 426 [case $target in
 427   i?86-*)                 llvm_cv_target_arch="x86" ;;
 428   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 429   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 430   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 431   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 432   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 433   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 434   avr-*)                  llvm_cv_target_arch="AVR" ;;
 435   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 436   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 437   xcore-*)                llvm_cv_target_arch="XCore" ;;
 438   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 439   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 440   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 441   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 442   wasm*-*)                llvm_cv_target_arch="WebAssembly" ;;
 443   *)                      llvm_cv_target_arch="Unknown" ;;
 444 esac])
 445
 446 if test "$llvm_cv_target_arch" = "Unknown" ; then
 447   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 448 fi
 449
 450 dnl Determine the LLVM native architecture for the target
 451 case "$llvm_cv_target_arch" in
 452     x86)     LLVM_NATIVE_ARCH="X86" ;;
 453     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 454     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 455 esac
 456
 457 dnl Define a substitution, ARCH, for the target architecture
 458 AC_SUBST(ARCH,$llvm_cv_target_arch)
 459 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 460
 461 dnl Determine what our host architecture.
 462 dnl This will allow MCJIT regress tests runs only for supported
 463 dnl platforms.
 464 case $host in
 465   i?86-*)                 host_arch="x86" ;;
 466   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 467   sparc*-*)               host_arch="Sparc" ;;
 468   powerpc*-*)             host_arch="PowerPC" ;;
 469   arm64*-*)               host_arch="AArch64" ;;
 470   arm*-*)                 host_arch="ARM" ;;
 471   aarch64*-*)             host_arch="AArch64" ;;
 472   avr-*)                  host_arch="AVR" ;;
 473   mips-* | mips64-*)      host_arch="Mips" ;;
 474   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 475   xcore-*)                host_arch="XCore" ;;
 476   msp430-*)               host_arch="MSP430" ;;
 477   hexagon-*)              host_arch="Hexagon" ;;
 478   s390x-*)                host_arch="SystemZ" ;;
 479   wasm*-*)                host_arch="WebAssembly" ;;
 480   *)                      host_arch="Unknown" ;;
 481 esac
 482
 483 if test "$host_arch" = "Unknown" ; then
 484   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 485 fi
 486
 487 AC_SUBST(HOST_ARCH,$host_arch)
 488
 489 dnl Check for build platform executable suffix if we're cross-compiling
 490 if test "$cross_compiling" = yes; then
 491   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 492   AC_BUILD_EXEEXT
 493   ac_build_prefix=${build_alias}-
 494   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 495   if test -z "$BUILD_CXX"; then
 496      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 497      if test -z "$BUILD_CXX"; then
 498        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 499      fi
 500   fi
 501 else
 502   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 503 fi
 504
 505 dnl Check to see if there's a .svn or .git directory indicating that this
 506 dnl build is being done from a checkout. This sets up several defaults for
 507 dnl the command line switches. When we build with a checkout directory,
 508 dnl we get a debug with assertions turned on. Without, we assume a source
 509 dnl release and we get an optimized build without assertions.
 510 dnl See --enable-optimized and --enable-assertions below
 511 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 512   cvsbuild="yes"
 513   optimize="no"
 514   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 515 else
 516   cvsbuild="no"
 517   optimize="yes"
 518 fi
 519
 520 dnl===-----------------------------------------------------------------------===
 521 dnl===
 522 dnl=== SECTION 3: Command line arguments for the configure script.
 523 dnl===
 524 dnl===-----------------------------------------------------------------------===
 525
 526 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 527 AC_ARG_ENABLE(libcpp,
 528               AS_HELP_STRING([--enable-libcpp],
 529                              [Use libc++ if available (default is NO)]),,
 530                              enableval=default)
 531 case "$enableval" in
 532   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 533   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 534   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 535   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 536 esac
 537
 538 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 539 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 540 dnl these checks here so that we have the configuration of the standard C++
 541 dnl library finished.
 542 AC_ARG_ENABLE(compiler-version-checks,
 543               AS_HELP_STRING([--enable-compiler-version-checks],
 544                              [Check the version of the host compiler (default is YES)]),,
 545                              enableval=default)
 546 case "$enableval" in
 547   no)
 548     ;;
 549   yes|default)
 550     AC_LANG_PUSH([C++])
 551     case "$llvm_cv_cxx_compiler" in
 552     clang)
 553       AC_MSG_CHECKING([whether Clang is new enough])
 554       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 555 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 556 #error This version of Clang is too old to build LLVM
 557 #endif
 558 ]])],
 559           [AC_MSG_RESULT([yes])],
 560           [AC_MSG_RESULT([no])
 561            AC_MSG_ERROR([
 562 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 563 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 564 bypass these sanity checks.])])
 565
 566       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 567       dnl are sometimes deeply confusing though. Here we test for an obvious
 568       dnl incomplete feature in 4.6's standard library that was completed in
 569       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 570       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 571       dnl that happening in the Makefile.
 572       if test "$ENABLE_LIBCPP" -eq 0 ; then
 573         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 574         llvm_cv_old_cxxflags="$CXXFLAGS"
 575         CXXFLAGS="$CXXFLAGS -std=c++0x"
 576         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 577 #include <atomic>
 578 std::atomic<float> x(0.0f);
 579 int main() { return (float)x; }
 580 ]])],
 581             [AC_MSG_RESULT([yes])],
 582             [AC_MSG_RESULT([no])
 583              AC_MSG_ERROR([
 584 We detected a missing feature in the standard C++ library that was known to be
 585 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 586 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 587 than 4.7. You will need to update your system and ensure Clang uses the newer
 588 standard library.
 589
 590 If this error is incorrect or you need to force things to work, you may pass
 591 '--disable-compiler-version-checks' to configure to bypass this test.])])
 592         CXXFLAGS="$llvm_cv_old_cxxflags"
 593       fi
 594       ;;
 595     gcc)
 596       AC_MSG_CHECKING([whether GCC is new enough])
 597       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 598 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 599 #error This version of GCC is too old to build LLVM
 600 #endif
 601 ]])],
 602           [AC_MSG_RESULT([yes])],
 603           [AC_MSG_RESULT([no])
 604            AC_MSG_ERROR([
 605 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 606 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 607 bypass these sanity checks.])])
 608       ;;
 609     unknown)
 610       ;;
 611     esac
 612     AC_LANG_POP([C++])
 613     ;;
 614   *)
 615     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 616     ;;
 617 esac
 618
 619 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 620 AC_ARG_ENABLE(cxx1y,
 621               AS_HELP_STRING([--enable-cxx1y],
 622                              [Use c++1y if available (default is NO)]),,
 623                              enableval=default)
 624 case "$enableval" in
 625   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 626   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 627   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 628   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 629 esac
 630
 631 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 632 dnl line
 633 AC_ARG_ENABLE(split-dwarf,
 634               AS_HELP_STRING([--enable-split-dwarf],
 635                              [Use split-dwarf if available (default is NO)]),,
 636                              enableval=default)
 637 case "$enableval" in
 638   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 639   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 640   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 641   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 642 esac
 643
 644 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 645 clang_arcmt="yes"
 646 AC_ARG_ENABLE(clang-arcmt,
 647               AS_HELP_STRING([--enable-clang-arcmt],
 648                              [Enable building of clang ARCMT (default is YES)]),
 649                              clang_arcmt="$enableval",
 650                              enableval="yes")
 651 case "$enableval" in
 652   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 653   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 654   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 655   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 656 esac
 657
 658 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 659 clang_plugin_support="yes"
 660 AC_ARG_ENABLE(clang-plugin-support,
 661               AS_HELP_STRING([--enable-clang-plugin-support],
 662                              [Enable plugin support in clang (default is YES)]),
 663                              clang_plugin_support="$enableval",
 664                              enableval="yes")
 665 case "$enableval" in
 666   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 667   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 668   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 669   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 670 esac
 671
 672 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 673 clang_static_analyzer="yes"
 674 AC_ARG_ENABLE(clang-static-analyzer,
 675               AS_HELP_STRING([--enable-clang-static-analyzer],
 676                              [Enable building of clang Static Analyzer (default is YES)]),
 677                              clang_static_analyzer="$enableval",
 678                              enableval="yes")
 679 case "$enableval" in
 680   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 681   no)
 682     if test ${clang_arcmt} != "no" ; then
 683       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 684     fi
 685     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 686     ;;
 687   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 688   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 689 esac
 690
 691 dnl --enable-optimized : check whether they want to do an optimized build:
 692 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 693  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 694 if test ${enableval} = "no" ; then
 695   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 696 else
 697   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 698 fi
 699
 700 dnl --enable-profiling : check whether they want to do a profile build:
 701 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 702  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 703 if test ${enableval} = "no" ; then
 704   AC_SUBST(ENABLE_PROFILING,[[]])
 705 else
 706   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 707 fi
 708
 709 dnl --enable-assertions : check whether they want to turn on assertions or not:
 710 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 711   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 712 if test ${enableval} = "yes" ; then
 713   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 714   assertions_enabled="yes"
 715 else
 716   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 717   assertions_enabled="no"
 718 fi
 719
 720 dnl --enable-werror : check whether we want Werror on by default
 721 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 722   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 723 case "$enableval" in
 724   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 725   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 726   default) AC_SUBST(ENABLE_WERROR,[0]);;
 727   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 728 esac
 729
 730 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 731 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 732   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 733 if test ${enableval} = "yes" ; then
 734   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 735   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 736 else
 737   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 738   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 739 fi
 740
 741 dnl --enable-abi-breaking-checks : decide whether we should compile in asserts and
 742 dnl checks that make the build ABI incompatible with an llvm built without these
 743 dnl checks enabled.
 744 AC_ARG_ENABLE(abi-breaking-checks,AS_HELP_STRING(
 745   --enable-abi-breaking-checks,[Compile with abi-breaking asserts support (default is with-asserts)]),, enableval="with-asserts")
 746 case "$enableval" in
 747   with-asserts)  if test ${assertions_enabled} = "yes" ; then
 748                    AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 749                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 750                  else
 751                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 752                  fi ;;
 753   yes)
 754                  AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 755                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 756                  ;;
 757   no)
 758                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 759                  ;;
 760   *) AC_MSG_ERROR([Invalid setting for --enable-abi-breaking-checks.  Use "with-asserts", "yes" or "no"])
 761 esac
 762
 763 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 764 AC_ARG_ENABLE(debug-runtime,
 765    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 766 if test ${enableval} = "no" ; then
 767   AC_SUBST(DEBUG_RUNTIME,[[]])
 768 else
 769   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 770 fi
 771
 772 dnl --enable-debug-symbols : should even optimized compiler libraries
 773 dnl have debug symbols?
 774 AC_ARG_ENABLE(debug-symbols,
 775    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 776 if test ${enableval} = "no" ; then
 777   AC_SUBST(DEBUG_SYMBOLS,[[]])
 778 else
 779   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 780 fi
 781
 782 dnl --enable-keep-symbols : do not strip installed executables
 783 AC_ARG_ENABLE(keep-symbols,
 784    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 785 if test ${enableval} = "no" ; then
 786   AC_SUBST(KEEP_SYMBOLS,[[]])
 787 else
 788   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 789 fi
 790
 791 dnl --enable-jit: check whether they want to enable the jit
 792 AC_ARG_ENABLE(jit,
 793   AS_HELP_STRING(--enable-jit,
 794                  [Enable Just In Time Compiling (default is YES)]),,
 795   enableval=default)
 796 if test ${enableval} = "no"
 797 then
 798   AC_SUBST(JIT,[[]])
 799 else
 800   case "$llvm_cv_target_arch" in
 801     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 802     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 803     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 804     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 805     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 806     AVR)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 807     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 808     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 809     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 810     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 811     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 812     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 813     WebAssembly) AC_SUBST(TARGET_HAS_JIT,0) ;;
 814     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 815   esac
 816 fi
 817
 818 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 819 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 820
 821 dnl Allow enablement of building and installing docs
 822 AC_ARG_ENABLE(docs,
 823               AS_HELP_STRING([--enable-docs],
 824                              [Build documents (default is YES)]),,
 825                              enableval=default)
 826 case "$enableval" in
 827   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 828   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 829   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 830   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 831 esac
 832
 833 dnl Allow enablement of doxygen generated documentation
 834 AC_ARG_ENABLE(doxygen,
 835               AS_HELP_STRING([--enable-doxygen],
 836                              [Build doxygen documentation (default is NO)]),,
 837                              enableval=default)
 838 case "$enableval" in
 839   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 840   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 841   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 842 esac
 843
 844 dnl Allow enablement of doxygen search engine
 845 AC_ARG_ENABLE(doxygen-search,
 846               AS_HELP_STRING([--enable-doxygen-search],
 847                              [Enable doxygen search support (default is NO)]),,
 848                              enableval=default)
 849 ENABLE_DOXYGEN_SEARCH="$enableval"
 850
 851 case "$enableval" in
 852   yes|no|default) ;;
 853   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 854 esac
 855
 856 AC_ARG_ENABLE(doxygen-external-search,
 857               AS_HELP_STRING([--enable-doxygen-external-search],
 858                              [Enable doxygen exteranl search (default is NO)]),,
 859                              enableval=default)
 860 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 861
 862 case "$enableval" in
 863   yes)
 864     dnl To match with the CMake behavior, enable doxygen when
 865     dnl --enable-doxygen-external-search is enabled.
 866     case "$ENABLE_DOXYGEN_SEARCH" in
 867       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 868       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 869     esac
 870     ;;
 871   no|default) ;;
 872   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 873 esac
 874
 875 AC_ARG_WITH(doxygen-search-engine-url,
 876             AS_HELP_STRING([--with-doxygen-search-engine-url],
 877                            [Specify the external search engine for doxygen]),,)
 878 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 879
 880 AC_ARG_WITH(doxygen-search-mappings,
 881             AS_HELP_STRING([--with-doxygen-search-mappings],
 882                            [Specify the extra search mapping for doxygen]),,)
 883 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 884
 885 case "$ENABLE_DOXYGEN_SEARCH" in
 886   yes)
 887     if test "$ENABLE_DOXYGEN" = "0" ; then
 888       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 889     fi
 890
 891     AC_SUBST(enable_searchengine,[YES])
 892
 893     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 894       yes)
 895         AC_SUBST(enable_external_search,[YES])
 896         AC_SUBST(enable_server_based_search,[YES])
 897         AC_SUBST(searchengine_url,["$WITH_DOXYGEN_SEARCH_ENGINE_URL"])
 898         AC_SUBST(extra_search_mappings,["$WITH_DOXYGEN_SEARCH_MAPPINGS"])
 899         ;;
 900
 901       no|default)
 902         AC_SUBST(enable_external_search,[NO])
 903         AC_SUBST(enable_server_based_search,[NO])
 904         AC_SUBST(searchengine_url,[])
 905         AC_SUBST(extra_search_mappings,[])
 906         ;;
 907     esac
 908     ;;
 909
 910   no|default)
 911     AC_SUBST(enable_searchengine,[NO])
 912     AC_SUBST(searchengine_url,[])
 913     AC_SUBST(enable_server_based_search,[NO])
 914     AC_SUBST(enable_external_search,[NO])
 915     AC_SUBST(extra_search_mappings,[])
 916     ;;
 917
 918   *)
 919     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 920     ;;
 921 esac
 922
 923 dnl Allow enablement of doxygen generated Qt help files
 924 AC_ARG_ENABLE(doxygen-qt-help,
 925               AS_HELP_STRING([--enable-doxygen-qt-help],
 926                              [Build Qt help files (default is NO)]),,
 927                              enableval=default)
 928 case "$enableval" in
 929   yes)
 930     if test "$ENABLE_DOXYGEN" = "0" ; then
 931       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 932     fi
 933
 934     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 935
 936     dnl Qt help file for llvm doxygen documentation
 937     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 938     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 939     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 940     AC_SUBST(llvm_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 941     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,["$PACKAGE_STRING"])
 942     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,["$PACKAGE_NAME,$PACKAGE_VERSION"])
 943
 944     dnl Qt help file for clang doxygen documentation
 945     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 946     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 947     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 948     AC_SUBST(clang_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 949     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 950     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 951     ;;
 952
 953   no|default)
 954     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 955     AC_SUBST(llvm_doxygen_qch_filename,[])
 956     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 957     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 958     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 959     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 960
 961     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 962     AC_SUBST(clang_doxygen_qch_filename,[])
 963     AC_SUBST(clang_doxygen_qhp_namespace,[])
 964     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 965     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 966     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 967     ;;
 968
 969   *)
 970     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 971 esac
 972
 973 dnl Allow disablement of threads
 974 AC_ARG_ENABLE(threads,
 975               AS_HELP_STRING([--enable-threads],
 976                              [Use threads if available (default is YES)]),,
 977                              enableval=default)
 978 case "$enableval" in
 979   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 980   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 981   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 982   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 983 esac
 984 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 985                    [Define if threads enabled])
 986
 987 dnl Allow disablement of pthread.h
 988 AC_ARG_ENABLE(pthreads,
 989               AS_HELP_STRING([--enable-pthreads],
 990                              [Use pthreads if available (default is YES)]),,
 991                              enableval=default)
 992 case "$enableval" in
 993   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 994   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 995   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 996   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 997 esac
 998
 999 dnl Allow disablement of zlib
1000 AC_ARG_ENABLE(zlib,
1001               AS_HELP_STRING([--enable-zlib],
1002                              [Use zlib for compression/decompression if
1003                               available (default is YES)]),,
1004                               enableval=default)
1005 case "$enableval" in
1006   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1007   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
1008   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1009   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
1010 esac
1011 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
1012                    [Define if zlib is enabled])
1013
1014 dnl Allow building without position independent code
1015 AC_ARG_ENABLE(pic,
1016   AS_HELP_STRING([--enable-pic],
1017                  [Build LLVM with Position Independent Code (default is YES)]),,
1018                  enableval=default)
1019 case "$enableval" in
1020   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
1021   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
1022   default) AC_SUBST(ENABLE_PIC,[1]) ;;
1023   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
1024 esac
1025 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
1026                    [Define if position independent code is enabled])
1027
1028 dnl Allow building a shared library and linking tools against it.
1029 AC_ARG_ENABLE(shared,
1030   AS_HELP_STRING([--enable-shared],
1031                  [Build a shared library and link tools against it (default is NO)]),,
1032                  enableval=default)
1033 case "$enableval" in
1034   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
1035   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1036   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1037   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1038 esac
1039
1040 dnl Allow libstdc++ is embedded in LLVM.dll.
1041 AC_ARG_ENABLE(embed-stdcxx,
1042   AS_HELP_STRING([--enable-embed-stdcxx],
1043                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1044                  enableval=default)
1045 case "$enableval" in
1046   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1047   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1048   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1049   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1050 esac
1051
1052 dnl Enable embedding timestamp information into build.
1053 AC_ARG_ENABLE(timestamps,
1054   AS_HELP_STRING([--enable-timestamps],
1055                  [Enable embedding timestamp information in build (default is YES)]),,
1056                  enableval=default)
1057 case "$enableval" in
1058   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1059   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1060   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1061   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1062 esac
1063 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1064                    [Define if timestamp information (e.g., __DATE__) is allowed])
1065
1066 dnl Enable support for showing backtraces.
1067 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1068   [--enable-backtraces],
1069   [Enable embedding backtraces on crash (default is YES)]),
1070   [case "$enableval" in
1071     yes) llvm_cv_enable_backtraces="yes" ;;
1072     no)  llvm_cv_enable_backtraces="no"  ;;
1073     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1074   esac],
1075   llvm_cv_enable_backtraces="yes")
1076 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1077   AC_DEFINE([ENABLE_BACKTRACES],[1],
1078             [Define if you want backtraces on crash])
1079 fi
1080
1081 dnl Enable installing platform specific signal handling overrides, for improved
1082 dnl CrashRecovery support or interaction with crash reporting software. This
1083 dnl support may be inappropriate for some clients embedding LLVM as a library.
1084 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1085   [--enable-crash-overrides],
1086   [Enable crash handling overrides (default is YES)]),
1087   [case "$enableval" in
1088     yes) llvm_cv_enable_crash_overrides="yes" ;;
1089     no)  llvm_cv_enable_crash_overrides="no"  ;;
1090     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1091   esac],
1092   llvm_cv_enable_crash_overrides="yes")
1093 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1094   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1095             [Define to enable crash handling overrides])
1096 fi
1097
1098 dnl List all possible targets
1099 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ AMDGPU BPF"
1100 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1101
1102 dnl Allow specific targets to be specified for building (or not)
1103 TARGETS_TO_BUILD=""
1104 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1105     [Build specific host targets: all or target1,target2,... Valid targets are:
1106      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1107      xcore, msp430, nvptx, systemz, r600, bpf, wasm, and cpp (default=all)]),,
1108     enableval=all)
1109 if test "$enableval" = host-only ; then
1110   enableval=host
1111 fi
1112 case "$enableval" in
1113   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1114   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1115       case "$a_target" in
1116         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1117         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1118         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1119         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1120         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1121         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1122         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1123         bpf)      TARGETS_TO_BUILD="BPF $TARGETS_TO_BUILD" ;;
1124         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1125         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1126         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1127         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1128         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1129         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1130         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1131         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1132         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1133         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1134         amdgpu)   TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1135         r600)     TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1136         wasm)     TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1137         host) case "$llvm_cv_target_arch" in
1138             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1139             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1140             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1141             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1142             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1143             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1144             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1145             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1146             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1147             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1148             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1149             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1150             WebAssembly) TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1151             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1152           esac ;;
1153         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1154       esac
1155   done
1156   ;;
1157 esac
1158
1159 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1160     [Build experimental host targets: disable or target1,target2,...
1161      (default=disable)]),,
1162     enableval=disable)
1163
1164 if test ${enableval} != "disable"
1165 then
1166   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1167 fi
1168
1169 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1170
1171 dnl Determine whether we are building LLVM support for the native architecture.
1172 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1173 for a_target in $TARGETS_TO_BUILD; do
1174   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1175     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1176       [LLVM architecture name for the native architecture, if available])
1177     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1178     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1179     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1180     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1181     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1182       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1183     fi
1184     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1185       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1186     fi
1187     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1188       [LLVM name for the native Target init function, if available])
1189     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1190       [LLVM name for the native TargetInfo init function, if available])
1191     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1192       [LLVM name for the native target MC init function, if available])
1193     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1194       [LLVM name for the native AsmPrinter init function, if available])
1195     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1196       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1197        [LLVM name for the native AsmParser init function, if available])
1198     fi
1199     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1200       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1201        [LLVM name for the native Disassembler init function, if available])
1202     fi
1203   fi
1204 done
1205
1206 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1207 dnl target feature def files.
1208 LLVM_ENUM_TARGETS=""
1209 LLVM_ENUM_ASM_PRINTERS=""
1210 LLVM_ENUM_ASM_PARSERS=""
1211 LLVM_ENUM_DISASSEMBLERS=""
1212 for target_to_build in $TARGETS_TO_BUILD; do
1213   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1214   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1215     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1216   fi
1217   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1218     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1219   fi
1220   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1221     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1222   fi
1223 done
1224 AC_SUBST(LLVM_ENUM_TARGETS)
1225 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1226 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1227 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1228
1229 dnl Override the option to use for optimized builds.
1230 AC_ARG_WITH(optimize-option,
1231   AS_HELP_STRING([--with-optimize-option],
1232                  [Select the compiler options to use for optimized builds]),,
1233                  withval=default)
1234 AC_MSG_CHECKING([optimization flags])
1235 case "$withval" in
1236   default)
1237     case "$llvm_cv_os_type" in
1238     FreeBSD) optimize_option=-O2 ;;
1239     MingW) optimize_option=-O2 ;;
1240     *)     optimize_option=-O3 ;;
1241     esac ;;
1242   *) optimize_option="$withval" ;;
1243 esac
1244 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1245 AC_MSG_RESULT([$optimize_option])
1246
1247 dnl Specify extra build options
1248 AC_ARG_WITH(extra-options,
1249   AS_HELP_STRING([--with-extra-options],
1250                  [Specify additional options to compile LLVM with]),,
1251                  withval=default)
1252 case "$withval" in
1253   default) EXTRA_OPTIONS= ;;
1254   *) EXTRA_OPTIONS=$withval ;;
1255 esac
1256 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1257
1258 dnl Specify extra linker build options
1259 AC_ARG_WITH(extra-ld-options,
1260   AS_HELP_STRING([--with-extra-ld-options],
1261                  [Specify additional options to link LLVM with]),,
1262                  withval=default)
1263 case "$withval" in
1264   default) EXTRA_LD_OPTIONS= ;;
1265   *) EXTRA_LD_OPTIONS=$withval ;;
1266 esac
1267 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1268
1269 dnl Allow specific bindings to be specified for building (or not)
1270 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1271     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1272     enableval=default)
1273 BINDINGS_TO_BUILD=""
1274 case "$enableval" in
1275   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1276   all ) BINDINGS_TO_BUILD="ocaml" ;;
1277   none | no) BINDINGS_TO_BUILD="" ;;
1278   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1279       case "$a_binding" in
1280         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1281         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1282       esac
1283   done
1284   ;;
1285 esac
1286
1287 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1288 dnl script for bindings/ocaml/configure, except that its auto value depends on
1289 dnl OCAMLC, which is found here to support tests.
1290 AC_ARG_WITH([ocaml-libdir],
1291   [AS_HELP_STRING([--with-ocaml-libdir],
1292     [Specify install location for ocaml bindings (default is stdlib)])],
1293   [],
1294   [withval=auto])
1295 case "$withval" in
1296   auto) with_ocaml_libdir="$withval" ;;
1297   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1298   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1299 esac
1300
1301 AC_ARG_WITH(clang-srcdir,
1302   AS_HELP_STRING([--with-clang-srcdir],
1303     [Directory to the out-of-tree Clang source]),,
1304     withval="-")
1305 case "$withval" in
1306   -) clang_src_root="" ;;
1307   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1308   *) clang_src_root="$ac_pwd/$withval" ;;
1309 esac
1310 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1311
1312 AC_ARG_WITH(clang-resource-dir,
1313   AS_HELP_STRING([--with-clang-resource-dir],
1314     [Relative directory from the Clang binary for resource files]),,
1315     withval="")
1316 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1317                    [Relative directory for resource files])
1318
1319 AC_ARG_WITH(c-include-dirs,
1320   AS_HELP_STRING([--with-c-include-dirs],
1321     [Colon separated list of directories clang will search for headers]),,
1322     withval="")
1323 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1324                    [Directories clang will search for headers])
1325
1326 # Clang normally uses the system c++ headers and libraries. With this option,
1327 # clang will use the ones provided by a gcc installation instead. This option should
1328 # be passed the same value that was used with --prefix when configuring gcc.
1329 AC_ARG_WITH(gcc-toolchain,
1330   AS_HELP_STRING([--with-gcc-toolchain],
1331     [Directory where gcc is installed.]),,
1332     withval="")
1333 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1334                    [Directory where gcc is installed.])
1335
1336 AC_ARG_WITH(default-sysroot,
1337   AS_HELP_STRING([--with-default-sysroot],
1338     [Add --sysroot=<path> to all compiler invocations.]),,
1339     withval="")
1340 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1341                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1342
1343 AC_ARG_WITH(clang-default-openmp-runtime,
1344   AS_HELP_STRING([--with-clang-default-openmp-runtime],
1345     [The default OpenMP runtime for Clang.]),,
1346     withval="libomp")
1347 AC_DEFINE_UNQUOTED(CLANG_DEFAULT_OPENMP_RUNTIME,"$withval",
1348                    [Default OpenMP runtime used by -fopenmp.])
1349
1350 dnl Allow linking of LLVM with GPLv3 binutils code.
1351 AC_ARG_WITH(binutils-include,
1352   AS_HELP_STRING([--with-binutils-include],
1353     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1354   withval=default)
1355 case "$withval" in
1356   default) WITH_BINUTILS_INCDIR=default ;;
1357   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1358   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1359 esac
1360 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1361   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1362   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1363      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1364      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1365   fi
1366 fi
1367
1368 dnl Specify the URL where bug reports should be submitted.
1369 AC_ARG_WITH(bug-report-url,
1370   AS_HELP_STRING([--with-bug-report-url],
1371     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1372     withval="http://llvm.org/bugs/")
1373 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1374                    [Bug report URL.])
1375
1376 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1377 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1378   [--enable-terminfo],
1379   [Query the terminfo database if available (default is YES)]),
1380   [case "$enableval" in
1381     yes) llvm_cv_enable_terminfo="yes" ;;
1382     no)  llvm_cv_enable_terminfo="no"  ;;
1383     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1384   esac],
1385   llvm_cv_enable_terminfo="yes")
1386 case "$llvm_cv_enable_terminfo" in
1387   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1388   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1389 esac
1390
1391 dnl --enable-libedit: check whether the user wants to turn off libedit.
1392 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1393   [--enable-libedit],
1394   [Use libedit if available (default is YES)]),
1395   [case "$enableval" in
1396     yes) llvm_cv_enable_libedit="yes" ;;
1397     no)  llvm_cv_enable_libedit="no"  ;;
1398     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1399   esac],
1400   llvm_cv_enable_libedit="yes")
1401
1402 dnl --enable-libffi : check whether the user wants to turn off libffi:
1403 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1404   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1405   [case "$enableval" in
1406     yes) llvm_cv_enable_libffi="yes" ;;
1407     no)  llvm_cv_enable_libffi="no"  ;;
1408     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1409   esac],
1410   llvm_cv_enable_libffi=no)
1411
1412 AC_ARG_WITH(internal-prefix,
1413   AS_HELP_STRING([--with-internal-prefix],
1414     [Installation directory for internal files]),,
1415     withval="")
1416 AC_SUBST(INTERNAL_PREFIX,[$withval])
1417
1418 dnl===-----------------------------------------------------------------------===
1419 dnl===
1420 dnl=== SECTION 4: Check for programs we need and that they are the right version
1421 dnl===
1422 dnl===-----------------------------------------------------------------------===
1423
1424 dnl Check for the tools that the makefiles require
1425 AC_CHECK_GNU_MAKE
1426 AC_PROG_LN_S
1427 AC_PATH_PROG(NM, [nm], [nm])
1428 AC_PATH_PROG(CMP, [cmp], [cmp])
1429 AC_PATH_PROG(CP, [cp], [cp])
1430 AC_PATH_PROG(DATE, [date], [date])
1431 AC_PATH_PROG(FIND, [find], [find])
1432 AC_PATH_PROG(GREP, [grep], [grep])
1433 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1434 AC_PATH_PROG(MV,   [mv],   [mv])
1435 AC_PROG_RANLIB
1436 AC_CHECK_TOOL(AR, ar, false)
1437 AC_PATH_PROG(RM,   [rm],   [rm])
1438 AC_PATH_PROG(SED,  [sed],  [sed])
1439 AC_PATH_PROG(TAR,  [tar],  [gtar])
1440 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1441
1442 dnl Looking for misc. graph plotting software
1443 AC_PATH_PROG(DOT, [dot], [echo dot])
1444 if test "$DOT" != "echo dot" ; then
1445   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1446   dnl If we're targeting for mingw we should emit windows paths, not msys
1447   if test "$llvm_cv_os_type" = "MingW" ; then
1448     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1449   fi
1450   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1451    [Define to path to dot program if found or 'echo dot' otherwise])
1452 fi
1453
1454 dnl Find the install program
1455 AC_PROG_INSTALL
1456 dnl Prepend src dir to install path dir if it's a relative path
1457 dnl This is a hack for installs that take place in something other
1458 dnl than the top level.
1459 case "$INSTALL" in
1460  [[\\/$]]* | ?:[[\\/]]* ) ;;
1461  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1462 esac
1463
1464 dnl Checks for documentation and testing tools that we can do without. If these
1465 dnl are not found then they are set to "true" which always succeeds but does
1466 dnl nothing. This just lets the build output show that we could have done
1467 dnl something if the tool was available.
1468 AC_PATH_PROG(BZIP2, [bzip2])
1469 AC_PATH_PROG(CAT, [cat])
1470 AC_PATH_PROG(DOXYGEN, [doxygen])
1471 AC_PATH_PROG(GROFF, [groff])
1472 AC_PATH_PROG(GZIPBIN, [gzip])
1473 AC_PATH_PROG(PDFROFF, [pdfroff])
1474 AC_PATH_PROG(ZIP, [zip])
1475 AC_PATH_PROG(GO, [go])
1476 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1477 AC_PATH_PROGS(GAS, [gas as])
1478
1479 dnl Get the version of the linker in use.
1480 AC_LINK_GET_VERSION
1481
1482 dnl Determine whether the linker supports the -R option.
1483 AC_LINK_USE_R
1484
1485 dnl Determine whether the compiler supports the -rdynamic option.
1486 AC_LINK_EXPORT_DYNAMIC
1487
1488 dnl Determine whether the linker supports the --version-script option.
1489 AC_LINK_VERSION_SCRIPT
1490
1491 AC_CHECK_HEADERS([errno.h])
1492
1493 case "$llvm_cv_os_type" in
1494   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1495   Darwin) llvm_shlib_ext=.dylib ;;
1496   *) llvm_shlib_ext=.so ;;
1497 esac
1498
1499 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1500
1501 AC_MSG_CHECKING([tool compatibility])
1502
1503 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1504 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1505 dnl to support those options.
1506 dnl "icc" emits gcc signatures
1507 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1508 ICC=no
1509 IXX=no
1510 case $CC in
1511   icc*|icpc*)
1512     ICC=yes
1513     IXX=yes
1514     ;;
1515    *)
1516     ;;
1517 esac
1518
1519 if test "$GCC" != "yes" && test "$ICC" != "yes"
1520 then
1521   AC_MSG_ERROR([gcc|icc required but not found])
1522 fi
1523
1524 dnl Ensure that compilation tools are compatible with GCC extensions
1525 if test "$GXX" != "yes" && test "$IXX" != "yes"
1526 then
1527   AC_MSG_ERROR([g++|clang++|icc required but not found])
1528 fi
1529
1530 dnl Verify that GCC is version 3.0 or higher
1531 if test "$GCC" = "yes"
1532 then
1533   AC_COMPILE_IFELSE(
1534 [
1535   AC_LANG_SOURCE([[
1536     #if !defined(__GNUC__) || __GNUC__ < 3
1537     #error Unsupported GCC version
1538     #endif
1539   ]])
1540 ],
1541 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1542 fi
1543
1544 dnl Check for GNU Make.  We use its extensions, so don't build without it
1545 if test -z "$llvm_cv_gnu_make_command"
1546 then
1547   AC_MSG_ERROR([GNU Make required but not found])
1548 fi
1549
1550 dnl Tool compatibility is okay if we make it here.
1551 AC_MSG_RESULT([ok])
1552
1553 dnl Check optional compiler flags.
1554 AC_MSG_CHECKING([optional compiler flags])
1555 case "$llvm_cv_cxx_compiler" in
1556   clang)
1557     CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1558     CXX_FLAG_CHECK(MISSING_FIELD_INITIALIZERS, [-Wmissing-field-initializers])
1559     CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1560     ;;
1561   gcc)
1562     dnl If we're using gcc check for -Wno-missing-field-initializers as gcc will warn
1563     dnl on plain open brace initializations. clang won't so use -Wmissing-field-initializers
1564     dnl there.
1565     CXX_FLAG_CHECK(MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1566     CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1567     CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1568     CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1569     dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1570     dnl known to be uninitialized from cases which might be uninitialized.  We
1571     dnl still want to catch the first kind of errors.
1572     if test -z "$NO_MAYBE_UNINITIALIZED"
1573     then
1574       CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1575     fi
1576     ;;
1577   unknown)
1578     ;;
1579 esac
1580
1581 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1582 dnl -Wno-comment to the flags.
1583 no_comment=
1584 llvm_cv_old_cxxflags="$CXXFLAGS"
1585 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1586 AC_COMPILE_IFELSE(
1587 [
1588   AC_LANG_SOURCE([[// Comment \o\
1589 // Another comment
1590 int main() { return 0; }
1591   ]])
1592 ],
1593 [
1594   no_comment=-Wno-comment
1595 ],
1596 [])
1597 AC_SUBST(NO_COMMENT, [$no_comment])
1598 CXXFLAGS="$llvm_cv_old_cxxflags"
1599
1600 AC_MSG_RESULT([$NO_VARIADIC_MACROS $MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1601
1602 AC_ARG_WITH([python],
1603             [AS_HELP_STRING([--with-python], [path to python])],
1604             [PYTHON="$withval"])
1605
1606 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1607   AC_MSG_CHECKING([for python])
1608   AC_MSG_RESULT([user defined: $with_python])
1609 else
1610   if test -n "$PYTHON" ; then
1611     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1612   fi
1613
1614   AC_PATH_PROG([PYTHON], [python python2 python27],
1615                [AC_MSG_RESULT([not found])
1616                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1617 fi
1618
1619 AC_MSG_CHECKING([for python >= 2.7])
1620 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1621 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1622 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1623 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1624 if test "$ac_python_version_major" -gt "2" || \
1625    (test "$ac_python_version_major" -eq "2" && \
1626     test "$ac_python_version_minor" -ge "7") ; then
1627   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1628 else
1629   AC_MSG_RESULT([not found])
1630   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1631 fi
1632
1633 dnl===-----------------------------------------------------------------------===
1634 dnl===
1635 dnl=== SECTION 5: Check for libraries
1636 dnl===
1637 dnl===-----------------------------------------------------------------------===
1638
1639 AC_CHECK_LIB(m,sin)
1640 if test "$llvm_cv_os_type" = "MingW" ; then
1641   dnl mingw-gcc's driver doesn't imply -lole32 by default so we may need this
1642   dnl when being built with gcc for bootstrapping purposes.
1643   AC_CHECK_LIB(ole32, main)
1644   AC_CHECK_LIB(psapi, main)
1645   AC_CHECK_LIB(shell32, main)
1646   AC_CHECK_LIB(uuid,main)
1647 fi
1648
1649 dnl dlopen() is required for plugin support.
1650 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1651                [Define if dlopen() is available on this platform.]),
1652                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1653
1654 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1655 dnl macros to detect whether clock_gettime is available, this just finds the
1656 dnl right libraries to link with.
1657 AC_SEARCH_LIBS(clock_gettime,rt)
1658
1659 dnl The curses library is optional; used for querying terminal info
1660 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1661   dnl We need the has_color functionality in curses for it to be useful.
1662   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1663                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1664                                    [Define if the setupterm() function is supported this platform.]))
1665 fi
1666
1667 dnl The libedit library is optional; used by lib/LineEditor
1668 if test "$llvm_cv_enable_libedit" = "yes" ; then
1669   AC_SEARCH_LIBS(el_init,edit,
1670                  AC_DEFINE([HAVE_LIBEDIT],[1],
1671                            [Define if libedit is available on this platform.]))
1672 fi
1673
1674 dnl libffi is optional; used to call external functions from the interpreter
1675 if test "$llvm_cv_enable_libffi" = "yes" ; then
1676   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1677                  [Define if libffi is available on this platform.]),
1678                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1679 fi
1680
1681 dnl mallinfo is optional; the code can compile (minus features) without it
1682 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1683                [Define if mallinfo() is available on this platform.]))
1684
1685 dnl pthread locking functions are optional - but llvm will not be thread-safe
1686 dnl without locks.
1687 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1688   AC_CHECK_LIB(pthread, pthread_mutex_init)
1689   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1690                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1691                            [Have pthread_mutex_lock]))
1692   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1693                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1694                  [Have pthread_rwlock_init]))
1695   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1696                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1697                  [Have pthread_getspecific]))
1698 fi
1699
1700 dnl zlib is optional; used for compression/uncompression
1701 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1702   AC_CHECK_LIB(z, compress2)
1703 fi
1704
1705 dnl Allow OProfile support for JIT output.
1706 AC_ARG_WITH(oprofile,
1707   AS_HELP_STRING([--with-oprofile=<prefix>],
1708     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1709     [
1710       AC_SUBST(USE_OPROFILE, [1])
1711       case "$withval" in
1712         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1713         no) llvm_cv_oppath=
1714             AC_SUBST(USE_OPROFILE, [0]) ;;
1715         *) llvm_cv_oppath="${withval}/lib/oprofile"
1716            CPPFLAGS="-I${withval}/include";;
1717       esac
1718       case $llvm_cv_os_type in
1719         Linux)
1720           if test -n "$llvm_cv_oppath" ; then
1721             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1722             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1723             dnl libbfd is not included properly in libopagent in some Debian
1724             dnl versions.  If libbfd isn't found at all, we assume opagent works
1725             dnl anyway.
1726             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1727             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1728               echo "Error! You need to have libopagent around."
1729               exit 1
1730             ])
1731             AC_CHECK_HEADER([opagent.h], [], [
1732               echo "Error! You need to have opagent.h around."
1733               exit 1
1734               ])
1735           fi ;;
1736         *)
1737           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1738       esac
1739     ],
1740     [
1741       AC_SUBST(USE_OPROFILE, [0])
1742     ])
1743 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1744                    [Define if we have the oprofile JIT-support library])
1745
1746 dnl Enable support for Intel JIT Events API.
1747 AC_ARG_WITH(intel-jitevents,
1748   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1749     [
1750        case "$withval" in
1751           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1752           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1753           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1754        esac
1755
1756       case $llvm_cv_os_type in
1757         Linux|Win32|Cygwin|MingW) ;;
1758         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1759       esac
1760
1761       case "$llvm_cv_target_arch" in
1762         x86|x86_64) ;;
1763         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1764       esac
1765     ],
1766     [
1767       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1768     ])
1769 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1770                    [Define if we have the Intel JIT API runtime support library])
1771
1772 dnl Check for libxml2
1773 dnl Right now we're just checking for the existence, we could also check for a
1774 dnl particular version via --version on xml2-config
1775 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1776
1777 AC_MSG_CHECKING(for libxml2 includes)
1778 if test "x$XML2CONFIG" = "x"; then
1779  AC_MSG_RESULT(xml2-config not found)
1780 else
1781  LIBXML2_INC=`$XML2CONFIG --cflags`
1782  AC_MSG_RESULT($LIBXML2_INC)
1783  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1784                                 LIBXML2_LIBS="-lxml2"])
1785 fi
1786 AC_SUBST(LIBXML2_LIBS)
1787 AC_SUBST(LIBXML2_INC)
1788
1789 dnl===-----------------------------------------------------------------------===
1790 dnl===
1791 dnl=== SECTION 6: Check for header files
1792 dnl===
1793 dnl===-----------------------------------------------------------------------===
1794
1795 dnl First, use autoconf provided macros for specific headers that we need
1796 dnl We don't check for ancient stuff or things that are guaranteed to be there
1797 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1798 dnl Generally we're looking for POSIX headers.
1799 AC_HEADER_DIRENT
1800 AC_HEADER_MMAP_ANONYMOUS
1801 AC_HEADER_STAT
1802 AC_HEADER_TIME
1803
1804 AC_LANG_PUSH([C++])
1805 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1806 AC_CHECK_HEADERS([cxxabi.h], [], [],
1807 [#include <stddef.h>
1808 ])
1809 AC_LANG_POP([C++])
1810
1811 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1812 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1813 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1814 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1815 AC_CHECK_HEADERS([valgrind/valgrind.h])
1816 AC_CHECK_HEADERS([fenv.h])
1817 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1818 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1819   AC_CHECK_HEADERS(pthread.h,
1820                    AC_SUBST(HAVE_PTHREAD, 1),
1821                    AC_SUBST(HAVE_PTHREAD, 0))
1822 else
1823   AC_SUBST(HAVE_PTHREAD, 0)
1824 fi
1825 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1826   AC_CHECK_HEADERS(zlib.h,
1827                    AC_SUBST(HAVE_LIBZ, 1),
1828                    AC_SUBST(HAVE_LIBZ, 0))
1829 else
1830   AC_SUBST(HAVE_LIBZ, 0)
1831 fi
1832
1833 dnl Try to find ffi.h.
1834 if test "$llvm_cv_enable_libffi" = "yes" ; then
1835   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1836 fi
1837
1838 dnl Try to find Darwin specific crash reporting libraries.
1839 AC_CHECK_HEADERS([CrashReporterClient.h])
1840
1841 dnl Try to find Darwin specific crash reporting global.
1842 AC_MSG_CHECKING([__crashreporter_info__])
1843 AC_LINK_IFELSE(
1844 [
1845   AC_LANG_SOURCE([[
1846     extern const char *__crashreporter_info__;
1847     int main() {
1848       __crashreporter_info__ = "test";
1849       return 0;
1850     }
1851   ]])
1852 ],
1853 [
1854   AC_MSG_RESULT([yes])
1855   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1856 ],
1857 [
1858   AC_MSG_RESULT([no])
1859   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1860 ])
1861
1862 dnl===-----------------------------------------------------------------------===
1863 dnl===
1864 dnl=== SECTION 7: Check for types and structures
1865 dnl===
1866 dnl===-----------------------------------------------------------------------===
1867
1868 AC_HUGE_VAL_CHECK
1869 AC_TYPE_PID_T
1870 AC_TYPE_SIZE_T
1871 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1872 AC_STRUCT_TM
1873 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1874 AC_CHECK_TYPES([uint64_t],,
1875          AC_CHECK_TYPES([u_int64_t],,
1876          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1877
1878 dnl===-----------------------------------------------------------------------===
1879 dnl===
1880 dnl=== SECTION 8: Check for specific functions needed
1881 dnl===
1882 dnl===-----------------------------------------------------------------------===
1883
1884 AC_CHECK_FUNCS([backtrace getcwd ])
1885 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1886 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1887 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1888 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1889 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1890 AC_CHECK_FUNCS([setjmp longjmp writev])
1891 AC_CHECK_FUNCS([futimes futimens])
1892 AC_C_PRINTF_A
1893
1894 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1895 AC_CHECK_DECLS([arc4random])
1896
1897 dnl Check the declaration "Secure API" on Windows environments.
1898 AC_CHECK_DECLS([strerror_s])
1899
1900 dnl Check symbols in libgcc.a for JIT on Mingw.
1901 if test "$llvm_cv_os_type" = "MingW" ; then
1902   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1903   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1904   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1905   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1906   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1907   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1908
1909   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1910   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1911   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1912   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1913   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1914   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1915   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1916   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1917   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1918   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1919
1920   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1921   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1922 fi
1923
1924 dnl Check Win32 API EnumerateLoadedModules.
1925 if test "$llvm_cv_os_type" = "MingW" ; then
1926   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1927   AC_COMPILE_IFELSE(
1928 [
1929   AC_LANG_SOURCE([[
1930     #include <windows.h>
1931     #include <imagehlp.h>
1932     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1933     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1934   ]])
1935 ],
1936 [
1937   AC_MSG_RESULT([yes])
1938   llvm_cv_win32_elmcb_pcstr="PCSTR"
1939 ],
1940 [
1941   AC_MSG_RESULT([no])
1942   llvm_cv_win32_elmcb_pcstr="PSTR"
1943 ])
1944   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1945 fi
1946
1947 dnl Check for mmap support.We also need to know if /dev/zero is required to
1948 dnl be opened for allocating RWX memory.
1949 dnl Make sure we aren't attempting to configure for an unknown system
1950 if test "$llvm_cv_platform_type" = "Unix" ; then
1951   AC_FUNC_MMAP
1952   AC_FUNC_MMAP_FILE
1953   AC_NEED_DEV_ZERO_FOR_MMAP
1954
1955   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1956   then
1957     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1958   fi
1959   if test "$ac_cv_func_mmap_file" = "no"
1960   then
1961     AC_MSG_WARN([mmap() of files required but not found])
1962   fi
1963 fi
1964
1965 dnl atomic builtins are required for threading support.
1966 AC_MSG_CHECKING(for GCC atomic builtins)
1967 dnl Since we'll be using these atomic builtins in C++ files we should test
1968 dnl the C++ compiler.
1969 AC_LANG_PUSH([C++])
1970 AC_LINK_IFELSE(
1971 [
1972   AC_LANG_SOURCE([[
1973     int main() {
1974       volatile unsigned long val = 1;
1975       __sync_synchronize();
1976       __sync_val_compare_and_swap(&val, 1, 0);
1977       __sync_add_and_fetch(&val, 1);
1978       __sync_sub_and_fetch(&val, 1);
1979       return 0;
1980     }
1981   ]])
1982 ],
1983 [
1984   AC_MSG_RESULT([yes])
1985   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1986 ],
1987 [
1988   AC_MSG_RESULT([no])
1989   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1990   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1991 ])
1992 AC_LANG_POP([C++])
1993
1994 dnl===-----------------------------------------------------------------------===
1995 dnl===
1996 dnl=== SECTION 9: Additional checks, variables, etc.
1997 dnl===
1998 dnl===-----------------------------------------------------------------------===
1999
2000 dnl Handle 32-bit linux systems running a 64-bit kernel.
2001 dnl This has to come after section 4 because it invokes the compiler.
2002 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
2003   AC_IS_LINUX_MIXED
2004   if test "$llvm_cv_linux_mixed" = "yes"; then
2005     llvm_cv_target_arch="x86"
2006     ARCH="x86"
2007   fi
2008 fi
2009
2010 dnl Check whether __dso_handle is present
2011 AC_CHECK_FUNCS([__dso_handle])
2012
2013 dnl Propagate the shared library extension that the libltdl checks did to
2014 dnl the Makefiles so we can use it there too
2015 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
2016
2017 dnl Translate the various configuration directories and other basic
2018 dnl information into substitutions that will end up in Makefile.config.in
2019 dnl that these configured values can be used by the makefiles
2020 if test "${prefix}" = "NONE" ; then
2021   prefix="/usr/local"
2022 fi
2023 eval LLVM_PREFIX="${prefix}";
2024 eval LLVM_BINDIR="${prefix}/bin";
2025 eval LLVM_DATADIR="${prefix}/share/llvm";
2026 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
2027 eval LLVM_ETCDIR="${prefix}/etc/llvm";
2028 eval LLVM_INCLUDEDIR="${prefix}/include";
2029 eval LLVM_INFODIR="${prefix}/info";
2030 eval LLVM_MANDIR="${prefix}/man";
2031 LLVM_CONFIGTIME=`date`
2032 AC_SUBST(LLVM_PREFIX)
2033 AC_SUBST(LLVM_BINDIR)
2034 AC_SUBST(LLVM_DATADIR)
2035 AC_SUBST(LLVM_DOCSDIR)
2036 AC_SUBST(LLVM_ETCDIR)
2037 AC_SUBST(LLVM_INCLUDEDIR)
2038 AC_SUBST(LLVM_INFODIR)
2039 AC_SUBST(LLVM_MANDIR)
2040 AC_SUBST(LLVM_CONFIGTIME)
2041
2042 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
2043 if test "${ENABLE_TIMESTAMPS}" = "0"; then
2044   LLVM_CONFIGTIME="(timestamp not enabled)"
2045 fi
2046
2047 dnl Place the various directories into the config.h file as #defines so that we
2048 dnl can know about the installation paths within LLVM.
2049 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
2050                    [Installation prefix directory])
2051 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
2052                    [Installation directory for binary executables])
2053 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2054                    [Installation directory for data files])
2055 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2056                    [Installation directory for documentation])
2057 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2058                    [Installation directory for config files])
2059 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2060                    [Installation directory for include files])
2061 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2062                    [Installation directory for .info files])
2063 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2064                    [Installation directory for man pages])
2065 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2066                    [Time at which LLVM was configured])
2067 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2068                    [Host triple LLVM will be executed on])
2069 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2070                    [Target triple LLVM will generate code for by default])
2071
2072 dnl Determine which bindings to build.
2073 if test "$BINDINGS_TO_BUILD" = auto ; then
2074   BINDINGS_TO_BUILD=""
2075   if test "x$OCAMLFIND" != x ; then
2076     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2077   fi
2078   if test "x$GO" != x ; then
2079     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2080       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2081     fi
2082   fi
2083 fi
2084 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2085
2086 dnl Do any work necessary to ensure that bindings have what they need.
2087 binding_prereqs_failed=0
2088 for a_binding in $BINDINGS_TO_BUILD ; do
2089   case "$a_binding" in
2090   ocaml)
2091     if test "x$OCAMLFIND" = x ; then
2092       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2093       binding_prereqs_failed=1
2094     fi
2095
2096     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2097       HAVE_OCAMLOPT=1
2098     else
2099       HAVE_OCAMLOPT=0
2100     fi
2101     AC_SUBST(HAVE_OCAMLOPT)
2102
2103     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2104       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2105       binding_prereqs_failed=1
2106     fi
2107
2108     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2109       HAVE_OCAML_OUNIT=1
2110     else
2111       HAVE_OCAML_OUNIT=0
2112       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2113       dnl oUnit is optional!
2114     fi
2115     AC_SUBST(HAVE_OCAML_OUNIT)
2116
2117     if test "x$with_ocaml_libdir" != xauto ; then
2118       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2119     else
2120       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2121       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2122       then
2123         # ocaml stdlib is beneath our prefix; use stdlib
2124         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2125       else
2126         # ocaml stdlib is outside our prefix; use libdir/ocaml
2127         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2128       fi
2129     fi
2130     ;;
2131   go)
2132     if test "x$GO" = x ; then
2133       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2134       binding_prereqs_failed=1
2135     else
2136       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2137         :
2138       else
2139         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2140         binding_prereqs_failed=1
2141       fi
2142     fi
2143     ;;
2144   esac
2145 done
2146 if test "$binding_prereqs_failed" = 1 ; then
2147   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2148 fi
2149
2150 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2151 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2152
2153 dnl Determine linker rpath flag
2154 if test "$llvm_cv_link_use_r" = "yes" ; then
2155   RPATH="-Wl,-R"
2156 else
2157   RPATH="-Wl,-rpath"
2158 fi
2159 AC_SUBST(RPATH)
2160
2161 dnl Determine linker rdynamic flag
2162 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2163   RDYNAMIC="-rdynamic"
2164 else
2165   RDYNAMIC=""
2166 fi
2167 AC_SUBST(RDYNAMIC)
2168
2169 dnl===-----------------------------------------------------------------------===
2170 dnl===
2171 dnl=== SECTION 10: Specify the output files and generate it
2172 dnl===
2173 dnl===-----------------------------------------------------------------------===
2174
2175 dnl Configure header files
2176 dnl WARNING: dnl If you add or remove any of the following config headers, then
2177 dnl you MUST also update Makefile so that the variable FilesToConfig
2178 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2179 dnl files can be updated automatically when their *.in sources change.
2180 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2181 AH_TOP([#ifndef CONFIG_H
2182 #define CONFIG_H
2183
2184 /* Exported configuration */
2185 #include "llvm/Config/llvm-config.h"])
2186 AH_BOTTOM([#endif])
2187
2188 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2189 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2190 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2191 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2192 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2193
2194 dnl Configure the makefile's configuration data
2195 AC_CONFIG_FILES([Makefile.config])
2196
2197 dnl Configure the RPM spec file for LLVM
2198 AC_CONFIG_FILES([llvm.spec])
2199
2200 dnl Configure doxygen's configuration file
2201 AC_CONFIG_FILES([docs/doxygen.cfg])
2202
2203 dnl Configure clang, if present
2204 if test "${clang_src_root}" = ""; then
2205   clang_src_root="$srcdir/tools/clang"
2206 fi
2207 if test -f ${clang_src_root}/README.txt; then
2208   dnl Clang supports build systems which use the multilib libdir suffix.
2209   dnl The autoconf system doesn't support this so stub out that variable.
2210   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2211                      [Multilib suffix for libdir.])
2212
2213   dnl Use variables to stay under 80 columns.
2214   configh="include/clang/Config/config.h"
2215   doxy="docs/doxygen.cfg"
2216   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2217   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2218 fi
2219
2220 dnl OCaml findlib META file
2221 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2222
2223 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2224 test "x$program_prefix" = "xNONE" && program_prefix=""
2225 AC_SUBST([program_prefix])
2226
2227
2228 dnl Do special configuration of Makefiles
2229 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2230 AC_CONFIG_MAKEFILE(Makefile)
2231 AC_CONFIG_MAKEFILE(Makefile.common)
2232 AC_CONFIG_MAKEFILE(examples/Makefile)
2233 AC_CONFIG_MAKEFILE(lib/Makefile)
2234 AC_CONFIG_MAKEFILE(test/Makefile)
2235 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2236 AC_CONFIG_MAKEFILE(unittests/Makefile)
2237 AC_CONFIG_MAKEFILE(tools/Makefile)
2238 AC_CONFIG_MAKEFILE(utils/Makefile)
2239 AC_CONFIG_MAKEFILE(projects/Makefile)
2240 AC_CONFIG_MAKEFILE(bindings/Makefile)
2241 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2242
2243 dnl Finally, crank out the output
2244 AC_OUTPUT
2245 echo ""
2246 echo ""
2247 echo "################################################################################"
2248 echo "################################################################################"
2249 echo "The LLVM project has deprecated building with configure & make."
2250 echo "The autoconf-based makefile build system will be removed in the 3.9 release."
2251 echo ""
2252 echo "Please migrate to the CMake-based build system."
2253 echo "For more information see: http://llvm.org/docs/CMake.html"
2254 echo "################################################################################"
2255 echo "################################################################################"