7e399fcddd0a7137f30bed5896230a0085995e9b
[oota-llvm.git] / autoconf / configure.ac
1 dnl === configure.ac --------------------------------------------------------===
2 dnl                     The LLVM Compiler Infrastructure
3 dnl
4 dnl This file is distributed under the University of Illinois Open Source
5 dnl License. See LICENSE.TXT for details.
6 dnl
7 dnl===-----------------------------------------------------------------------===
8 dnl This is the LLVM configuration script. It is processed by the autoconf
9 dnl program to produce a script named configure. This script contains the
10 dnl configuration checks that LLVM needs in order to support multiple platforms.
11 dnl This file is composed of 10 sections per the recommended organization of
12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
13 dnl please keep the various types of checks within their sections. The sections
14 dnl are as follows:
15 dnl
16 dnl SECTION 1: Initialization & Setup
17 dnl SECTION 2: Architecture, target, and host checks
18 dnl SECTION 3: Command line arguments for the configure script.
19 dnl SECTION 4: Check for programs we need and that they are the right version
20 dnl SECTION 5: Check for libraries
21 dnl SECTION 6: Check for header files
22 dnl SECTION 7: Check for types and structures
23 dnl SECTION 8: Check for specific functions needed
24 dnl SECTION 9: Additional checks, variables, etc.
25 dnl SECTION 10: Specify the output files and generate it
26 dnl
27 dnl===-----------------------------------------------------------------------===
28 dnl===
29 dnl=== SECTION 1: Initialization & Setup
30 dnl===
31 dnl===-----------------------------------------------------------------------===
32 dnl Initialize autoconf and define the package name, version number and
33 dnl address for reporting bugs.
34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
36 AC_DEFINE([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
37
38 dnl Provide a copyright substitution and ensure the copyright notice is included
39 dnl in the output of --version option of the generated configure script.
40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
42
43 dnl Indicate that we require autoconf 2.60 or later.
44 AC_PREREQ(2.60)
45
46 dnl Verify that the source directory is valid. This makes sure that we are
47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
49
50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
51 dnl various tools where the m4 autoconf macros are.
52 AC_CONFIG_AUX_DIR([autoconf])
53
54 dnl Quit if the source directory has already been configured.
55 dnl NOTE: This relies upon undocumented autoconf behavior.
56 if test ${srcdir} != "." ; then
57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
58     AC_MSG_ERROR([Already configured in ${srcdir}])
59   fi
60 fi
61
62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
64 : ${CFLAGS=}
65 : ${CXXFLAGS=}
66
67 dnl We need to check for the compiler up here to avoid anything else
68 dnl starting with a different one.
69 AC_PROG_CC(clang gcc)
70 AC_PROG_CXX(clang++ g++)
71 AC_PROG_CPP
72
73 dnl If CXX is Clang, check that it can find and parse C++ standard library
74 dnl headers.
75 if test "$CXX" = "clang++" ; then
76   AC_MSG_CHECKING([whether clang works])
77   AC_LANG_PUSH([C++])
78   dnl Note that space between 'include' and '(' is required.  There's a broken
79   dnl regex in aclocal that otherwise will think that we call m4's include
80   dnl builtin.
81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
82 #if __has_include (<cxxabi.h>)
83 #include <cxxabi.h>
84 #endif
85 #if __has_include (<unwind.h>)
86 #include <unwind.h>
87 #endif
88 ]])],
89 [
90   AC_MSG_RESULT([yes])
91 ],
92 [
93   AC_MSG_RESULT([no])
94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
95 ])
96   AC_LANG_POP([C++])
97 fi
98
99 dnl Set up variables that track whether the host compiler is GCC or Clang where
100 dnl we can effectively sanity check them. We don't try to sanity check all the
101 dnl other possible compilers.
102 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
103 AC_LANG_PUSH([C++])
104 llvm_cv_cxx_compiler=unknown
105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
106                                     #error
107                                     #endif
108                                     ]])],
109                   llvm_cv_cxx_compiler=clang,
110                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
111                                                        #error
112                                                        #endif
113                                                        ]])],
114                                      llvm_cv_cxx_compiler=gcc, [])])
115 AC_LANG_POP([C++])
116 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
117
118 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
119 dnl be bypassed by passing a flag if necessary on a platform.
120 AC_ARG_ENABLE(compiler-version-checks,
121               AS_HELP_STRING([--enable-compiler-version-checks],
122                              [Check the version of the host compiler (default is YES)]),,
123                              enableval=default)
124 case "$enableval" in
125   no)
126     ;;
127   yes|default)
128     AC_LANG_PUSH([C++])
129     case "$llvm_cv_cxx_compiler" in
130     clang)
131       AC_MSG_CHECKING([whether Clang is new enough])
132       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
133 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
134 #error This version of Clang is too old to build LLVM
135 #endif
136 ]])],
137           [AC_MSG_RESULT([yes])],
138           [AC_MSG_RESULT([no])
139            AC_MSG_ERROR([
140 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
141 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
142 bypass these sanity checks.])])
143
144       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
145       dnl are sometimes deeply confusing though. Here we test for an obvious
146       dnl incomplete feature in 4.6's standard library that was completed in
147       dnl 4.7's.
148       AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
149       llvm_cv_old_cxxflags="$CXXFLAGS"
150       CXXFLAGS="$CXXFLAGS -std=c++0x"
151       AC_LINK_IFELSE([AC_LANG_SOURCE([[
152 #include <atomic>
153 std::atomic<float> x(0.0f);
154 int main() { return (float)x; }
155 ]])],
156           [AC_MSG_RESULT([yes])],
157           [AC_MSG_RESULT([no])
158            AC_MSG_ERROR([
159 We detected a missing feature in the standard C++ library that was known to be
160 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
161 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
162 than 4.7. You will need to update your system and ensure Clang uses the newer
163 standard library.
164
165 If this error is incorrect or you need to force things to work, you may pass
166 '--disable-compiler-version-checks' to configure to bypass this test.])])
167       CXXFLAGS="$llvm_cv_old_cxxflags"
168       ;;
169     gcc)
170       AC_MSG_CHECKING([whether GCC is new enough])
171       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
172 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
173 #error This version of GCC is too old to build LLVM
174 #endif
175 ]])],
176           [AC_MSG_RESULT([yes])],
177           [AC_MSG_RESULT([no])
178            AC_MSG_ERROR([
179 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
180 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
181 bypass these sanity checks.])])
182       ;;
183     unknown)
184       ;;
185     esac
186     AC_LANG_POP([C++])
187     ;;
188   *)
189     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
190     ;;
191 esac
192
193 dnl Configure all of the projects present in our source tree. While we could
194 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
195 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
196 dnl Instead we match on the known projects.
197
198 dnl
199 dnl One tricky part of doing this is that some projects depend upon other
200 dnl projects.  For example, several projects rely upon the LLVM test suite.
201 dnl We want to configure those projects first so that their object trees are
202 dnl created before running the configure scripts of projects that depend upon
203 dnl them.
204 dnl
205
206 dnl Several projects use the LLVM test suite, so configure it next.
207 if test -d ${srcdir}/projects/test-suite ; then
208   AC_CONFIG_SUBDIRS([projects/test-suite])
209 fi
210
211 dnl llvm-test is the old name of the test-suite, kept here for backwards
212 dnl compatibility
213 if test -d ${srcdir}/projects/llvm-test ; then
214   AC_CONFIG_SUBDIRS([projects/llvm-test])
215 fi
216
217 dnl Some projects use poolalloc; configure that next
218 if test -d ${srcdir}/projects/poolalloc ; then
219   AC_CONFIG_SUBDIRS([projects/poolalloc])
220 fi
221
222 if test -d ${srcdir}/projects/llvm-poolalloc ; then
223   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
224 fi
225
226 dnl Check for all other projects
227 for i in `ls ${srcdir}/projects`
228 do
229   if test -d ${srcdir}/projects/${i} ; then
230     case ${i} in
231       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
232       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
233       compiler-rt)       ;;
234       test-suite)     ;;
235       llvm-test)      ;;
236       poolalloc)      ;;
237       llvm-poolalloc) ;;
238       *)
239         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
240         ;;
241     esac
242   fi
243 done
244
245 dnl Disable the build of polly, even if it is checked out into tools/polly.
246 AC_ARG_ENABLE(polly,
247               AS_HELP_STRING([--enable-polly],
248                              [Use polly if available (default is YES)]),,
249                              enableval=default)
250 case "$enableval" in
251   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
252   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
253   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
254   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
255 esac
256
257
258 dnl Check if polly is checked out into tools/polly and configure it if
259 dnl available.
260 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
261   AC_SUBST(LLVM_HAS_POLLY,1)
262   AC_CONFIG_SUBDIRS([tools/polly])
263 fi
264
265 dnl===-----------------------------------------------------------------------===
266 dnl===
267 dnl=== SECTION 2: Architecture, target, and host checks
268 dnl===
269 dnl===-----------------------------------------------------------------------===
270
271 dnl Check the target for which we're compiling and the host that will do the
272 dnl compilations. This will tell us which LLVM compiler will be used for
273 dnl compiling SSA into object code. This needs to be done early because
274 dnl following tests depend on it.
275 AC_CANONICAL_TARGET
276
277 dnl Determine the platform type and cache its value. This helps us configure
278 dnl the System library to the correct build platform.
279 AC_CACHE_CHECK([type of operating system we're going to host on],
280                [llvm_cv_os_type],
281 [case $host in
282   *-*-aix*)
283     llvm_cv_link_all_option="-Wl,--whole-archive"
284     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
285     llvm_cv_os_type="AIX"
286     llvm_cv_platform_type="Unix" ;;
287   *-*-irix*)
288     llvm_cv_link_all_option="-Wl,--whole-archive"
289     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
290     llvm_cv_os_type="IRIX"
291     llvm_cv_platform_type="Unix" ;;
292   *-*-cygwin*)
293     llvm_cv_link_all_option="-Wl,--whole-archive"
294     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
295     llvm_cv_os_type="Cygwin"
296     llvm_cv_platform_type="Unix" ;;
297   *-*-darwin*)
298     llvm_cv_link_all_option="-Wl,-all_load"
299     llvm_cv_no_link_all_option="-Wl,-noall_load"
300     llvm_cv_os_type="Darwin"
301     llvm_cv_platform_type="Unix" ;;
302   *-*-minix*)
303     llvm_cv_link_all_option="-Wl,-all_load"
304     llvm_cv_no_link_all_option="-Wl,-noall_load"
305     llvm_cv_os_type="Minix"
306     llvm_cv_platform_type="Unix" ;;
307   *-*-freebsd*)
308     llvm_cv_link_all_option="-Wl,--whole-archive"
309     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
310     llvm_cv_os_type="FreeBSD"
311     llvm_cv_platform_type="Unix" ;;
312   *-*-kfreebsd-gnu)
313     llvm_cv_link_all_option="-Wl,--whole-archive"
314     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
315     llvm_cv_os_type="GNU/kFreeBSD"
316     llvm_cv_platform_type="Unix" ;;
317   *-*-openbsd*)
318     llvm_cv_link_all_option="-Wl,--whole-archive"
319     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
320     llvm_cv_os_type="OpenBSD"
321     llvm_cv_platform_type="Unix" ;;
322   *-*-netbsd*)
323     llvm_cv_link_all_option="-Wl,--whole-archive"
324     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
325     llvm_cv_os_type="NetBSD"
326     llvm_cv_platform_type="Unix" ;;
327   *-*-dragonfly*)
328     llvm_cv_link_all_option="-Wl,--whole-archive"
329     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
330     llvm_cv_os_type="DragonFly"
331     llvm_cv_platform_type="Unix" ;;
332   *-*-hpux*)
333     llvm_cv_link_all_option="-Wl,--whole-archive"
334     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
335     llvm_cv_os_type="HP-UX"
336     llvm_cv_platform_type="Unix" ;;
337   *-*-interix*)
338     llvm_cv_link_all_option="-Wl,--whole-archive"
339     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
340     llvm_cv_os_type="Interix"
341     llvm_cv_platform_type="Unix" ;;
342   *-*-linux*)
343     llvm_cv_link_all_option="-Wl,--whole-archive"
344     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
345     llvm_cv_os_type="Linux"
346     llvm_cv_platform_type="Unix" ;;
347   *-*-gnu*)
348     llvm_cv_link_all_option="-Wl,--whole-archive"
349     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
350     llvm_cv_os_type="GNU"
351     llvm_cv_platform_type="Unix" ;;
352   *-*-solaris*)
353     llvm_cv_link_all_option="-Wl,-z,allextract"
354     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
355     llvm_cv_os_type="SunOS"
356     llvm_cv_platform_type="Unix" ;;
357   *-*-auroraux*)
358     llvm_cv_link_all_option="-Wl,-z,allextract"
359     llvm_cv_link_all_option="-Wl,-z,defaultextract"
360     llvm_cv_os_type="AuroraUX"
361     llvm_cv_platform_type="Unix" ;;
362   *-*-win32*)
363     llvm_cv_link_all_option="-Wl,--whole-archive"
364     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
365     llvm_cv_os_type="Win32"
366     llvm_cv_platform_type="Win32" ;;
367   *-*-mingw*)
368     llvm_cv_link_all_option="-Wl,--whole-archive"
369     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
370     llvm_cv_os_type="MingW"
371     llvm_cv_platform_type="Win32" ;;
372   *-*-haiku*)
373     llvm_cv_link_all_option="-Wl,--whole-archive"
374     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
375     llvm_cv_os_type="Haiku"
376     llvm_cv_platform_type="Unix" ;;
377   *-unknown-eabi*)
378     llvm_cv_link_all_option="-Wl,--whole-archive"
379     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
380     llvm_cv_os_type="Freestanding"
381     llvm_cv_platform_type="Unix" ;;
382   *-unknown-elf*)
383     llvm_cv_link_all_option="-Wl,--whole-archive"
384     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
385     llvm_cv_os_type="Freestanding"
386     llvm_cv_platform_type="Unix" ;;
387   *)
388     llvm_cv_link_all_option=""
389     llvm_cv_no_link_all_option=""
390     llvm_cv_os_type="Unknown"
391     llvm_cv_platform_type="Unknown" ;;
392 esac])
393
394 AC_CACHE_CHECK([type of operating system we're going to target],
395                [llvm_cv_target_os_type],
396 [case $target in
397   *-*-aix*)
398     llvm_cv_target_os_type="AIX" ;;
399   *-*-irix*)
400     llvm_cv_target_os_type="IRIX" ;;
401   *-*-cygwin*)
402     llvm_cv_target_os_type="Cygwin" ;;
403   *-*-darwin*)
404     llvm_cv_target_os_type="Darwin" ;;
405   *-*-minix*)
406     llvm_cv_target_os_type="Minix" ;;
407   *-*-freebsd*)
408     llvm_cv_target_os_type="FreeBSD" ;;
409   *-*-kfreebsd-gnu)
410     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
411   *-*-openbsd*)
412     llvm_cv_target_os_type="OpenBSD" ;;
413   *-*-netbsd*)
414     llvm_cv_target_os_type="NetBSD" ;;
415   *-*-dragonfly*)
416     llvm_cv_target_os_type="DragonFly" ;;
417   *-*-hpux*)
418     llvm_cv_target_os_type="HP-UX" ;;
419   *-*-interix*)
420     llvm_cv_target_os_type="Interix" ;;
421   *-*-linux*)
422     llvm_cv_target_os_type="Linux" ;;
423   *-*-gnu*)
424     llvm_cv_target_os_type="GNU" ;;
425   *-*-solaris*)
426     llvm_cv_target_os_type="SunOS" ;;
427   *-*-auroraux*)
428     llvm_cv_target_os_type="AuroraUX" ;;
429   *-*-win32*)
430     llvm_cv_target_os_type="Win32" ;;
431   *-*-mingw*)
432     llvm_cv_target_os_type="MingW" ;;
433   *-*-haiku*)
434     llvm_cv_target_os_type="Haiku" ;;
435   *-*-rtems*)
436     llvm_cv_target_os_type="RTEMS" ;;
437   *-*-nacl*)
438     llvm_cv_target_os_type="NativeClient" ;;
439   *-unknown-eabi*)
440     llvm_cv_target_os_type="Freestanding" ;;
441   *)
442     llvm_cv_target_os_type="Unknown" ;;
443 esac])
444
445 dnl Make sure we aren't attempting to configure for an unknown system
446 if test "$llvm_cv_os_type" = "Unknown" ; then
447   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
448 fi
449
450 dnl Set the "OS" Makefile variable based on the platform type so the
451 dnl makefile can configure itself to specific build hosts
452 AC_SUBST(OS,$llvm_cv_os_type)
453 AC_SUBST(HOST_OS,$llvm_cv_os_type)
454 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
455
456 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
457 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
458 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
459
460 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
461 dnl This is used by lib/Support to determine the basic kind of implementation
462 dnl to use.
463 case $llvm_cv_platform_type in
464   Unix)
465     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
466     AC_SUBST(LLVM_ON_UNIX,[1])
467     AC_SUBST(LLVM_ON_WIN32,[0])
468     ;;
469   Win32)
470     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
471     AC_SUBST(LLVM_ON_UNIX,[0])
472     AC_SUBST(LLVM_ON_WIN32,[1])
473     ;;
474 esac
475
476 dnl Determine what our target architecture is and configure accordingly.
477 dnl This will allow Makefiles to make a distinction between the hardware and
478 dnl the OS.
479 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
480 [case $target in
481   i?86-*)                 llvm_cv_target_arch="x86" ;;
482   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
483   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
484   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
485   arm*-*)                 llvm_cv_target_arch="ARM" ;;
486   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
487   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
488   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
489   xcore-*)                llvm_cv_target_arch="XCore" ;;
490   msp430-*)               llvm_cv_target_arch="MSP430" ;;
491   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
492   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
493   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
494   *)                      llvm_cv_target_arch="Unknown" ;;
495 esac])
496
497 if test "$llvm_cv_target_arch" = "Unknown" ; then
498   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
499 fi
500
501 dnl Determine the LLVM native architecture for the target
502 case "$llvm_cv_target_arch" in
503     x86)     LLVM_NATIVE_ARCH="X86" ;;
504     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
505     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
506 esac
507
508 dnl Define a substitution, ARCH, for the target architecture
509 AC_SUBST(ARCH,$llvm_cv_target_arch)
510
511 dnl Determine what our host architecture.
512 dnl This will allow MCJIT regress tests runs only for supported
513 dnl platforms.
514 case $host in
515   i?86-*)                 host_arch="x86" ;;
516   amd64-* | x86_64-*)     host_arch="x86_64" ;;
517   sparc*-*)               host_arch="Sparc" ;;
518   powerpc*-*)             host_arch="PowerPC" ;;
519   arm*-*)                 host_arch="ARM" ;;
520   aarch64*-*)             host_arch="AArch64" ;;
521   mips-* | mips64-*)      host_arch="Mips" ;;
522   mipsel-* | mips64el-*)  host_arch="Mips" ;;
523   xcore-*)                host_arch="XCore" ;;
524   msp430-*)               host_arch="MSP430" ;;
525   hexagon-*)              host_arch="Hexagon" ;;
526   s390x-*)                host_arch="SystemZ" ;;
527   *)                      host_arch="Unknown" ;;
528 esac
529
530 if test "$host_arch" = "Unknown" ; then
531   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
532 fi
533
534 AC_SUBST(HOST_ARCH,$host_arch)
535
536 dnl Check for build platform executable suffix if we're cross-compiling
537 if test "$cross_compiling" = yes; then
538   AC_SUBST(LLVM_CROSS_COMPILING, [1])
539   AC_BUILD_EXEEXT
540   ac_build_prefix=${build_alias}-
541   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
542   if test -z "$BUILD_CXX"; then
543      AC_CHECK_PROG(BUILD_CXX, g++, g++)
544      if test -z "$BUILD_CXX"; then
545        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
546      fi
547   fi
548 else
549   AC_SUBST(LLVM_CROSS_COMPILING, [0])
550 fi
551
552 dnl Check to see if there's a .svn or .git directory indicating that this
553 dnl build is being done from a checkout. This sets up several defaults for
554 dnl the command line switches. When we build with a checkout directory,
555 dnl we get a debug with assertions turned on. Without, we assume a source
556 dnl release and we get an optimized build without assertions.
557 dnl See --enable-optimized and --enable-assertions below
558 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
559   cvsbuild="yes"
560   optimize="no"
561   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
562 else
563   cvsbuild="no"
564   optimize="yes"
565 fi
566
567 dnl===-----------------------------------------------------------------------===
568 dnl===
569 dnl=== SECTION 3: Command line arguments for the configure script.
570 dnl===
571 dnl===-----------------------------------------------------------------------===
572
573 dnl --enable-libcpp : check whether or not to use libc++ on the command line
574 AC_ARG_ENABLE(libcpp,
575               AS_HELP_STRING([--enable-libcpp],
576                              [Use libc++ if available (default is NO)]),,
577                              enableval=default)
578 case "$enableval" in
579   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
580   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
581   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
582   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
583 esac
584
585 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
586 AC_ARG_ENABLE(cxx11,
587               AS_HELP_STRING([--enable-cxx11],
588                              [Use c++11 if available (default is NO)]),,
589                              enableval=default)
590 case "$enableval" in
591   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
592   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
593   default) AC_SUBST(ENABLE_CXX11,[0]);;
594   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
595 esac
596
597 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
598 dnl line
599 AC_ARG_ENABLE(split-dwarf,
600               AS_HELP_STRING([--enable-split-dwarf],
601                              [Use split-dwarf if available (default is NO)]),,
602                              enableval=default)
603 case "$enableval" in
604   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
605   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
606   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
607   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
608 esac
609
610 dnl --enable-clang-arcmt: check whether to enable clang arcmt
611 clang_arcmt="yes"
612 AC_ARG_ENABLE(clang-arcmt,
613               AS_HELP_STRING([--enable-clang-arcmt],
614                              [Enable building of clang ARCMT (default is YES)]),
615                              clang_arcmt="$enableval",
616                              enableval="yes")
617 case "$enableval" in
618   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
619   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
620   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
621   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
622 esac
623
624 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
625 clang_static_analyzer="yes"
626 AC_ARG_ENABLE(clang-static-analyzer,
627               AS_HELP_STRING([--enable-clang-static-analyzer],
628                              [Enable building of clang Static Analyzer (default is YES)]),
629                              clang_static_analyzer="$enableval",
630                              enableval="yes")
631 case "$enableval" in
632   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
633   no)  
634     if test ${clang_arcmt} != "no" ; then
635       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
636     fi
637     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) 
638     ;;
639   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
640   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
641 esac
642
643 dnl --enable-clang-rewriter: check whether to enable clang rewriter
644 AC_ARG_ENABLE(clang-rewriter,
645               AS_HELP_STRING([--enable-clang-rewriter],
646                              [Enable building of clang rewriter (default is YES)]),,
647                              enableval="yes")
648 case "$enableval" in
649   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
650   no)  
651     if test ${clang_arcmt} != "no" ; then
652       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
653     fi
654     if test ${clang_static_analyzer} != "no" ; then
655       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
656     fi
657     AC_SUBST(ENABLE_CLANG_REWRITER,[0]) 
658     ;;
659   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
660   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
661 esac
662
663 dnl --enable-optimized : check whether they want to do an optimized build:
664 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
665  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
666 if test ${enableval} = "no" ; then
667   AC_SUBST(ENABLE_OPTIMIZED,[[]])
668 else
669   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
670 fi
671
672 dnl --enable-profiling : check whether they want to do a profile build:
673 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
674  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
675 if test ${enableval} = "no" ; then
676   AC_SUBST(ENABLE_PROFILING,[[]])
677 else
678   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
679 fi
680
681 dnl --enable-assertions : check whether they want to turn on assertions or not:
682 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
683   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
684 if test ${enableval} = "yes" ; then
685   AC_SUBST(DISABLE_ASSERTIONS,[[]])
686 else
687   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
688 fi
689
690 dnl --enable-werror : check whether we want Werror on by default
691 AC_ARG_ENABLE(werror,AS_HELP_STRING(
692   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
693 case "$enableval" in
694   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
695   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
696   default) AC_SUBST(ENABLE_WERROR,[0]);;
697   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
698 esac
699
700 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
701 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
702   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
703 if test ${enableval} = "yes" ; then
704   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
705   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
706 else
707   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
708   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
709 fi
710
711 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
712 AC_ARG_ENABLE(debug-runtime,
713    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
714 if test ${enableval} = "no" ; then
715   AC_SUBST(DEBUG_RUNTIME,[[]])
716 else
717   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
718 fi
719
720 dnl --enable-debug-symbols : should even optimized compiler libraries
721 dnl have debug symbols?
722 AC_ARG_ENABLE(debug-symbols,
723    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
724 if test ${enableval} = "no" ; then
725   AC_SUBST(DEBUG_SYMBOLS,[[]])
726 else
727   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
728 fi
729
730 dnl --enable-keep-symbols : do not strip installed executables
731 AC_ARG_ENABLE(keep-symbols,
732    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
733 if test ${enableval} = "no" ; then
734   AC_SUBST(KEEP_SYMBOLS,[[]])
735 else
736   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
737 fi
738
739 dnl --enable-jit: check whether they want to enable the jit
740 AC_ARG_ENABLE(jit,
741   AS_HELP_STRING(--enable-jit,
742                  [Enable Just In Time Compiling (default is YES)]),,
743   enableval=default)
744 if test ${enableval} = "no"
745 then
746   AC_SUBST(JIT,[[]])
747 else
748   case "$llvm_cv_target_arch" in
749     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
750     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
751     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
752     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
753     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
754     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
755     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
756     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
757     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
758     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
759     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
760     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
761     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
762   esac
763 fi
764
765 dnl Allow enablement of building and installing docs
766 AC_ARG_ENABLE(docs,
767               AS_HELP_STRING([--enable-docs],
768                              [Build documents (default is YES)]),,
769                              enableval=default)
770 case "$enableval" in
771   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
772   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
773   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
774   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
775 esac
776
777 dnl Allow enablement of doxygen generated documentation
778 AC_ARG_ENABLE(doxygen,
779               AS_HELP_STRING([--enable-doxygen],
780                              [Build doxygen documentation (default is NO)]),,
781                              enableval=default)
782 case "$enableval" in
783   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
784   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
785   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
786   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
787 esac
788
789 dnl Allow disablement of threads
790 AC_ARG_ENABLE(threads,
791               AS_HELP_STRING([--enable-threads],
792                              [Use threads if available (default is YES)]),,
793                              enableval=default)
794 case "$enableval" in
795   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
796   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
797   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
798   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
799 esac
800 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
801                    [Define if threads enabled])
802
803 dnl Allow disablement of pthread.h
804 AC_ARG_ENABLE(pthreads,
805               AS_HELP_STRING([--enable-pthreads],
806                              [Use pthreads if available (default is YES)]),,
807                              enableval=default)
808 case "$enableval" in
809   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
810   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
811   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
812   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
813 esac
814
815 dnl Allow disablement of zlib
816 AC_ARG_ENABLE(zlib,
817               AS_HELP_STRING([--enable-zlib],
818                              [Use zlib for compression/decompression if
819                               available (default is YES)]),,
820                               enableval=default)
821 case "$enableval" in
822   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
823   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
824   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
825   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
826 esac
827 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
828                    [Define if zlib is enabled])
829
830 dnl Allow building without position independent code
831 AC_ARG_ENABLE(pic,
832   AS_HELP_STRING([--enable-pic],
833                  [Build LLVM with Position Independent Code (default is YES)]),,
834                  enableval=default)
835 case "$enableval" in
836   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
837   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
838   default) AC_SUBST(ENABLE_PIC,[1]) ;;
839   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
840 esac
841 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
842                    [Define if position independent code is enabled])
843
844 dnl Allow building a shared library and linking tools against it.
845 AC_ARG_ENABLE(shared,
846   AS_HELP_STRING([--enable-shared],
847                  [Build a shared library and link tools against it (default is NO)]),,
848                  enableval=default)
849 case "$enableval" in
850   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
851   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
852   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
853   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
854 esac
855
856 dnl Allow libstdc++ is embedded in LLVM.dll.
857 AC_ARG_ENABLE(embed-stdcxx,
858   AS_HELP_STRING([--enable-embed-stdcxx],
859                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
860                  enableval=default)
861 case "$enableval" in
862   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
863   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
864   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
865   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
866 esac
867
868 dnl Enable embedding timestamp information into build.
869 AC_ARG_ENABLE(timestamps,
870   AS_HELP_STRING([--enable-timestamps],
871                  [Enable embedding timestamp information in build (default is YES)]),,
872                  enableval=default)
873 case "$enableval" in
874   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
875   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
876   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
877   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
878 esac
879 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
880                    [Define if timestamp information (e.g., __DATE__) is allowed])
881
882 dnl Enable support for showing backtraces.
883 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
884   [--enable-backtraces],
885   [Enable embedding backtraces on crash (default is YES)]),
886   [case "$enableval" in
887     yes) llvm_cv_enable_backtraces="yes" ;;
888     no)  llvm_cv_enable_backtraces="no"  ;;
889     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
890   esac],
891   llvm_cv_enable_backtraces="yes")
892 if test "$llvm_cv_enable_backtraces" = "yes" ; then
893   AC_DEFINE([ENABLE_BACKTRACES],[1],
894             [Define if you want backtraces on crash])
895 fi
896
897 dnl Enable installing platform specific signal handling overrides, for improved
898 dnl CrashRecovery support or interaction with crash reporting software. This
899 dnl support may be inappropriate for some clients embedding LLVM as a library.
900 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
901   [--enable-crash-overrides],
902   [Enable crash handling overrides (default is YES)]),
903   [case "$enableval" in
904     yes) llvm_cv_enable_crash_overrides="yes" ;;
905     no)  llvm_cv_enable_crash_overrides="no"  ;;
906     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
907   esac],
908   llvm_cv_enable_crash_overrides="yes")
909 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
910   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
911             [Define to enable crash handling overrides])
912 fi
913
914 dnl Allow specific targets to be specified for building (or not)
915 TARGETS_TO_BUILD=""
916 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
917     [Build specific host targets: all or target1,target2,... Valid targets are:
918      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
919      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
920     enableval=all)
921 if test "$enableval" = host-only ; then
922   enableval=host
923 fi
924 case "$enableval" in
925   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
926   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
927       case "$a_target" in
928         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
929         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
930         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
931         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
932         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
933         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
934         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
935         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
936         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
937         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
938         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
939         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
940         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
941         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
942         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
943         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
944         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
945         host) case "$llvm_cv_target_arch" in
946             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
947             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
948             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
949             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
950             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
951             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
952             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
953             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
954             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
955             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
956             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
957             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
958             *)       AC_MSG_ERROR([Can not set target to build]) ;;
959           esac ;;
960         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
961       esac
962   done
963   ;;
964 esac
965
966 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
967     [Build experimental host targets: disable or target1,target2,...
968      (default=disable)]),,
969     enableval=disable)
970
971 if test ${enableval} != "disable"
972 then
973   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
974 fi
975
976 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
977
978 dnl Determine whether we are building LLVM support for the native architecture.
979 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
980 for a_target in $TARGETS_TO_BUILD; do
981   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
982     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
983       [LLVM architecture name for the native architecture, if available])
984     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
985     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
986     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
987     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
988     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
989       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
990     fi
991     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
992       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
993     fi
994     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
995       [LLVM name for the native Target init function, if available])
996     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
997       [LLVM name for the native TargetInfo init function, if available])
998     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
999       [LLVM name for the native target MC init function, if available])
1000     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1001       [LLVM name for the native AsmPrinter init function, if available])
1002     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1003       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1004        [LLVM name for the native AsmParser init function, if available])
1005     fi
1006     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1007       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1008        [LLVM name for the native Disassembler init function, if available])
1009     fi
1010   fi
1011 done
1012
1013 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1014 dnl target feature def files.
1015 LLVM_ENUM_TARGETS=""
1016 LLVM_ENUM_ASM_PRINTERS=""
1017 LLVM_ENUM_ASM_PARSERS=""
1018 LLVM_ENUM_DISASSEMBLERS=""
1019 for target_to_build in $TARGETS_TO_BUILD; do
1020   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1021   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1022     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1023   fi
1024   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1025     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1026   fi
1027   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1028     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1029   fi
1030 done
1031 AC_SUBST(LLVM_ENUM_TARGETS)
1032 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1033 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1034 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1035
1036 dnl Override the option to use for optimized builds.
1037 AC_ARG_WITH(optimize-option,
1038   AS_HELP_STRING([--with-optimize-option],
1039                  [Select the compiler options to use for optimized builds]),,
1040                  withval=default)
1041 AC_MSG_CHECKING([optimization flags])
1042 case "$withval" in
1043   default)
1044     case "$llvm_cv_os_type" in
1045     FreeBSD) optimize_option=-O2 ;;
1046     MingW) optimize_option=-O2 ;;
1047     *)     optimize_option=-O3 ;;
1048     esac ;;
1049   *) optimize_option="$withval" ;;
1050 esac
1051 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1052 AC_MSG_RESULT([$optimize_option])
1053
1054 dnl Specify extra build options
1055 AC_ARG_WITH(extra-options,
1056   AS_HELP_STRING([--with-extra-options],
1057                  [Specify additional options to compile LLVM with]),,
1058                  withval=default)
1059 case "$withval" in
1060   default) EXTRA_OPTIONS= ;;
1061   *) EXTRA_OPTIONS=$withval ;;
1062 esac
1063 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1064
1065 dnl Specify extra linker build options
1066 AC_ARG_WITH(extra-ld-options,
1067   AS_HELP_STRING([--with-extra-ld-options],
1068                  [Specify additional options to link LLVM with]),,
1069                  withval=default)
1070 case "$withval" in
1071   default) EXTRA_LD_OPTIONS= ;;
1072   *) EXTRA_LD_OPTIONS=$withval ;;
1073 esac
1074 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1075
1076 dnl Allow specific bindings to be specified for building (or not)
1077 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1078     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1079     enableval=default)
1080 BINDINGS_TO_BUILD=""
1081 case "$enableval" in
1082   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1083   all ) BINDINGS_TO_BUILD="ocaml" ;;
1084   none | no) BINDINGS_TO_BUILD="" ;;
1085   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1086       case "$a_binding" in
1087         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1088         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1089       esac
1090   done
1091   ;;
1092 esac
1093
1094 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1095 dnl script for bindings/ocaml/configure, except that its auto value depends on
1096 dnl OCAMLC, which is found here to support tests.
1097 AC_ARG_WITH([ocaml-libdir],
1098   [AS_HELP_STRING([--with-ocaml-libdir],
1099     [Specify install location for ocaml bindings (default is stdlib)])],
1100   [],
1101   [withval=auto])
1102 case "$withval" in
1103   auto) with_ocaml_libdir="$withval" ;;
1104   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1105   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1106 esac
1107
1108 AC_ARG_WITH(clang-srcdir,
1109   AS_HELP_STRING([--with-clang-srcdir],
1110     [Directory to the out-of-tree Clang source]),,
1111     withval="-")
1112 case "$withval" in
1113   -) clang_src_root="" ;;
1114   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1115   *) clang_src_root="$ac_pwd/$withval" ;;
1116 esac
1117 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1118
1119 AC_ARG_WITH(clang-resource-dir,
1120   AS_HELP_STRING([--with-clang-resource-dir],
1121     [Relative directory from the Clang binary for resource files]),,
1122     withval="")
1123 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1124                    [Relative directory for resource files])
1125
1126 AC_ARG_WITH(c-include-dirs,
1127   AS_HELP_STRING([--with-c-include-dirs],
1128     [Colon separated list of directories clang will search for headers]),,
1129     withval="")
1130 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1131                    [Directories clang will search for headers])
1132
1133 # Clang normally uses the system c++ headers and libraries. With this option,
1134 # clang will use the ones provided by a gcc installation instead. This option should
1135 # be passed the same value that was used with --prefix when configuring gcc.
1136 AC_ARG_WITH(gcc-toolchain,
1137   AS_HELP_STRING([--with-gcc-toolchain],
1138     [Directory where gcc is installed.]),,
1139     withval="")
1140 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1141                    [Directory where gcc is installed.])
1142
1143 AC_ARG_WITH(default-sysroot,
1144   AS_HELP_STRING([--with-default-sysroot],
1145     [Add --sysroot=<path> to all compiler invocations.]),,
1146     withval="")
1147 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1148                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1149
1150 dnl Allow linking of LLVM with GPLv3 binutils code.
1151 AC_ARG_WITH(binutils-include,
1152   AS_HELP_STRING([--with-binutils-include],
1153     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1154   withval=default)
1155 case "$withval" in
1156   default) WITH_BINUTILS_INCDIR=default ;;
1157   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1158   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1159 esac
1160 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1161   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1162   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1163      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1164      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1165   fi
1166 fi
1167
1168 dnl Specify the URL where bug reports should be submitted.
1169 AC_ARG_WITH(bug-report-url,
1170   AS_HELP_STRING([--with-bug-report-url],
1171     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1172     withval="http://llvm.org/bugs/")
1173 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1174                    [Bug report URL.])
1175
1176 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1177 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1178   [--enable-terminfo],
1179   [Query the terminfo database if available (default is YES)]),
1180   [case "$enableval" in
1181     yes) llvm_cv_enable_terminfo="yes" ;;
1182     no)  llvm_cv_enable_terminfo="no"  ;;
1183     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1184   esac],
1185   llvm_cv_enable_terminfo="yes")
1186
1187 dnl --enable-libffi : check whether the user wants to turn off libffi:
1188 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1189   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1190   [case "$enableval" in
1191     yes) llvm_cv_enable_libffi="yes" ;;
1192     no)  llvm_cv_enable_libffi="no"  ;;
1193     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1194   esac],
1195   llvm_cv_enable_libffi=no)
1196
1197 AC_ARG_WITH(internal-prefix,
1198   AS_HELP_STRING([--with-internal-prefix],
1199     [Installation directory for internal files]),,
1200     withval="")
1201 AC_SUBST(INTERNAL_PREFIX,[$withval])
1202
1203 dnl===-----------------------------------------------------------------------===
1204 dnl===
1205 dnl=== SECTION 4: Check for programs we need and that they are the right version
1206 dnl===
1207 dnl===-----------------------------------------------------------------------===
1208
1209 AC_PROG_NM
1210 AC_SUBST(NM)
1211
1212 dnl Check for the tools that the makefiles require
1213 AC_CHECK_GNU_MAKE
1214 AC_PROG_LN_S
1215 AC_PATH_PROG(CMP, [cmp], [cmp])
1216 AC_PATH_PROG(CP, [cp], [cp])
1217 AC_PATH_PROG(DATE, [date], [date])
1218 AC_PATH_PROG(FIND, [find], [find])
1219 AC_PATH_PROG(GREP, [grep], [grep])
1220 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1221 AC_PATH_PROG(MV,   [mv],   [mv])
1222 AC_PROG_RANLIB
1223 AC_CHECK_TOOL(AR, ar, false)
1224 AC_PATH_PROG(RM,   [rm],   [rm])
1225 AC_PATH_PROG(SED,  [sed],  [sed])
1226 AC_PATH_PROG(TAR,  [tar],  [gtar])
1227 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1228
1229 dnl Looking for misc. graph plotting software
1230 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1231 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1232   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1233   dnl If we're targeting for mingw we should emit windows paths, not msys
1234   if test "$llvm_cv_os_type" = "MingW" ; then
1235     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1236   fi
1237   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1238    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1239 fi
1240 AC_PATH_PROG(DOT, [dot], [echo dot])
1241 if test "$DOT" != "echo dot" ; then
1242   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1243   dnl If we're targeting for mingw we should emit windows paths, not msys
1244   if test "$llvm_cv_os_type" = "MingW" ; then
1245     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1246   fi
1247   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1248    [Define to path to dot program if found or 'echo dot' otherwise])
1249 fi
1250 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1251 if test "$FDP" != "echo fdp" ; then
1252   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1253   dnl If we're targeting for mingw we should emit windows paths, not msys
1254   if test "$llvm_cv_os_type" = "MingW" ; then
1255     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1256   fi
1257   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1258    [Define to path to fdp program if found or 'echo fdp' otherwise])
1259 fi
1260 AC_PATH_PROG(NEATO, [neato], [echo neato])
1261 if test "$NEATO" != "echo neato" ; then
1262   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1263   dnl If we're targeting for mingw we should emit windows paths, not msys
1264   if test "$llvm_cv_os_type" = "MingW" ; then
1265     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1266   fi
1267   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1268    [Define to path to neato program if found or 'echo neato' otherwise])
1269 fi
1270 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1271 if test "$TWOPI" != "echo twopi" ; then
1272   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1273   dnl If we're targeting for mingw we should emit windows paths, not msys
1274   if test "$llvm_cv_os_type" = "MingW" ; then
1275     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1276   fi
1277   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1278    [Define to path to twopi program if found or 'echo twopi' otherwise])
1279 fi
1280 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1281 if test "$CIRCO" != "echo circo" ; then
1282   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1283   dnl If we're targeting for mingw we should emit windows paths, not msys
1284   if test "$llvm_cv_os_type" = "MingW" ; then
1285     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1286   fi
1287   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1288    [Define to path to circo program if found or 'echo circo' otherwise])
1289 fi
1290 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1291 if test "$GV" != "echo gv" ; then
1292   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1293   dnl If we're targeting for mingw we should emit windows paths, not msys
1294   if test "$llvm_cv_os_type" = "MingW" ; then
1295     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1296   fi
1297   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1298    [Define to path to gv program if found or 'echo gv' otherwise])
1299 fi
1300 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1301 if test "$DOTTY" != "echo dotty" ; then
1302   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1303   dnl If we're targeting for mingw we should emit windows paths, not msys
1304   if test "$llvm_cv_os_type" = "MingW" ; then
1305     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1306   fi
1307   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1308    [Define to path to dotty program if found or 'echo dotty' otherwise])
1309 fi
1310 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1311 if test "$XDOT" != "echo xdot" ; then
1312   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1313   dnl If we're targeting for mingw we should emit windows paths, not msys
1314   if test "$llvm_cv_os_type" = "MingW" ; then
1315     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1316   fi
1317   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1318    [Define to path to xdot program if found or 'echo xdot' otherwise])
1319 fi
1320
1321 dnl Find the install program
1322 AC_PROG_INSTALL
1323 dnl Prepend src dir to install path dir if it's a relative path
1324 dnl This is a hack for installs that take place in something other
1325 dnl than the top level.
1326 case "$INSTALL" in
1327  [[\\/$]]* | ?:[[\\/]]* ) ;;
1328  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1329 esac
1330
1331 dnl Checks for documentation and testing tools that we can do without. If these
1332 dnl are not found then they are set to "true" which always succeeds but does
1333 dnl nothing. This just lets the build output show that we could have done
1334 dnl something if the tool was available.
1335 AC_PATH_PROG(BZIP2, [bzip2])
1336 AC_PATH_PROG(CAT, [cat])
1337 AC_PATH_PROG(DOXYGEN, [doxygen])
1338 AC_PATH_PROG(GROFF, [groff])
1339 AC_PATH_PROG(GZIPBIN, [gzip])
1340 AC_PATH_PROG(PDFROFF, [pdfroff])
1341 AC_PATH_PROG(ZIP, [zip])
1342 AC_PATH_PROGS(OCAMLC, [ocamlc])
1343 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1344 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1345 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1346 AC_PATH_PROGS(GAS, [gas as])
1347
1348 dnl Get the version of the linker in use.
1349 AC_LINK_GET_VERSION
1350
1351 dnl Determine whether the linker supports the -R option.
1352 AC_LINK_USE_R
1353
1354 dnl Determine whether the compiler supports the -rdynamic option.
1355 AC_LINK_EXPORT_DYNAMIC
1356
1357 dnl Determine whether the linker supports the --version-script option.
1358 AC_LINK_VERSION_SCRIPT
1359
1360 dnl Check for libtool and the library that has dlopen function (which must come
1361 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1362 dnl libtool).
1363 AC_LIBTOOL_DLOPEN
1364 AC_LIB_LTDL
1365
1366 AC_MSG_CHECKING([tool compatibility])
1367
1368 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1369 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1370 dnl to support those options.
1371 dnl "icc" emits gcc signatures
1372 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1373 ICC=no
1374 IXX=no
1375 case $CC in
1376   icc*|icpc*)
1377     ICC=yes
1378     IXX=yes
1379     ;;
1380    *)
1381     ;;
1382 esac
1383
1384 if test "$GCC" != "yes" && test "$ICC" != "yes"
1385 then
1386   AC_MSG_ERROR([gcc|icc required but not found])
1387 fi
1388
1389 dnl Ensure that compilation tools are compatible with GCC extensions
1390 if test "$GXX" != "yes" && test "$IXX" != "yes"
1391 then
1392   AC_MSG_ERROR([g++|clang++|icc required but not found])
1393 fi
1394
1395 dnl Verify that GCC is version 3.0 or higher
1396 if test "$GCC" = "yes"
1397 then
1398   AC_COMPILE_IFELSE(
1399 [
1400   AC_LANG_SOURCE([[
1401     #if !defined(__GNUC__) || __GNUC__ < 3
1402     #error Unsupported GCC version
1403     #endif
1404   ]])
1405 ],
1406 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1407 fi
1408
1409 dnl Check for GNU Make.  We use its extensions, so don't build without it
1410 if test -z "$llvm_cv_gnu_make_command"
1411 then
1412   AC_MSG_ERROR([GNU Make required but not found])
1413 fi
1414
1415 dnl Tool compatibility is okay if we make it here.
1416 AC_MSG_RESULT([ok])
1417
1418 dnl Check optional compiler flags.
1419 AC_MSG_CHECKING([optional compiler flags])
1420 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1421 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1422 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1423
1424 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1425 dnl false positives, so disable it.
1426 NO_UNINITIALIZED=
1427 NO_MAYBE_UNINITIALIZED=
1428 if test "$GXX" = "yes"
1429 then
1430   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1431   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1432   dnl known to be uninitialized from cases which might be uninitialized.  We
1433   dnl still want to catch the first kind of errors.
1434   if test -z "$NO_MAYBE_UNINITIALIZED"
1435   then
1436     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1437   fi
1438 fi
1439 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1440
1441 AC_ARG_WITH([python],
1442             [AS_HELP_STRING([--with-python], [path to python])],
1443             [PYTHON="$withval"])
1444
1445 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1446   AC_MSG_CHECKING([for python])
1447   AC_MSG_RESULT([user defined: $with_python])
1448 else
1449   if test -n "$PYTHON" ; then
1450     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1451   fi
1452
1453   AC_PATH_PROG([PYTHON], [python python2 python26],
1454                [AC_MSG_RESULT([not found])
1455                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1456 fi
1457
1458 AC_MSG_CHECKING([for python >= 2.5])
1459 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1460 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1461 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1462 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1463 if test "$ac_python_version_major" -gt "2" || \
1464    (test "$ac_python_version_major" -eq "2" && \
1465     test "$ac_python_version_minor" -ge "5") ; then
1466   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1467 else
1468   AC_MSG_RESULT([not found])
1469   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1470 fi
1471
1472 dnl===-----------------------------------------------------------------------===
1473 dnl===
1474 dnl=== SECTION 5: Check for libraries
1475 dnl===
1476 dnl===-----------------------------------------------------------------------===
1477
1478 AC_CHECK_LIB(m,sin)
1479 if test "$llvm_cv_os_type" = "MingW" ; then
1480   AC_CHECK_LIB(imagehlp, main)
1481   AC_CHECK_LIB(psapi, main)
1482   AC_CHECK_LIB(shell32, main)
1483 fi
1484
1485 dnl dlopen() is required for plugin support.
1486 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1487                [Define if dlopen() is available on this platform.]),
1488                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1489
1490 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1491 dnl macros to detect whether clock_gettime is available, this just finds the
1492 dnl right libraries to link with.
1493 AC_SEARCH_LIBS(clock_gettime,rt)
1494
1495 dnl The curses library is optional; used for querying terminal info
1496 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1497   dnl We need the has_color functionality in curses for it to be useful.
1498   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1499                  AC_DEFINE([HAVE_TERMINFO],[1],
1500                            [Define if the setupterm() function is supported this platform.]))
1501 fi
1502
1503 dnl libffi is optional; used to call external functions from the interpreter
1504 if test "$llvm_cv_enable_libffi" = "yes" ; then
1505   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1506                  [Define if libffi is available on this platform.]),
1507                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1508 fi
1509
1510 dnl mallinfo is optional; the code can compile (minus features) without it
1511 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1512                [Define if mallinfo() is available on this platform.]))
1513
1514 dnl pthread locking functions are optional - but llvm will not be thread-safe
1515 dnl without locks.
1516 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1517   AC_CHECK_LIB(pthread, pthread_mutex_init)
1518   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1519                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1520                            [Have pthread_mutex_lock]))
1521   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1522                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1523                  [Have pthread_rwlock_init]))
1524   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1525                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1526                  [Have pthread_getspecific]))
1527 fi
1528
1529 dnl zlib is optional; used for compression/uncompression
1530 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1531   AC_CHECK_LIB(z, compress2)
1532 fi
1533
1534 dnl Allow extra x86-disassembler library
1535 AC_ARG_WITH(udis86,
1536   AS_HELP_STRING([--with-udis86=<path>],
1537     [Use udis86 external x86 disassembler library]),
1538     [
1539       AC_SUBST(USE_UDIS86, [1])
1540       case "$withval" in
1541         /usr/lib|yes) ;;
1542         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1543       esac
1544       AC_CHECK_LIB(udis86, ud_init, [], [
1545         echo "Error! You need to have libudis86 around."
1546         exit -1
1547       ])
1548     ],
1549     AC_SUBST(USE_UDIS86, [0]))
1550 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1551                    [Define if use udis86 library])
1552
1553 dnl Allow OProfile support for JIT output.
1554 AC_ARG_WITH(oprofile,
1555   AS_HELP_STRING([--with-oprofile=<prefix>],
1556     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1557     [
1558       AC_SUBST(USE_OPROFILE, [1])
1559       case "$withval" in
1560         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1561         no) llvm_cv_oppath=
1562             AC_SUBST(USE_OPROFILE, [0]) ;;
1563         *) llvm_cv_oppath="${withval}/lib/oprofile"
1564            CPPFLAGS="-I${withval}/include";;
1565       esac
1566       case $llvm_cv_os_type in
1567         Linux)
1568           if test -n "$llvm_cv_oppath" ; then
1569             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1570             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1571             dnl libbfd is not included properly in libopagent in some Debian
1572             dnl versions.  If libbfd isn't found at all, we assume opagent works
1573             dnl anyway.
1574             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1575             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1576               echo "Error! You need to have libopagent around."
1577               exit -1
1578             ])
1579             AC_CHECK_HEADER([opagent.h], [], [
1580               echo "Error! You need to have opagent.h around."
1581               exit -1
1582               ])
1583           fi ;;
1584         *)
1585           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1586       esac 
1587     ],
1588     [
1589       AC_SUBST(USE_OPROFILE, [0])
1590     ])
1591 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1592                    [Define if we have the oprofile JIT-support library])
1593
1594 dnl Enable support for Intel JIT Events API.
1595 AC_ARG_WITH(intel-jitevents,
1596   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1597     [
1598        case "$withval" in
1599           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1600           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1601           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1602        esac
1603
1604       case $llvm_cv_os_type in
1605         Linux|Win32|Cygwin|MingW) ;;
1606         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1607       esac
1608
1609       case "$llvm_cv_target_arch" in
1610         x86|x86_64) ;;
1611         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1612       esac
1613     ],
1614     [
1615       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1616     ])
1617 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1618                    [Define if we have the Intel JIT API runtime support library])
1619
1620 dnl Check for libxml2
1621 dnl Right now we're just checking for the existence, we could also check for a
1622 dnl particular version via --version on xml2-config
1623 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1624
1625 AC_MSG_CHECKING(for libxml2 includes)
1626 if test "x$XML2CONFIG" = "x"; then
1627  AC_MSG_RESULT(xml2-config not found)
1628 else
1629  LIBXML2_INC=`$XML2CONFIG --cflags`
1630  AC_MSG_RESULT($LIBXML2_INC)
1631  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1632                                 LIBXML2_LIBS="-lxml2"])
1633 fi
1634 AC_SUBST(LIBXML2_LIBS)
1635 AC_SUBST(LIBXML2_INC)
1636
1637 dnl===-----------------------------------------------------------------------===
1638 dnl===
1639 dnl=== SECTION 6: Check for header files
1640 dnl===
1641 dnl===-----------------------------------------------------------------------===
1642
1643 dnl First, use autoconf provided macros for specific headers that we need
1644 dnl We don't check for ancient stuff or things that are guaranteed to be there
1645 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1646 dnl Generally we're looking for POSIX headers.
1647 AC_HEADER_DIRENT
1648 AC_HEADER_MMAP_ANONYMOUS
1649 AC_HEADER_STAT
1650 AC_HEADER_SYS_WAIT
1651 AC_HEADER_TIME
1652
1653 AC_LANG_PUSH([C++])
1654 AC_CHECK_HEADERS([cxxabi.h])
1655 AC_LANG_POP([C++])
1656 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1657 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1658 AC_CHECK_HEADERS([utime.h])
1659 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1660 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1661 AC_CHECK_HEADERS([valgrind/valgrind.h])
1662 AC_CHECK_HEADERS([fenv.h])
1663 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1664 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1665   AC_CHECK_HEADERS(pthread.h,
1666                    AC_SUBST(HAVE_PTHREAD, 1),
1667                    AC_SUBST(HAVE_PTHREAD, 0))
1668 else
1669   AC_SUBST(HAVE_PTHREAD, 0)
1670 fi
1671 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1672   AC_CHECK_HEADERS(zlib.h,
1673                    AC_SUBST(HAVE_LIBZ, 1),
1674                    AC_SUBST(HAVE_LIBZ, 0))
1675 else
1676   AC_SUBST(HAVE_LIBZ, 0)
1677 fi
1678
1679 dnl Try to find ffi.h.
1680 if test "$llvm_cv_enable_libffi" = "yes" ; then
1681   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1682 fi
1683
1684 dnl Try to find Darwin specific crash reporting libraries.
1685 AC_CHECK_HEADERS([CrashReporterClient.h])
1686
1687 dnl Try to find Darwin specific crash reporting global.
1688 AC_MSG_CHECKING([__crashreporter_info__])
1689 AC_LINK_IFELSE(
1690 [
1691   AC_LANG_SOURCE([[
1692     extern const char *__crashreporter_info__;
1693     int main() {
1694       __crashreporter_info__ = "test";
1695       return 0;
1696     }
1697   ]])
1698 ],
1699 [
1700   AC_MSG_RESULT([yes])
1701   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1702 ],
1703 [
1704   AC_MSG_RESULT([no])
1705   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1706 ])
1707
1708 dnl===-----------------------------------------------------------------------===
1709 dnl===
1710 dnl=== SECTION 7: Check for types and structures
1711 dnl===
1712 dnl===-----------------------------------------------------------------------===
1713
1714 AC_HUGE_VAL_CHECK
1715 AC_TYPE_PID_T
1716 AC_TYPE_SIZE_T
1717 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1718 AC_STRUCT_TM
1719 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1720 AC_CHECK_TYPES([uint64_t],,
1721          AC_CHECK_TYPES([u_int64_t],,
1722          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1723
1724 dnl===-----------------------------------------------------------------------===
1725 dnl===
1726 dnl=== SECTION 8: Check for specific functions needed
1727 dnl===
1728 dnl===-----------------------------------------------------------------------===
1729
1730 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1731 AC_CHECK_FUNCS([powf fmodf strtof round ])
1732 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1733 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1734 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1735 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1736 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1737 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1738 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1739 AC_CHECK_FUNCS([futimes futimens])
1740 AC_C_PRINTF_A
1741 AC_FUNC_RAND48
1742
1743 dnl Check the declaration "Secure API" on Windows environments.
1744 AC_CHECK_DECLS([strerror_s])
1745
1746 dnl Check symbols in libgcc.a for JIT on Mingw.
1747 if test "$llvm_cv_os_type" = "MingW" ; then
1748   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1749   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1750   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1751   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1752
1753   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1754   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1755   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1756   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1757   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1758   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1759   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1760   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1761   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1762   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1763
1764   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1765   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1766 fi
1767
1768 dnl Check Win32 API EnumerateLoadedModules.
1769 if test "$llvm_cv_os_type" = "MingW" ; then
1770   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1771   AC_COMPILE_IFELSE(
1772 [
1773   AC_LANG_SOURCE([[
1774     #include <windows.h>
1775     #include <imagehlp.h>
1776     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1777     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1778   ]])
1779 ],
1780 [
1781   AC_MSG_RESULT([yes])
1782   llvm_cv_win32_elmcb_pcstr="PCSTR"
1783 ],
1784 [
1785   AC_MSG_RESULT([no])
1786   llvm_cv_win32_elmcb_pcstr="PSTR"
1787 ])
1788   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1789 fi
1790
1791 dnl Check for variations in the Standard C++ library and STL. These macros are
1792 dnl provided by LLVM in the autoconf/m4 directory.
1793 AC_FUNC_ISNAN
1794 AC_FUNC_ISINF
1795
1796 dnl Check for mmap support.We also need to know if /dev/zero is required to
1797 dnl be opened for allocating RWX memory.
1798 dnl Make sure we aren't attempting to configure for an unknown system
1799 if test "$llvm_cv_platform_type" = "Unix" ; then
1800   AC_FUNC_MMAP
1801   AC_FUNC_MMAP_FILE
1802   AC_NEED_DEV_ZERO_FOR_MMAP
1803
1804   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1805   then
1806     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1807   fi
1808   if test "$ac_cv_func_mmap_file" = "no"
1809   then
1810     AC_MSG_WARN([mmap() of files required but not found])
1811   fi
1812 fi
1813
1814 dnl atomic builtins are required for threading support.
1815 AC_MSG_CHECKING(for GCC atomic builtins)
1816 dnl Since we'll be using these atomic builtins in C++ files we should test
1817 dnl the C++ compiler.
1818 AC_LANG_PUSH([C++])
1819 AC_LINK_IFELSE(
1820 [
1821   AC_LANG_SOURCE([[
1822     int main() {
1823       volatile unsigned long val = 1;
1824       __sync_synchronize();
1825       __sync_val_compare_and_swap(&val, 1, 0);
1826       __sync_add_and_fetch(&val, 1);
1827       __sync_sub_and_fetch(&val, 1);
1828       return 0;
1829     }
1830   ]])
1831 ],
1832 [
1833   AC_MSG_RESULT([yes])
1834   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1835 ],
1836 [
1837   AC_MSG_RESULT([no])
1838   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1839   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1840 ])
1841 AC_LANG_POP([C++])
1842
1843 dnl===-----------------------------------------------------------------------===
1844 dnl===
1845 dnl=== SECTION 9: Additional checks, variables, etc.
1846 dnl===
1847 dnl===-----------------------------------------------------------------------===
1848
1849 dnl Handle 32-bit linux systems running a 64-bit kernel.
1850 dnl This has to come after section 4 because it invokes the compiler.
1851 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1852   AC_IS_LINUX_MIXED
1853   if test "$llvm_cv_linux_mixed" = "yes"; then
1854     llvm_cv_target_arch="x86"
1855     ARCH="x86"
1856   fi
1857 fi
1858
1859 dnl Check whether __dso_handle is present
1860 AC_CHECK_FUNCS([__dso_handle])
1861
1862 dnl Propagate the shared library extension that the libltdl checks did to
1863 dnl the Makefiles so we can use it there too
1864 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1865
1866 dnl Propagate the run-time library path variable that the libltdl
1867 dnl checks found to the Makefiles so we can use it there too
1868 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1869
1870 dnl Translate the various configuration directories and other basic
1871 dnl information into substitutions that will end up in Makefile.config.in
1872 dnl that these configured values can be used by the makefiles
1873 if test "${prefix}" = "NONE" ; then
1874   prefix="/usr/local"
1875 fi
1876 eval LLVM_PREFIX="${prefix}";
1877 eval LLVM_BINDIR="${prefix}/bin";
1878 eval LLVM_DATADIR="${prefix}/share/llvm";
1879 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1880 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1881 eval LLVM_INCLUDEDIR="${prefix}/include";
1882 eval LLVM_INFODIR="${prefix}/info";
1883 eval LLVM_MANDIR="${prefix}/man";
1884 LLVM_CONFIGTIME=`date`
1885 AC_SUBST(LLVM_PREFIX)
1886 AC_SUBST(LLVM_BINDIR)
1887 AC_SUBST(LLVM_DATADIR)
1888 AC_SUBST(LLVM_DOCSDIR)
1889 AC_SUBST(LLVM_ETCDIR)
1890 AC_SUBST(LLVM_INCLUDEDIR)
1891 AC_SUBST(LLVM_INFODIR)
1892 AC_SUBST(LLVM_MANDIR)
1893 AC_SUBST(LLVM_CONFIGTIME)
1894
1895 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1896 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1897   LLVM_CONFIGTIME="(timestamp not enabled)"
1898 fi
1899
1900 dnl Place the various directories into the config.h file as #defines so that we
1901 dnl can know about the installation paths within LLVM.
1902 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1903                    [Installation prefix directory])
1904 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1905                    [Installation directory for binary executables])
1906 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1907                    [Installation directory for data files])
1908 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1909                    [Installation directory for documentation])
1910 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1911                    [Installation directory for config files])
1912 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1913                    [Installation directory for include files])
1914 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1915                    [Installation directory for .info files])
1916 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1917                    [Installation directory for man pages])
1918 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1919                    [Time at which LLVM was configured])
1920 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1921                    [Host triple LLVM will be executed on])
1922 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1923                    [Target triple LLVM will generate code for by default])
1924
1925 dnl Determine which bindings to build.
1926 if test "$BINDINGS_TO_BUILD" = auto ; then
1927   BINDINGS_TO_BUILD=""
1928   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1929     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1930   fi
1931 fi
1932 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1933
1934 dnl This isn't really configurey, but it avoids having to repeat the list in
1935 dnl other files.
1936 AC_SUBST(ALL_BINDINGS,ocaml)
1937
1938 dnl Do any work necessary to ensure that bindings have what they need.
1939 binding_prereqs_failed=0
1940 for a_binding in $BINDINGS_TO_BUILD ; do
1941   case "$a_binding" in
1942   ocaml)
1943     if test "x$OCAMLC" = x ; then
1944       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1945       binding_prereqs_failed=1
1946     fi
1947     if test "x$OCAMLDEP" = x ; then
1948       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1949       binding_prereqs_failed=1
1950     fi
1951     if test "x$OCAMLOPT" = x ; then
1952       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1953       dnl ocamlopt is optional!
1954     fi
1955     if test "x$with_ocaml_libdir" != xauto ; then
1956       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1957     else
1958       ocaml_stdlib="`"$OCAMLC" -where`"
1959       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1960       then
1961         # ocaml stdlib is beneath our prefix; use stdlib
1962         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1963       else
1964         # ocaml stdlib is outside our prefix; use libdir/ocaml
1965         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1966       fi
1967     fi
1968     ;;
1969   esac
1970 done
1971 if test "$binding_prereqs_failed" = 1 ; then
1972   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1973 fi
1974
1975 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1976 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1977
1978 dnl Determine linker rpath flag
1979 if test "$llvm_cv_link_use_r" = "yes" ; then
1980   RPATH="-Wl,-R"
1981 else
1982   RPATH="-Wl,-rpath"
1983 fi
1984 AC_SUBST(RPATH)
1985
1986 dnl Determine linker rdynamic flag
1987 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1988   RDYNAMIC="-rdynamic"
1989 else
1990   RDYNAMIC=""
1991 fi
1992 AC_SUBST(RDYNAMIC)
1993
1994 dnl===-----------------------------------------------------------------------===
1995 dnl===
1996 dnl=== SECTION 10: Specify the output files and generate it
1997 dnl===
1998 dnl===-----------------------------------------------------------------------===
1999
2000 dnl Configure header files
2001 dnl WARNING: dnl If you add or remove any of the following config headers, then
2002 dnl you MUST also update Makefile so that the variable FilesToConfig
2003 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2004 dnl files can be updated automatically when their *.in sources change.
2005 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2006 AH_TOP([#ifndef CONFIG_H
2007 #define CONFIG_H])
2008 AH_BOTTOM([#endif])
2009
2010 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2011 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2012 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2013 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2014 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2015
2016 dnl Configure the makefile's configuration data
2017 AC_CONFIG_FILES([Makefile.config])
2018
2019 dnl Configure the RPM spec file for LLVM
2020 AC_CONFIG_FILES([llvm.spec])
2021
2022 dnl Configure doxygen's configuration file
2023 AC_CONFIG_FILES([docs/doxygen.cfg])
2024
2025 dnl Configure clang, if present
2026 if test "${clang_src_root}" = ""; then
2027   clang_src_root="$srcdir/tools/clang"
2028 fi
2029 if test -f ${clang_src_root}/README.txt; then
2030   dnl Use variables to stay under 80 columns.
2031   configh="include/clang/Config/config.h"
2032   doxy="docs/doxygen.cfg"
2033   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2034   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2035 fi
2036
2037 dnl OCaml findlib META file
2038 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2039
2040 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2041 test "x$program_prefix" = "xNONE" && program_prefix=""
2042 AC_SUBST([program_prefix])
2043
2044
2045 dnl Do special configuration of Makefiles
2046 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2047 AC_CONFIG_MAKEFILE(Makefile)
2048 AC_CONFIG_MAKEFILE(Makefile.common)
2049 AC_CONFIG_MAKEFILE(examples/Makefile)
2050 AC_CONFIG_MAKEFILE(lib/Makefile)
2051 AC_CONFIG_MAKEFILE(test/Makefile)
2052 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2053 AC_CONFIG_MAKEFILE(unittests/Makefile)
2054 AC_CONFIG_MAKEFILE(tools/Makefile)
2055 AC_CONFIG_MAKEFILE(utils/Makefile)
2056 AC_CONFIG_MAKEFILE(projects/Makefile)
2057 AC_CONFIG_MAKEFILE(bindings/Makefile)
2058 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2059
2060 dnl Finally, crank out the output
2061 AC_OUTPUT