autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.4svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [4], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd* | *-*-kfreebsd-gnu)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-openbsd*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="OpenBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-netbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="NetBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-dragonfly*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="DragonFly"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-hpux*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="HP-UX"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-interix*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="Interix"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-linux*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Linux"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-gnu*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="GNU"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-solaris*)
 266     llvm_cv_link_all_option="-Wl,-z,allextract"
 267     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 268     llvm_cv_os_type="SunOS"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-auroraux*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="AuroraUX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-win32*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Win32"
 279     llvm_cv_platform_type="Win32" ;;
 280   *-*-mingw*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="MingW"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-haiku*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Haiku"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-unknown-eabi*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Freestanding"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-elf*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *)
 301     llvm_cv_link_all_option=""
 302     llvm_cv_no_link_all_option=""
 303     llvm_cv_os_type="Unknown"
 304     llvm_cv_platform_type="Unknown" ;;
 305 esac])
 306
 307 AC_CACHE_CHECK([type of operating system we're going to target],
 308                [llvm_cv_target_os_type],
 309 [case $target in
 310   *-*-aix*)
 311     llvm_cv_target_os_type="AIX" ;;
 312   *-*-irix*)
 313     llvm_cv_target_os_type="IRIX" ;;
 314   *-*-cygwin*)
 315     llvm_cv_target_os_type="Cygwin" ;;
 316   *-*-darwin*)
 317     llvm_cv_target_os_type="Darwin" ;;
 318   *-*-minix*)
 319     llvm_cv_target_os_type="Minix" ;;
 320   *-*-freebsd* | *-*-kfreebsd-gnu)
 321     llvm_cv_target_os_type="FreeBSD" ;;
 322   *-*-openbsd*)
 323     llvm_cv_target_os_type="OpenBSD" ;;
 324   *-*-netbsd*)
 325     llvm_cv_target_os_type="NetBSD" ;;
 326   *-*-dragonfly*)
 327     llvm_cv_target_os_type="DragonFly" ;;
 328   *-*-hpux*)
 329     llvm_cv_target_os_type="HP-UX" ;;
 330   *-*-interix*)
 331     llvm_cv_target_os_type="Interix" ;;
 332   *-*-linux*)
 333     llvm_cv_target_os_type="Linux" ;;
 334   *-*-gnu*)
 335     llvm_cv_target_os_type="GNU" ;;
 336   *-*-solaris*)
 337     llvm_cv_target_os_type="SunOS" ;;
 338   *-*-auroraux*)
 339     llvm_cv_target_os_type="AuroraUX" ;;
 340   *-*-win32*)
 341     llvm_cv_target_os_type="Win32" ;;
 342   *-*-mingw*)
 343     llvm_cv_target_os_type="MingW" ;;
 344   *-*-haiku*)
 345     llvm_cv_target_os_type="Haiku" ;;
 346   *-*-rtems*)
 347     llvm_cv_target_os_type="RTEMS" ;;
 348   *-*-nacl*)
 349     llvm_cv_target_os_type="NativeClient" ;;
 350   *-unknown-eabi*)
 351     llvm_cv_target_os_type="Freestanding" ;;
 352   *)
 353     llvm_cv_target_os_type="Unknown" ;;
 354 esac])
 355
 356 dnl Make sure we aren't attempting to configure for an unknown system
 357 if test "$llvm_cv_os_type" = "Unknown" ; then
 358   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 359 fi
 360
 361 dnl Set the "OS" Makefile variable based on the platform type so the
 362 dnl makefile can configure itself to specific build hosts
 363 AC_SUBST(OS,$llvm_cv_os_type)
 364 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 365 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 366
 367 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 368 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 369 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 370
 371 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 372 dnl This is used by lib/Support to determine the basic kind of implementation
 373 dnl to use.
 374 case $llvm_cv_platform_type in
 375   Unix)
 376     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 377     AC_SUBST(LLVM_ON_UNIX,[1])
 378     AC_SUBST(LLVM_ON_WIN32,[0])
 379     ;;
 380   Win32)
 381     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 382     AC_SUBST(LLVM_ON_UNIX,[0])
 383     AC_SUBST(LLVM_ON_WIN32,[1])
 384     ;;
 385 esac
 386
 387 dnl Determine what our target architecture is and configure accordingly.
 388 dnl This will allow Makefiles to make a distinction between the hardware and
 389 dnl the OS.
 390 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 391 [case $target in
 392   i?86-*)                 llvm_cv_target_arch="x86" ;;
 393   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 394   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 395   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 396   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 397   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 398   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 399   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 400   xcore-*)                llvm_cv_target_arch="XCore" ;;
 401   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 402   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 403   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 404   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 405   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 406   *)                      llvm_cv_target_arch="Unknown" ;;
 407 esac])
 408
 409 if test "$llvm_cv_target_arch" = "Unknown" ; then
 410   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 411 fi
 412
 413 dnl Determine the LLVM native architecture for the target
 414 case "$llvm_cv_target_arch" in
 415     x86)     LLVM_NATIVE_ARCH="X86" ;;
 416     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 417     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 418 esac
 419
 420 dnl Define a substitution, ARCH, for the target architecture
 421 AC_SUBST(ARCH,$llvm_cv_target_arch)
 422
 423 dnl Determine what our host architecture.
 424 dnl This will allow MCJIT regress tests runs only for supported
 425 dnl platforms.
 426 case $host in
 427   i?86-*)                 host_arch="x86" ;;
 428   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 429   sparc*-*)               host_arch="Sparc" ;;
 430   powerpc*-*)             host_arch="PowerPC" ;;
 431   arm*-*)                 host_arch="ARM" ;;
 432   aarch64*-*)             host_arch="AArch64" ;;
 433   mips-* | mips64-*)      host_arch="Mips" ;;
 434   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 435   xcore-*)                host_arch="XCore" ;;
 436   msp430-*)               host_arch="MSP430" ;;
 437   hexagon-*)              host_arch="Hexagon" ;;
 438   mblaze-*)               host_arch="MBlaze" ;;
 439   s390x-*)                host_arch="SystemZ" ;;
 440   *)                      host_arch="Unknown" ;;
 441 esac
 442
 443 if test "$host_arch" = "Unknown" ; then
 444   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 445 fi
 446
 447 AC_SUBST(HOST_ARCH,$host_arch)
 448
 449 dnl Check for the endianness of the target
 450 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 451
 452 dnl Check for build platform executable suffix if we're cross-compiling
 453 if test "$cross_compiling" = yes; then
 454   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 455   AC_BUILD_EXEEXT
 456   ac_build_prefix=${build_alias}-
 457   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 458   if test -z "$BUILD_CXX"; then
 459      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 460      if test -z "$BUILD_CXX"; then
 461        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 462      fi
 463   fi
 464 else
 465   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 466 fi
 467
 468 dnl Check to see if there's a .svn or .git directory indicating that this
 469 dnl build is being done from a checkout. This sets up several defaults for
 470 dnl the command line switches. When we build with a checkout directory,
 471 dnl we get a debug with assertions turned on. Without, we assume a source
 472 dnl release and we get an optimized build without assertions.
 473 dnl See --enable-optimized and --enable-assertions below
 474 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 475   cvsbuild="yes"
 476   optimize="no"
 477   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 478 else
 479   cvsbuild="no"
 480   optimize="yes"
 481 fi
 482
 483 dnl===-----------------------------------------------------------------------===
 484 dnl===
 485 dnl=== SECTION 3: Command line arguments for the configure script.
 486 dnl===
 487 dnl===-----------------------------------------------------------------------===
 488
 489 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 490 AC_ARG_ENABLE(libcpp,
 491               AS_HELP_STRING([--enable-libcpp],
 492                              [Use libc++ if available (default is NO)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 496   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 497   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 499 esac
 500
 501 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 502 AC_ARG_ENABLE(cxx11,
 503               AS_HELP_STRING([--enable-cxx11],
 504                              [Use c++11 if available (default is NO)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 508   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 509   default) AC_SUBST(ENABLE_CXX11,[0]);;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 514 clang_arcmt="yes"
 515 AC_ARG_ENABLE(clang-arcmt,
 516               AS_HELP_STRING([--enable-clang-arcmt],
 517                              [Enable building of clang ARCMT (default is YES)]),
 518                              clang_arcmt="$enableval",
 519                              enableval="yes")
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 522   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 523   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 528 clang_static_analyzer="yes"
 529 AC_ARG_ENABLE(clang-static-analyzer,
 530               AS_HELP_STRING([--enable-clang-static-analyzer],
 531                              [Enable building of clang Static Analyzer (default is YES)]),
 532                              clang_static_analyzer="$enableval",
 533                              enableval="yes")
 534 case "$enableval" in
 535   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 536   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 537   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 538   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 539 esac
 540
 541 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 542 AC_ARG_ENABLE(clang-rewriter,
 543               AS_HELP_STRING([--enable-clang-rewriter],
 544                              [Enable building of clang rewriter (default is YES)]),,
 545                              enableval="yes")
 546 case "$enableval" in
 547   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 548   no)
 549     if test ${clang_arcmt} != "no" ; then
 550       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 551     fi
 552     if test ${clang_static_analyzer} != "no" ; then
 553       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 554     fi
 555     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 556     ;;
 557   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 558   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 559 esac
 560
 561 dnl --enable-optimized : check whether they want to do an optimized build:
 562 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 563  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 564 if test ${enableval} = "no" ; then
 565   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 566 else
 567   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 568 fi
 569
 570 dnl --enable-profiling : check whether they want to do a profile build:
 571 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 572  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 573 if test ${enableval} = "no" ; then
 574   AC_SUBST(ENABLE_PROFILING,[[]])
 575 else
 576   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 577 fi
 578
 579 dnl --enable-assertions : check whether they want to turn on assertions or not:
 580 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 581   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 582 if test ${enableval} = "yes" ; then
 583   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 584 else
 585   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 586 fi
 587
 588 dnl --enable-werror : check whether we want Werror on by default
 589 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 590   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 593   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 594   default) AC_SUBST(ENABLE_WERROR,[0]);;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 599 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 600   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 601 if test ${enableval} = "yes" ; then
 602   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 603   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 604 else
 605   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 606   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 607 fi
 608
 609 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 610 AC_ARG_ENABLE(debug-runtime,
 611    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 612 if test ${enableval} = "no" ; then
 613   AC_SUBST(DEBUG_RUNTIME,[[]])
 614 else
 615   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 616 fi
 617
 618 dnl --enable-debug-symbols : should even optimized compiler libraries
 619 dnl have debug symbols?
 620 AC_ARG_ENABLE(debug-symbols,
 621    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 622 if test ${enableval} = "no" ; then
 623   AC_SUBST(DEBUG_SYMBOLS,[[]])
 624 else
 625   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 626 fi
 627
 628 dnl --enable-keep-symbols : do not strip installed executables
 629 AC_ARG_ENABLE(keep-symbols,
 630    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 631 if test ${enableval} = "no" ; then
 632   AC_SUBST(KEEP_SYMBOLS,[[]])
 633 else
 634   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 635 fi
 636
 637 dnl --enable-jit: check whether they want to enable the jit
 638 AC_ARG_ENABLE(jit,
 639   AS_HELP_STRING(--enable-jit,
 640                  [Enable Just In Time Compiling (default is YES)]),,
 641   enableval=default)
 642 if test ${enableval} = "no"
 643 then
 644   AC_SUBST(JIT,[[]])
 645 else
 646   case "$llvm_cv_target_arch" in
 647     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 648     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 649     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 650     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 651     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 652     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 653     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 654     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 655     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 656     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 657     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 658     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 659     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 660     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 661   esac
 662 fi
 663
 664 dnl Allow enablement of building and installing docs
 665 AC_ARG_ENABLE(docs,
 666               AS_HELP_STRING([--enable-docs],
 667                              [Build documents (default is YES)]),,
 668                              enableval=default)
 669 case "$enableval" in
 670   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 671   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 672   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 673   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 674 esac
 675
 676 dnl Allow enablement of doxygen generated documentation
 677 AC_ARG_ENABLE(doxygen,
 678               AS_HELP_STRING([--enable-doxygen],
 679                              [Build doxygen documentation (default is NO)]),,
 680                              enableval=default)
 681 case "$enableval" in
 682   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 683   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 684   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 685   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 686 esac
 687
 688 dnl Allow disablement of threads
 689 AC_ARG_ENABLE(threads,
 690               AS_HELP_STRING([--enable-threads],
 691                              [Use threads if available (default is YES)]),,
 692                              enableval=default)
 693 case "$enableval" in
 694   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 695   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 696   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 697   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 698 esac
 699 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 700                    [Define if threads enabled])
 701
 702 dnl Allow disablement of pthread.h
 703 AC_ARG_ENABLE(pthreads,
 704               AS_HELP_STRING([--enable-pthreads],
 705                              [Use pthreads if available (default is YES)]),,
 706                              enableval=default)
 707 case "$enableval" in
 708   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 709   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 710   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 711   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 712 esac
 713
 714 dnl Allow disablement of zlib
 715 AC_ARG_ENABLE(zlib,
 716               AS_HELP_STRING([--enable-zlib],
 717                              [Use zlib for compression/decompression if
 718                               available (default is YES)]),,
 719                               enableval=default)
 720 case "$enableval" in
 721   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 722   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 723   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 724   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 725 esac
 726 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 727                    [Define if zlib is enabled])
 728
 729 dnl Allow building without position independent code
 730 AC_ARG_ENABLE(pic,
 731   AS_HELP_STRING([--enable-pic],
 732                  [Build LLVM with Position Independent Code (default is YES)]),,
 733                  enableval=default)
 734 case "$enableval" in
 735   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 736   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 737   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 738   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 739 esac
 740 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 741                    [Define if position independent code is enabled])
 742
 743 dnl Allow building a shared library and linking tools against it.
 744 AC_ARG_ENABLE(shared,
 745   AS_HELP_STRING([--enable-shared],
 746                  [Build a shared library and link tools against it (default is NO)]),,
 747                  enableval=default)
 748 case "$enableval" in
 749   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 750   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 751   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 752   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 753 esac
 754
 755 dnl Allow libstdc++ is embedded in LLVM.dll.
 756 AC_ARG_ENABLE(embed-stdcxx,
 757   AS_HELP_STRING([--enable-embed-stdcxx],
 758                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 759                  enableval=default)
 760 case "$enableval" in
 761   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 762   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 763   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 764   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 765 esac
 766
 767 dnl Enable embedding timestamp information into build.
 768 AC_ARG_ENABLE(timestamps,
 769   AS_HELP_STRING([--enable-timestamps],
 770                  [Enable embedding timestamp information in build (default is YES)]),,
 771                  enableval=default)
 772 case "$enableval" in
 773   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 774   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 775   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 776   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 777 esac
 778 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 779                    [Define if timestamp information (e.g., __DATE__) is allowed])
 780
 781 dnl Enable embedding timestamp information into build.
 782
 783 AC_ARG_ENABLE(backtraces,
 784   AS_HELP_STRING([--enable-backtraces],
 785                  [Enable embedding backtraces on crash (default is YES)]),,
 786                  enableval=default)
 787 case "$enableval" in
 788   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 789   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 790   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 791   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 792 esac
 793 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 794                    [Define if you want backtraces on crash])
 795
 796 dnl Allow specific targets to be specified for building (or not)
 797 TARGETS_TO_BUILD=""
 798 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 799     [Build specific host targets: all or target1,target2,... Valid targets are:
 800      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 801      xcore, msp430, nvptx, systemz, and cpp (default=all)]),,
 802     enableval=all)
 803 if test "$enableval" = host-only ; then
 804   enableval=host
 805 fi
 806 case "$enableval" in
 807   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend MBlaze NVPTX Hexagon SystemZ" ;;
 808   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 809       case "$a_target" in
 810         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 811         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 812         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 813         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 814         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 815         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 816         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 817         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 818         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 819         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 820         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 821         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 822         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 823         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 824         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 825         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 826         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 827         host) case "$llvm_cv_target_arch" in
 828             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 829             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 830             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 831             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 832             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 833             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 834             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 835             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 836             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 837             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 838             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 839             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 840             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 841             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 842           esac ;;
 843         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 844       esac
 845   done
 846   ;;
 847 esac
 848
 849 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 850     [Build experimental host targets: disable or target1,target2,...
 851      (default=disable)]),,
 852     enableval=disable)
 853
 854 if test ${enableval} != "disable"
 855 then
 856   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 857 fi
 858
 859 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 860
 861 dnl Determine whether we are building LLVM support for the native architecture.
 862 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 863 for a_target in $TARGETS_TO_BUILD; do
 864   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 865     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 866       [LLVM architecture name for the native architecture, if available])
 867     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 868     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 869     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 870     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 871     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 872       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 873     fi
 874     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 875       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 876     fi
 877     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 878       [LLVM name for the native Target init function, if available])
 879     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 880       [LLVM name for the native TargetInfo init function, if available])
 881     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 882       [LLVM name for the native target MC init function, if available])
 883     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 884       [LLVM name for the native AsmPrinter init function, if available])
 885     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 886       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 887        [LLVM name for the native AsmParser init function, if available])
 888     fi
 889     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 890       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 891        [LLVM name for the native Disassembler init function, if available])
 892     fi
 893   fi
 894 done
 895
 896 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 897 dnl target feature def files.
 898 LLVM_ENUM_TARGETS=""
 899 LLVM_ENUM_ASM_PRINTERS=""
 900 LLVM_ENUM_ASM_PARSERS=""
 901 LLVM_ENUM_DISASSEMBLERS=""
 902 for target_to_build in $TARGETS_TO_BUILD; do
 903   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 904   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 905     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 906   fi
 907   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 908     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 909   fi
 910   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 911     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 912   fi
 913 done
 914 AC_SUBST(LLVM_ENUM_TARGETS)
 915 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 916 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 917 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 918
 919 dnl Override the option to use for optimized builds.
 920 AC_ARG_WITH(optimize-option,
 921   AS_HELP_STRING([--with-optimize-option],
 922                  [Select the compiler options to use for optimized builds]),,
 923                  withval=default)
 924 AC_MSG_CHECKING([optimization flags])
 925 case "$withval" in
 926   default)
 927     case "$llvm_cv_os_type" in
 928     FreeBSD) optimize_option=-O2 ;;
 929     MingW) optimize_option=-O2 ;;
 930     *)     optimize_option=-O3 ;;
 931     esac ;;
 932   *) optimize_option="$withval" ;;
 933 esac
 934 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 935 AC_MSG_RESULT([$optimize_option])
 936
 937 dnl Specify extra build options
 938 AC_ARG_WITH(extra-options,
 939   AS_HELP_STRING([--with-extra-options],
 940                  [Specify additional options to compile LLVM with]),,
 941                  withval=default)
 942 case "$withval" in
 943   default) EXTRA_OPTIONS= ;;
 944   *) EXTRA_OPTIONS=$withval ;;
 945 esac
 946 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 947
 948 dnl Specify extra linker build options
 949 AC_ARG_WITH(extra-ld-options,
 950   AS_HELP_STRING([--with-extra-ld-options],
 951                  [Specify additional options to link LLVM with]),,
 952                  withval=default)
 953 case "$withval" in
 954   default) EXTRA_LD_OPTIONS= ;;
 955   *) EXTRA_LD_OPTIONS=$withval ;;
 956 esac
 957 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 958
 959 dnl Allow specific bindings to be specified for building (or not)
 960 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 961     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 962     enableval=default)
 963 BINDINGS_TO_BUILD=""
 964 case "$enableval" in
 965   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 966   all ) BINDINGS_TO_BUILD="ocaml" ;;
 967   none | no) BINDINGS_TO_BUILD="" ;;
 968   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 969       case "$a_binding" in
 970         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 971         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 972       esac
 973   done
 974   ;;
 975 esac
 976
 977 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 978 dnl script for bindings/ocaml/configure, except that its auto value depends on
 979 dnl OCAMLC, which is found here to support tests.
 980 AC_ARG_WITH([ocaml-libdir],
 981   [AS_HELP_STRING([--with-ocaml-libdir],
 982     [Specify install location for ocaml bindings (default is stdlib)])],
 983   [],
 984   [withval=auto])
 985 case "$withval" in
 986   auto) with_ocaml_libdir="$withval" ;;
 987   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 988   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 989 esac
 990
 991 AC_ARG_WITH(clang-srcdir,
 992   AS_HELP_STRING([--with-clang-srcdir],
 993     [Directory to the out-of-tree Clang source]),,
 994     withval="-")
 995 case "$withval" in
 996   -) clang_src_root="" ;;
 997   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 998   *) clang_src_root="$ac_pwd/$withval" ;;
 999 esac
