autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.3svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [3], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd* | *-*-kfreebsd-gnu)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-openbsd*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="OpenBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-netbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="NetBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-dragonfly*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="DragonFly"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-hpux*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="HP-UX"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-interix*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="Interix"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-linux*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Linux"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-gnu*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="GNU"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-solaris*)
 266     llvm_cv_link_all_option="-Wl,-z,allextract"
 267     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 268     llvm_cv_os_type="SunOS"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-auroraux*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="AuroraUX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-win32*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Win32"
 279     llvm_cv_platform_type="Win32" ;;
 280   *-*-mingw*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="MingW"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-haiku*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Haiku"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-unknown-eabi*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Freestanding"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-elf*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *)
 301     llvm_cv_link_all_option=""
 302     llvm_cv_no_link_all_option=""
 303     llvm_cv_os_type="Unknown"
 304     llvm_cv_platform_type="Unknown" ;;
 305 esac])
 306
 307 AC_CACHE_CHECK([type of operating system we're going to target],
 308                [llvm_cv_target_os_type],
 309 [case $target in
 310   *-*-aix*)
 311     llvm_cv_target_os_type="AIX" ;;
 312   *-*-irix*)
 313     llvm_cv_target_os_type="IRIX" ;;
 314   *-*-cygwin*)
 315     llvm_cv_target_os_type="Cygwin" ;;
 316   *-*-darwin*)
 317     llvm_cv_target_os_type="Darwin" ;;
 318   *-*-minix*)
 319     llvm_cv_target_os_type="Minix" ;;
 320   *-*-freebsd* | *-*-kfreebsd-gnu)
 321     llvm_cv_target_os_type="FreeBSD" ;;
 322   *-*-openbsd*)
 323     llvm_cv_target_os_type="OpenBSD" ;;
 324   *-*-netbsd*)
 325     llvm_cv_target_os_type="NetBSD" ;;
 326   *-*-dragonfly*)
 327     llvm_cv_target_os_type="DragonFly" ;;
 328   *-*-hpux*)
 329     llvm_cv_target_os_type="HP-UX" ;;
 330   *-*-interix*)
 331     llvm_cv_target_os_type="Interix" ;;
 332   *-*-linux*)
 333     llvm_cv_target_os_type="Linux" ;;
 334   *-*-gnu*)
 335     llvm_cv_target_os_type="GNU" ;;
 336   *-*-solaris*)
 337     llvm_cv_target_os_type="SunOS" ;;
 338   *-*-auroraux*)
 339     llvm_cv_target_os_type="AuroraUX" ;;
 340   *-*-win32*)
 341     llvm_cv_target_os_type="Win32" ;;
 342   *-*-mingw*)
 343     llvm_cv_target_os_type="MingW" ;;
 344   *-*-haiku*)
 345     llvm_cv_target_os_type="Haiku" ;;
 346   *-*-rtems*)
 347     llvm_cv_target_os_type="RTEMS" ;;
 348   *-*-nacl*)
 349     llvm_cv_target_os_type="NativeClient" ;;
 350   *-unknown-eabi*)
 351     llvm_cv_target_os_type="Freestanding" ;;
 352   *)
 353     llvm_cv_target_os_type="Unknown" ;;
 354 esac])
 355
 356 dnl Make sure we aren't attempting to configure for an unknown system
 357 if test "$llvm_cv_os_type" = "Unknown" ; then
 358   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 359 fi
 360
 361 dnl Set the "OS" Makefile variable based on the platform type so the
 362 dnl makefile can configure itself to specific build hosts
 363 AC_SUBST(OS,$llvm_cv_os_type)
 364 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 365 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 366
 367 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 368 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 369 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 370
 371 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 372 dnl This is used by lib/Support to determine the basic kind of implementation
 373 dnl to use.
 374 case $llvm_cv_platform_type in
 375   Unix)
 376     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 377     AC_SUBST(LLVM_ON_UNIX,[1])
 378     AC_SUBST(LLVM_ON_WIN32,[0])
 379     ;;
 380   Win32)
 381     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 382     AC_SUBST(LLVM_ON_UNIX,[0])
 383     AC_SUBST(LLVM_ON_WIN32,[1])
 384     ;;
 385 esac
 386
 387 dnl Determine what our target architecture is and configure accordingly.
 388 dnl This will allow Makefiles to make a distinction between the hardware and
 389 dnl the OS.
 390 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 391 [case $target in
 392   i?86-*)                 llvm_cv_target_arch="x86" ;;
 393   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 394   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 395   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 396   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 397   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 398   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 399   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 400   xcore-*)                llvm_cv_target_arch="XCore" ;;
 401   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 402   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 403   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 404   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 405   *)                      llvm_cv_target_arch="Unknown" ;;
 406 esac])
 407
 408 if test "$llvm_cv_target_arch" = "Unknown" ; then
 409   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 410 fi
 411
 412 dnl Determine the LLVM native architecture for the target
 413 case "$llvm_cv_target_arch" in
 414     x86)     LLVM_NATIVE_ARCH="X86" ;;
 415     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 416     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 417 esac
 418
 419 dnl Define a substitution, ARCH, for the target architecture
 420 AC_SUBST(ARCH,$llvm_cv_target_arch)
 421
 422 dnl Determine what our host architecture.
 423 dnl This will allow MCJIT regress tests runs only for supported
 424 dnl platforms.
 425 case $host in
 426   i?86-*)                 host_arch="x86" ;;
 427   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 428   sparc*-*)               host_arch="Sparc" ;;
 429   powerpc*-*)             host_arch="PowerPC" ;;
 430   arm*-*)                 host_arch="ARM" ;;
 431   aarch64*-*)             host_arch="AArch64" ;;
 432   mips-* | mips64-*)      host_arch="Mips" ;;
 433   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 434   xcore-*)                host_arch="XCore" ;;
 435   msp430-*)               host_arch="MSP430" ;;
 436   hexagon-*)              host_arch="Hexagon" ;;
 437   mblaze-*)               host_arch="MBlaze" ;;
 438   *)                      host_arch="Unknown" ;;
 439 esac
 440
 441 if test "$host_arch" = "Unknown" ; then
 442   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 443 fi
 444
 445 AC_SUBST(HOST_ARCH,$host_arch)
 446
 447 dnl Check for the endianness of the target
 448 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 449
 450 dnl Check for build platform executable suffix if we're cross-compiling
 451 if test "$cross_compiling" = yes; then
 452   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 453   AC_BUILD_EXEEXT
 454   ac_build_prefix=${build_alias}-
 455   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 456   if test -z "$BUILD_CXX"; then
 457      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 458      if test -z "$BUILD_CXX"; then
 459        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 460      fi
 461   fi
 462 else
 463   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 464 fi
 465
 466 dnl Check to see if there's a .svn or .git directory indicating that this
 467 dnl build is being done from a checkout. This sets up several defaults for
 468 dnl the command line switches. When we build with a checkout directory,
 469 dnl we get a debug with assertions turned on. Without, we assume a source
 470 dnl release and we get an optimized build without assertions.
 471 dnl See --enable-optimized and --enable-assertions below
 472 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 473   cvsbuild="yes"
 474   optimize="no"
 475   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 476 else
 477   cvsbuild="no"
 478   optimize="yes"
 479 fi
 480
 481 dnl===-----------------------------------------------------------------------===
 482 dnl===
 483 dnl=== SECTION 3: Command line arguments for the configure script.
 484 dnl===
 485 dnl===-----------------------------------------------------------------------===
 486
 487 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 488 AC_ARG_ENABLE(libcpp,
 489               AS_HELP_STRING([--enable-libcpp],
 490                              [Use libc++ if available (default is NO)]),,
 491                              enableval=default)
 492 case "$enableval" in
 493   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 494   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 495   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 496   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 497 esac
 498
 499 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 500 AC_ARG_ENABLE(cxx11,
 501               AS_HELP_STRING([--enable-cxx11],
 502                              [Use c++11 if available (default is NO)]),,
 503                              enableval=default)
 504 case "$enableval" in
 505   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 506   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 507   default) AC_SUBST(ENABLE_CXX11,[0]);;
 508   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 509 esac
 510
 511 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 512 clang_arcmt="yes"
 513 AC_ARG_ENABLE(clang-arcmt,
 514               AS_HELP_STRING([--enable-clang-arcmt],
 515                              [Enable building of clang ARCMT (default is YES)]),
 516                              clang_arcmt="$enableval",
 517                              enableval="yes")
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 520   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 521   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 523 esac
 524
 525 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 526 clang_static_analyzer="yes"
 527 AC_ARG_ENABLE(clang-static-analyzer,
 528               AS_HELP_STRING([--enable-clang-static-analyzer],
 529                              [Enable building of clang Static Analyzer (default is YES)]),
 530                              clang_static_analyzer="$enableval",
 531                              enableval="yes")
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 534   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 535   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 537 esac
 538
 539 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 540 AC_ARG_ENABLE(clang-rewriter,
 541               AS_HELP_STRING([--enable-clang-rewriter],
 542                              [Enable building of clang rewriter (default is YES)]),,
 543                              enableval="yes")
 544 case "$enableval" in
 545   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 546   no)
 547     if test ${clang_arcmt} != "no" ; then
 548       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 549     fi
 550     if test ${clang_static_analyzer} != "no" ; then
 551       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 552     fi
 553     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 554     ;;
 555   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 557 esac
 558
 559 dnl --enable-optimized : check whether they want to do an optimized build:
 560 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 561  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 562 if test ${enableval} = "no" ; then
 563   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 564 else
 565   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 566 fi
 567
 568 dnl --enable-profiling : check whether they want to do a profile build:
 569 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 570  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 571 if test ${enableval} = "no" ; then
 572   AC_SUBST(ENABLE_PROFILING,[[]])
 573 else
 574   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 575 fi
 576
 577 dnl --enable-assertions : check whether they want to turn on assertions or not:
 578 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 579   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 580 if test ${enableval} = "yes" ; then
 581   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 582 else
 583   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 584 fi
 585
 586 dnl --enable-werror : check whether we want Werror on by default
 587 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 588   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 589 case "$enableval" in
 590   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 591   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 592   default) AC_SUBST(ENABLE_WERROR,[0]);;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 597 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 598   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 599 if test ${enableval} = "yes" ; then
 600   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 601   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 602 else
 603   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 604   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 605 fi
 606
 607 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 608 AC_ARG_ENABLE(debug-runtime,
 609    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 610 if test ${enableval} = "no" ; then
 611   AC_SUBST(DEBUG_RUNTIME,[[]])
 612 else
 613   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 614 fi
 615
 616 dnl --enable-debug-symbols : should even optimized compiler libraries
 617 dnl have debug symbols?
 618 AC_ARG_ENABLE(debug-symbols,
 619    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 620 if test ${enableval} = "no" ; then
 621   AC_SUBST(DEBUG_SYMBOLS,[[]])
 622 else
 623   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 624 fi
 625
 626 dnl --enable-keep-symbols : do not strip installed executables
 627 AC_ARG_ENABLE(keep-symbols,
 628    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 629 if test ${enableval} = "no" ; then
 630   AC_SUBST(KEEP_SYMBOLS,[[]])
 631 else
 632   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 633 fi
 634
 635 dnl --enable-jit: check whether they want to enable the jit
 636 AC_ARG_ENABLE(jit,
 637   AS_HELP_STRING(--enable-jit,
 638                  [Enable Just In Time Compiling (default is YES)]),,
 639   enableval=default)
 640 if test ${enableval} = "no"
 641 then
 642   AC_SUBST(JIT,[[]])
 643 else
 644   case "$llvm_cv_target_arch" in
 645     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 646     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 647     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 648     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 649     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 650     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 651     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 652     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 653     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 654     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 655     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 656     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 657     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 658   esac
 659 fi
 660
 661 dnl Allow enablement of building and installing docs
 662 AC_ARG_ENABLE(docs,
 663               AS_HELP_STRING([--enable-docs],
 664                              [Build documents (default is YES)]),,
 665                              enableval=default)
 666 case "$enableval" in
 667   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 668   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 669   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 670   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 671 esac
 672
 673 dnl Allow enablement of doxygen generated documentation
 674 AC_ARG_ENABLE(doxygen,
 675               AS_HELP_STRING([--enable-doxygen],
 676                              [Build doxygen documentation (default is NO)]),,
 677                              enableval=default)
 678 case "$enableval" in
 679   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 680   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 681   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 682   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 683 esac
 684
 685 dnl Allow disablement of threads
 686 AC_ARG_ENABLE(threads,
 687               AS_HELP_STRING([--enable-threads],
 688                              [Use threads if available (default is YES)]),,
 689                              enableval=default)
 690 case "$enableval" in
 691   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 692   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 693   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 694   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 695 esac
 696 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 697                    [Define if threads enabled])
 698
 699 dnl Allow disablement of pthread.h
 700 AC_ARG_ENABLE(pthreads,
 701               AS_HELP_STRING([--enable-pthreads],
 702                              [Use pthreads if available (default is YES)]),,
 703                              enableval=default)
 704 case "$enableval" in
 705   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 706   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 707   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 708   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 709 esac
 710
 711 dnl Allow disablement of zlib
 712 AC_ARG_ENABLE(zlib,
 713               AS_HELP_STRING([--enable-zlib],
 714                              [Use zlib for compression/decompression if
 715                               available (default is YES)]),,
 716                               enableval=default)
 717 case "$enableval" in
 718   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 719   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 720   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 721   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 722 esac
 723 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 724                    [Define if zlib is enabled])
 725
 726 dnl Allow building without position independent code
 727 AC_ARG_ENABLE(pic,
 728   AS_HELP_STRING([--enable-pic],
 729                  [Build LLVM with Position Independent Code (default is YES)]),,
 730                  enableval=default)
 731 case "$enableval" in
 732   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 733   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 734   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 735   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 736 esac
 737 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 738                    [Define if position independent code is enabled])
 739
 740 dnl Allow building a shared library and linking tools against it.
 741 AC_ARG_ENABLE(shared,
 742   AS_HELP_STRING([--enable-shared],
 743                  [Build a shared library and link tools against it (default is NO)]),,
 744                  enableval=default)
 745 case "$enableval" in
 746   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 747   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 748   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 749   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 750 esac
 751
 752 dnl Allow libstdc++ is embedded in LLVM.dll.
 753 AC_ARG_ENABLE(embed-stdcxx,
 754   AS_HELP_STRING([--enable-embed-stdcxx],
 755                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 756                  enableval=default)
 757 case "$enableval" in
 758   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 759   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 760   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 761   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 762 esac
 763
 764 dnl Enable embedding timestamp information into build.
 765 AC_ARG_ENABLE(timestamps,
 766   AS_HELP_STRING([--enable-timestamps],
 767                  [Enable embedding timestamp information in build (default is YES)]),,
 768                  enableval=default)
 769 case "$enableval" in
 770   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 771   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 772   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 773   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 774 esac
 775 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 776                    [Define if timestamp information (e.g., __DATE__) is allowed])
 777
 778 dnl Enable embedding timestamp information into build.
 779
 780 AC_ARG_ENABLE(backtraces,
 781   AS_HELP_STRING([--enable-backtraces],
 782                  [Enable embedding backtraces on crash (default is YES)]),,
 783                  enableval=default)
 784 case "$enableval" in
 785   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 786   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 787   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 788   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 789 esac
 790 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 791                    [Define if you want backtraces on crash])
 792
 793 dnl Allow specific targets to be specified for building (or not)
 794 TARGETS_TO_BUILD=""
 795 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 796     [Build specific host targets: all or target1,target2,... Valid targets are:
 797      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 798      xcore, msp430, nvptx, and cpp (default=all)]),,
 799     enableval=all)
 800 if test "$enableval" = host-only ; then
 801   enableval=host
 802 fi
 803 case "$enableval" in
 804   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend MBlaze NVPTX Hexagon" ;;
 805   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 806       case "$a_target" in
 807         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 808         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 809         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 810         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 811         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 812         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 813         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 814         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 815         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 816         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 817         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 818         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 819         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 820         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 821         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 822         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 823         host) case "$llvm_cv_target_arch" in
 824             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 825             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 826             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 827             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 828             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 829             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 830             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 831             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 832             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 833             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 834             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 835             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 836             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 837           esac ;;
 838         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 839       esac
 840   done
 841   ;;
 842 esac
 843
 844 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 845     [Build experimental host targets: disable or target1,target2,...
 846      (default=disable)]),,
 847     enableval=disable)
 848
 849 if test ${enableval} != "disable"
 850 then
 851   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 852 fi
 853
 854 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 855
 856 dnl Determine whether we are building LLVM support for the native architecture.
 857 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 858 for a_target in $TARGETS_TO_BUILD; do
 859   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 860     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 861       [LLVM architecture name for the native architecture, if available])
 862     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 863     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 864     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 865     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 866     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 867       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 868     fi
 869     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 870       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 871     fi
 872     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 873       [LLVM name for the native Target init function, if available])
 874     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 875       [LLVM name for the native TargetInfo init function, if available])
 876     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 877       [LLVM name for the native target MC init function, if available])
 878     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 879       [LLVM name for the native AsmPrinter init function, if available])
 880     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 881       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 882        [LLVM name for the native AsmParser init function, if available])
 883     fi
 884     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 885       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 886        [LLVM name for the native Disassembler init function, if available])
 887     fi
 888   fi
 889 done
 890
 891 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 892 dnl target feature def files.
 893 LLVM_ENUM_TARGETS=""
 894 LLVM_ENUM_ASM_PRINTERS=""
 895 LLVM_ENUM_ASM_PARSERS=""
 896 LLVM_ENUM_DISASSEMBLERS=""
 897 for target_to_build in $TARGETS_TO_BUILD; do
 898   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 899   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 900     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 901   fi
 902   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 903     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 904   fi
 905   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 906     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 907   fi
 908 done
 909 AC_SUBST(LLVM_ENUM_TARGETS)
 910 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 911 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 912 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 913
 914 dnl Override the option to use for optimized builds.
 915 AC_ARG_WITH(optimize-option,
 916   AS_HELP_STRING([--with-optimize-option],
 917                  [Select the compiler options to use for optimized builds]),,
 918                  withval=default)
 919 AC_MSG_CHECKING([optimization flags])
 920 case "$withval" in
 921   default)
 922     case "$llvm_cv_os_type" in
 923     FreeBSD) optimize_option=-O2 ;;
 924     MingW) optimize_option=-O2 ;;
 925     *)     optimize_option=-O3 ;;
 926     esac ;;
 927   *) optimize_option="$withval" ;;
 928 esac
 929 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 930 AC_MSG_RESULT([$optimize_option])
 931
 932 dnl Specify extra build options
 933 AC_ARG_WITH(extra-options,
 934   AS_HELP_STRING([--with-extra-options],
 935                  [Specify additional options to compile LLVM with]),,
 936                  withval=default)
 937 case "$withval" in
 938   default) EXTRA_OPTIONS= ;;
 939   *) EXTRA_OPTIONS=$withval ;;
 940 esac
 941 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 942
 943 dnl Specify extra linker build options
 944 AC_ARG_WITH(extra-ld-options,
 945   AS_HELP_STRING([--with-extra-ld-options],
 946                  [Specify additional options to link LLVM with]),,
 947                  withval=default)
 948 case "$withval" in
 949   default) EXTRA_LD_OPTIONS= ;;
 950   *) EXTRA_LD_OPTIONS=$withval ;;
 951 esac
 952 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 953
 954 dnl Allow specific bindings to be specified for building (or not)
 955 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 956     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 957     enableval=default)
 958 BINDINGS_TO_BUILD=""
 959 case "$enableval" in
 960   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 961   all ) BINDINGS_TO_BUILD="ocaml" ;;
 962   none | no) BINDINGS_TO_BUILD="" ;;
 963   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 964       case "$a_binding" in
 965         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 966         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 967       esac
 968   done
 969   ;;
 970 esac
 971
 972 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 973 dnl script for bindings/ocaml/configure, except that its auto value depends on
 974 dnl OCAMLC, which is found here to support tests.
 975 AC_ARG_WITH([ocaml-libdir],
 976   [AS_HELP_STRING([--with-ocaml-libdir],
 977     [Specify install location for ocaml bindings (default is stdlib)])],
 978   [],
 979   [withval=auto])
 980 case "$withval" in
 981   auto) with_ocaml_libdir="$withval" ;;
 982   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 983   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 984 esac
 985
 986 AC_ARG_WITH(clang-srcdir,
 987   AS_HELP_STRING([--with-clang-srcdir],
 988     [Directory to the out-of-tree Clang source]),,
 989     withval="-")
 990 case "$withval" in
 991   -) clang_src_root="" ;;
 992   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 993   *) clang_src_root="$ac_pwd/$withval" ;;
 994 esac
 995 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 996
 997 AC_ARG_WITH(clang-resource-dir,
 998   AS_HELP_STRING([--with-clang-resource-dir],
 999     [Relative directory from the Clang binary for resource files]),,
1000     withval="")
1001 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1002                    [Relative directory for resource files])
1003
1004 AC_ARG_WITH(c-include-dirs,
1005   AS_HELP_STRING([--with-c-include-dirs],
1006     [Colon separated list of directories clang will search for headers]),,
1007     withval="")
1008 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1009                    [Directories clang will search for headers])
1010
1011 # Clang normally uses the system c++ headers and libraries. With this option,
1012 # clang will use the ones provided by a gcc installation instead. This option should
1013 # be passed the same value that was used with --prefix when configuring gcc.
1014 AC_ARG_WITH(gcc-toolchain,
1015   AS_HELP_STRING([--with-gcc-toolchain],
1016     [Directory where gcc is installed.]),,
1017     withval="")
1018 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1019                    [Directory where gcc is installed.])
1020
1021 AC_ARG_WITH(default-sysroot,
1022   AS_HELP_STRING([--with-default-sysroot],
1023     [Add --sysroot=<path> to all compiler invocations.]),,
1024     withval="")
1025 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1026                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1027
1028 dnl Allow linking of LLVM with GPLv3 binutils code.
1029 AC_ARG_WITH(binutils-include,
1030   AS_HELP_STRING([--with-binutils-include],
1031     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1032   withval=default)
1033 case "$withval" in
1034   default) WITH_BINUTILS_INCDIR=default ;;
1035   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1036   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1037 esac
1038 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1039   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1040   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1041      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1042      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1043   fi
1044 fi
1045
1046 dnl Specify the URL where bug reports should be submitted.
1047 AC_ARG_WITH(bug-report-url,
1048   AS_HELP_STRING([--with-bug-report-url],
1049     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1050     withval="http://llvm.org/bugs/")
1051 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1052                    [Bug report URL.])
1053
1054 dnl --enable-libffi : check whether the user wants to turn off libffi:
1055 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1056   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1057   [case "$enableval" in
1058     yes) llvm_cv_enable_libffi="yes" ;;
1059     no)  llvm_cv_enable_libffi="no"  ;;
1060     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1061   esac],
1062   llvm_cv_enable_libffi=no)
1063
1064 AC_ARG_WITH(internal-prefix,
1065   AS_HELP_STRING([--with-internal-prefix],
1066     [Installation directory for internal files]),,
1067     withval="")
1068 AC_SUBST(INTERNAL_PREFIX,[$withval])
1069
1070 dnl===-----------------------------------------------------------------------===
1071 dnl===
1072 dnl=== SECTION 4: Check for programs we need and that they are the right version
1073 dnl===
1074 dnl===-----------------------------------------------------------------------===
1075
1076 AC_PROG_NM
1077 AC_SUBST(NM)
1078
1079 dnl Check for the tools that the makefiles require
1080 AC_CHECK_GNU_MAKE
1081 AC_PROG_LN_S
1082 AC_PATH_PROG(CMP, [cmp], [cmp])
1083 AC_PATH_PROG(CP, [cp], [cp])
1084 AC_PATH_PROG(DATE, [date], [date])
1085 AC_PATH_PROG(FIND, [find], [find])
1086 AC_PATH_PROG(GREP, [grep], [grep])
1087 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1088 AC_PATH_PROG(MV,   [mv],   [mv])
1089 AC_PROG_RANLIB
1090 AC_CHECK_TOOL(AR, ar, false)
1091 AC_PATH_PROG(RM,   [rm],   [rm])
1092 AC_PATH_PROG(SED,  [sed],  [sed])
1093 AC_PATH_PROG(TAR,  [tar],  [gtar])
1094 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1095
1096 dnl Looking for misc. graph plotting software
1097 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1098 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1099   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1100   dnl If we're targeting for mingw we should emit windows paths, not msys
1101   if test "$llvm_cv_os_type" = "MingW" ; then
1102     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1103   fi
1104   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1105    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1106 fi
1107 AC_PATH_PROG(DOT, [dot], [echo dot])
1108 if test "$DOT" != "echo dot" ; then
1109   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1110   dnl If we're targeting for mingw we should emit windows paths, not msys
1111   if test "$llvm_cv_os_type" = "MingW" ; then
1112     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1113   fi
1114   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1115    [Define to path to dot program if found or 'echo dot' otherwise])
1116 fi
1117 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1118 if test "$FDP" != "echo fdp" ; then
1119   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1120   dnl If we're targeting for mingw we should emit windows paths, not msys
1121   if test "$llvm_cv_os_type" = "MingW" ; then
1122     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1123   fi
1124   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1125    [Define to path to fdp program if found or 'echo fdp' otherwise])
1126 fi
1127 AC_PATH_PROG(NEATO, [neato], [echo neato])
1128 if test "$NEATO" != "echo neato" ; then
1129   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1130   dnl If we're targeting for mingw we should emit windows paths, not msys
1131   if test "$llvm_cv_os_type" = "MingW" ; then
1132     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1133   fi
1134   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1135    [Define to path to neato program if found or 'echo neato' otherwise])
1136 fi
1137 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1138 if test "$TWOPI" != "echo twopi" ; then
1139   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1140   dnl If we're targeting for mingw we should emit windows paths, not msys
1141   if test "$llvm_cv_os_type" = "MingW" ; then
1142     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1143   fi
1144   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1145    [Define to path to twopi program if found or 'echo twopi' otherwise])
1146 fi
1147 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1148 if test "$CIRCO" != "echo circo" ; then
1149   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1150   dnl If we're targeting for mingw we should emit windows paths, not msys
1151   if test "$llvm_cv_os_type" = "MingW" ; then
1152     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1153   fi
1154   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1155    [Define to path to circo program if found or 'echo circo' otherwise])
1156 fi
1157 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1158 if test "$GV" != "echo gv" ; then
1159   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1160   dnl If we're targeting for mingw we should emit windows paths, not msys
1161   if test "$llvm_cv_os_type" = "MingW" ; then
1162     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1163   fi
1164   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1165    [Define to path to gv program if found or 'echo gv' otherwise])
1166 fi
1167 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1168 if test "$DOTTY" != "echo dotty" ; then
1169   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1170   dnl If we're targeting for mingw we should emit windows paths, not msys
1171   if test "$llvm_cv_os_type" = "MingW" ; then
1172     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1173   fi
1174   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1175    [Define to path to dotty program if found or 'echo dotty' otherwise])
1176 fi
1177 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1178 if test "$XDOT_PY" != "echo xdot.py" ; then
1179   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1180   dnl If we're targeting for mingw we should emit windows paths, not msys
1181   if test "$llvm_cv_os_type" = "MingW" ; then
1182     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1183   fi
1184   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1185    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1186 fi
1187
1188 dnl Find the install program
1189 AC_PROG_INSTALL
1190 dnl Prepend src dir to install path dir if it's a relative path
1191 dnl This is a hack for installs that take place in something other
1192 dnl than the top level.
1193 case "$INSTALL" in
1194  [[\\/$]]* | ?:[[\\/]]* ) ;;
1195  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1196 esac
1197
1198 dnl Checks for documentation and testing tools that we can do without. If these
1199 dnl are not found then they are set to "true" which always succeeds but does
1200 dnl nothing. This just lets the build output show that we could have done
1201 dnl something if the tool was available.
1202 AC_PATH_PROG(BZIP2, [bzip2])
1203 AC_PATH_PROG(CAT, [cat])
1204 AC_PATH_PROG(DOXYGEN, [doxygen])
1205 AC_PATH_PROG(GROFF, [groff])
1206 AC_PATH_PROG(GZIPBIN, [gzip])
1207 AC_PATH_PROG(PDFROFF, [pdfroff])
1208 AC_PATH_PROG(ZIP, [zip])
1209 AC_PATH_PROGS(OCAMLC, [ocamlc])
1210 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1211 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1212 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1213 AC_PATH_PROGS(GAS, [gas as])
1214
1215 dnl Get the version of the linker in use.
1216 AC_LINK_GET_VERSION
1217
1218 dnl Determine whether the linker supports the -R option.
1219 AC_LINK_USE_R
1220
1221 dnl Determine whether the linker supports the -export-dynamic option.
1222 AC_LINK_EXPORT_DYNAMIC
1223
1224 dnl Determine whether the linker supports the --version-script option.
1225 AC_LINK_VERSION_SCRIPT
1226
1227 dnl Check for libtool and the library that has dlopen function (which must come
1228 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1229 dnl libtool).
1230 AC_LIBTOOL_DLOPEN
1231 AC_LIB_LTDL
1232
1233 AC_MSG_CHECKING([tool compatibility])
1234
1235 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1236 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1237 dnl to support those options.
1238 dnl "icc" emits gcc signatures
1239 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1240 ICC=no
1241 IXX=no
1242 case $CC in
1243   icc*|icpc*)
1244     ICC=yes
1245     IXX=yes
1246     ;;
1247    *)
1248     ;;
1249 esac
1250
1251 if test "$GCC" != "yes" && test "$ICC" != "yes"
1252 then
1253   AC_MSG_ERROR([gcc|icc required but not found])
1254 fi
1255
1256 dnl Ensure that compilation tools are compatible with GCC extensions
1257 if test "$GXX" != "yes" && test "$IXX" != "yes"
1258 then
1259   AC_MSG_ERROR([g++|clang++|icc required but not found])
1260 fi
1261
1262 dnl Verify that GCC is version 3.0 or higher
1263 if test "$GCC" = "yes"
1264 then
1265   AC_COMPILE_IFELSE(
1266 [
1267   AC_LANG_SOURCE([[
1268     #if !defined(__GNUC__) || __GNUC__ < 3
1269     #error Unsupported GCC version
1270     #endif
1271   ]])
1272 ],
1273 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1274 fi
1275
1276 dnl Check for GNU Make.  We use its extensions, so don't build without it
1277 if test -z "$llvm_cv_gnu_make_command"
1278 then
1279   AC_MSG_ERROR([GNU Make required but not found])
1280 fi
1281
1282 dnl Tool compatibility is okay if we make it here.
1283 AC_MSG_RESULT([ok])
1284
1285 dnl Check optional compiler flags.
1286 AC_MSG_CHECKING([optional compiler flags])
1287 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1288 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1289 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1290
1291 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1292 dnl false positives, so disable it.
1293 NO_UNINITIALIZED=
1294 NO_MAYBE_UNINITIALIZED=
1295 if test "$GXX" = "yes"
1296 then
1297   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1298   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1299   dnl known to be uninitialized from cases which might be uninitialized.  We
1300   dnl still want to catch the first kind of errors.
1301   if test -z "$NO_MAYBE_UNINITIALIZED"
1302   then
1303     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1304   fi
1305 fi
1306 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1307
1308 AC_ARG_WITH([python],
1309             [AS_HELP_STRING([--with-python], [path to python])],
1310             [PYTHON="$withval"])
1311
1312 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1313   AC_MSG_CHECKING([for python])
1314   AC_MSG_RESULT([user defined: $with_python])
1315 else
1316   if test -n "$PYTHON" ; then
1317     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1318   fi
1319
1320   AC_PATH_PROG([PYTHON], [python python2 python26],
1321                [AC_MSG_RESULT([not found])
1322                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1323 fi
1324
1325 AC_MSG_CHECKING([for python >= 2.5])
1326 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1327 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1328 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1329 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1330 if   test "$ac_python_version_major" -eq "2" \
1331    && test "$ac_python_version_minor" -ge "5" ; then
1332   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1333 else
1334   AC_MSG_RESULT([not found])
1335   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1336 fi
1337
1338 dnl===-----------------------------------------------------------------------===
1339 dnl===
1340 dnl=== SECTION 5: Check for libraries
1341 dnl===
1342 dnl===-----------------------------------------------------------------------===
1343
1344 AC_CHECK_LIB(m,sin)
1345 if test "$llvm_cv_os_type" = "MingW" ; then
1346   AC_CHECK_LIB(imagehlp, main)
1347   AC_CHECK_LIB(psapi, main)
1348 fi
1349
1350 dnl dlopen() is required for plugin support.
1351 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1352                [Define if dlopen() is available on this platform.]),
1353                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1354
1355 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1356 dnl macros to detect whether clock_gettime is available, this just finds the
1357 dnl right libraries to link with.
1358 AC_SEARCH_LIBS(clock_gettime,rt)
1359
1360 dnl libffi is optional; used to call external functions from the interpreter
1361 if test "$llvm_cv_enable_libffi" = "yes" ; then
1362   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1363                  [Define if libffi is available on this platform.]),
1364                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1365 fi
1366
1367 dnl mallinfo is optional; the code can compile (minus features) without it
1368 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1369                [Define if mallinfo() is available on this platform.]))
1370
1371 dnl pthread locking functions are optional - but llvm will not be thread-safe
1372 dnl without locks.
1373 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1374   AC_CHECK_LIB(pthread, pthread_mutex_init)
1375   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1376                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1377                            [Have pthread_mutex_lock]))
1378   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1379                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1380                  [Have pthread_rwlock_init]))
1381   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1382                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1383                  [Have pthread_getspecific]))
1384 fi
1385
1386 dnl zlib is optional; used for compression/uncompression
1387 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1388   AC_CHECK_LIB(z, compress2)
1389 fi
1390
1391 dnl Allow extra x86-disassembler library
1392 AC_ARG_WITH(udis86,
1393   AS_HELP_STRING([--with-udis86=<path>],
1394     [Use udis86 external x86 disassembler library]),
1395     [
1396       AC_SUBST(USE_UDIS86, [1])
1397       case "$withval" in
1398         /usr/lib|yes) ;;
1399         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1400       esac
1401       AC_CHECK_LIB(udis86, ud_init, [], [
1402         echo "Error! You need to have libudis86 around."
1403         exit -1
1404       ])
1405     ],
1406     AC_SUBST(USE_UDIS86, [0]))
1407 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1408                    [Define if use udis86 library])
1409
1410 dnl Allow OProfile support for JIT output.
1411 AC_ARG_WITH(oprofile,
1412   AS_HELP_STRING([--with-oprofile=<prefix>],
1413     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1414     [
1415       AC_SUBST(USE_OPROFILE, [1])
1416       case "$withval" in
1417         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1418         no) llvm_cv_oppath=
1419             AC_SUBST(USE_OPROFILE, [0]) ;;
1420         *) llvm_cv_oppath="${withval}/lib/oprofile"
1421            CPPFLAGS="-I${withval}/include";;
1422       esac
1423       case $llvm_cv_os_type in
1424         Linux)
1425           if test -n "$llvm_cv_oppath" ; then
1426             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1427             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1428             dnl libbfd is not included properly in libopagent in some Debian
1429             dnl versions.  If libbfd isn't found at all, we assume opagent works
1430             dnl anyway.
1431             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1432             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1433               echo "Error! You need to have libopagent around."
1434               exit -1
1435             ])
1436             AC_CHECK_HEADER([opagent.h], [], [
1437               echo "Error! You need to have opagent.h around."
1438               exit -1
1439               ])
1440           fi ;;
1441         *)
1442           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1443       esac
1444     ],
1445     [
1446       AC_SUBST(USE_OPROFILE, [0])
1447     ])
1448 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1449                    [Define if we have the oprofile JIT-support library])
1450
1451 dnl Enable support for Intel JIT Events API.
1452 AC_ARG_WITH(intel-jitevents,
1453   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1454     [
1455        case "$withval" in
1456           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1457           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1458           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1459        esac
1460
1461       case $llvm_cv_os_type in
1462         Linux|Win32|Cygwin|MingW) ;;
1463         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1464       esac
1465
1466       case "$llvm_cv_target_arch" in
1467         x86|x86_64) ;;
1468         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1469       esac
1470     ],
1471     [
1472       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1473     ])
1474 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1475                    [Define if we have the Intel JIT API runtime support library])
1476
1477 dnl Check for libxml2
1478 dnl Right now we're just checking for the existence, we could also check for a
1479 dnl particular version via --version on xml2-config
1480 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1481
1482 AC_MSG_CHECKING(for libxml2 includes)
1483 if test "x$XML2CONFIG" = "x"; then
1484  AC_MSG_RESULT(xml2-config not found)
1485 else
1486  LIBXML2_INC=`$XML2CONFIG --cflags`
1487  AC_MSG_RESULT($LIBXML2_INC)
1488  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1489                                 LIBXML2_LIBS="-lxml2"])
1490 fi
1491 AC_SUBST(LIBXML2_LIBS)
1492 AC_SUBST(LIBXML2_INC)
1493
1494 dnl===-----------------------------------------------------------------------===
1495 dnl===
1496 dnl=== SECTION 6: Check for header files
1497 dnl===
1498 dnl===-----------------------------------------------------------------------===
1499
1500 dnl First, use autoconf provided macros for specific headers that we need
1501 dnl We don't check for ancient stuff or things that are guaranteed to be there
1502 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1503 dnl Generally we're looking for POSIX headers.
1504 AC_HEADER_DIRENT
1505 AC_HEADER_MMAP_ANONYMOUS
1506 AC_HEADER_STAT
1507 AC_HEADER_SYS_WAIT
1508 AC_HEADER_TIME
1509
1510 AC_CHECK_HEADERS([cxxabi.h dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1511 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1512 AC_CHECK_HEADERS([utime.h windows.h])
1513 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1514 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1515 AC_CHECK_HEADERS([valgrind/valgrind.h])
1516 AC_CHECK_HEADERS([fenv.h])
1517 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1518 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1519   AC_CHECK_HEADERS(pthread.h,
1520                    AC_SUBST(HAVE_PTHREAD, 1),
1521                    AC_SUBST(HAVE_PTHREAD, 0))
1522 else
1523   AC_SUBST(HAVE_PTHREAD, 0)
1524 fi
1525 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1526   AC_CHECK_HEADERS(zlib.h,
1527                    AC_SUBST(HAVE_LIBZ, 1),
1528                    AC_SUBST(HAVE_LIBZ, 0))
1529 else
1530   AC_SUBST(HAVE_LIBZ, 0)
1531 fi
1532
1533 dnl Try to find ffi.h.
1534 if test "$llvm_cv_enable_libffi" = "yes" ; then
1535   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1536 fi
1537
1538 dnl Try to find Darwin specific crash reporting libraries.
1539 AC_CHECK_HEADERS([CrashReporterClient.h])
1540
1541 dnl Try to find Darwin specific crash reporting global.
1542 AC_MSG_CHECKING([__crashreporter_info__])
1543 AC_LINK_IFELSE(
1544 [
1545   AC_LANG_SOURCE([[
1546     extern const char *__crashreporter_info__;
1547     int main() {
1548       __crashreporter_info__ = "test";
1549       return 0;
1550     }
1551   ]])
1552 ],
1553 [
1554   AC_MSG_RESULT([yes])
1555   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1556 ],
1557 [
1558   AC_MSG_RESULT([no])
1559   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1560 ])
1561
1562 dnl===-----------------------------------------------------------------------===
1563 dnl===
1564 dnl=== SECTION 7: Check for types and structures
1565 dnl===
1566 dnl===-----------------------------------------------------------------------===
1567
1568 AC_HUGE_VAL_CHECK
1569 AC_TYPE_PID_T
1570 AC_TYPE_SIZE_T
1571 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1572 AC_STRUCT_TM
1573 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1574 AC_CHECK_TYPES([uint64_t],,
1575          AC_CHECK_TYPES([u_int64_t],,
1576          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1577
1578 dnl===-----------------------------------------------------------------------===
1579 dnl===
1580 dnl=== SECTION 8: Check for specific functions needed
1581 dnl===
1582 dnl===-----------------------------------------------------------------------===
1583
1584 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1585 AC_CHECK_FUNCS([powf fmodf strtof round ])
1586 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1587 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1588 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1589 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1590 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1591 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1592 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1593 AC_C_PRINTF_A
1594 AC_FUNC_RAND48
1595
1596 dnl Check the declaration "Secure API" on Windows environments.
1597 AC_CHECK_DECLS([strerror_s])
1598
1599 dnl Check symbols in libgcc.a for JIT on Mingw.
1600 if test "$llvm_cv_os_type" = "MingW" ; then
1601   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1602   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1603   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1604   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1605
1606   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1607   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1608   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1609   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1610   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1611   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1612   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1613   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1614   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1615   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1616
1617   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1618   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1619 fi
1620
1621 dnl Check Win32 API EnumerateLoadedModules.
1622 if test "$llvm_cv_os_type" = "MingW" ; then
1623   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1624   AC_COMPILE_IFELSE(
1625 [
1626   AC_LANG_SOURCE([[
1627     #include <windows.h>
1628     #include <imagehlp.h>
1629     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1630     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1631   ]])
1632 ],
1633 [
1634   AC_MSG_RESULT([yes])
1635   llvm_cv_win32_elmcb_pcstr="PCSTR"
1636 ],
1637 [
1638   AC_MSG_RESULT([no])
1639   llvm_cv_win32_elmcb_pcstr="PSTR"
1640 ])
1641   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1642 fi
1643
1644 dnl Check for variations in the Standard C++ library and STL. These macros are
1645 dnl provided by LLVM in the autoconf/m4 directory.
1646 AC_FUNC_ISNAN
1647 AC_FUNC_ISINF
1648
1649 dnl Check for mmap support.We also need to know if /dev/zero is required to
1650 dnl be opened for allocating RWX memory.
1651 dnl Make sure we aren't attempting to configure for an unknown system
1652 if test "$llvm_cv_platform_type" = "Unix" ; then
1653   AC_FUNC_MMAP
1654   AC_FUNC_MMAP_FILE
1655   AC_NEED_DEV_ZERO_FOR_MMAP
1656
1657   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1658   then
1659     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1660   fi
1661   if test "$ac_cv_func_mmap_file" = "no"
1662   then
1663     AC_MSG_WARN([mmap() of files required but not found])
1664   fi
1665 fi
1666
1667 dnl atomic builtins are required for threading support.
1668 AC_MSG_CHECKING(for GCC atomic builtins)
1669 dnl Since we'll be using these atomic builtins in C++ files we should test
1670 dnl the C++ compiler.
1671 AC_LANG_PUSH([C++])
1672 AC_LINK_IFELSE(
1673 [
1674   AC_LANG_SOURCE([[
1675     int main() {
1676       volatile unsigned long val = 1;
1677       __sync_synchronize();
1678       __sync_val_compare_and_swap(&val, 1, 0);
1679       __sync_add_and_fetch(&val, 1);
1680       __sync_sub_and_fetch(&val, 1);
1681       return 0;
1682     }
1683   ]])
1684 ],
1685 [
1686   AC_MSG_RESULT([yes])
1687   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1688 ],
1689 [
1690   AC_MSG_RESULT([no])
1691   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1692   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1693 ])
1694 AC_LANG_POP([C++])
1695
1696 dnl===-----------------------------------------------------------------------===
1697 dnl===
1698 dnl=== SECTION 9: Additional checks, variables, etc.
1699 dnl===
1700 dnl===-----------------------------------------------------------------------===
1701
1702 dnl Handle 32-bit linux systems running a 64-bit kernel.
1703 dnl This has to come after section 4 because it invokes the compiler.
1704 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1705   AC_IS_LINUX_MIXED
1706   if test "$llvm_cv_linux_mixed" = "yes"; then
1707     llvm_cv_target_arch="x86"
1708     ARCH="x86"
1709   fi
1710 fi
1711
1712 dnl Check whether __dso_handle is present
1713 AC_CHECK_FUNCS([__dso_handle])
1714
1715 dnl Propagate the shared library extension that the libltdl checks did to
1716 dnl the Makefiles so we can use it there too
1717 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1718
1719 dnl Propagate the run-time library path variable that the libltdl
1720 dnl checks found to the Makefiles so we can use it there too
1721 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1722
1723 dnl Translate the various configuration directories and other basic
1724 dnl information into substitutions that will end up in Makefile.config.in
1725 dnl that these configured values can be used by the makefiles
1726 if test "${prefix}" = "NONE" ; then
1727   prefix="/usr/local"
1728 fi
1729 eval LLVM_PREFIX="${prefix}";
1730 eval LLVM_BINDIR="${prefix}/bin";
1731 eval LLVM_LIBDIR="${prefix}/lib";
1732 eval LLVM_DATADIR="${prefix}/share/llvm";
1733 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1734 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1735 eval LLVM_INCLUDEDIR="${prefix}/include";
1736 eval LLVM_INFODIR="${prefix}/info";
1737 eval LLVM_MANDIR="${prefix}/man";
1738 LLVM_CONFIGTIME=`date`
1739 AC_SUBST(LLVM_PREFIX)
1740 AC_SUBST(LLVM_BINDIR)
1741 AC_SUBST(LLVM_LIBDIR)
1742 AC_SUBST(LLVM_DATADIR)
1743 AC_SUBST(LLVM_DOCSDIR)
1744 AC_SUBST(LLVM_ETCDIR)
1745 AC_SUBST(LLVM_INCLUDEDIR)
1746 AC_SUBST(LLVM_INFODIR)
1747 AC_SUBST(LLVM_MANDIR)
1748 AC_SUBST(LLVM_CONFIGTIME)
1749
1750 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1751 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1752   LLVM_CONFIGTIME="(timestamp not enabled)"
1753 fi
1754
1755 dnl Place the various directories into the config.h file as #defines so that we
1756 dnl can know about the installation paths within LLVM.
1757 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1758                    [Installation prefix directory])
1759 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1760                    [Installation directory for binary executables])
1761 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1762                    [Installation directory for libraries])
1763 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1764                    [Installation directory for data files])
1765 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1766                    [Installation directory for documentation])
1767 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1768                    [Installation directory for config files])
1769 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1770                    [Installation directory for include files])
1771 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1772                    [Installation directory for .info files])
1773 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1774                    [Installation directory for man pages])
1775 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1776                    [Time at which LLVM was configured])
1777 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1778                    [Host triple LLVM will be executed on])
1779 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1780                    [Target triple LLVM will generate code for by default])
1781
1782 dnl Determine which bindings to build.
1783 if test "$BINDINGS_TO_BUILD" = auto ; then
1784   BINDINGS_TO_BUILD=""
1785   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1786     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1787   fi
1788 fi
1789 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1790
1791 dnl This isn't really configurey, but it avoids having to repeat the list in
1792 dnl other files.
1793 AC_SUBST(ALL_BINDINGS,ocaml)
1794
1795 dnl Do any work necessary to ensure that bindings have what they need.
1796 binding_prereqs_failed=0
1797 for a_binding in $BINDINGS_TO_BUILD ; do
1798   case "$a_binding" in
1799   ocaml)
1800     if test "x$OCAMLC" = x ; then
1801       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1802       binding_prereqs_failed=1
1803     fi
1804     if test "x$OCAMLDEP" = x ; then
1805       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1806       binding_prereqs_failed=1
1807     fi
1808     if test "x$OCAMLOPT" = x ; then
1809       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1810       dnl ocamlopt is optional!
1811     fi
1812     if test "x$with_ocaml_libdir" != xauto ; then
1813       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1814     else
1815       ocaml_stdlib="`"$OCAMLC" -where`"
1816       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1817       then
1818         # ocaml stdlib is beneath our prefix; use stdlib
1819         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1820       else
1821         # ocaml stdlib is outside our prefix; use libdir/ocaml
1822         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1823       fi
1824     fi
1825     ;;
1826   esac
1827 done
1828 if test "$binding_prereqs_failed" = 1 ; then
1829   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1830 fi
1831
1832 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1833 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1834
1835 dnl Determine linker rpath flag
1836 if test "$llvm_cv_link_use_r" = "yes" ; then
1837   RPATH="-Wl,-R"
1838 else
1839   RPATH="-Wl,-rpath"
1840 fi
1841 AC_SUBST(RPATH)
1842
1843 dnl Determine linker rdynamic flag
1844 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1845   RDYNAMIC="-Wl,-export-dynamic"
1846 else
1847   RDYNAMIC=""
1848 fi
1849 AC_SUBST(RDYNAMIC)
1850
1851 dnl===-----------------------------------------------------------------------===
1852 dnl===
1853 dnl=== SECTION 10: Specify the output files and generate it
1854 dnl===
1855 dnl===-----------------------------------------------------------------------===
1856
1857 dnl Configure header files
1858 dnl WARNING: dnl If you add or remove any of the following config headers, then
1859 dnl you MUST also update Makefile so that the variable FilesToConfig
1860 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1861 dnl files can be updated automatically when their *.in sources change.
1862 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1863 AH_TOP([#ifndef CONFIG_H
1864 #define CONFIG_H])
1865 AH_BOTTOM([#endif])
1866
1867 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1868 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1869 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1870 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1871 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1872
1873 dnl Configure the makefile's configuration data
1874 AC_CONFIG_FILES([Makefile.config])
1875
1876 dnl Configure the RPM spec file for LLVM
1877 AC_CONFIG_FILES([llvm.spec])
1878
1879 dnl Configure doxygen's configuration file
1880 AC_CONFIG_FILES([docs/doxygen.cfg])
1881
1882 dnl Configure clang, if present
1883 if test "${clang_src_root}" = ""; then
1884   clang_src_root="$srcdir/tools/clang"
1885 fi
1886 if test -f ${clang_src_root}/README.txt; then
1887   dnl Use variables to stay under 80 columns.
1888   configh="include/clang/Config/config.h"
1889   doxy="docs/doxygen.cfg"
1890   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1891   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1892 fi
1893
1894 dnl OCaml findlib META file
1895 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1896
1897 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1898 test "x$program_prefix" = "xNONE" && program_prefix=""
1899 AC_SUBST([program_prefix])
1900
1901
1902 dnl Do special configuration of Makefiles
1903 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1904 AC_CONFIG_MAKEFILE(Makefile)
1905 AC_CONFIG_MAKEFILE(Makefile.common)
1906 AC_CONFIG_MAKEFILE(examples/Makefile)
1907 AC_CONFIG_MAKEFILE(lib/Makefile)
1908 AC_CONFIG_MAKEFILE(runtime/Makefile)
1909 AC_CONFIG_MAKEFILE(test/Makefile)
1910 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1911 AC_CONFIG_MAKEFILE(unittests/Makefile)
1912 AC_CONFIG_MAKEFILE(tools/Makefile)
1913 AC_CONFIG_MAKEFILE(utils/Makefile)
1914 AC_CONFIG_MAKEFILE(projects/Makefile)
1915 AC_CONFIG_MAKEFILE(bindings/Makefile)
1916 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1917
1918 dnl Finally, crank out the output
1919 AC_OUTPUT