autoconf/configure.ac

   1 dnl Autoconf requirements
   2 dnl AC_INIT(package, version, bug-report-address)
   3 dnl information on the package
   4 dnl checks for programs
   5 dnl checks for libraries
   6 dnl checks for header files
   7 dnl checks for types
   8 dnl checks for structures
   9 dnl checks for compiler characteristics
  10 dnl checks for library functions
  11 dnl checks for system services
  12 dnl AC_CONFIG_FILES([file...])
  13 dnl AC_OUTPUT
  14
  15 dnl **************************************************************************
  16 dnl * Initialize
  17 dnl **************************************************************************
  18 AC_INIT([[[LLVM]]],[[[1.0]]],[llvmbugs@cs.uiuc.edu])
  19
  20 dnl Place all of the extra autoconf files into the config subdirectory
  21 AC_CONFIG_AUX_DIR([autoconf])
  22
  23 dnl Quit if the source directory has already been configured.
  24 dnl NOTE: This relies upon undocumented autoconf behavior.
  25 if test ${srcdir} != "."
  26 then
  27         if test -f ${srcdir}/include/Config/config.h
  28         then
  29                 AC_MSG_ERROR([Already configured in ${srcdir}])
  30         fi
  31 fi
  32
  33 dnl Configure a header file
  34 AC_CONFIG_HEADERS(include/Config/config.h)
  35 AC_CONFIG_MAKEFILE(Makefile)
  36 AC_CONFIG_MAKEFILE(Makefile.common)
  37 AC_CONFIG_MAKEFILE(Makefile.rules)
  38 AC_CONFIG_MAKEFILE(lib/Makefile)
  39 AC_CONFIG_MAKEFILE(lib/Analysis/Makefile)
  40 AC_CONFIG_MAKEFILE(lib/Analysis/DataStructure/Makefile)
  41 AC_CONFIG_MAKEFILE(lib/Analysis/IPA/Makefile)
  42 AC_CONFIG_MAKEFILE(lib/Analysis/LiveVar/Makefile)
  43 AC_CONFIG_MAKEFILE(lib/AsmParser/Makefile)
  44 AC_CONFIG_MAKEFILE(lib/Bytecode/Makefile)
  45 AC_CONFIG_MAKEFILE(lib/Bytecode/Reader/Makefile)
  46 AC_CONFIG_MAKEFILE(lib/Bytecode/Writer/Makefile)
  47 AC_CONFIG_MAKEFILE(lib/CWriter/Makefile)
  48 AC_CONFIG_MAKEFILE(lib/CodeGen/Makefile)
  49 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSched/Makefile)
  50 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSelection/Makefile)
  51 AC_CONFIG_MAKEFILE(lib/CodeGen/ModuloScheduling/Makefile)
  52 AC_CONFIG_MAKEFILE(lib/CodeGen/RegAlloc/Makefile)
  53 AC_CONFIG_MAKEFILE(lib/CodeGen/SelectionDAG/Makefile)
  54 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Makefile)
  55 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Interpreter/Makefile)
  56 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/JIT/Makefile)
  57 AC_CONFIG_MAKEFILE(lib/Support/Makefile)
  58 AC_CONFIG_MAKEFILE(lib/Target/Makefile)
  59 AC_CONFIG_MAKEFILE(lib/Target/Sparc/Makefile)
  60 AC_CONFIG_MAKEFILE(lib/Target/X86/Makefile)
  61 AC_CONFIG_MAKEFILE(lib/Transforms/Makefile)
  62 AC_CONFIG_MAKEFILE(lib/Transforms/Hello/Makefile)
  63 AC_CONFIG_MAKEFILE(lib/Transforms/IPO/Makefile)
  64 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/Makefile)
  65 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/ProfilePaths/Makefile)
  66 AC_CONFIG_MAKEFILE(lib/Transforms/Scalar/Makefile)
  67 AC_CONFIG_MAKEFILE(lib/Transforms/Utils/Makefile)
  68 AC_CONFIG_MAKEFILE(lib/VMCore/Makefile)
  69 AC_CONFIG_MAKEFILE(runtime/Makefile)
  70 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/Makefile)
  71 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/crtend/Makefile)
  72 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libc/Makefile)
  73 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libcurses/Makefile)
  74 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libg/Makefile)
  75 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libgcc/Makefile)
  76 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libm/Makefile)
  77 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libmalloc/Makefile)
  78 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libtermcap/Makefile)
  79 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libucb/Makefile)
  80 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutempter/Makefile)
  81 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutil/Makefile)
  82 AC_CONFIG_MAKEFILE(runtime/libdummy/Makefile)
  83 AC_CONFIG_MAKEFILE(runtime/libtrace/Makefile)
  84 AC_CONFIG_MAKEFILE(test/Makefile)
  85 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  86 AC_CONFIG_MAKEFILE(test/QMTestDB/QMTest/llvm.py)
  87 AC_CONFIG_MAKEFILE(test/Programs/Makefile)
  88 AC_CONFIG_MAKEFILE(test/Programs/Makefile.programs)
  89 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.Makefile)
  90 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.report)
  91 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.report)
  92 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.report)
  93 AC_CONFIG_MAKEFILE(test/Programs/TEST.example.Makefile)
  94 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.Makefile)
  95 AC_CONFIG_MAKEFILE(test/Programs/TEST.buildrepo.Makefile)
  96 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.Makefile)
  97 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.report)
  98 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.Makefile)
  99 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.report)
 100 AC_CONFIG_MAKEFILE(test/Programs/TEST.typesafe.Makefile)
 101 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.gnuplot)
 102 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.Makefile)
 103 AC_CONFIG_MAKEFILE(test/Programs/External/Makefile)
 104 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile)
 105 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec)
 106 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/Makefile)
 107 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/179.art/Makefile)
 108 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/183.equake/Makefile)
 109 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/188.ammp/Makefile)
 110 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/Makefile)
 111 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/164.gzip/Makefile)
 112 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/175.vpr/Makefile)
 113 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/176.gcc/Makefile)
 114 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/181.mcf/Makefile)
 115 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/186.crafty/Makefile)
 116 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/197.parser/Makefile)
 117 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/254.gap/Makefile)
 118 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/255.vortex/Makefile)
 119 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/256.bzip2/Makefile)
 120 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/300.twolf/Makefile)
 121 AC_CONFIG_MAKEFILE(test/Programs/LLVMSource/Makefile)
 122 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile)
 123 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile.multisrc)
 124 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Makefile)
 125 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Burg/Makefile)
 126 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/aha/Makefile)
 127 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/sgefa/Makefile)
 128 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Makefile)
 129 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Fhourstones/Makefile)
 130 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/Makefile)
 131 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/01-qbsort/Makefile)
 132 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/03-testtrie/Makefile)
 133 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/04-bisect/Makefile)
 134 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/05-eks/Makefile)
 135 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/08-main/Makefile)
 136 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/09-vor/Makefile)
 137 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/12-IOtest/Makefile)
 138 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/15-trie/Makefile)
 139 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/17-bintr/Makefile)
 140 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/18-imp/Makefile)
 141 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/Makefile)
 142 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bh/Makefile)
 143 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bisort/Makefile)
 144 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/em3d/Makefile)
 145 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/health/Makefile)
 146 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/mst/Makefile)
 147 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/perimeter/Makefile)
 148 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/power/Makefile)
 149 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/treeadd/Makefile)
 150 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/tsp/Makefile)
 151 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/voronoi/Makefile)
 152 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/OptimizerEval/Makefile)
 153 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/Makefile)
 154 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/anagram/Makefile)
 155 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/bc/Makefile)
 156 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ft/Makefile)
 157 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ks/Makefile)
 158 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/yacr2/Makefile)
 159 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/llubenchmark/Makefile)
 160 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/sim/Makefile)
 161 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Makefile)
 162 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Flex/Makefile)
 163 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Larn/Makefile)
 164 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Moria-5.5.2/Makefile)
 165 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Povray31/Makefile)
 166 AC_CONFIG_MAKEFILE(test/Programs/NoSource/m4/Makefile)
 167 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile)
 168 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile.singlesrc)
 169 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Gizmos/Makefile)
 170 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Makefile)
 171 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Dhrystone/Makefile)
 172 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Shootout/Makefile)
 173 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Stanford/Makefile)
 174 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Misc/Makefile)
 175 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/CustomChecked/Makefile)
 176 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/Makefile)
 177 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/SetjmpLongjmp/Makefile)
 178 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/Makefile)
 179 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C/Makefile)
 180 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C++/Makefile)
 181 AC_CONFIG_MAKEFILE(tools/Makefile)
 182 AC_CONFIG_MAKEFILE(tools/analyze/Makefile)
 183 AC_CONFIG_MAKEFILE(tools/bugpoint/Makefile)
 184 AC_CONFIG_MAKEFILE(tools/extract/Makefile)
 185 AC_CONFIG_MAKEFILE(tools/gccas/Makefile)
 186 AC_CONFIG_MAKEFILE(tools/gccld/Makefile)
 187 AC_CONFIG_MAKEFILE(tools/llc/Makefile)
 188 AC_CONFIG_MAKEFILE(tools/llee/Makefile)
 189 AC_CONFIG_MAKEFILE(tools/lli/Makefile)
 190 AC_CONFIG_MAKEFILE(tools/llvm-ar/Makefile)
 191 AC_CONFIG_MAKEFILE(tools/llvm-as/Makefile)
 192 AC_CONFIG_MAKEFILE(tools/llvm-dis/Makefile)
 193 AC_CONFIG_MAKEFILE(tools/llvm-link/Makefile)
 194 AC_CONFIG_MAKEFILE(tools/opt/Makefile)
 195 AC_CONFIG_MAKEFILE(utils/Makefile)
 196 AC_CONFIG_MAKEFILE(utils/Burg/Makefile)
 197 AC_CONFIG_MAKEFILE(utils/Burg/Doc/Makefile)
 198 AC_CONFIG_MAKEFILE(utils/TableGen/Makefile)
 199 AC_CONFIG_MAKEFILE(www/docs/Makefile)
 200 AC_CONFIG_MAKEFILE(projects/Makefile)
 201 AC_CONFIG_MAKEFILE(projects/sample/Makefile)
 202 AC_CONFIG_MAKEFILE(projects/sample/Makefile.common)
 203 AC_CONFIG_MAKEFILE(projects/sample/Makefile.config)
 204 AC_CONFIG_MAKEFILE(projects/sample/lib/Makefile)
 205 AC_CONFIG_MAKEFILE(projects/sample/lib/sample/Makefile)
 206 AC_CONFIG_MAKEFILE(projects/sample/tools/Makefile)
 207 AC_CONFIG_MAKEFILE(projects/sample/tools/sample/Makefile)
 208 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile)
 209 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile.common)
 210 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/Makefile)
 211 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/ModuleMaker/Makefile)
 212
 213 dnl **************************************************************************
 214 dnl * Determine which system we are building on
 215 dnl **************************************************************************
 216
 217 dnl Check the install program (needs to be done before canonical stuff)
 218 AC_PROG_INSTALL
 219
 220 dnl Check which host for which we're compiling.  This will tell us which LLVM
 221 dnl compiler will be used for compiling SSA into object code.
 222 AC_CANONICAL_TARGET
 223
 224 dnl
 225 dnl Now, for some of our own magic:
 226 dnl We will use the build machine information to set some variables.
 227 dnl
 228 case $build in
 229         *i*86*)  AC_SUBST(OS,[Linux])
 230                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 231                  ;;
 232
 233         *sparc*) AC_SUBST(OS,[SunOS])
 234                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 235                  ;;
 236
 237         *)       AC_SUBST(OS,[Unknown])
 238                  ;;
 239 esac
 240
 241 dnl
 242 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 243 dnl V9, since that is all that we support at the moment, and autoconf will only
 244 dnl tell us we're a sparc.
 245 dnl
 246 case $target in
 247         *sparc*solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 248                           ;;
 249 esac
 250
 251 dnl
 252 dnl Determine what our target architecture is and configure accordingly.
 253 dnl This will allow Makefiles to make a distinction between the hardware and
 254 dnl the OS.
 255 dnl
 256 case $target in
 257         *i*86*)           AC_SUBST(ARCH,[x86])
 258                           ;;
 259         *sparc*solaris*)  AC_SUBST(ARCH,[Sparc])
 260                           ;;
 261 esac
 262
 263 dnl **************************************************************************
 264 dnl * Check for programs.
 265 dnl **************************************************************************
 266
 267 dnl Check for compilation tools
 268 AC_PROG_CXX
 269 AC_PROG_CC(gcc)
 270 AC_PROG_CPP
 271
 272 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 273 if test "$GCC" != "yes"
 274 then
 275         AC_MSG_ERROR([gcc required but not found])
 276 fi
 277
 278 if test "$GXX" != "yes"
 279 then
 280         AC_MSG_ERROR([g++ required but not found])
 281 fi
 282
 283 dnl Verify that GCC is version 3.0 or higher
 284 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 285 if test "$gccmajor" -lt "3"
 286 then
 287         AC_MSG_ERROR([gcc 3.x required])
 288 fi
 289
 290 dnl Check for GNU Make.  We use its extensions to, so don't build without it
 291 CHECK_GNU_MAKE
 292 if test -z "$_cv_gnu_make_command"
 293 then
 294         AC_MSG_ERROR([GNU Make required but not found])
 295 fi
 296
 297 dnl Check for compiler-compiler tools (reminds me of Little Caesar's Pizza)
 298 AC_PROG_FLEX
 299 AC_PROG_BISON
 300
 301 dnl Check for libtool
 302 AC_PROG_LIBTOOL
 303
 304 dnl Check for our special programs
 305 AC_PATH_PROG(RPWD,[pwd],[false])
 306 if test ${RPWD} = "false"
 307 then
 308         AC_MSG_ERROR([pwd required but not found])
 309 fi
 310
 311 AC_PATH_PROG(AR,[ar],[false])
 312 if test ${AR} = "false"
 313 then
 314         AC_MSG_ERROR([ar required but not found])
 315 fi
 316
 317 AC_PATH_PROG(SED,[sed],[false])
 318 if test ${SED} = "false"
 319 then
 320         AC_MSG_ERROR([sed required but not found])
 321 fi
 322
 323 AC_PATH_PROG(RM,[rm],[false])
 324 if test ${RM} = "false"
 325 then
 326         AC_MSG_ERROR([rm required but not found])
 327 fi
 328
 329 AC_PATH_PROG(ECHO,[echo],[false])
 330 if test ${ECHO} = "false"
 331 then
 332         AC_MSG_ERROR([echo required but not found])
 333 fi
 334
 335 AC_PATH_PROG(MKDIR,[mkdir],[false])
 336 if test ${MKDIR} = "false"
 337 then
 338         AC_MSG_ERROR([mkdir required but not found])
 339 fi
 340
 341 AC_PATH_PROG(DATE,[date],[false])
 342 if test ${DATE} = "false"
 343 then
 344         AC_MSG_ERROR([date required but not found])
 345 fi
 346
 347 AC_PATH_PROG(MV,[mv],[false])
 348 if test ${MV} = "false"
 349 then
 350         AC_MSG_ERROR([mv required but not found])
 351 fi
 352
 353 AC_PATH_PROG(DOT,[dot],[false])
 354
 355 AC_PATH_PROG(ETAGS,[etags],[false])
 356
 357 AC_PATH_PROG(PURIFY,[purify],[false])
 358
 359 AC_PATH_PROG(PYTHON,[python],[false])
 360 if test ${PYTHON} = "false"
 361 then
 362         AC_MSG_WARN([python required but not found])
 363 fi
 364
 365 AC_PATH_PROG(QMTEST,[qmtest],[false])
 366 if test ${QMTEST} = "false"
 367 then
 368         AC_MSG_WARN([qmtest required but not found])
 369 fi
 370
 371 dnl Verify that the version of python available is high enough for qmtest
 372 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 373 pymajor=`echo $pyversion | cut -d. -f1`
 374 pyminor=`echo $pyversion | cut -d. -f2`
 375
 376 if test "$pymajor" -ge "2"
 377 then
 378         if test "$pymajor" -eq "2"
 379         then
 380                 if test "$pyminor" -lt "2"
 381                 then
 382                         AC_MSG_ERROR([Python 2.2 or greater required])
 383                 fi
 384         fi
 385 else
 386         AC_MSG_ERROR([Python 2.2 or greater required])
 387 fi
 388
 389 dnl Verify that the source directory is valid
 390 AC_CONFIG_SRCDIR(["Makefile.config.in"])
 391
 392 dnl **************************************************************************
 393 dnl * Check for libraries.
 394 dnl **************************************************************************
 395
 396 dnl libelf is for sparc only; we can ignore it if we don't have it
 397 AC_CHECK_LIB(elf, elf_begin)
 398
 399 dnl dlopen() is required.  If we don't find it, quit.
 400 AC_SEARCH_LIBS(dlopen,dl,,AC_MSG_ERROR([dlopen() required but not found]))
 401
 402 dnl mallinfo is optional; the code can compile (minus features) without it
 403 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1]))
 404
 405 dnl
 406 dnl The math libraries are used by the test code, but not by the actual LLVM
 407 dnl code.
 408 dnl
 409 dnl AC_CHECK_LIB(m, cos)
 410
 411 dnl **************************************************************************
 412 dnl * Checks for header files.
 413 dnl *   Chances are, if the standard C or POSIX type header files are missing,
 414 dnl *   then LLVM just isn't going to compile.  However, it is possible that
 415 dnl *   the necessary functions/macros will be included from other
 416 dnl *   (non-standard and non-obvious) header files.
 417 dnl *
 418 dnl *   So, we'll be gracious, give it a chance, and try to go on without
 419 dnl *   them.
 420 dnl **************************************************************************
 421 AC_HEADER_STDC
 422 AC_HEADER_SYS_WAIT
 423
 424 dnl Check for ANSI C/POSIX header files
 425 AC_CHECK_HEADERS(assert.h fcntl.h limits.h sys/time.h unistd.h errno.h signal.h math.h)
 426
 427 dnl Check for system specific header files
 428 AC_CHECK_HEADERS(malloc.h strings.h sys/mman.h sys/resource.h)
 429
 430 dnl Check for header files associated with dlopen and friends
 431 AC_CHECK_HEADERS(dlfcn.h link.h)
 432
 433 dnl **************************************************************************
 434 dnl * Checks for typedefs, structures, and compiler characteristics.
 435 dnl **************************************************************************
 436
 437 dnl Check for const and inline keywords
 438 AC_C_CONST
 439 AC_C_INLINE
 440
 441 dnl Check for machine endian-ness
 442 AC_C_BIGENDIAN(AC_DEFINE([ENDIAN_BIG]),AC_DEFINE(ENDIAN_LITTLE))
 443
 444 dnl Check for types
 445 AC_TYPE_PID_T
 446 AC_TYPE_SIZE_T
 447 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 448 AC_CHECK_TYPES([uint64_t],,AC_MSG_ERROR([Type uint64_t required but not found]))
 449 AC_HEADER_TIME
 450 AC_STRUCT_TM
 451
 452 dnl Check for C++ extensions
 453 AC_CXX_HAVE_EXT_HASH_MAP
 454 AC_CXX_HAVE_EXT_HASH_SET
 455 AC_CXX_HAVE_EXT_SLIST
 456 AC_CXX_HAVE_STD_ITERATOR
 457 AC_CXX_HAVE_BI_ITERATOR
 458 AC_CXX_HAVE_FWD_ITERATOR
 459
 460 dnl **************************************************************************
 461 dnl * Checks for library functions.
 462 dnl **************************************************************************
 463 AC_FUNC_ALLOCA
 464 AC_PROG_GCC_TRADITIONAL
 465 AC_FUNC_MEMCMP
 466 AC_FUNC_MMAP
 467 AC_FUNC_MMAP_FILE
 468 if test ${ac_cv_func_mmap_file} = "no"
 469 then
 470         AC_MSG_ERROR([mmap() of files required but not found])
 471 fi
 472 AC_HEADER_MMAP_ANONYMOUS
 473 AC_TYPE_SIGNAL
 474 AC_CHECK_FUNCS(getcwd gettimeofday strcspn strdup strerror strspn strstr strtod strtol)
 475
 476 dnl
 477 dnl Need to check mmap for MAP_PRIVATE, MAP_ANONYMOUS, MAP_ANON, MAP_FIXED
 478 dnl MAP_FIXED is only needed for Sparc
 479 dnl MAP_ANON is used for Sparc and BSD
 480 dnl Everyone should have MAP_PRIVATE
 481 dnl
 482
 483 dnl Check for certain functions (even if we've already found them) so that we
 484 dnl can quit with an error if they are unavailable.
 485 dnl
 486 dnl As the code is made more portable (i.e. less reliant on these functions,
 487 dnl these checks should go away.
 488 AC_CHECK_FUNC(mmap,,AC_MSG_ERROR([Function mmap() required but not found]))
 489 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 490
 491 dnl **************************************************************************
 492 dnl * Enable various compile-time options
 493 dnl **************************************************************************
 494
 495 dnl Purify Option
 496 AC_ARG_ENABLE(purify,AC_HELP_STRING([--enable-purify],[Compile with purify (default is NO)]),,enableval="no")
 497 if test ${enableval} = "no"
 498 then
 499         AC_SUBST(ENABLE_PURIFY,[[]])
 500 else
 501         AC_SUBST(ENABLE_PURIFY,[[ENABLE_PURIFY=1]])
 502 fi
 503
 504 dnl Optimized Option
 505 AC_ARG_ENABLE(optimized,AC_HELP_STRING([--enable-optimized],[Compile with optimizations enabled (default is NO)]),,enableval=no)
 506 if test ${enableval} = "no"
 507 then
 508         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 509 else
 510         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 511 fi
 512
 513 dnl Spec Benchmarks
 514 AC_ARG_ENABLE(spec,AC_HELP_STRING([--enable-spec],[Compile SPEC benchmarks (default is NO)]),,enableval=no)
 515 if test ${enableval} = "no"
 516 then
 517         AC_SUBST(USE_SPEC,[[]])
 518 else
 519         AC_SUBST(USE_SPEC,[[USE_SPEC=1]])
 520 fi
 521
 522 dnl Precompiled Bytecode Option
 523 AC_ARG_ENABLE(precompiled_bytecode,AC_HELP_STRING([--enable-precompiled_bytecode],[Use pre-compiled bytecode (default is NO)]),,enableval=no)
 524 if test ${enableval} = "no"
 525 then
 526         AC_SUBST(UPB,[[]])
 527 else
 528         AC_SUBST(UPB,[[USE_PRECOMPILED_BYTECODE=1]])
 529 fi
 530
 531
 532 dnl LLC Diff Option
 533 AC_ARG_ENABLE(llc_diffs,AC_HELP_STRING([--enable-llc_diffs],[Enable LLC Diffs when testing (default is YES)]),,enableval=yes)
 534 if test ${enableval} = "no"
 535 then
 536         AC_SUBST(DISABLE_LLC_DIFFS,[DISABLE_LLC_DIFFS:=1])
 537 else
 538         AC_SUBST(DISABLE_LLC_DIFFS,[[]])
 539 fi
 540
 541 dnl JIT Option
 542 AC_ARG_ENABLE(jit,AC_HELP_STRING([--enable-jit],[Enable Just In Time Compiling (default is YES)]),,enableval=default)
 543
 544 if test ${enableval} = "no"
 545 then
 546         AC_SUBST(JIT,[[]])
 547 else
 548         case $target in
 549                 *i*86*)
 550                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 551                         ;;
 552                 *sparc*)
 553                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 554                         ;;
 555                 *)
 556                         AC_SUBST(JIT,[[]])
 557                         ;;
 558         esac
 559 fi
 560
 561 dnl **************************************************************************
 562 dnl * Set the location of various third-party software packages
 563 dnl **************************************************************************
 564
 565 dnl Location of SPEC benchmarks
 566 AC_ARG_WITH(spec,AC_HELP_STRING([--with-spec],[Location of SPEC benchmarks]),AC_SUBST(SPEC_ROOT,[$withval]),AC_SUBST(SPEC_ROOT,[/home/vadve/shared/benchmarks/speccpu2000/benchspec]))
 567
 568 dnl Location of the LLVM C front end
 569 AC_ARG_WITH(llvmgccdir,AC_HELP_STRING([--with-llvmgccdir],[Location of LLVM GCC front-end]),AC_SUBST(LLVMGCCDIR,[$withval]))
 570
 571 dnl Location of the bytecode repository
 572 AC_ARG_WITH(bcrepos,AC_HELP_STRING([--with-bcrepos],[Location of Bytecode Repository]),AC_SUBST(BCR,[$withval]),AC_SUBST(BCR,[/home/vadve/lattner/LLVMPrograms]))
 573
 574 dnl Location of PAPI
 575 AC_ARG_WITH(papi,AC_HELP_STRING([--with-papi],[Location of PAPI]),AC_SUBST(PAPIDIR,[$withval]),AC_SUBST(PAPIDIR,[/home/vadve/shared/Sparc/papi-2.3.4.1]))
 576
 577 dnl Location of the purify program
 578 AC_ARG_WITH(purify,AC_HELP_STRING([--with-purify],[Location of purify program]),AC_SUBST(PURIFY,[$withval]))
 579
 580 dnl **************************************************************************
 581 dnl * Configure other software packages (via AC_CONFIG_SUBDIRS)
 582 dnl **************************************************************************
 583
 584 dnl **************************************************************************
 585 dnl * Create the output files
 586 dnl **************************************************************************
 587 AC_OUTPUT(Makefile.config)