1000 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1001
1002 AC_ARG_WITH(clang-resource-dir,
1003   AS_HELP_STRING([--with-clang-resource-dir],
1004     [Relative directory from the Clang binary for resource files]),,
1005     withval="")
1006 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1007                    [Relative directory for resource files])
1008
1009 AC_ARG_WITH(c-include-dirs,
1010   AS_HELP_STRING([--with-c-include-dirs],
1011     [Colon separated list of directories clang will search for headers]),,
1012     withval="")
1013 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1014                    [Directories clang will search for headers])
1015
1016 # Clang normally uses the system c++ headers and libraries. With this option,
1017 # clang will use the ones provided by a gcc installation instead. This option should
1018 # be passed the same value that was used with --prefix when configuring gcc.
1019 AC_ARG_WITH(gcc-toolchain,
1020   AS_HELP_STRING([--with-gcc-toolchain],
1021     [Directory where gcc is installed.]),,
1022     withval="")
1023 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1024                    [Directory where gcc is installed.])
1025
1026 AC_ARG_WITH(default-sysroot,
1027   AS_HELP_STRING([--with-default-sysroot],
1028     [Add --sysroot=<path> to all compiler invocations.]),,
1029     withval="")
1030 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1031                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1032
1033 dnl Allow linking of LLVM with GPLv3 binutils code.
1034 AC_ARG_WITH(binutils-include,
1035   AS_HELP_STRING([--with-binutils-include],
1036     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1037   withval=default)
1038 case "$withval" in
1039   default) WITH_BINUTILS_INCDIR=default ;;
1040   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1041   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1042 esac
1043 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1044   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1045   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1046      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1047      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1048   fi
1049 fi
1050
1051 dnl Specify the URL where bug reports should be submitted.
1052 AC_ARG_WITH(bug-report-url,
1053   AS_HELP_STRING([--with-bug-report-url],
1054     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1055     withval="http://llvm.org/bugs/")
1056 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1057                    [Bug report URL.])
1058
1059 dnl --enable-libffi : check whether the user wants to turn off libffi:
1060 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1061   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1062   [case "$enableval" in
1063     yes) llvm_cv_enable_libffi="yes" ;;
1064     no)  llvm_cv_enable_libffi="no"  ;;
1065     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1066   esac],
1067   llvm_cv_enable_libffi=no)
1068
1069 AC_ARG_WITH(internal-prefix,
1070   AS_HELP_STRING([--with-internal-prefix],
1071     [Installation directory for internal files]),,
1072     withval="")
1073 AC_SUBST(INTERNAL_PREFIX,[$withval])
1074
1075 dnl===-----------------------------------------------------------------------===
1076 dnl===
1077 dnl=== SECTION 4: Check for programs we need and that they are the right version
1078 dnl===
1079 dnl===-----------------------------------------------------------------------===
1080
1081 AC_PROG_NM
1082 AC_SUBST(NM)
1083
1084 dnl Check for the tools that the makefiles require
1085 AC_CHECK_GNU_MAKE
1086 AC_PROG_LN_S
1087 AC_PATH_PROG(CMP, [cmp], [cmp])
1088 AC_PATH_PROG(CP, [cp], [cp])
1089 AC_PATH_PROG(DATE, [date], [date])
1090 AC_PATH_PROG(FIND, [find], [find])
1091 AC_PATH_PROG(GREP, [grep], [grep])
1092 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1093 AC_PATH_PROG(MV,   [mv],   [mv])
1094 AC_PROG_RANLIB
1095 AC_CHECK_TOOL(AR, ar, false)
1096 AC_PATH_PROG(RM,   [rm],   [rm])
1097 AC_PATH_PROG(SED,  [sed],  [sed])
1098 AC_PATH_PROG(TAR,  [tar],  [gtar])
1099 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1100
1101 dnl Looking for misc. graph plotting software
1102 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1103 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1104   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1105   dnl If we're targeting for mingw we should emit windows paths, not msys
1106   if test "$llvm_cv_os_type" = "MingW" ; then
1107     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1108   fi
1109   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1110    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1111 fi
1112 AC_PATH_PROG(DOT, [dot], [echo dot])
1113 if test "$DOT" != "echo dot" ; then
1114   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1115   dnl If we're targeting for mingw we should emit windows paths, not msys
1116   if test "$llvm_cv_os_type" = "MingW" ; then
1117     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1118   fi
1119   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1120    [Define to path to dot program if found or 'echo dot' otherwise])
1121 fi
1122 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1123 if test "$FDP" != "echo fdp" ; then
1124   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1125   dnl If we're targeting for mingw we should emit windows paths, not msys
1126   if test "$llvm_cv_os_type" = "MingW" ; then
1127     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1128   fi
1129   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1130    [Define to path to fdp program if found or 'echo fdp' otherwise])
1131 fi
1132 AC_PATH_PROG(NEATO, [neato], [echo neato])
1133 if test "$NEATO" != "echo neato" ; then
1134   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1135   dnl If we're targeting for mingw we should emit windows paths, not msys
1136   if test "$llvm_cv_os_type" = "MingW" ; then
1137     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1138   fi
1139   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1140    [Define to path to neato program if found or 'echo neato' otherwise])
1141 fi
1142 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1143 if test "$TWOPI" != "echo twopi" ; then
1144   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1145   dnl If we're targeting for mingw we should emit windows paths, not msys
1146   if test "$llvm_cv_os_type" = "MingW" ; then
1147     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1148   fi
1149   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1150    [Define to path to twopi program if found or 'echo twopi' otherwise])
1151 fi
1152 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1153 if test "$CIRCO" != "echo circo" ; then
1154   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1155   dnl If we're targeting for mingw we should emit windows paths, not msys
1156   if test "$llvm_cv_os_type" = "MingW" ; then
1157     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1158   fi
1159   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1160    [Define to path to circo program if found or 'echo circo' otherwise])
1161 fi
1162 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1163 if test "$GV" != "echo gv" ; then
1164   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1165   dnl If we're targeting for mingw we should emit windows paths, not msys
1166   if test "$llvm_cv_os_type" = "MingW" ; then
1167     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1168   fi
1169   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1170    [Define to path to gv program if found or 'echo gv' otherwise])
1171 fi
1172 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1173 if test "$DOTTY" != "echo dotty" ; then
1174   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1175   dnl If we're targeting for mingw we should emit windows paths, not msys
1176   if test "$llvm_cv_os_type" = "MingW" ; then
1177     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1178   fi
1179   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1180    [Define to path to dotty program if found or 'echo dotty' otherwise])
1181 fi
1182 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1183 if test "$XDOT_PY" != "echo xdot.py" ; then
1184   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1185   dnl If we're targeting for mingw we should emit windows paths, not msys
1186   if test "$llvm_cv_os_type" = "MingW" ; then
1187     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1188   fi
1189   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1190    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1191 fi
1192
1193 dnl Find the install program
1194 AC_PROG_INSTALL
1195 dnl Prepend src dir to install path dir if it's a relative path
1196 dnl This is a hack for installs that take place in something other
1197 dnl than the top level.
1198 case "$INSTALL" in
1199  [[\\/$]]* | ?:[[\\/]]* ) ;;
1200  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1201 esac
1202
1203 dnl Checks for documentation and testing tools that we can do without. If these
1204 dnl are not found then they are set to "true" which always succeeds but does
1205 dnl nothing. This just lets the build output show that we could have done
1206 dnl something if the tool was available.
1207 AC_PATH_PROG(BZIP2, [bzip2])
1208 AC_PATH_PROG(CAT, [cat])
1209 AC_PATH_PROG(DOXYGEN, [doxygen])
1210 AC_PATH_PROG(GROFF, [groff])
1211 AC_PATH_PROG(GZIPBIN, [gzip])
1212 AC_PATH_PROG(PDFROFF, [pdfroff])
1213 AC_PATH_PROG(ZIP, [zip])
1214 AC_PATH_PROGS(OCAMLC, [ocamlc])
1215 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1216 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1217 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1218 AC_PATH_PROGS(GAS, [gas as])
1219
1220 dnl Get the version of the linker in use.
1221 AC_LINK_GET_VERSION
1222
1223 dnl Determine whether the linker supports the -R option.
1224 AC_LINK_USE_R
1225
1226 dnl Determine whether the linker supports the -export-dynamic option.
1227 AC_LINK_EXPORT_DYNAMIC
1228
1229 dnl Determine whether the linker supports the --version-script option.
1230 AC_LINK_VERSION_SCRIPT
1231
1232 dnl Check for libtool and the library that has dlopen function (which must come
1233 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1234 dnl libtool).
1235 AC_LIBTOOL_DLOPEN
1236 AC_LIB_LTDL
1237
1238 AC_MSG_CHECKING([tool compatibility])
1239
1240 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1241 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1242 dnl to support those options.
1243 dnl "icc" emits gcc signatures
1244 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1245 ICC=no
1246 IXX=no
1247 case $CC in
1248   icc*|icpc*)
1249     ICC=yes
1250     IXX=yes
1251     ;;
1252    *)
1253     ;;
1254 esac
1255
1256 if test "$GCC" != "yes" && test "$ICC" != "yes"
1257 then
1258   AC_MSG_ERROR([gcc|icc required but not found])
1259 fi
1260
1261 dnl Ensure that compilation tools are compatible with GCC extensions
1262 if test "$GXX" != "yes" && test "$IXX" != "yes"
1263 then
1264   AC_MSG_ERROR([g++|clang++|icc required but not found])
1265 fi
1266
1267 dnl Verify that GCC is version 3.0 or higher
1268 if test "$GCC" = "yes"
1269 then
1270   AC_COMPILE_IFELSE(
1271 [
1272   AC_LANG_SOURCE([[
1273     #if !defined(__GNUC__) || __GNUC__ < 3
1274     #error Unsupported GCC version
1275     #endif
1276   ]])
1277 ],
1278 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1279 fi
1280
1281 dnl Check for GNU Make.  We use its extensions, so don't build without it
1282 if test -z "$llvm_cv_gnu_make_command"
1283 then
1284   AC_MSG_ERROR([GNU Make required but not found])
1285 fi
1286
1287 dnl Tool compatibility is okay if we make it here.
1288 AC_MSG_RESULT([ok])
1289
1290 dnl Check optional compiler flags.
1291 AC_MSG_CHECKING([optional compiler flags])
1292 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1293 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1294 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1295
1296 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1297 dnl false positives, so disable it.
1298 NO_UNINITIALIZED=
1299 NO_MAYBE_UNINITIALIZED=
1300 if test "$GXX" = "yes"
1301 then
1302   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1303   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1304   dnl known to be uninitialized from cases which might be uninitialized.  We
1305   dnl still want to catch the first kind of errors.
1306   if test -z "$NO_MAYBE_UNINITIALIZED"
1307   then
1308     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1309   fi
1310 fi
1311 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1312
1313 AC_ARG_WITH([python],
1314             [AS_HELP_STRING([--with-python], [path to python])],
1315             [PYTHON="$withval"])
1316
1317 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1318   AC_MSG_CHECKING([for python])
1319   AC_MSG_RESULT([user defined: $with_python])
1320 else
1321   if test -n "$PYTHON" ; then
1322     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1323   fi
1324
1325   AC_PATH_PROG([PYTHON], [python python2 python26],
1326                [AC_MSG_RESULT([not found])
1327                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1328 fi
1329
1330 AC_MSG_CHECKING([for python >= 2.5])
1331 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1332 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1333 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1334 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1335 if   test "$ac_python_version_major" -eq "2" \
1336    && test "$ac_python_version_minor" -ge "5" ; then
1337   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1338 else
1339   AC_MSG_RESULT([not found])
1340   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1341 fi
1342
1343 dnl===-----------------------------------------------------------------------===
1344 dnl===
1345 dnl=== SECTION 5: Check for libraries
1346 dnl===
1347 dnl===-----------------------------------------------------------------------===
1348
1349 AC_CHECK_LIB(m,sin)
1350 if test "$llvm_cv_os_type" = "MingW" ; then
1351   AC_CHECK_LIB(imagehlp, main)
1352   AC_CHECK_LIB(psapi, main)
1353 fi
1354
1355 dnl dlopen() is required for plugin support.
1356 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1357                [Define if dlopen() is available on this platform.]),
1358                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1359
1360 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1361 dnl macros to detect whether clock_gettime is available, this just finds the
1362 dnl right libraries to link with.
1363 AC_SEARCH_LIBS(clock_gettime,rt)
1364
1365 dnl libffi is optional; used to call external functions from the interpreter
1366 if test "$llvm_cv_enable_libffi" = "yes" ; then
1367   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1368                  [Define if libffi is available on this platform.]),
1369                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1370 fi
1371
1372 dnl mallinfo is optional; the code can compile (minus features) without it
1373 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1374                [Define if mallinfo() is available on this platform.]))
1375
1376 dnl pthread locking functions are optional - but llvm will not be thread-safe
1377 dnl without locks.
1378 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1379   AC_CHECK_LIB(pthread, pthread_mutex_init)
1380   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1381                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1382                            [Have pthread_mutex_lock]))
1383   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1384                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1385                  [Have pthread_rwlock_init]))
1386   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1387                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1388                  [Have pthread_getspecific]))
1389 fi
1390
1391 dnl zlib is optional; used for compression/uncompression
1392 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1393   AC_CHECK_LIB(z, compress2)
1394 fi
1395
1396 dnl Allow extra x86-disassembler library
1397 AC_ARG_WITH(udis86,
1398   AS_HELP_STRING([--with-udis86=<path>],
1399     [Use udis86 external x86 disassembler library]),
1400     [
1401       AC_SUBST(USE_UDIS86, [1])
1402       case "$withval" in
1403         /usr/lib|yes) ;;
1404         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1405       esac
1406       AC_CHECK_LIB(udis86, ud_init, [], [
1407         echo "Error! You need to have libudis86 around."
1408         exit -1
1409       ])
1410     ],
1411     AC_SUBST(USE_UDIS86, [0]))
1412 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1413                    [Define if use udis86 library])
1414
1415 dnl Allow OProfile support for JIT output.
1416 AC_ARG_WITH(oprofile,
1417   AS_HELP_STRING([--with-oprofile=<prefix>],
1418     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1419     [
1420       AC_SUBST(USE_OPROFILE, [1])
1421       case "$withval" in
1422         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1423         no) llvm_cv_oppath=
1424             AC_SUBST(USE_OPROFILE, [0]) ;;
1425         *) llvm_cv_oppath="${withval}/lib/oprofile"
1426            CPPFLAGS="-I${withval}/include";;
1427       esac
1428       case $llvm_cv_os_type in
1429         Linux)
1430           if test -n "$llvm_cv_oppath" ; then
1431             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1432             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1433             dnl libbfd is not included properly in libopagent in some Debian
1434             dnl versions.  If libbfd isn't found at all, we assume opagent works
1435             dnl anyway.
1436             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1437             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1438               echo "Error! You need to have libopagent around."
1439               exit -1
1440             ])
1441             AC_CHECK_HEADER([opagent.h], [], [
1442               echo "Error! You need to have opagent.h around."
1443               exit -1
1444               ])
1445           fi ;;
1446         *)
1447           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1448       esac
1449     ],
1450     [
1451       AC_SUBST(USE_OPROFILE, [0])
1452     ])
1453 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1454                    [Define if we have the oprofile JIT-support library])
1455
1456 dnl Enable support for Intel JIT Events API.
1457 AC_ARG_WITH(intel-jitevents,
1458   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1459     [
1460        case "$withval" in
1461           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1462           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1463           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1464        esac
1465
1466       case $llvm_cv_os_type in
1467         Linux|Win32|Cygwin|MingW) ;;
1468         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1469       esac
1470
1471       case "$llvm_cv_target_arch" in
1472         x86|x86_64) ;;
1473         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1474       esac
1475     ],
1476     [
1477       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1478     ])
1479 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1480                    [Define if we have the Intel JIT API runtime support library])
1481
1482 dnl Check for libxml2
1483 dnl Right now we're just checking for the existence, we could also check for a
1484 dnl particular version via --version on xml2-config
1485 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1486
1487 AC_MSG_CHECKING(for libxml2 includes)
1488 if test "x$XML2CONFIG" = "x"; then
1489  AC_MSG_RESULT(xml2-config not found)
1490 else
1491  LIBXML2_INC=`$XML2CONFIG --cflags`
1492  AC_MSG_RESULT($LIBXML2_INC)
1493  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1494                                 LIBXML2_LIBS="-lxml2"])
1495 fi
1496 AC_SUBST(LIBXML2_LIBS)
1497 AC_SUBST(LIBXML2_INC)
1498
1499 dnl===-----------------------------------------------------------------------===
1500 dnl===
1501 dnl=== SECTION 6: Check for header files
1502 dnl===
1503 dnl===-----------------------------------------------------------------------===
1504
1505 dnl First, use autoconf provided macros for specific headers that we need
1506 dnl We don't check for ancient stuff or things that are guaranteed to be there
1507 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1508 dnl Generally we're looking for POSIX headers.
1509 AC_HEADER_DIRENT
1510 AC_HEADER_MMAP_ANONYMOUS
1511 AC_HEADER_STAT
1512 AC_HEADER_SYS_WAIT
1513 AC_HEADER_TIME
1514
1515 AC_LANG_PUSH([C++])
1516 AC_CHECK_HEADERS([cxxabi.h])
1517 AC_LANG_POP([C++])
1518 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1519 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1520 AC_CHECK_HEADERS([utime.h windows.h])
1521 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1522 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1523 AC_CHECK_HEADERS([valgrind/valgrind.h])
1524 AC_CHECK_HEADERS([fenv.h])
1525 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1526 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1527   AC_CHECK_HEADERS(pthread.h,
1528                    AC_SUBST(HAVE_PTHREAD, 1),
1529                    AC_SUBST(HAVE_PTHREAD, 0))
1530 else
1531   AC_SUBST(HAVE_PTHREAD, 0)
1532 fi
1533 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1534   AC_CHECK_HEADERS(zlib.h,
1535                    AC_SUBST(HAVE_LIBZ, 1),
1536                    AC_SUBST(HAVE_LIBZ, 0))
1537 else
1538   AC_SUBST(HAVE_LIBZ, 0)
1539 fi
1540
1541 dnl Try to find ffi.h.
1542 if test "$llvm_cv_enable_libffi" = "yes" ; then
1543   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1544 fi
1545
1546 dnl Try to find Darwin specific crash reporting libraries.
1547 AC_CHECK_HEADERS([CrashReporterClient.h])
1548
1549 dnl Try to find Darwin specific crash reporting global.
1550 AC_MSG_CHECKING([__crashreporter_info__])
1551 AC_LINK_IFELSE(
1552 [
1553   AC_LANG_SOURCE([[
1554     extern const char *__crashreporter_info__;
1555     int main() {
1556       __crashreporter_info__ = "test";
1557       return 0;
1558     }
1559   ]])
1560 ],
1561 [
1562   AC_MSG_RESULT([yes])
1563   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1564 ],
1565 [
1566   AC_MSG_RESULT([no])
1567   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1568 ])
1569
1570 dnl===-----------------------------------------------------------------------===
1571 dnl===
1572 dnl=== SECTION 7: Check for types and structures
1573 dnl===
1574 dnl===-----------------------------------------------------------------------===
1575
1576 AC_HUGE_VAL_CHECK
1577 AC_TYPE_PID_T
1578 AC_TYPE_SIZE_T
1579 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1580 AC_STRUCT_TM
1581 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1582 AC_CHECK_TYPES([uint64_t],,
1583          AC_CHECK_TYPES([u_int64_t],,
1584          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1585
1586 dnl===-----------------------------------------------------------------------===
1587 dnl===
1588 dnl=== SECTION 8: Check for specific functions needed
1589 dnl===
1590 dnl===-----------------------------------------------------------------------===
1591
1592 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1593 AC_CHECK_FUNCS([powf fmodf strtof round ])
1594 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1595 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1596 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1597 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1598 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1599 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1600 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1601 AC_C_PRINTF_A
1602 AC_FUNC_RAND48
1603
1604 dnl Check the declaration "Secure API" on Windows environments.
1605 AC_CHECK_DECLS([strerror_s])
1606
1607 dnl Check symbols in libgcc.a for JIT on Mingw.
1608 if test "$llvm_cv_os_type" = "MingW" ; then
1609   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1610   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1611   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1612   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1613
1614   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1615   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1616   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1617   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1618   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1619   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1620   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1621   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1622   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1623   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1624
1625   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1626   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1627 fi
1628
1629 dnl Check Win32 API EnumerateLoadedModules.
1630 if test "$llvm_cv_os_type" = "MingW" ; then
1631   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1632   AC_COMPILE_IFELSE(
1633 [
1634   AC_LANG_SOURCE([[
1635     #include <windows.h>
1636     #include <imagehlp.h>
1637     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1638     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1639   ]])
1640 ],
1641 [
1642   AC_MSG_RESULT([yes])
1643   llvm_cv_win32_elmcb_pcstr="PCSTR"
1644 ],
1645 [
1646   AC_MSG_RESULT([no])
1647   llvm_cv_win32_elmcb_pcstr="PSTR"
1648 ])
1649   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1650 fi
1651
1652 dnl Check for variations in the Standard C++ library and STL. These macros are
1653 dnl provided by LLVM in the autoconf/m4 directory.
1654 AC_FUNC_ISNAN
1655 AC_FUNC_ISINF
1656
1657 dnl Check for mmap support.We also need to know if /dev/zero is required to
1658 dnl be opened for allocating RWX memory.
1659 dnl Make sure we aren't attempting to configure for an unknown system
1660 if test "$llvm_cv_platform_type" = "Unix" ; then
1661   AC_FUNC_MMAP
1662   AC_FUNC_MMAP_FILE
1663   AC_NEED_DEV_ZERO_FOR_MMAP
1664
1665   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1666   then
1667     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1668   fi
1669   if test "$ac_cv_func_mmap_file" = "no"
1670   then
1671     AC_MSG_WARN([mmap() of files required but not found])
1672   fi
1673 fi
1674
1675 dnl atomic builtins are required for threading support.
1676 AC_MSG_CHECKING(for GCC atomic builtins)
1677 dnl Since we'll be using these atomic builtins in C++ files we should test
1678 dnl the C++ compiler.
1679 AC_LANG_PUSH([C++])
1680 AC_LINK_IFELSE(
1681 [
1682   AC_LANG_SOURCE([[
1683     int main() {
1684       volatile unsigned long val = 1;
1685       __sync_synchronize();
1686       __sync_val_compare_and_swap(&val, 1, 0);
1687       __sync_add_and_fetch(&val, 1);
1688       __sync_sub_and_fetch(&val, 1);
1689       return 0;
1690     }
1691   ]])
1692 ],
1693 [
1694   AC_MSG_RESULT([yes])
1695   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1696 ],
1697 [
1698   AC_MSG_RESULT([no])
1699   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1700   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1701 ])
1702 AC_LANG_POP([C++])
1703
1704 dnl===-----------------------------------------------------------------------===
1705 dnl===
1706 dnl=== SECTION 9: Additional checks, variables, etc.
1707 dnl===
1708 dnl===-----------------------------------------------------------------------===
1709
1710 dnl Handle 32-bit linux systems running a 64-bit kernel.
1711 dnl This has to come after section 4 because it invokes the compiler.
1712 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1713   AC_IS_LINUX_MIXED
1714   if test "$llvm_cv_linux_mixed" = "yes"; then
1715     llvm_cv_target_arch="x86"
1716     ARCH="x86"
1717   fi
1718 fi
1719
1720 dnl Check whether __dso_handle is present
1721 AC_CHECK_FUNCS([__dso_handle])
1722
1723 dnl Propagate the shared library extension that the libltdl checks did to
1724 dnl the Makefiles so we can use it there too
1725 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1726
1727 dnl Propagate the run-time library path variable that the libltdl
1728 dnl checks found to the Makefiles so we can use it there too
1729 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1730
1731 dnl Translate the various configuration directories and other basic
1732 dnl information into substitutions that will end up in Makefile.config.in
1733 dnl that these configured values can be used by the makefiles
1734 if test "${prefix}" = "NONE" ; then
1735   prefix="/usr/local"
1736 fi
1737 eval LLVM_PREFIX="${prefix}";
1738 eval LLVM_BINDIR="${prefix}/bin";
1739 eval LLVM_LIBDIR="${prefix}/lib";
1740 eval LLVM_DATADIR="${prefix}/share/llvm";
1741 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1742 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1743 eval LLVM_INCLUDEDIR="${prefix}/include";
1744 eval LLVM_INFODIR="${prefix}/info";
1745 eval LLVM_MANDIR="${prefix}/man";
1746 LLVM_CONFIGTIME=`date`
1747 AC_SUBST(LLVM_PREFIX)
1748 AC_SUBST(LLVM_BINDIR)
1749 AC_SUBST(LLVM_LIBDIR)
1750 AC_SUBST(LLVM_DATADIR)
1751 AC_SUBST(LLVM_DOCSDIR)
1752 AC_SUBST(LLVM_ETCDIR)
1753 AC_SUBST(LLVM_INCLUDEDIR)
1754 AC_SUBST(LLVM_INFODIR)
1755 AC_SUBST(LLVM_MANDIR)
1756 AC_SUBST(LLVM_CONFIGTIME)
1757
1758 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1759 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1760   LLVM_CONFIGTIME="(timestamp not enabled)"
1761 fi
1762
1763 dnl Place the various directories into the config.h file as #defines so that we
1764 dnl can know about the installation paths within LLVM.
1765 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1766                    [Installation prefix directory])
1767 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1768                    [Installation directory for binary executables])
1769 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1770                    [Installation directory for libraries])
1771 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1772                    [Installation directory for data files])
1773 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1774                    [Installation directory for documentation])
1775 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1776                    [Installation directory for config files])
1777 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1778                    [Installation directory for include files])
1779 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1780                    [Installation directory for .info files])
1781 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1782                    [Installation directory for man pages])
1783 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1784                    [Time at which LLVM was configured])
1785 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1786                    [Host triple LLVM will be executed on])
1787 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1788                    [Target triple LLVM will generate code for by default])
1789
1790 dnl Determine which bindings to build.
1791 if test "$BINDINGS_TO_BUILD" = auto ; then
1792   BINDINGS_TO_BUILD=""
1793   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1794     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1795   fi
1796 fi
1797 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1798
1799 dnl This isn't really configurey, but it avoids having to repeat the list in
1800 dnl other files.
1801 AC_SUBST(ALL_BINDINGS,ocaml)
1802
1803 dnl Do any work necessary to ensure that bindings have what they need.
1804 binding_prereqs_failed=0
1805 for a_binding in $BINDINGS_TO_BUILD ; do
1806   case "$a_binding" in
1807   ocaml)
1808     if test "x$OCAMLC" = x ; then
1809       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1810       binding_prereqs_failed=1
1811     fi
1812     if test "x$OCAMLDEP" = x ; then
1813       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1814       binding_prereqs_failed=1
1815     fi
1816     if test "x$OCAMLOPT" = x ; then
1817       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1818       dnl ocamlopt is optional!
1819     fi
1820     if test "x$with_ocaml_libdir" != xauto ; then
1821       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1822     else
1823       ocaml_stdlib="`"$OCAMLC" -where`"
1824       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1825       then
1826         # ocaml stdlib is beneath our prefix; use stdlib
1827         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1828       else
1829         # ocaml stdlib is outside our prefix; use libdir/ocaml
1830         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1831       fi
1832     fi
1833     ;;
1834   esac
1835 done
1836 if test "$binding_prereqs_failed" = 1 ; then
1837   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1838 fi
1839
1840 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1841 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1842
1843 dnl Determine linker rpath flag
1844 if test "$llvm_cv_link_use_r" = "yes" ; then
1845   RPATH="-Wl,-R"
1846 else
1847   RPATH="-Wl,-rpath"
1848 fi
1849 AC_SUBST(RPATH)
1850
1851 dnl Determine linker rdynamic flag
1852 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1853   RDYNAMIC="-Wl,-export-dynamic"
1854 else
1855   RDYNAMIC=""
1856 fi
1857 AC_SUBST(RDYNAMIC)
1858
1859 dnl===-----------------------------------------------------------------------===
1860 dnl===
1861 dnl=== SECTION 10: Specify the output files and generate it
1862 dnl===
1863 dnl===-----------------------------------------------------------------------===
1864
1865 dnl Configure header files
1866 dnl WARNING: dnl If you add or remove any of the following config headers, then
1867 dnl you MUST also update Makefile so that the variable FilesToConfig
1868 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1869 dnl files can be updated automatically when their *.in sources change.
1870 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1871 AH_TOP([#ifndef CONFIG_H
1872 #define CONFIG_H])
1873 AH_BOTTOM([#endif])
1874
1875 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1876 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1877 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1878 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1879 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1880
1881 dnl Configure the makefile's configuration data
1882 AC_CONFIG_FILES([Makefile.config])
1883
1884 dnl Configure the RPM spec file for LLVM
1885 AC_CONFIG_FILES([llvm.spec])
1886
1887 dnl Configure doxygen's configuration file
1888 AC_CONFIG_FILES([docs/doxygen.cfg])
1889
1890 dnl Configure clang, if present
1891 if test "${clang_src_root}" = ""; then
1892   clang_src_root="$srcdir/tools/clang"
1893 fi
1894 if test -f ${clang_src_root}/README.txt; then
1895   dnl Use variables to stay under 80 columns.
1896   configh="include/clang/Config/config.h"
1897   doxy="docs/doxygen.cfg"
1898   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1899   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1900 fi
1901
1902 dnl OCaml findlib META file
1903 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1904
1905 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1906 test "x$program_prefix" = "xNONE" && program_prefix=""
1907 AC_SUBST([program_prefix])
1908
1909
1910 dnl Do special configuration of Makefiles
1911 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1912 AC_CONFIG_MAKEFILE(Makefile)
1913 AC_CONFIG_MAKEFILE(Makefile.common)
1914 AC_CONFIG_MAKEFILE(examples/Makefile)
1915 AC_CONFIG_MAKEFILE(lib/Makefile)
1916 AC_CONFIG_MAKEFILE(runtime/Makefile)
1917 AC_CONFIG_MAKEFILE(test/Makefile)
1918 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1919 AC_CONFIG_MAKEFILE(unittests/Makefile)
1920 AC_CONFIG_MAKEFILE(tools/Makefile)
1921 AC_CONFIG_MAKEFILE(utils/Makefile)
1922 AC_CONFIG_MAKEFILE(projects/Makefile)
1923 AC_CONFIG_MAKEFILE(bindings/Makefile)
1924 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1925
1926 dnl Finally, crank out the output
1927 AC_OUTPUT