autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.2svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  80       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  81       *)
  82         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  83         ;;
  84     esac
  85   fi
  86 done
  87
  88 dnl===-----------------------------------------------------------------------===
  89 dnl===
  90 dnl=== SECTION 2: Architecture, target, and host checks
  91 dnl===
  92 dnl===-----------------------------------------------------------------------===
  93
  94 dnl Check the target for which we're compiling and the host that will do the
  95 dnl compilations. This will tell us which LLVM compiler will be used for
  96 dnl compiling SSA into object code. This needs to be done early because
  97 dnl following tests depend on it.
  98 AC_CANONICAL_TARGET
  99
 100 dnl Determine the platform type and cache its value. This helps us configure
 101 dnl the System library to the correct build platform.
 102 AC_CACHE_CHECK([type of operating system we're going to host on],
 103                [llvm_cv_os_type],
 104 [case $host in
 105   *-*-aix*)
 106     llvm_cv_link_all_option="-Wl,--whole-archive"
 107     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 108     llvm_cv_os_type="AIX"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-irix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="IRIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-cygwin*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="Cygwin"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-darwin*)
 121     llvm_cv_link_all_option="-Wl,-all_load"
 122     llvm_cv_link_all_option="-Wl,-noall_load"
 123     llvm_cv_os_type="Darwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-freebsd*)
 126     llvm_cv_link_all_option="-Wl,--whole-archive"
 127     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 128     llvm_cv_os_type="FreeBSD"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-openbsd*)
 131     llvm_cv_link_all_option="-Wl,--whole-archive"
 132     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 133     llvm_cv_os_type="OpenBSD"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-netbsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="NetBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-hpux*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="HP-UX"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-interix*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="Interix"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-linux*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="Linux"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-solaris*)
 156     llvm_cv_link_all_option="-Wl,-z,allextract"
 157     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 158     llvm_cv_os_type="SunOS"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-win32*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Win32"
 164     llvm_cv_platform_type="Win32" ;;
 165   *-*-mingw*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="MingW"
 169     llvm_cv_platform_type="Win32" ;;
 170   *)
 171     llvm_cv_link_all_option=""
 172     llvm_cv_no_link_all_option=""
 173     llvm_cv_os_type="Unknown"
 174     llvm_cv_platform_type="Unknown" ;;
 175 esac])
 176
 177 dnl Make sure we aren't attempting to configure for an unknown system
 178 if test "$llvm_cv_os_type" = "Unknown" ; then
 179   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 180 fi
 181
 182 dnl Set the "OS" Makefile variable based on the platform type so the
 183 dnl makefile can configure itself to specific build hosts
 184 AC_SUBST(OS,$llvm_cv_os_type)
 185
 186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 189
 190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 191 dnl This is used by lib/System to determine the basic kind of implementation
 192 dnl to use.
 193 case $llvm_cv_platform_type in
 194   Unix)
 195     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 196     AC_SUBST(LLVM_ON_UNIX,[1])
 197     AC_SUBST(LLVM_ON_WIN32,[0])
 198     ;;
 199   Win32)
 200     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 201     AC_SUBST(LLVM_ON_UNIX,[0])
 202     AC_SUBST(LLVM_ON_WIN32,[1])
 203     ;;
 204 esac
 205
 206 dnl Determine what our target architecture is and configure accordingly.
 207 dnl This will allow Makefiles to make a distinction between the hardware and
 208 dnl the OS.
 209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 210 [case $target in
 211   i?86-*)                 llvm_cv_target_arch="x86" ;;
 212   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 213   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 214   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 215   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 216   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 217   arm-*)                  llvm_cv_target_arch="ARM" ;;
 218   mips-*)                 llvm_cv_target_arch="Mips" ;;
 219   *)                      llvm_cv_target_arch="Unknown" ;;
 220 esac])
 221
 222 if test "$llvm_cv_target_arch" = "Unknown" ; then
 223   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 224 fi
 225
 226 dnl Define a substitution, ARCH, for the target architecture
 227 AC_SUBST(ARCH,$llvm_cv_target_arch)
 228
 229 dnl Check for the endianness of the target
 230 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 231
 232 dnl Check for build platform executable suffix if we're crosscompiling
 233 if test "$cross_compiling" = yes; then
 234   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 235   AC_BUILD_EXEEXT
 236 else
 237   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 238 fi
 239
 240 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 241 dnl build is being done from a checkout. This sets up several defaults for the
 242 dnl command line switches. When we build with a CVS directory, we get a
 243 dnl debug with assertions turned on. Without, we assume a source release and we
 244 dnl get an optimized build without assertions. See --enable-optimized and
 245 dnl --enable-assertions below
 246 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 247   cvsbuild="yes"
 248   optimize="no"
 249   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 250 else
 251   cvsbuild="no"
 252   optimize="yes"
 253 fi
 254
 255 dnl===-----------------------------------------------------------------------===
 256 dnl===
 257 dnl=== SECTION 3: Command line arguments for the configure script.
 258 dnl===
 259 dnl===-----------------------------------------------------------------------===
 260
 261 dnl --enable-optimized : check whether they want to do an optimized build:
 262 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 263  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 264 if test ${enableval} = "no" ; then
 265   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 266 else
 267   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 268 fi
 269
 270 dnl --enable-assertions : check whether they want to turn on assertions or not:
 271 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 272   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 273 if test ${enableval} = "yes" ; then
 274   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 275 else
 276   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 277 fi
 278
 279 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 280 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 281   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 282 if test ${enableval} = "yes" ; then
 283   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 284   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 285 else
 286   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 287   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 288 fi
 289
 290 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 291 AC_ARG_ENABLE(debug-runtime,
 292    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 293 if test ${enableval} = "no" ; then
 294   AC_SUBST(DEBUG_RUNTIME,[[]])
 295 else
 296   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 297 fi
 298
 299 dnl --enable-jit: check whether they want to enable the jit
 300 AC_ARG_ENABLE(jit,
 301   AS_HELP_STRING(--enable-jit,
 302                  [Enable Just In Time Compiling (default is YES)]),,
 303   enableval=default)
 304 if test ${enableval} = "no"
 305 then
 306   AC_SUBST(JIT,[[]])
 307 else
 308   case "$llvm_cv_target_arch" in
 309     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 310     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 311     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 312     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 313     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 314     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 315     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 316     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 317     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 318   esac
 319 fi
 320
 321 dnl Allow enablement of doxygen generated documentation
 322 AC_ARG_ENABLE(doxygen,
 323               AS_HELP_STRING([--enable-doxygen],
 324                              [Build doxygen documentation (default is NO)]),,
 325                              enableval=default)
 326 case "$enableval" in
 327   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 328   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 329   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 330   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 331 esac
 332
 333 dnl Allow disablement of threads
 334 AC_ARG_ENABLE(threads,
 335               AS_HELP_STRING([--enable-threads],
 336                              [Use threads if available (default is YES)]),,
 337                              enableval=default)
 338 case "$enableval" in
 339   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 340   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 341   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 342   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 343 esac
 344 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 345
 346 dnl Allow building with position independent code
 347 AC_ARG_ENABLE(pic,
 348   AS_HELP_STRING([--enable-pic],
 349                  [Build LLVM with Position Independent Code (default is NO)]),,
 350                  enableval=default)
 351 case "$enableval" in
 352   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 353   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 354   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 355   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 356 esac
 357 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 358                    [Define if position independent code is enabled])
 359
 360 dnl Allow specific targets to be specified for building (or not)
 361 TARGETS_TO_BUILD=""
 362 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 363     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 364     enableval=all)
 365 case "$enableval" in
 366   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips" ;;
 367   host-only)
 368     case "$llvm_cv_target_arch" in
 369       x86)     TARGETS_TO_BUILD="X86" ;;
 370       x86_64)  TARGETS_TO_BUILD="X86" ;;
 371       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 372       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 373       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 374       IA64)    TARGETS_TO_BUILD="IA64" ;;
 375       ARM)     TARGETS_TO_BUILD="ARM" ;;
 376       Mips)    TARGETS_TO_BUILD="Mips" ;;
 377       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 378     esac
 379     ;;
 380   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 381       case "$a_target" in
 382         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 383         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 384         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 385         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 386         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 387         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 388         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 389         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 390         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 391       esac
 392   done
 393   ;;
 394 esac
 395 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 396 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 397
 398 dnl Prevent the CBackend from using printf("%a") for floating point so older
 399 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 400 dnl can still compile the CBE's output
 401 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 402   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 403   enableval=default)
 404 case "$enableval" in
 405   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 406   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 407   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 408   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 409 esac
 410 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 411                    [Define if CBE is enabled for printf %a output])
 412
 413 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 414 AC_ARG_WITH(llvmgccdir,
 415   AS_HELP_STRING([--with-llvmgccdir],
 416     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 417     withval=default)
 418 case "$withval" in
 419   default) WITH_LLVMGCCDIR=default ;;
 420   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 421   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 422 esac
 423
 424 dnl Specify extra build options
 425 AC_ARG_WITH(extra-options,
 426   AS_HELP_STRING([--with-extra-options],
 427                  [Specify addtional options to compile LLVM with]),,
 428                  withval=default)
 429 case "$withval" in
 430   default) EXTRA_OPTIONS= ;;
 431   *) EXTRA_OPTIONS=$withval ;;
 432 esac
 433 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 434
 435 dnl Allow specific bindings to be specified for building (or not)
 436 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 437     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 438     enableval=default)
 439 BINDINGS_TO_BUILD=""
 440 case "$enableval" in
 441   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 442   all ) BINDINGS_TO_BUILD="ocaml" ;;
 443   none | no) BINDINGS_TO_BUILD="" ;;
 444   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 445       case "$a_binding" in
 446         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 447         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 448       esac
 449   done
 450   ;;
 451 esac
 452
 453 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 454 dnl script for bindings/ocaml/configure, except that its auto value depends on
 455 dnl OCAMLC, which is found here to support tests.
 456 AC_ARG_WITH([ocaml-libdir],
 457   [AS_HELP_STRING([--with-ocaml-libdir],
 458     [Specify install location for ocaml bindings (default is stdlib)])],
 459   [],
 460   [withval=auto])
 461 case "$withval" in
 462   auto) with_ocaml_libdir="$withval" ;;
 463   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 464   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 465 esac
 466
 467 dnl===-----------------------------------------------------------------------===
 468 dnl===
 469 dnl=== SECTION 4: Check for programs we need and that they are the right version
 470 dnl===
 471 dnl===-----------------------------------------------------------------------===
 472
 473 dnl Check for compilation tools
 474 AC_PROG_CPP
 475 AC_PROG_CC(gcc)
 476 AC_PROG_CXX(g++)
 477 AC_PROG_FLEX
 478 AC_PROG_BISON
 479
 480 AC_PROG_NM
 481 AC_SUBST(NM)
 482
 483 dnl Check for the tools that the makefiles require
 484 AC_CHECK_GNU_MAKE
 485 AC_PROG_LN_S
 486 AC_PATH_PROG(CMP, [cmp], [cmp])
 487 AC_PATH_PROG(CP, [cp], [cp])
 488 AC_PATH_PROG(DATE, [date], [date])
 489 AC_PATH_PROG(FIND, [find], [find])
 490 AC_PATH_PROG(GREP, [grep], [grep])
 491 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 492 AC_PATH_PROG(MV,   [mv],   [mv])
 493 AC_PROG_RANLIB
 494 AC_PATH_PROG(RM,   [rm],   [rm])
 495 AC_PATH_PROG(SED,  [sed],  [sed])
 496 AC_PATH_PROG(TAR,  [tar],  [gtar])
 497 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 498
 499 dnl Looking for misc. graph plotting software
 500 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 501 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 502   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 503   dnl If we're targeting for mingw we should emit windows paths, not msys
 504   if test "$llvm_cv_os_type" = "MingW" ; then
 505     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 506   fi
 507   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 508    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 509 fi
 510 AC_PATH_PROG(DOT, [dot], [echo dot])
 511 if test "$DOT" != "echo dot" ; then
 512   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 513   dnl If we're targeting for mingw we should emit windows paths, not msys
 514   if test "$llvm_cv_os_type" = "MingW" ; then
 515     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 516   fi
 517   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 518    [Define to path to dot program if found or 'echo dot' otherwise])
 519 fi
 520 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 521 if test "$GV" != "echo gv" ; then
 522   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 523   dnl If we're targeting for mingw we should emit windows paths, not msys
 524   if test "$llvm_cv_os_type" = "MingW" ; then
 525     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 526   fi
 527   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 528    [Define to path to gv program if found or 'echo gv' otherwise])
 529 fi
 530 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 531 if test "$DOTTY" != "echo dotty" ; then
 532   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 533   dnl If we're targeting for mingw we should emit windows paths, not msys
 534   if test "$llvm_cv_os_type" = "MingW" ; then
 535     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 536   fi
 537   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 538    [Define to path to dotty program if found or 'echo dotty' otherwise])
 539 fi
 540
 541 dnl Look for a sufficiently recent version of Perl.
 542 LLVM_PROG_PERL([5.006])
 543 AC_SUBST(PERL)
 544 if test x"$PERL" = xnone; then
 545    AC_SUBST(HAVE_PERL,0)
 546    AC_MSG_ERROR([perl is required but was not found, please install it])
 547 else
 548    AC_SUBST(HAVE_PERL,1)
 549 fi
 550
 551 dnl Find the install program
 552 AC_PROG_INSTALL
 553
 554 dnl Checks for documentation and testing tools that we can do without. If these
 555 dnl are not found then they are set to "true" which always succeeds but does
 556 dnl nothing. This just lets the build output show that we could have done
 557 dnl something if the tool was available.
 558 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 559 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 560 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 561 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 562 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 563 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 564 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 565 DJ_AC_PATH_TCLSH
 566 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 567 AC_PATH_PROG(OCAMLC,[ocamlc],[echo "Skipped: ocamlc not found"])
 568 AC_PATH_PROG(OCAMLOPT,[ocamlopt],[echo "Skipped: ocamlopt not found"])
 569 AC_PATH_PROG(OCAMLDEP,[ocamldep],[echo "Skipped: ocamldep not found"])
 570
 571 dnl Determine if the linker supports the -R option.
 572 AC_LINK_USE_R
 573
 574 dnl Check for libtool and the library that has dlopen function (which must come
 575 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 576 dnl libtool).
 577 AC_LIBTOOL_DLOPEN
 578 AC_LIB_LTDL
 579 AC_PROG_LIBTOOL
 580
 581 if test "$lt_cv_dlopen_self" = "yes" ; then
 582   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 583               [Define if dlopen(0) will open the symbols of the program])
 584 fi
 585
 586 if test "$WITH_LLVMGCCDIR" = "default" ; then
 587   LLVMGCC="llvm-gcc${EXEEXT}"
 588   LLVMGXX="llvm-g++${EXEEXT}"
 589   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 590   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 591 else
 592   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 593   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 594   AC_SUBST(LLVMGCC,$LLVMGCC)
 595   AC_SUBST(LLVMGXX,$LLVMGXX)
 596 fi
 597
 598 AC_MSG_CHECKING([tool compatibility])
 599
 600 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 601 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 602 dnl to support those options.
 603 dnl "icc" emits gcc signatures
 604 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 605 ICC=no
 606 IXX=no
 607 case $CC in
 608   icc*|icpc*)
 609     ICC=yes
 610     IXX=yes
 611     ;;
 612    *)
 613     ;;
 614 esac
 615
 616 if test "$GCC" != "yes" && test "$ICC" != "yes"
 617 then
 618   AC_MSG_ERROR([gcc|icc required but not found])
 619 fi
 620
 621 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 622 if test "$GXX" != "yes" && test "$IXX" != "yes"
 623 then
 624   AC_MSG_ERROR([g++|icc required but not found])
 625 fi
 626
 627 dnl Verify that GCC is version 3.0 or higher
 628 if test "$GCC" = "yes"
 629 then
 630   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 631   if test "$gccmajor" -lt "3"
 632   then
 633     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 634   fi
 635 fi
 636
 637 dnl Check for GNU Make.  We use its extensions, so don't build without it
 638 if test -z "$llvm_cv_gnu_make_command"
 639 then
 640   AC_MSG_ERROR([GNU Make required but not found])
 641 fi
 642
 643 dnl Tool compatibility is okay if we make it here.
 644 AC_MSG_RESULT([ok])
 645
 646 dnl===-----------------------------------------------------------------------===
 647 dnl===
 648 dnl=== SECTION 5: Check for libraries
 649 dnl===
 650 dnl===-----------------------------------------------------------------------===
 651
 652 dnl libelf is for sparc only; we can ignore it if we don't have it
 653 AC_CHECK_LIB(elf, elf_begin)
 654 AC_CHECK_LIB(m,sin)
 655 if test "$llvm_cv_os_type" = "MingW" ; then
 656   AC_CHECK_LIB(imagehlp, main)
 657   AC_CHECK_LIB(psapi, main)
 658 fi
 659
 660 dnl lt_dlopen may be required for plugin support.
 661 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 662               [Define if lt_dlopen() is available on this platform]),
 663               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 664                            not be available]))
 665
 666 dnl dlopen() is required for plugin support.
 667 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 668                [Define if dlopen() is available on this platform.]),
 669                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 670
 671 dnl mallinfo is optional; the code can compile (minus features) without it
 672 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 673                [Define if mallinfo() is available on this platform.]))
 674
 675 dnl pthread locking functions are optional - but llvm will not be thread-safe
 676 dnl without locks.
 677 if test "$ENABLE_THREADS" -eq 1 ; then
 678   AC_CHECK_LIB(pthread,pthread_mutex_init)
 679   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 680                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 681                            [Have pthread_mutex_lock]))
 682 fi
 683
 684 dnl Allow extra x86-disassembler library
 685 AC_ARG_WITH(udis86,
 686   AS_HELP_STRING([--with-udis86=<path>],
 687     [Use udis86 external x86 disassembler library]),
 688     [
 689       AC_SUBST(USE_UDIS86, [1])
 690       case "$withval" in
 691         /usr/lib|yes) ;;
 692         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 693       esac
 694       AC_CHECK_LIB(udis86, ud_init, [], [
 695         echo "Error! You need to have libudis86 around."
 696         exit -1
 697       ])
 698     ],
 699     AC_SUBST(USE_UDIS86, [0]))
 700 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 701                    [Define if use udis86 library])
 702
 703 dnl===-----------------------------------------------------------------------===
 704 dnl===
 705 dnl=== SECTION 6: Check for header files
 706 dnl===
 707 dnl===-----------------------------------------------------------------------===
 708
 709 dnl First, use autoconf provided macros for specific headers that we need
 710 dnl We don't check for ancient stuff or things that are guaranteed to be there
 711 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 712 dnl Generally we're looking for POSIX headers.
 713 AC_HEADER_DIRENT
 714 AC_HEADER_MMAP_ANONYMOUS
 715 AC_HEADER_STAT
 716 AC_HEADER_STDC
 717 AC_HEADER_SYS_WAIT
 718 AC_HEADER_TIME
 719
 720 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 721 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 722 AC_CHECK_HEADERS([windows.h])
 723 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 724 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 725 if test "$ENABLE_THREADS" -eq 1 ; then
 726   AC_CHECK_HEADERS(pthread.h,
 727                   AC_SUBST(HAVE_PTHREAD, 1),
 728                    AC_SUBST(HAVE_PTHREAD, 0))
 729 else
 730   AC_SUBST(HAVE_PTHREAD, 0)
 731 fi
 732
 733 dnl===-----------------------------------------------------------------------===
 734 dnl===
 735 dnl=== SECTION 7: Check for types and structures
 736 dnl===
 737 dnl===-----------------------------------------------------------------------===
 738
 739 AC_HUGE_VAL_CHECK
 740 AC_TYPE_PID_T
 741 AC_TYPE_SIZE_T
 742 AC_TYPE_SIGNAL
 743 AC_STRUCT_TM
 744 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 745 AC_CHECK_TYPES([uint64_t],,
 746          AC_CHECK_TYPES([u_int64_t],,
 747          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 748
 749 dnl===-----------------------------------------------------------------------===
 750 dnl===
 751 dnl=== SECTION 8: Check for specific functions needed
 752 dnl===
 753 dnl===-----------------------------------------------------------------------===
 754
 755 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 756 AC_CHECK_FUNCS([powf fmodf strtof round ])
 757 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 758 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 759 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 760 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 761 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 762 AC_C_PRINTF_A
 763 AC_FUNC_ALLOCA
 764 AC_FUNC_RAND48
 765
 766 dnl Check for variations in the Standard C++ library and STL. These macros are
 767 dnl provided by LLVM in the autoconf/m4 directory.
 768 AC_CXX_HAVE_HASH_MAP
 769 AC_CXX_HAVE_HASH_SET
 770 AC_CXX_HAVE_STD_ITERATOR
 771 AC_CXX_HAVE_BI_ITERATOR
 772 AC_CXX_HAVE_FWD_ITERATOR
 773 AC_FUNC_ISNAN
 774 AC_FUNC_ISINF
 775
 776 dnl Check for mmap support.We also need to know if /dev/zero is required to
 777 dnl be opened for allocating RWX memory.
 778 dnl Make sure we aren't attempting to configure for an unknown system
 779 if test "$llvm_cv_platform_type" = "Unix" ; then
 780   AC_FUNC_MMAP
 781   AC_FUNC_MMAP_FILE
 782   AC_NEED_DEV_ZERO_FOR_MMAP
 783
 784   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 785   then
 786     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 787   fi
 788   if test "$ac_cv_func_mmap_file" = "no"
 789   then
 790     AC_MSG_WARN([mmap() of files required but not found])
 791   fi
 792 fi
 793
 794 dnl===-----------------------------------------------------------------------===
 795 dnl===
 796 dnl=== SECTION 9: Additional checks, variables, etc.
 797 dnl===
 798 dnl===-----------------------------------------------------------------------===
 799
 800 dnl Check, whether __dso_handle is present
 801 AC_CHECK_FUNCS([__dso_handle])
 802
 803 dnl See if the llvm-gcc executable can compile to LLVM assembly
 804 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 805 [llvm_cv_llvmgcc_sanity="no"
 806 if test -x "$LLVMGCC" ; then
 807   cp /dev/null conftest.c
 808   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 809       grep 'target datalayout =' > /dev/null 2>&1
 810   if test $? -eq 0 ; then
 811     llvm_cv_llvmgcc_sanity="yes"
 812   fi
 813   rm conftest.c
 814 fi])
 815
 816 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 817 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 818   AC_MSG_CHECKING([llvm-gcc component support])
 819   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 820   AC_SUBST(LLVMCC1,$llvmcc1path)
 821   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 822   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 823   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 824   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 825   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 826   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 827   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 828   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 829   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 830   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 831   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 832   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 833   AC_MSG_RESULT([ok])
 834 fi
 835
 836 dnl Propagate the shared library extension that the libltdl checks did to
 837 dnl the Makefiles so we can use it there too
 838 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 839
 840 # Translate the various configuration directories and other basic
 841 # information into substitutions that will end up in Makefile.config.in
 842 # that these configured values can be used by the makefiles
 843 if test "${prefix}" = "NONE" ; then
 844   prefix="/usr/local"
 845 fi
 846 eval LLVM_PREFIX="${prefix}";
 847 eval LLVM_BINDIR="${prefix}/bin";
 848 eval LLVM_LIBDIR="${prefix}/lib";
 849 eval LLVM_DATADIR="${prefix}/share/llvm";
 850 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 851 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 852 eval LLVM_INCLUDEDIR="${prefix}/include";
 853 eval LLVM_INFODIR="${prefix}/info";
 854 eval LLVM_MANDIR="${prefix}/man";
 855 LLVM_CONFIGTIME=`date`
 856 AC_SUBST(LLVM_PREFIX)
 857 AC_SUBST(LLVM_BINDIR)
 858 AC_SUBST(LLVM_LIBDIR)
 859 AC_SUBST(LLVM_DATADIR)
 860 AC_SUBST(LLVM_DOCSDIR)
 861 AC_SUBST(LLVM_ETCDIR)
 862 AC_SUBST(LLVM_INCLUDEDIR)
 863 AC_SUBST(LLVM_INFODIR)
 864 AC_SUBST(LLVM_MANDIR)
 865 AC_SUBST(LLVM_CONFIGTIME)
 866
 867 # Place the various directores into the config.h file as #defines so that we
 868 # can know about the installation paths within LLVM.
 869 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 870                    [Installation prefix directory])
 871 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 872                    [Installation directory for binary executables])
 873 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 874                    [Installation directory for libraries])
 875 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 876                    [Installation directory for data files])
 877 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 878                    [Installation directory for documentation])
 879 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 880                    [Installation directory for config files])
 881 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 882                    [Installation directory for include files])
 883 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 884                    [Installation directory for .info files])
 885 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 886                    [Installation directory for man pages])
 887 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 888                    [Time at which LLVM was configured])
 889
 890 # Determine which bindings to build.
 891 if test "$BINDINGS_TO_BUILD" = auto ; then
 892   BINDINGS_TO_BUILD=""
 893   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 894     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 895   fi
 896 fi
 897 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 898
 899 # This isn't really configurey, but it avoids having to repeat the list in
 900 # other files.
 901 AC_SUBST(ALL_BINDINGS,ocaml)
 902
 903 # Do any work necessary to ensure that bindings have what they need.
 904 binding_prereqs_failed=0
 905 for a_binding in $BINDINGS_TO_BUILD ; do
 906   case "$a_binding" in
 907   ocaml)
 908     if test "x$OCAMLC" = x ; then
 909       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 910       binding_prereqs_failed=1
 911     fi
 912     if test "x$OCAMLDEP" = x ; then
 913       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 914       binding_prereqs_failed=1
 915     fi
 916     if test "x$OCAMLOPT" = x ; then
 917       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 918       dnl ocamlopt is optional!
 919     fi
 920     if test "x$with_ocaml_libdir" != xauto ; then
 921       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 922     else
 923       ocaml_stdlib="`"$OCAMLC" -where`"
 924       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 925       then
 926         # ocaml stdlib is beneath our prefix; use stdlib
 927         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 928       else
 929         # ocaml stdlib is outside our prefix; use libdir/ocaml
 930         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 931       fi
 932     fi
 933     ;;
 934   esac
 935 done
 936 if test "$binding_prereqs_failed" = 1 ; then
 937   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 938 fi
 939
 940
 941 dnl===-----------------------------------------------------------------------===
 942 dnl===
 943 dnl=== SECTION 10: Specify the output files and generate it
 944 dnl===
 945 dnl===-----------------------------------------------------------------------===
 946
 947 dnl Configure header files
 948 dnl WARNING: dnl If you add or remove any of the following config headers, then
 949 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 950 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 951 dnl files can be updated automatically when their *.in sources change.
 952 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 953 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 954 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 955 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 956 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 957
 958 dnl Configure the makefile's configuration data
 959 AC_CONFIG_FILES([Makefile.config])
 960
 961 dnl Configure the RPM spec file for LLVM
 962 AC_CONFIG_FILES([llvm.spec])
 963
 964 dnl Configure doxygen's configuration file
 965 AC_CONFIG_FILES([docs/doxygen.cfg])
 966
 967 dnl Do the first stage of configuration for llvm-config.in.
 968 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 969
 970 dnl Do special configuration of Makefiles
 971 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 972 AC_CONFIG_MAKEFILE(Makefile)
 973 AC_CONFIG_MAKEFILE(Makefile.common)
 974 AC_CONFIG_MAKEFILE(examples/Makefile)
 975 AC_CONFIG_MAKEFILE(lib/Makefile)
 976 AC_CONFIG_MAKEFILE(runtime/Makefile)
 977 AC_CONFIG_MAKEFILE(test/Makefile)
 978 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 979 AC_CONFIG_MAKEFILE(tools/Makefile)
 980 AC_CONFIG_MAKEFILE(utils/Makefile)
 981 AC_CONFIG_MAKEFILE(projects/Makefile)
 982 AC_CONFIG_MAKEFILE(bindings/Makefile)
 983 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
 984
 985 dnl Finally, crank out the output
 986 AC_OUTPUT
 987