autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-cygwin*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="Cygwin"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-darwin*)
 115     llvm_cv_link_all_option="-Wl,-all_load"
 116     llvm_cv_link_all_option="-Wl,-noall_load"
 117     llvm_cv_os_type="Darwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-freebsd*)
 120     llvm_cv_link_all_option="-Wl,--whole-archive"
 121     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 122     llvm_cv_os_type="FreeBSD"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-openbsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="OpenBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-hpux*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="HP-UX"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-interix*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="Interix"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-linux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="Linux"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-solaris*)
 145     llvm_cv_link_all_option="-Wl,-z,allextract"
 146     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 147     llvm_cv_os_type="SunOS"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-win32*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Win32"
 153     llvm_cv_platform_type="Win32" ;;
 154   *-*-mingw*)
 155     llvm_cv_link_all_option="-Wl,--whole-archive"
 156     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 157     llvm_cv_os_type="MingW"
 158     llvm_cv_platform_type="Win32" ;;
 159   *)
 160     llvm_cv_link_all_option=""
 161     llvm_cv_no_link_all_option=""
 162     llvm_cv_os_type="Unknown"
 163     llvm_cv_platform_type="Unknown" ;;
 164 esac])
 165
 166 dnl Make sure we aren't attempting to configure for an unknown system
 167 if test "$llvm_cv_os_type" = "Unknown" ; then
 168   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 169 fi
 170
 171 dnl Set the "OS" Makefile variable based on the platform type so the
 172 dnl makefile can configure itself to specific build hosts
 173 AC_SUBST(OS,$llvm_cv_os_type)
 174
 175 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 176 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 177 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 178
 179 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 180 dnl This is used by lib/System to determine the basic kind of implementation
 181 dnl to use.
 182 case $llvm_cv_platform_type in
 183   Unix)
 184     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 185     AC_SUBST(LLVM_ON_UNIX,[1])
 186     AC_SUBST(LLVM_ON_WIN32,[0])
 187     ;;
 188   Win32)
 189     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 190     AC_SUBST(LLVM_ON_UNIX,[0])
 191     AC_SUBST(LLVM_ON_WIN32,[1])
 192     ;;
 193 esac
 194
 195 dnl Determine what our target architecture is and configure accordingly.
 196 dnl This will allow Makefiles to make a distinction between the hardware and
 197 dnl the OS.
 198 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 199 [case $target in
 200   i?86-*)                 llvm_cv_target_arch="x86" ;;
 201   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 202   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 203   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 204   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 205   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 206   *)                      llvm_cv_target_arch="Unknown" ;;
 207 esac])
 208
 209 if test "$llvm_cv_target_arch" = "Unknown" ; then
 210   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 211 fi
 212
 213 dnl Define a substitution, ARCH, for the target architecture
 214 AC_SUBST(ARCH,$llvm_cv_target_arch)
 215
 216 dnl Check for the endianness of the target
 217 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 218
 219 dnl Check for build platform executable suffix if we're crosscompiling
 220 if test "$cross_compiling" = yes; then
 221   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 222   AC_BUILD_EXEEXT
 223 else
 224   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 225 fi
 226
 227 dnl Check to see if there's a "CVS" directory indicating that this build is
 228 dnl being done from a CVS checkout. This sets up several defaults for the
 229 dnl command line switches. When we build with a CVS directory, we get a
 230 dnl debug with assertions turned on. Without, we assume a source release and we
 231 dnl get an optimized build without assertions. See --enable-optimized and
 232 dnl --enable-assertions below
 233 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 234   cvsbuild="yes"
 235   optimize="no"
 236   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 237 else
 238   cvsbuild="no"
 239   optimize="yes"
 240 fi
 241
 242 dnl===-----------------------------------------------------------------------===
 243 dnl===
 244 dnl=== SECTION 3: Command line arguments for the configure script.
 245 dnl===
 246 dnl===-----------------------------------------------------------------------===
 247
 248 dnl --enable-optimized : check whether they want to do an optimized build:
 249 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 250  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 251 if test ${enableval} = "no" ; then
 252   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 253 else
 254   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 255 fi
 256
 257 dnl --enable-assertions : check whether they want to turn on assertions or not:
 258 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 259   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 260 if test ${enableval} = "yes" ; then
 261   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 262 else
 263   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 264 fi
 265
 266 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 267 AC_ARG_ENABLE(debug-runtime,
 268    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 269 if test ${enableval} = "no" ; then
 270   AC_SUBST(DEBUG_RUNTIME,[[]])
 271 else
 272   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 273 fi
 274
 275 dnl --enable-jit: check whether they want to enable the jit
 276 AC_ARG_ENABLE(jit,
 277   AS_HELP_STRING(--enable-jit,
 278                  [Enable Just In Time Compiling (default is YES)]),,
 279   enableval=default)
 280 if test ${enableval} = "no"
 281 then
 282   AC_SUBST(JIT,[[]])
 283 else
 284   case "$llvm_cv_target_arch" in
 285     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 286     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 287     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 288     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 289     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 290     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 291     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 292   esac
 293 fi
 294
 295 dnl Allow enablement of doxygen generated documentation
 296 AC_ARG_ENABLE(doxygen,
 297               AS_HELP_STRING([--enable-doxygen],
 298                              [Build doxygen documentation (default is NO)]),,
 299                              enableval=default)
 300 case "$enableval" in
 301   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 302   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 303   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 304   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 305 esac
 306
 307 dnl Allow disablement of threads
 308 AC_ARG_ENABLE(threads,
 309               AS_HELP_STRING([--enable-threads],
 310                              [Use threads if available (default is YES)]),,
 311                              enableval=yes)
 312 case "$enableval" in
 313   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 314   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 315   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 316 esac
 317 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 318
 319 dnl Allow specific targets to be specified for building (or not)
 320 TARGETS_TO_BUILD=""
 321 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 322     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 323     enableval=all)
 324 case "$enableval" in
 325   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 326   host-only)
 327     case "$llvm_cv_target_arch" in
 328       x86)     TARGETS_TO_BUILD="X86" ;;
 329       x86_64)  TARGETS_TO_BUILD="X86" ;;
 330       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 331       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 332       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 333       IA64)    TARGETS_TO_BUILD="IA64" ;;
 334       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 335     esac
 336     ;;
 337   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 338       case "$a_target" in
 339         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 340         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 341         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 342         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 343         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 344         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 345         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 346       esac
 347   done
 348   ;;
 349 esac
 350 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 351 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 352
 353 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 354 AC_ARG_WITH(llvmgccdir,
 355   AS_HELP_STRING([--with-llvmgccdir],
 356     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 357     withval=default)
 358 case "$withval" in
 359   default) WITH_LLVMGCCDIR=default ;;
 360   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 361   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 362 esac
 363
 364 dnl Specify extra build options
 365 AC_ARG_WITH(extra-options,
 366   AS_HELP_STRING([--with-extra-options],
 367                  [Specify addtional options to compile LLVM with]),,
 368                  withval=default)
 369 case "$withval" in
 370   default) EXTRA_OPTIONS= ;;
 371   *) EXTRA_OPTIONS=$withval ;;
 372 esac
 373 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 374
 375 dnl===-----------------------------------------------------------------------===
 376 dnl===
 377 dnl=== SECTION 4: Check for programs we need and that they are the right version
 378 dnl===
 379 dnl===-----------------------------------------------------------------------===
 380
 381 dnl Check for compilation tools
 382 AC_PROG_CPP
 383 AC_PROG_CC(gcc)
 384 AC_PROG_CXX(g++)
 385 AC_PROG_FLEX
 386 AC_PROG_BISON
 387
 388 AC_PROG_NM
 389 AC_SUBST(NM)
 390
 391 dnl Check for the tools that the makefiles require
 392 AC_CHECK_GNU_MAKE
 393 AC_PROG_LN_S
 394 AC_PATH_PROG(CMP, [cmp], [cmp])
 395 AC_PATH_PROG(CP, [cp], [cp])
 396 AC_PATH_PROG(DATE, [date], [date])
 397 AC_PATH_PROG(FIND, [find], [find])
 398 AC_PATH_PROG(GREP, [grep], [grep])
 399 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 400 AC_PATH_PROG(MV,   [mv],   [mv])
 401 AC_PROG_RANLIB
 402 AC_PATH_PROG(RM,   [rm],   [rm])
 403 AC_PATH_PROG(SED,  [sed],  [sed])
 404 AC_PATH_PROG(TAR,  [tar],  [gtar])
 405 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 406
 407 dnl Looking for misc. graph plotting software
 408 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 409 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 410   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 411   dnl If we're targeting for mingw we should emit windows paths, not msys
 412   if test "$llvm_cv_os_type" == "MingW" ; then
 413     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 414   fi
 415   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 416    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 417 fi
 418 AC_PATH_PROG(DOT, [dot], [echo dot])
 419 if test "$DOT" != "echo dot" ; then
 420   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 421   dnl If we're targeting for mingw we should emit windows paths, not msys
 422   if test "$llvm_cv_os_type" == "MingW" ; then
 423     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 424   fi
 425   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 426    [Define to path to dot program if found or 'echo dot' otherwise])
 427 fi
 428 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 429 if test "$GV" != "echo gv" ; then
 430   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 431   dnl If we're targeting for mingw we should emit windows paths, not msys
 432   if test "$llvm_cv_os_type" == "MingW" ; then
 433     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 434   fi
 435   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 436    [Define to path to gv program if found or 'echo gv' otherwise])
 437 fi
 438 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 439 if test "$DOTTY" != "echo dotty" ; then
 440   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 441   dnl If we're targeting for mingw we should emit windows paths, not msys
 442   if test "$llvm_cv_os_type" == "MingW" ; then
 443     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 444   fi
 445   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 446    [Define to path to dotty program if found or 'echo dotty' otherwise])
 447 fi
 448
 449 dnl Look for a sufficiently recent version of Perl.
 450 LLVM_PROG_PERL([5.006])
 451 AC_SUBST(PERL)
 452 if test x"$PERL" = xnone; then
 453    AC_SUBST(HAVE_PERL,0)
 454 else
 455    AC_SUBST(HAVE_PERL,1)
 456 fi
 457
 458 dnl Find the install program
 459 AC_PROG_INSTALL
 460
 461 dnl Checks for documentation and testing tools that we can do without. If these
 462 dnl are not found then they are set to "true" which always succeeds but does
 463 dnl nothing. This just lets the build output show that we could have done
 464 dnl something if the tool was available.
 465 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 466 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 467 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 468 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 469 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 470 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 471 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 472 DJ_AC_PATH_TCLSH
 473 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 474
 475 dnl Determine if the linker supports the -R option.
 476 AC_LINK_USE_R
 477
 478 dnl Check for libtool and the library that has dlopen function (which must come
 479 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 480 dnl libtool).
 481 AC_LIBTOOL_DLOPEN
 482 AC_LIB_LTDL
 483 AC_PROG_LIBTOOL
 484
 485 if test "$lt_cv_dlopen_self" = "yes" ; then
 486   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 487               [Define if dlopen(0) will open the symbols of the program])
 488 fi
 489
 490 dnl Check if we know how to tell etags we are using C++:
 491 etags_version=`$ETAGS --version 2>&1`
 492 case "$etags_version" in
 493         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 494         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 495         *) ETAGSFLAGS="" ;;
 496 esac
 497 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 498
 499 if test "$WITH_LLVMGCCDIR" = "default" ; then
 500   LLVMGCC="llvm-gcc${EXEEXT}"
 501   LLVMGXX="llvm-g++${EXEEXT}"
 502   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 503   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 504 else
 505   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 506   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 507   AC_SUBST(LLVMGCC,$LLVMGCC)
 508   AC_SUBST(LLVMGXX,$LLVMGXX)
 509 fi
 510
 511 AC_MSG_CHECKING([tool compatibility])
 512
 513 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 514 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 515 dnl to support those options.
 516 dnl "icc" emits gcc signatures
 517 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 518 ICC=no
 519 IXX=no
 520 case $CC in
 521   icc*|icpc*)
 522     ICC=yes
 523     IXX=yes
 524     ;;
 525    *)
 526     ;;
 527 esac
 528
 529 if test "$GCC" != "yes" && test "$ICC" != "yes"
 530 then
 531   AC_MSG_ERROR([gcc|icc required but not found])
 532 fi
 533
 534 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 535 if test "$GXX" != "yes" && test "$IXX" != "yes"
 536 then
 537   AC_MSG_ERROR([g++|icc required but not found])
 538 fi
 539
 540 dnl Verify that GCC is version 3.0 or higher
 541 if test "$GCC" = "yes"
 542 then
 543   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 544   if test "$gccmajor" -lt "3"
 545   then
 546     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 547   fi
 548 fi
 549
 550 dnl Check for GNU Make.  We use its extensions, so don't build without it
 551 if test -z "$llvm_cv_gnu_make_command"
 552 then
 553   AC_MSG_ERROR([GNU Make required but not found])
 554 fi
 555
 556 dnl Tool compatibility is okay if we make it here.
 557 AC_MSG_RESULT([ok])
 558
 559 dnl===-----------------------------------------------------------------------===
 560 dnl===
 561 dnl=== SECTION 5: Check for libraries
 562 dnl===
 563 dnl===-----------------------------------------------------------------------===
 564
 565 dnl libelf is for sparc only; we can ignore it if we don't have it
 566 AC_CHECK_LIB(elf, elf_begin)
 567 AC_CHECK_LIB(m,sin)
 568 if test "$llvm_cv_os_type" == "MingW" ; then
 569   AC_CHECK_LIB(imagehlp, main)
 570   AC_CHECK_LIB(psapi, main)
 571 fi
 572
 573 dnl lt_dlopen may be required for plugin support.
 574 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 575               [Define if lt_dlopen() is available on this platform]),
 576               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 577                            not be available]))
 578
 579 dnl dlopen() is required for plugin support.
 580 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 581                [Define if dlopen() is available on this platform.]),
 582                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 583
 584 dnl mallinfo is optional; the code can compile (minus features) without it
 585 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 586                [Define if mallinfo() is available on this platform.]))
 587
 588 dnl pthread locking functions are optional - but llvm will not be thread-safe
 589 dnl without locks.
 590 if test "$ENABLE_THREADS" -eq 1 ; then
 591   AC_CHECK_LIB(pthread,pthread_mutex_init)
 592   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 593                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 594                            [Have pthread_mutex_lock]))
 595 fi
 596
 597 dnl===-----------------------------------------------------------------------===
 598 dnl===
 599 dnl=== SECTION 6: Check for header files
 600 dnl===
 601 dnl===-----------------------------------------------------------------------===
 602
 603 dnl First, use autoconf provided macros for specific headers that we need
 604 dnl We don't check for ancient stuff or things that are guaranteed to be there
 605 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 606 dnl Generally we're looking for POSIX headers.
 607 AC_HEADER_DIRENT
 608 AC_HEADER_MMAP_ANONYMOUS
 609 AC_HEADER_STAT
 610 AC_HEADER_STDC
 611 AC_HEADER_SYS_WAIT
 612 AC_HEADER_TIME
 613
 614 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 615 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 616 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 617 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h])
 618 if test "$ENABLE_THREADS" -eq 1 ; then
 619   AC_CHECK_HEADERS(pthread.h)
 620 fi
 621
 622 dnl===-----------------------------------------------------------------------===
 623 dnl===
 624 dnl=== SECTION 7: Check for types and structures
 625 dnl===
 626 dnl===-----------------------------------------------------------------------===
 627
 628 AC_TYPE_PID_T
 629 AC_TYPE_SIZE_T
 630 AC_TYPE_SIGNAL
 631 AC_STRUCT_TM
 632 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 633 AC_CHECK_TYPES([uint64_t],,
 634          AC_CHECK_TYPES([u_int64_t],,
 635          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 636
 637 dnl===-----------------------------------------------------------------------===
 638 dnl===
 639 dnl=== SECTION 8: Check for specific functions needed
 640 dnl===
 641 dnl===-----------------------------------------------------------------------===
 642
 643 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 644 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 645 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 646 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 647 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 648 AC_C_PRINTF_A
 649 AC_FUNC_ALLOCA
 650 AC_FUNC_RAND48
 651
 652 dnl Check for variations in the Standard C++ library and STL. These macros are
 653 dnl provided by LLVM in the autoconf/m4 directory.
 654 AC_CXX_HAVE_HASH_MAP
 655 AC_CXX_HAVE_HASH_SET
 656 AC_CXX_HAVE_STD_ITERATOR
 657 AC_CXX_HAVE_BI_ITERATOR
 658 AC_CXX_HAVE_FWD_ITERATOR
 659 AC_FUNC_ISNAN
 660 AC_FUNC_ISINF
 661
 662 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 663 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 664 dnl be opened for allocating RWX memory.
 665 AC_FUNC_MMAP
 666 AC_FUNC_MMAP_FILE
 667 AC_NEED_DEV_ZERO_FOR_MMAP
 668 AC_CHECK_FUNC(mprotect,,
 669               AC_MSG_ERROR([Function mprotect() required but not found]))
 670
 671 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 672 then
 673   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 674 fi
 675 if test "$ac_cv_func_mmap_file" = "no"
 676 then
 677   AC_MSG_WARN([mmap() of files required but not found])
 678 fi
 679
 680 dnl===-----------------------------------------------------------------------===
 681 dnl===
 682 dnl=== SECTION 9: Additional checks, variables, etc.
 683 dnl===
 684 dnl===-----------------------------------------------------------------------===
 685
 686 dnl See if the llvm-gcc executable can compile to LLVM assembly
 687 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 688 [llvm_cv_llvmgcc_sanity="no"
 689 if test -x "$LLVMGCC" ; then
 690   cp /dev/null conftest.c
 691   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 692   if test $? -eq 0 ; then
 693     llvm_cv_llvmgcc_sanity="yes"
 694   fi
 695   rm conftest.c
 696 fi])
 697
 698 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 699 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 700   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 701   AC_SUBST(LLVMCC1,$llvmcc1path)
 702   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 703   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 704   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 705   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 706   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 707   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 708   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 709   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 710 fi
 711
 712 dnl Propagate the shared library extension that the libltdl checks did to
 713 dnl the Makefiles so we can use it there too
 714 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 715
 716 # Translate the various configuration directories and other basic
 717 # information into substitutions that will end up in Makefile.config.in
 718 # that these configured values can be used by the makefiles
 719 if test "${prefix}" == "NONE" ; then
 720   prefix="/usr/local"
 721 fi
 722 eval LLVM_PREFIX="${prefix}";
 723 eval LLVM_BINDIR="${prefix}/bin";
 724 eval LLVM_LIBDIR="${prefix}/lib";
 725 eval LLVM_DATADIR="${prefix}/share/llvm";
 726 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 727 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 728 eval LLVM_INCLUDEDIR="${prefix}/include";
 729 eval LLVM_INFODIR="${prefix}/info";
 730 eval LLVM_MANDIR="${prefix}/man";
 731 LLVM_CONFIGTIME=`date`
 732 AC_SUBST(LLVM_PREFIX)
 733 AC_SUBST(LLVM_BINDIR)
 734 AC_SUBST(LLVM_LIBDIR)
 735 AC_SUBST(LLVM_DATADIR)
 736 AC_SUBST(LLVM_DOCSDIR)
 737 AC_SUBST(LLVM_ETCDIR)
 738 AC_SUBST(LLVM_INCLUDEDIR)
 739 AC_SUBST(LLVM_INFODIR)
 740 AC_SUBST(LLVM_MANDIR)
 741 AC_SUBST(LLVM_CONFIGTIME)
 742
 743 # Place the various directores into the config.h file as #defines so that we
 744 # can know about the installation paths within LLVM.
 745 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 746                    [Installation prefix directory])
 747 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 748                    [Installation directory for binary executables])
 749 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 750                    [Installation directory for libraries])
 751 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 752                    [Installation directory for data files])
 753 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 754                    [Installation directory for documentation])
 755 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 756                    [Installation directory for config files])
 757 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 758                    [Installation directory for include files])
 759 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 760                    [Installation directory for .info files])
 761 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 762                    [Installation directory for man pages])
 763 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 764                    [Time at which LLVM was configured])
 765
 766 dnl===-----------------------------------------------------------------------===
 767 dnl===
 768 dnl=== SECTION 10: Specify the output files and generate it
 769 dnl===
 770 dnl===-----------------------------------------------------------------------===
 771
 772 dnl Configure header files
 773 dnl WARNING: dnl If you add or remove any of the following config headers, then
 774 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 775 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 776 dnl files can be updated automatically when their *.in sources change.
 777 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 778 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 779 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 780 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 781 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 782
 783 dnl Configure the makefile's configuration data
 784 AC_CONFIG_FILES([Makefile.config])
 785
 786 dnl Configure the RPM spec file for LLVM
 787 AC_CONFIG_FILES([llvm.spec])
 788
 789 dnl Configure doxygen's configuration file
 790 AC_CONFIG_FILES([docs/doxygen.cfg])
 791
 792 dnl Do the first stage of configuration for llvm-config.in.
 793 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 794
 795 dnl Do special configuration of Makefiles
 796 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 797 AC_CONFIG_MAKEFILE(Makefile)
 798 AC_CONFIG_MAKEFILE(Makefile.common)
 799 AC_CONFIG_MAKEFILE(examples/Makefile)
 800 AC_CONFIG_MAKEFILE(lib/Makefile)
 801 AC_CONFIG_MAKEFILE(runtime/Makefile)
 802 AC_CONFIG_MAKEFILE(test/Makefile)
 803 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 804 AC_CONFIG_MAKEFILE(tools/Makefile)
 805 AC_CONFIG_MAKEFILE(utils/Makefile)
 806 AC_CONFIG_MAKEFILE(projects/Makefile)
 807
 808 dnl Finally, crank out the output
 809 AC_OUTPUT
 810
 811 dnl Warn loudly if llvm-gcc was not obviously working
 812 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 813  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 814  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 815  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 816  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 817  AC_MSG_WARN([***** build the llvm tools.])
 818 fi