autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.4svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [4], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-kfreebsd-gnu)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="GNU/kFreeBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-openbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="OpenBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-netbsd*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="NetBSD"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-dragonfly*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="DragonFly"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-hpux*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="HP-UX"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-interix*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Interix"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-linux*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="Linux"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-gnu*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="GNU"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-solaris*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="SunOS"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-auroraux*)
 276     llvm_cv_link_all_option="-Wl,-z,allextract"
 277     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 278     llvm_cv_os_type="AuroraUX"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-win32*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Win32"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-mingw*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="MingW"
 289     llvm_cv_platform_type="Win32" ;;
 290   *-*-haiku*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Haiku"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-eabi*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-unknown-elf*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Freestanding"
 304     llvm_cv_platform_type="Unix" ;;
 305   *)
 306     llvm_cv_link_all_option=""
 307     llvm_cv_no_link_all_option=""
 308     llvm_cv_os_type="Unknown"
 309     llvm_cv_platform_type="Unknown" ;;
 310 esac])
 311
 312 AC_CACHE_CHECK([type of operating system we're going to target],
 313                [llvm_cv_target_os_type],
 314 [case $target in
 315   *-*-aix*)
 316     llvm_cv_target_os_type="AIX" ;;
 317   *-*-irix*)
 318     llvm_cv_target_os_type="IRIX" ;;
 319   *-*-cygwin*)
 320     llvm_cv_target_os_type="Cygwin" ;;
 321   *-*-darwin*)
 322     llvm_cv_target_os_type="Darwin" ;;
 323   *-*-minix*)
 324     llvm_cv_target_os_type="Minix" ;;
 325   *-*-freebsd*)
 326     llvm_cv_target_os_type="FreeBSD" ;;
 327   *-*-kfreebsd-gnu)
 328     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 329   *-*-openbsd*)
 330     llvm_cv_target_os_type="OpenBSD" ;;
 331   *-*-netbsd*)
 332     llvm_cv_target_os_type="NetBSD" ;;
 333   *-*-dragonfly*)
 334     llvm_cv_target_os_type="DragonFly" ;;
 335   *-*-hpux*)
 336     llvm_cv_target_os_type="HP-UX" ;;
 337   *-*-interix*)
 338     llvm_cv_target_os_type="Interix" ;;
 339   *-*-linux*)
 340     llvm_cv_target_os_type="Linux" ;;
 341   *-*-gnu*)
 342     llvm_cv_target_os_type="GNU" ;;
 343   *-*-solaris*)
 344     llvm_cv_target_os_type="SunOS" ;;
 345   *-*-auroraux*)
 346     llvm_cv_target_os_type="AuroraUX" ;;
 347   *-*-win32*)
 348     llvm_cv_target_os_type="Win32" ;;
 349   *-*-mingw*)
 350     llvm_cv_target_os_type="MingW" ;;
 351   *-*-haiku*)
 352     llvm_cv_target_os_type="Haiku" ;;
 353   *-*-rtems*)
 354     llvm_cv_target_os_type="RTEMS" ;;
 355   *-*-nacl*)
 356     llvm_cv_target_os_type="NativeClient" ;;
 357   *-unknown-eabi*)
 358     llvm_cv_target_os_type="Freestanding" ;;
 359   *)
 360     llvm_cv_target_os_type="Unknown" ;;
 361 esac])
 362
 363 dnl Make sure we aren't attempting to configure for an unknown system
 364 if test "$llvm_cv_os_type" = "Unknown" ; then
 365   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 366 fi
 367
 368 dnl Set the "OS" Makefile variable based on the platform type so the
 369 dnl makefile can configure itself to specific build hosts
 370 AC_SUBST(OS,$llvm_cv_os_type)
 371 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 372 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 373
 374 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 375 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 376 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 377
 378 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 379 dnl This is used by lib/Support to determine the basic kind of implementation
 380 dnl to use.
 381 case $llvm_cv_platform_type in
 382   Unix)
 383     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 384     AC_SUBST(LLVM_ON_UNIX,[1])
 385     AC_SUBST(LLVM_ON_WIN32,[0])
 386     ;;
 387   Win32)
 388     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 389     AC_SUBST(LLVM_ON_UNIX,[0])
 390     AC_SUBST(LLVM_ON_WIN32,[1])
 391     ;;
 392 esac
 393
 394 dnl Determine what our target architecture is and configure accordingly.
 395 dnl This will allow Makefiles to make a distinction between the hardware and
 396 dnl the OS.
 397 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 398 [case $target in
 399   i?86-*)                 llvm_cv_target_arch="x86" ;;
 400   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 401   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 402   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 403   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 404   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 405   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 406   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 407   xcore-*)                llvm_cv_target_arch="XCore" ;;
 408   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 409   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 410   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 411   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 412   *)                      llvm_cv_target_arch="Unknown" ;;
 413 esac])
 414
 415 if test "$llvm_cv_target_arch" = "Unknown" ; then
 416   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 417 fi
 418
 419 dnl Determine the LLVM native architecture for the target
 420 case "$llvm_cv_target_arch" in
 421     x86)     LLVM_NATIVE_ARCH="X86" ;;
 422     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 423     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 424 esac
 425
 426 dnl Define a substitution, ARCH, for the target architecture
 427 AC_SUBST(ARCH,$llvm_cv_target_arch)
 428
 429 dnl Determine what our host architecture.
 430 dnl This will allow MCJIT regress tests runs only for supported
 431 dnl platforms.
 432 case $host in
 433   i?86-*)                 host_arch="x86" ;;
 434   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 435   sparc*-*)               host_arch="Sparc" ;;
 436   powerpc*-*)             host_arch="PowerPC" ;;
 437   arm*-*)                 host_arch="ARM" ;;
 438   aarch64*-*)             host_arch="AArch64" ;;
 439   mips-* | mips64-*)      host_arch="Mips" ;;
 440   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 441   xcore-*)                host_arch="XCore" ;;
 442   msp430-*)               host_arch="MSP430" ;;
 443   hexagon-*)              host_arch="Hexagon" ;;
 444   s390x-*)                host_arch="SystemZ" ;;
 445   *)                      host_arch="Unknown" ;;
 446 esac
 447
 448 if test "$host_arch" = "Unknown" ; then
 449   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 450 fi
 451
 452 AC_SUBST(HOST_ARCH,$host_arch)
 453
 454 dnl Check for the endianness of the target
 455 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 456
 457 dnl Check for build platform executable suffix if we're cross-compiling
 458 if test "$cross_compiling" = yes; then
 459   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 460   AC_BUILD_EXEEXT
 461   ac_build_prefix=${build_alias}-
 462   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 463   if test -z "$BUILD_CXX"; then
 464      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 465      if test -z "$BUILD_CXX"; then
 466        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 467      fi
 468   fi
 469 else
 470   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 471 fi
 472
 473 dnl Check to see if there's a .svn or .git directory indicating that this
 474 dnl build is being done from a checkout. This sets up several defaults for
 475 dnl the command line switches. When we build with a checkout directory,
 476 dnl we get a debug with assertions turned on. Without, we assume a source
 477 dnl release and we get an optimized build without assertions.
 478 dnl See --enable-optimized and --enable-assertions below
 479 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 480   cvsbuild="yes"
 481   optimize="no"
 482   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 483 else
 484   cvsbuild="no"
 485   optimize="yes"
 486 fi
 487
 488 dnl===-----------------------------------------------------------------------===
 489 dnl===
 490 dnl=== SECTION 3: Command line arguments for the configure script.
 491 dnl===
 492 dnl===-----------------------------------------------------------------------===
 493
 494 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 495 AC_ARG_ENABLE(libcpp,
 496               AS_HELP_STRING([--enable-libcpp],
 497                              [Use libc++ if available (default is NO)]),,
 498                              enableval=default)
 499 case "$enableval" in
 500   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 501   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 502   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 503   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 504 esac
 505
 506 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 507 AC_ARG_ENABLE(cxx11,
 508               AS_HELP_STRING([--enable-cxx11],
 509                              [Use c++11 if available (default is NO)]),,
 510                              enableval=default)
 511 case "$enableval" in
 512   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 513   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 514   default) AC_SUBST(ENABLE_CXX11,[0]);;
 515   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 516 esac
 517
 518 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 519 dnl line
 520 AC_ARG_ENABLE(split-dwarf,
 521               AS_HELP_STRING([--enable-split-dwarf],
 522                              [Use split-dwarf if available (default is NO)]),,
 523                              enableval=default)
 524 case "$enableval" in
 525   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 526   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 527   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 528   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 529 esac
 530
 531 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 532 clang_arcmt="yes"
 533 AC_ARG_ENABLE(clang-arcmt,
 534               AS_HELP_STRING([--enable-clang-arcmt],
 535                              [Enable building of clang ARCMT (default is YES)]),
 536                              clang_arcmt="$enableval",
 537                              enableval="yes")
 538 case "$enableval" in
 539   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 540   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 541   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 542   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 543 esac
 544
 545 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 546 clang_static_analyzer="yes"
 547 AC_ARG_ENABLE(clang-static-analyzer,
 548               AS_HELP_STRING([--enable-clang-static-analyzer],
 549                              [Enable building of clang Static Analyzer (default is YES)]),
 550                              clang_static_analyzer="$enableval",
 551                              enableval="yes")
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 554   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 555   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 557 esac
 558
 559 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 560 AC_ARG_ENABLE(clang-rewriter,
 561               AS_HELP_STRING([--enable-clang-rewriter],
 562                              [Enable building of clang rewriter (default is YES)]),,
 563                              enableval="yes")
 564 case "$enableval" in
 565   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 566   no)
 567     if test ${clang_arcmt} != "no" ; then
 568       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 569     fi
 570     if test ${clang_static_analyzer} != "no" ; then
 571       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 572     fi
 573     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 574     ;;
 575   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 576   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 577 esac
 578
 579 dnl --enable-optimized : check whether they want to do an optimized build:
 580 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 581  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 582 if test ${enableval} = "no" ; then
 583   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 584 else
 585   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 586 fi
 587
 588 dnl --enable-profiling : check whether they want to do a profile build:
 589 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 590  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 591 if test ${enableval} = "no" ; then
 592   AC_SUBST(ENABLE_PROFILING,[[]])
 593 else
 594   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 595 fi
 596
 597 dnl --enable-assertions : check whether they want to turn on assertions or not:
 598 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 599   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 600 if test ${enableval} = "yes" ; then
 601   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 602 else
 603   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 604 fi
 605
 606 dnl --enable-werror : check whether we want Werror on by default
 607 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 608   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 609 case "$enableval" in
 610   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 611   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 612   default) AC_SUBST(ENABLE_WERROR,[0]);;
 613   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 614 esac
 615
 616 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 617 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 618   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 619 if test ${enableval} = "yes" ; then
 620   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 621   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 622 else
 623   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 624   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 625 fi
 626
 627 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 628 AC_ARG_ENABLE(debug-runtime,
 629    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 630 if test ${enableval} = "no" ; then
 631   AC_SUBST(DEBUG_RUNTIME,[[]])
 632 else
 633   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 634 fi
 635
 636 dnl --enable-debug-symbols : should even optimized compiler libraries
 637 dnl have debug symbols?
 638 AC_ARG_ENABLE(debug-symbols,
 639    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 640 if test ${enableval} = "no" ; then
 641   AC_SUBST(DEBUG_SYMBOLS,[[]])
 642 else
 643   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 644 fi
 645
 646 dnl --enable-keep-symbols : do not strip installed executables
 647 AC_ARG_ENABLE(keep-symbols,
 648    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 649 if test ${enableval} = "no" ; then
 650   AC_SUBST(KEEP_SYMBOLS,[[]])
 651 else
 652   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 653 fi
 654
 655 dnl --enable-jit: check whether they want to enable the jit
 656 AC_ARG_ENABLE(jit,
 657   AS_HELP_STRING(--enable-jit,
 658                  [Enable Just In Time Compiling (default is YES)]),,
 659   enableval=default)
 660 if test ${enableval} = "no"
 661 then
 662   AC_SUBST(JIT,[[]])
 663 else
 664   case "$llvm_cv_target_arch" in
 665     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 666     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 667     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 668     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 669     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 670     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 671     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 672     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 673     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 674     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 675     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 676     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 677     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 678   esac
 679 fi
 680
 681 dnl Allow enablement of building and installing docs
 682 AC_ARG_ENABLE(docs,
 683               AS_HELP_STRING([--enable-docs],
 684                              [Build documents (default is YES)]),,
 685                              enableval=default)
 686 case "$enableval" in
 687   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 688   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 689   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 690   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 691 esac
 692
 693 dnl Allow enablement of doxygen generated documentation
 694 AC_ARG_ENABLE(doxygen,
 695               AS_HELP_STRING([--enable-doxygen],
 696                              [Build doxygen documentation (default is NO)]),,
 697                              enableval=default)
 698 case "$enableval" in
 699   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 700   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 701   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 702   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 703 esac
 704
 705 dnl Allow disablement of threads
 706 AC_ARG_ENABLE(threads,
 707               AS_HELP_STRING([--enable-threads],
 708                              [Use threads if available (default is YES)]),,
 709                              enableval=default)
 710 case "$enableval" in
 711   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 712   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 713   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 714   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 715 esac
 716 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 717                    [Define if threads enabled])
 718
 719 dnl Allow disablement of pthread.h
 720 AC_ARG_ENABLE(pthreads,
 721               AS_HELP_STRING([--enable-pthreads],
 722                              [Use pthreads if available (default is YES)]),,
 723                              enableval=default)
 724 case "$enableval" in
 725   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 726   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 727   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 728   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 729 esac
 730
 731 dnl Allow disablement of zlib
 732 AC_ARG_ENABLE(zlib,
 733               AS_HELP_STRING([--enable-zlib],
 734                              [Use zlib for compression/decompression if
 735                               available (default is YES)]),,
 736                               enableval=default)
 737 case "$enableval" in
 738   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 739   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 740   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 741   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 742 esac
 743 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 744                    [Define if zlib is enabled])
 745
 746 dnl Allow building without position independent code
 747 AC_ARG_ENABLE(pic,
 748   AS_HELP_STRING([--enable-pic],
 749                  [Build LLVM with Position Independent Code (default is YES)]),,
 750                  enableval=default)
 751 case "$enableval" in
 752   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 753   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 754   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 755   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 756 esac
 757 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 758                    [Define if position independent code is enabled])
 759
 760 dnl Allow building a shared library and linking tools against it.
 761 AC_ARG_ENABLE(shared,
 762   AS_HELP_STRING([--enable-shared],
 763                  [Build a shared library and link tools against it (default is NO)]),,
 764                  enableval=default)
 765 case "$enableval" in
 766   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 767   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 768   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 769   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 770 esac
 771
 772 dnl Allow libstdc++ is embedded in LLVM.dll.
 773 AC_ARG_ENABLE(embed-stdcxx,
 774   AS_HELP_STRING([--enable-embed-stdcxx],
 775                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 776                  enableval=default)
 777 case "$enableval" in
 778   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 779   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 780   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 781   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 782 esac
 783
 784 dnl Enable embedding timestamp information into build.
 785 AC_ARG_ENABLE(timestamps,
 786   AS_HELP_STRING([--enable-timestamps],
 787                  [Enable embedding timestamp information in build (default is YES)]),,
 788                  enableval=default)
 789 case "$enableval" in
 790   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 791   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 792   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 793   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 794 esac
 795 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 796                    [Define if timestamp information (e.g., __DATE__) is allowed])
 797
 798 dnl Enable embedding timestamp information into build.
 799
 800 AC_ARG_ENABLE(backtraces,
 801   AS_HELP_STRING([--enable-backtraces],
 802                  [Enable embedding backtraces on crash (default is YES)]),,
 803                  enableval=default)
 804 case "$enableval" in
 805   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 806   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 807   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 808   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 809 esac
 810 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 811                    [Define if you want backtraces on crash])
 812
 813 dnl Allow specific targets to be specified for building (or not)
 814 TARGETS_TO_BUILD=""
 815 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 816     [Build specific host targets: all or target1,target2,... Valid targets are:
 817      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 818      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 819     enableval=all)
 820 if test "$enableval" = host-only ; then
 821   enableval=host
 822 fi
 823 case "$enableval" in
 824   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 825   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 826       case "$a_target" in
 827         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 828         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 829         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 830         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 831         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 832         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 833         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 834         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 835         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 836         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 837         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 838         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 839         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 840         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 841         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 842         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 843         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 844         host) case "$llvm_cv_target_arch" in
 845             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 846             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 847             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 848             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 849             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 850             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 851             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 852             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 853             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 854             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 855             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 856             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 857             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 858           esac ;;
 859         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 860       esac
 861   done
 862   ;;
 863 esac
 864
 865 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 866     [Build experimental host targets: disable or target1,target2,...
 867      (default=disable)]),,
 868     enableval=disable)
 869
 870 if test ${enableval} != "disable"
 871 then
 872   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 873 fi
 874
 875 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 876
 877 dnl Determine whether we are building LLVM support for the native architecture.
 878 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 879 for a_target in $TARGETS_TO_BUILD; do
 880   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 881     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 882       [LLVM architecture name for the native architecture, if available])
 883     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 884     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 885     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 886     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 887     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 888       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 889     fi
 890     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 891       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 892     fi
 893     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 894       [LLVM name for the native Target init function, if available])
 895     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 896       [LLVM name for the native TargetInfo init function, if available])
 897     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 898       [LLVM name for the native target MC init function, if available])
 899     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 900       [LLVM name for the native AsmPrinter init function, if available])
 901     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 902       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 903        [LLVM name for the native AsmParser init function, if available])
 904     fi
 905     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 906       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 907        [LLVM name for the native Disassembler init function, if available])
 908     fi
 909   fi
 910 done
 911
 912 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 913 dnl target feature def files.
 914 LLVM_ENUM_TARGETS=""
 915 LLVM_ENUM_ASM_PRINTERS=""
 916 LLVM_ENUM_ASM_PARSERS=""
 917 LLVM_ENUM_DISASSEMBLERS=""
 918 for target_to_build in $TARGETS_TO_BUILD; do
 919   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 920   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 921     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 922   fi
 923   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 924     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 925   fi
 926   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 927     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 928   fi
 929 done
 930 AC_SUBST(LLVM_ENUM_TARGETS)
 931 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 932 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 933 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 934
 935 dnl Override the option to use for optimized builds.
 936 AC_ARG_WITH(optimize-option,
 937   AS_HELP_STRING([--with-optimize-option],
 938                  [Select the compiler options to use for optimized builds]),,
 939                  withval=default)
 940 AC_MSG_CHECKING([optimization flags])
 941 case "$withval" in
 942   default)
 943     case "$llvm_cv_os_type" in
 944     FreeBSD) optimize_option=-O2 ;;
 945     MingW) optimize_option=-O2 ;;
 946     *)     optimize_option=-O3 ;;
 947     esac ;;
 948   *) optimize_option="$withval" ;;
 949 esac
 950 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 951 AC_MSG_RESULT([$optimize_option])
 952
 953 dnl Specify extra build options
 954 AC_ARG_WITH(extra-options,
 955   AS_HELP_STRING([--with-extra-options],
 956                  [Specify additional options to compile LLVM with]),,
 957                  withval=default)
 958 case "$withval" in
 959   default) EXTRA_OPTIONS= ;;
 960   *) EXTRA_OPTIONS=$withval ;;
 961 esac
 962 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 963
 964 dnl Specify extra linker build options
 965 AC_ARG_WITH(extra-ld-options,
 966   AS_HELP_STRING([--with-extra-ld-options],
 967                  [Specify additional options to link LLVM with]),,
 968                  withval=default)
 969 case "$withval" in
 970   default) EXTRA_LD_OPTIONS= ;;
 971   *) EXTRA_LD_OPTIONS=$withval ;;
 972 esac
 973 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 974
 975 dnl Allow specific bindings to be specified for building (or not)
 976 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 977     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 978     enableval=default)
 979 BINDINGS_TO_BUILD=""
 980 case "$enableval" in
 981   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 982   all ) BINDINGS_TO_BUILD="ocaml" ;;
 983   none | no) BINDINGS_TO_BUILD="" ;;
 984   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 985       case "$a_binding" in
 986         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 987         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 988       esac
 989   done
 990   ;;
 991 esac
 992
 993 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 994 dnl script for bindings/ocaml/configure, except that its auto value depends on
 995 dnl OCAMLC, which is found here to support tests.
 996 AC_ARG_WITH([ocaml-libdir],
 997   [AS_HELP_STRING([--with-ocaml-libdir],
 998     [Specify install location for ocaml bindings (default is stdlib)])],
 999   [],
1000   [withval=auto])
1001 case "$withval" in
1002   auto) with_ocaml_libdir="$withval" ;;
1003   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1004   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1005 esac
1006
1007 AC_ARG_WITH(clang-srcdir,
1008   AS_HELP_STRING([--with-clang-srcdir],
1009     [Directory to the out-of-tree Clang source]),,
1010     withval="-")
1011 case "$withval" in
1012   -) clang_src_root="" ;;
1013   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1014   *) clang_src_root="$ac_pwd/$withval" ;;
1015 esac
1016 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1017
1018 AC_ARG_WITH(clang-resource-dir,
1019   AS_HELP_STRING([--with-clang-resource-dir],
1020     [Relative directory from the Clang binary for resource files]),,
1021     withval="")
1022 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1023                    [Relative directory for resource files])
1024
1025 AC_ARG_WITH(c-include-dirs,
1026   AS_HELP_STRING([--with-c-include-dirs],
1027     [Colon separated list of directories clang will search for headers]),,
1028     withval="")
1029 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1030                    [Directories clang will search for headers])
1031
1032 # Clang normally uses the system c++ headers and libraries. With this option,
1033 # clang will use the ones provided by a gcc installation instead. This option should
1034 # be passed the same value that was used with --prefix when configuring gcc.
1035 AC_ARG_WITH(gcc-toolchain,
1036   AS_HELP_STRING([--with-gcc-toolchain],
1037     [Directory where gcc is installed.]),,
1038     withval="")
1039 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1040                    [Directory where gcc is installed.])
1041
1042 AC_ARG_WITH(default-sysroot,
1043   AS_HELP_STRING([--with-default-sysroot],
1044     [Add --sysroot=<path> to all compiler invocations.]),,
1045     withval="")
1046 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1047                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1048
1049 dnl Allow linking of LLVM with GPLv3 binutils code.
1050 AC_ARG_WITH(binutils-include,
1051   AS_HELP_STRING([--with-binutils-include],
1052     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1053   withval=default)
1054 case "$withval" in
1055   default) WITH_BINUTILS_INCDIR=default ;;
1056   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1057   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1058 esac
1059 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1060   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1061   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1062      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1063      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1064   fi
1065 fi
1066
1067 dnl Specify the URL where bug reports should be submitted.
1068 AC_ARG_WITH(bug-report-url,
1069   AS_HELP_STRING([--with-bug-report-url],
1070     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1071     withval="http://llvm.org/bugs/")
1072 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1073                    [Bug report URL.])
1074
1075 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1076 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1077   [--enable-terminfo],
1078   [Query the terminfo database if available (default is YES)]),
1079   [case "$enableval" in
1080     yes) llvm_cv_enable_terminfo="yes" ;;
1081     no)  llvm_cv_enable_terminfo="no"  ;;
1082     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1083   esac],
1084   llvm_cv_enable_terminfo="yes")
1085
1086 dnl --enable-libffi : check whether the user wants to turn off libffi:
1087 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1088   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1089   [case "$enableval" in
1090     yes) llvm_cv_enable_libffi="yes" ;;
1091     no)  llvm_cv_enable_libffi="no"  ;;
1092     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1093   esac],
1094   llvm_cv_enable_libffi=no)
1095
1096 AC_ARG_WITH(internal-prefix,
1097   AS_HELP_STRING([--with-internal-prefix],
1098     [Installation directory for internal files]),,
1099     withval="")
1100 AC_SUBST(INTERNAL_PREFIX,[$withval])
1101
1102 dnl===-----------------------------------------------------------------------===
1103 dnl===
1104 dnl=== SECTION 4: Check for programs we need and that they are the right version
1105 dnl===
1106 dnl===-----------------------------------------------------------------------===
1107
1108 AC_PROG_NM
1109 AC_SUBST(NM)
1110
1111 dnl Check for the tools that the makefiles require
1112 AC_CHECK_GNU_MAKE
1113 AC_PROG_LN_S
1114 AC_PATH_PROG(CMP, [cmp], [cmp])
1115 AC_PATH_PROG(CP, [cp], [cp])
1116 AC_PATH_PROG(DATE, [date], [date])
1117 AC_PATH_PROG(FIND, [find], [find])
1118 AC_PATH_PROG(GREP, [grep], [grep])
1119 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1120 AC_PATH_PROG(MV,   [mv],   [mv])
1121 AC_PROG_RANLIB
1122 AC_CHECK_TOOL(AR, ar, false)
1123 AC_PATH_PROG(RM,   [rm],   [rm])
1124 AC_PATH_PROG(SED,  [sed],  [sed])
1125 AC_PATH_PROG(TAR,  [tar],  [gtar])
1126 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1127
1128 dnl Looking for misc. graph plotting software
1129 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1130 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1131   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1132   dnl If we're targeting for mingw we should emit windows paths, not msys
1133   if test "$llvm_cv_os_type" = "MingW" ; then
1134     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1135   fi
1136   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1137    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1138 fi
1139 AC_PATH_PROG(DOT, [dot], [echo dot])
1140 if test "$DOT" != "echo dot" ; then
1141   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1142   dnl If we're targeting for mingw we should emit windows paths, not msys
1143   if test "$llvm_cv_os_type" = "MingW" ; then
1144     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1145   fi
1146   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1147    [Define to path to dot program if found or 'echo dot' otherwise])
1148 fi
1149 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1150 if test "$FDP" != "echo fdp" ; then
1151   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1152   dnl If we're targeting for mingw we should emit windows paths, not msys
1153   if test "$llvm_cv_os_type" = "MingW" ; then
1154     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1155   fi
1156   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1157    [Define to path to fdp program if found or 'echo fdp' otherwise])
1158 fi
1159 AC_PATH_PROG(NEATO, [neato], [echo neato])
1160 if test "$NEATO" != "echo neato" ; then
1161   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1162   dnl If we're targeting for mingw we should emit windows paths, not msys
1163   if test "$llvm_cv_os_type" = "MingW" ; then
1164     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1165   fi
1166   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1167    [Define to path to neato program if found or 'echo neato' otherwise])
1168 fi
1169 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1170 if test "$TWOPI" != "echo twopi" ; then
1171   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1172   dnl If we're targeting for mingw we should emit windows paths, not msys
1173   if test "$llvm_cv_os_type" = "MingW" ; then
1174     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1175   fi
1176   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1177    [Define to path to twopi program if found or 'echo twopi' otherwise])
1178 fi
1179 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1180 if test "$CIRCO" != "echo circo" ; then
1181   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1182   dnl If we're targeting for mingw we should emit windows paths, not msys
1183   if test "$llvm_cv_os_type" = "MingW" ; then
1184     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1185   fi
1186   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1187    [Define to path to circo program if found or 'echo circo' otherwise])
1188 fi
1189 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1190 if test "$GV" != "echo gv" ; then
1191   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1192   dnl If we're targeting for mingw we should emit windows paths, not msys
1193   if test "$llvm_cv_os_type" = "MingW" ; then
1194     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1195   fi
1196   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1197    [Define to path to gv program if found or 'echo gv' otherwise])
1198 fi
1199 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1200 if test "$DOTTY" != "echo dotty" ; then
1201   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1202   dnl If we're targeting for mingw we should emit windows paths, not msys
1203   if test "$llvm_cv_os_type" = "MingW" ; then
1204     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1205   fi
1206   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1207    [Define to path to dotty program if found or 'echo dotty' otherwise])
1208 fi
1209 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1210 if test "$XDOT" != "echo xdot" ; then
1211   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1212   dnl If we're targeting for mingw we should emit windows paths, not msys
1213   if test "$llvm_cv_os_type" = "MingW" ; then
1214     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1215   fi
1216   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1217    [Define to path to xdot program if found or 'echo xdot' otherwise])
1218 fi
1219
1220 dnl Find the install program
1221 AC_PROG_INSTALL
1222 dnl Prepend src dir to install path dir if it's a relative path
1223 dnl This is a hack for installs that take place in something other
1224 dnl than the top level.
1225 case "$INSTALL" in
1226  [[\\/$]]* | ?:[[\\/]]* ) ;;
1227  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1228 esac
1229
1230 dnl Checks for documentation and testing tools that we can do without. If these
1231 dnl are not found then they are set to "true" which always succeeds but does
1232 dnl nothing. This just lets the build output show that we could have done
1233 dnl something if the tool was available.
1234 AC_PATH_PROG(BZIP2, [bzip2])
1235 AC_PATH_PROG(CAT, [cat])
1236 AC_PATH_PROG(DOXYGEN, [doxygen])
1237 AC_PATH_PROG(GROFF, [groff])
1238 AC_PATH_PROG(GZIPBIN, [gzip])
1239 AC_PATH_PROG(PDFROFF, [pdfroff])
1240 AC_PATH_PROG(ZIP, [zip])
1241 AC_PATH_PROGS(OCAMLC, [ocamlc])
1242 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1243 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1244 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1245 AC_PATH_PROGS(GAS, [gas as])
1246
1247 dnl Get the version of the linker in use.
1248 AC_LINK_GET_VERSION
1249
1250 dnl Determine whether the linker supports the -R option.
1251 AC_LINK_USE_R
1252
1253 dnl Determine whether the compiler supports the -rdynamic option.
1254 AC_LINK_EXPORT_DYNAMIC
1255
1256 dnl Determine whether the linker supports the --version-script option.
1257 AC_LINK_VERSION_SCRIPT
1258
1259 dnl Check for libtool and the library that has dlopen function (which must come
1260 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1261 dnl libtool).
1262 AC_LIBTOOL_DLOPEN
1263 AC_LIB_LTDL
1264
1265 AC_MSG_CHECKING([tool compatibility])
1266
1267 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1268 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1269 dnl to support those options.
1270 dnl "icc" emits gcc signatures
1271 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1272 ICC=no
1273 IXX=no
1274 case $CC in
1275   icc*|icpc*)
1276     ICC=yes
1277     IXX=yes
1278     ;;
1279    *)
1280     ;;
1281 esac
1282
1283 if test "$GCC" != "yes" && test "$ICC" != "yes"
1284 then
1285   AC_MSG_ERROR([gcc|icc required but not found])
1286 fi
1287
1288 dnl Ensure that compilation tools are compatible with GCC extensions
1289 if test "$GXX" != "yes" && test "$IXX" != "yes"
1290 then
1291   AC_MSG_ERROR([g++|clang++|icc required but not found])
1292 fi
1293
1294 dnl Verify that GCC is version 3.0 or higher
1295 if test "$GCC" = "yes"
1296 then
1297   AC_COMPILE_IFELSE(
1298 [
1299   AC_LANG_SOURCE([[
1300     #if !defined(__GNUC__) || __GNUC__ < 3
1301     #error Unsupported GCC version
1302     #endif
1303   ]])
1304 ],
1305 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1306 fi
1307
1308 dnl Check for GNU Make.  We use its extensions, so don't build without it
1309 if test -z "$llvm_cv_gnu_make_command"
1310 then
1311   AC_MSG_ERROR([GNU Make required but not found])
1312 fi
1313
1314 dnl Tool compatibility is okay if we make it here.
1315 AC_MSG_RESULT([ok])
1316
1317 dnl Check optional compiler flags.
1318 AC_MSG_CHECKING([optional compiler flags])
1319 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1320 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1321 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1322
1323 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1324 dnl false positives, so disable it.
1325 NO_UNINITIALIZED=
1326 NO_MAYBE_UNINITIALIZED=
1327 if test "$GXX" = "yes"
1328 then
1329   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1330   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1331   dnl known to be uninitialized from cases which might be uninitialized.  We
1332   dnl still want to catch the first kind of errors.
1333   if test -z "$NO_MAYBE_UNINITIALIZED"
1334   then
1335     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1336   fi
1337 fi
1338 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1339
1340 AC_ARG_WITH([python],
1341             [AS_HELP_STRING([--with-python], [path to python])],
1342             [PYTHON="$withval"])
1343
1344 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1345   AC_MSG_CHECKING([for python])
1346   AC_MSG_RESULT([user defined: $with_python])
1347 else
1348   if test -n "$PYTHON" ; then
1349     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1350   fi
1351
1352   AC_PATH_PROG([PYTHON], [python python2 python26],
1353                [AC_MSG_RESULT([not found])
1354                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1355 fi
1356
1357 AC_MSG_CHECKING([for python >= 2.5])
1358 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1359 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1360 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1361 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1362 if   test "$ac_python_version_major" -eq "2" \
1363    && test "$ac_python_version_minor" -ge "5" ; then
1364   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1365 else
1366   AC_MSG_RESULT([not found])
1367   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1368 fi
1369
1370 dnl===-----------------------------------------------------------------------===
1371 dnl===
1372 dnl=== SECTION 5: Check for libraries
1373 dnl===
1374 dnl===-----------------------------------------------------------------------===
1375
1376 AC_CHECK_LIB(m,sin)
1377 if test "$llvm_cv_os_type" = "MingW" ; then
1378   AC_CHECK_LIB(imagehlp, main)
1379   AC_CHECK_LIB(psapi, main)
1380 fi
1381
1382 dnl dlopen() is required for plugin support.
1383 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1384                [Define if dlopen() is available on this platform.]),
1385                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1386
1387 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1388 dnl macros to detect whether clock_gettime is available, this just finds the
1389 dnl right libraries to link with.
1390 AC_SEARCH_LIBS(clock_gettime,rt)
1391
1392 dnl The curses library is optional; used for querying terminal info
1393 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1394   dnl We need the has_color functionality in curses for it to be useful.
1395   AC_SEARCH_LIBS(setupterm,tinfo curses ncurses ncursesw,
1396                  AC_DEFINE([HAVE_TERMINFO],[1],
1397                            [Define if the setupterm() function is supported this platform.]))
1398 fi
1399
1400 dnl libffi is optional; used to call external functions from the interpreter
1401 if test "$llvm_cv_enable_libffi" = "yes" ; then
1402   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1403                  [Define if libffi is available on this platform.]),
1404                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1405 fi
1406
1407 dnl mallinfo is optional; the code can compile (minus features) without it
1408 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1409                [Define if mallinfo() is available on this platform.]))
1410
1411 dnl pthread locking functions are optional - but llvm will not be thread-safe
1412 dnl without locks.
1413 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1414   AC_CHECK_LIB(pthread, pthread_mutex_init)
1415   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1416                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1417                            [Have pthread_mutex_lock]))
1418   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1419                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1420                  [Have pthread_rwlock_init]))
1421   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1422                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1423                  [Have pthread_getspecific]))
1424 fi
1425
1426 dnl zlib is optional; used for compression/uncompression
1427 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1428   AC_CHECK_LIB(z, compress2)
1429 fi
1430
1431 dnl Allow extra x86-disassembler library
1432 AC_ARG_WITH(udis86,
1433   AS_HELP_STRING([--with-udis86=<path>],
1434     [Use udis86 external x86 disassembler library]),
1435     [
1436       AC_SUBST(USE_UDIS86, [1])
1437       case "$withval" in
1438         /usr/lib|yes) ;;
1439         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1440       esac
1441       AC_CHECK_LIB(udis86, ud_init, [], [
1442         echo "Error! You need to have libudis86 around."
1443         exit -1
1444       ])
1445     ],
1446     AC_SUBST(USE_UDIS86, [0]))
1447 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1448                    [Define if use udis86 library])
1449
1450 dnl Allow OProfile support for JIT output.
1451 AC_ARG_WITH(oprofile,
1452   AS_HELP_STRING([--with-oprofile=<prefix>],
1453     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1454     [
1455       AC_SUBST(USE_OPROFILE, [1])
1456       case "$withval" in
1457         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1458         no) llvm_cv_oppath=
1459             AC_SUBST(USE_OPROFILE, [0]) ;;
1460         *) llvm_cv_oppath="${withval}/lib/oprofile"
1461            CPPFLAGS="-I${withval}/include";;
1462       esac
1463       case $llvm_cv_os_type in
1464         Linux)
1465           if test -n "$llvm_cv_oppath" ; then
1466             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1467             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1468             dnl libbfd is not included properly in libopagent in some Debian
1469             dnl versions.  If libbfd isn't found at all, we assume opagent works
1470             dnl anyway.
1471             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1472             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1473               echo "Error! You need to have libopagent around."
1474               exit -1
1475             ])
1476             AC_CHECK_HEADER([opagent.h], [], [
1477               echo "Error! You need to have opagent.h around."
1478               exit -1
1479               ])
1480           fi ;;
1481         *)
1482           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1483       esac
1484     ],
1485     [
1486       AC_SUBST(USE_OPROFILE, [0])
1487     ])
1488 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1489                    [Define if we have the oprofile JIT-support library])
1490
1491 dnl Enable support for Intel JIT Events API.
1492 AC_ARG_WITH(intel-jitevents,
1493   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1494     [
1495        case "$withval" in
1496           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1497           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1498           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1499        esac
1500
1501       case $llvm_cv_os_type in
1502         Linux|Win32|Cygwin|MingW) ;;
1503         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1504       esac
1505
1506       case "$llvm_cv_target_arch" in
1507         x86|x86_64) ;;
1508         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1509       esac
1510     ],
1511     [
1512       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1513     ])
1514 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1515                    [Define if we have the Intel JIT API runtime support library])
1516
1517 dnl Check for libxml2
1518 dnl Right now we're just checking for the existence, we could also check for a
1519 dnl particular version via --version on xml2-config
1520 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1521
1522 AC_MSG_CHECKING(for libxml2 includes)
1523 if test "x$XML2CONFIG" = "x"; then
1524  AC_MSG_RESULT(xml2-config not found)
1525 else
1526  LIBXML2_INC=`$XML2CONFIG --cflags`
1527  AC_MSG_RESULT($LIBXML2_INC)
1528  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1529                                 LIBXML2_LIBS="-lxml2"])
1530 fi
1531 AC_SUBST(LIBXML2_LIBS)
1532 AC_SUBST(LIBXML2_INC)
1533
1534 dnl===-----------------------------------------------------------------------===
1535 dnl===
1536 dnl=== SECTION 6: Check for header files
1537 dnl===
1538 dnl===-----------------------------------------------------------------------===
1539
1540 dnl First, use autoconf provided macros for specific headers that we need
1541 dnl We don't check for ancient stuff or things that are guaranteed to be there
1542 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1543 dnl Generally we're looking for POSIX headers.
1544 AC_HEADER_DIRENT
1545 AC_HEADER_MMAP_ANONYMOUS
1546 AC_HEADER_STAT
1547 AC_HEADER_SYS_WAIT
1548 AC_HEADER_TIME
1549
1550 AC_LANG_PUSH([C++])
1551 AC_CHECK_HEADERS([cxxabi.h])
1552 AC_LANG_POP([C++])
1553 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1554 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1555 AC_CHECK_HEADERS([utime.h])
1556 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1557 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1558 AC_CHECK_HEADERS([valgrind/valgrind.h])
1559 AC_CHECK_HEADERS([fenv.h])
1560 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1561 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1562   AC_CHECK_HEADERS(pthread.h,
1563                    AC_SUBST(HAVE_PTHREAD, 1),
1564                    AC_SUBST(HAVE_PTHREAD, 0))
1565 else
1566   AC_SUBST(HAVE_PTHREAD, 0)
1567 fi
1568 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1569   AC_CHECK_HEADERS(zlib.h,
1570                    AC_SUBST(HAVE_LIBZ, 1),
1571                    AC_SUBST(HAVE_LIBZ, 0))
1572 else
1573   AC_SUBST(HAVE_LIBZ, 0)
1574 fi
1575
1576 dnl Try to find a suitable curses header.
1577 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1578   AC_CHECK_HEADERS([term.h curses.h ncurses.h ncursesw.h ncurses/curses.h ncursesw/curses.h])
1579 fi
1580
1581 dnl Try to find ffi.h.
1582 if test "$llvm_cv_enable_libffi" = "yes" ; then
1583   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1584 fi
1585
1586 dnl Try to find Darwin specific crash reporting libraries.
1587 AC_CHECK_HEADERS([CrashReporterClient.h])
1588
1589 dnl Try to find Darwin specific crash reporting global.
1590 AC_MSG_CHECKING([__crashreporter_info__])
1591 AC_LINK_IFELSE(
1592 [
1593   AC_LANG_SOURCE([[
1594     extern const char *__crashreporter_info__;
1595     int main() {
1596       __crashreporter_info__ = "test";
1597       return 0;
1598     }
1599   ]])
1600 ],
1601 [
1602   AC_MSG_RESULT([yes])
1603   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1604 ],
1605 [
1606   AC_MSG_RESULT([no])
1607   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1608 ])
1609
1610 dnl===-----------------------------------------------------------------------===
1611 dnl===
1612 dnl=== SECTION 7: Check for types and structures
1613 dnl===
1614 dnl===-----------------------------------------------------------------------===
1615
1616 AC_HUGE_VAL_CHECK
1617 AC_TYPE_PID_T
1618 AC_TYPE_SIZE_T
1619 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1620 AC_STRUCT_TM
1621 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1622 AC_CHECK_TYPES([uint64_t],,
1623          AC_CHECK_TYPES([u_int64_t],,
1624          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1625
1626 dnl===-----------------------------------------------------------------------===
1627 dnl===
1628 dnl=== SECTION 8: Check for specific functions needed
1629 dnl===
1630 dnl===-----------------------------------------------------------------------===
1631
1632 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1633 AC_CHECK_FUNCS([powf fmodf strtof round ])
1634 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1635 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1636 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1637 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1638 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1639 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1640 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1641 AC_CHECK_FUNCS([futimes futimens])
1642 AC_C_PRINTF_A
1643 AC_FUNC_RAND48
1644
1645 dnl Check the declaration "Secure API" on Windows environments.
1646 AC_CHECK_DECLS([strerror_s])
1647
1648 dnl Check symbols in libgcc.a for JIT on Mingw.
1649 if test "$llvm_cv_os_type" = "MingW" ; then
1650   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1651   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1652   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1653   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1654
1655   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1656   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1657   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1658   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1659   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1660   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1661   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1662   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1663   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1664   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1665
1666   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1667   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1668 fi
1669
1670 dnl Check Win32 API EnumerateLoadedModules.
1671 if test "$llvm_cv_os_type" = "MingW" ; then
1672   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1673   AC_COMPILE_IFELSE(
1674 [
1675   AC_LANG_SOURCE([[
1676     #include <windows.h>
1677     #include <imagehlp.h>
1678     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1679     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1680   ]])
1681 ],
1682 [
1683   AC_MSG_RESULT([yes])
1684   llvm_cv_win32_elmcb_pcstr="PCSTR"
1685 ],
1686 [
1687   AC_MSG_RESULT([no])
1688   llvm_cv_win32_elmcb_pcstr="PSTR"
1689 ])
1690   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1691 fi
1692
1693 dnl Check for variations in the Standard C++ library and STL. These macros are
1694 dnl provided by LLVM in the autoconf/m4 directory.
1695 AC_FUNC_ISNAN
1696 AC_FUNC_ISINF
1697
1698 dnl Check for mmap support.We also need to know if /dev/zero is required to
1699 dnl be opened for allocating RWX memory.
1700 dnl Make sure we aren't attempting to configure for an unknown system
1701 if test "$llvm_cv_platform_type" = "Unix" ; then
1702   AC_FUNC_MMAP
1703   AC_FUNC_MMAP_FILE
1704   AC_NEED_DEV_ZERO_FOR_MMAP
1705
1706   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1707   then
1708     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1709   fi
1710   if test "$ac_cv_func_mmap_file" = "no"
1711   then
1712     AC_MSG_WARN([mmap() of files required but not found])
1713   fi
1714 fi
1715
1716 dnl atomic builtins are required for threading support.
1717 AC_MSG_CHECKING(for GCC atomic builtins)
1718 dnl Since we'll be using these atomic builtins in C++ files we should test
1719 dnl the C++ compiler.
1720 AC_LANG_PUSH([C++])
1721 AC_LINK_IFELSE(
1722 [
1723   AC_LANG_SOURCE([[
1724     int main() {
1725       volatile unsigned long val = 1;
1726       __sync_synchronize();
1727       __sync_val_compare_and_swap(&val, 1, 0);
1728       __sync_add_and_fetch(&val, 1);
1729       __sync_sub_and_fetch(&val, 1);
1730       return 0;
1731     }
1732   ]])
1733 ],
1734 [
1735   AC_MSG_RESULT([yes])
1736   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1737 ],
1738 [
1739   AC_MSG_RESULT([no])
1740   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1741   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1742 ])
1743 AC_LANG_POP([C++])
1744
1745 dnl===-----------------------------------------------------------------------===
1746 dnl===
1747 dnl=== SECTION 9: Additional checks, variables, etc.
1748 dnl===
1749 dnl===-----------------------------------------------------------------------===
1750
1751 dnl Handle 32-bit linux systems running a 64-bit kernel.
1752 dnl This has to come after section 4 because it invokes the compiler.
1753 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1754   AC_IS_LINUX_MIXED
1755   if test "$llvm_cv_linux_mixed" = "yes"; then
1756     llvm_cv_target_arch="x86"
1757     ARCH="x86"
1758   fi
1759 fi
1760
1761 dnl Check whether __dso_handle is present
1762 AC_CHECK_FUNCS([__dso_handle])
1763
1764 dnl Propagate the shared library extension that the libltdl checks did to
1765 dnl the Makefiles so we can use it there too
1766 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1767
1768 dnl Propagate the run-time library path variable that the libltdl
1769 dnl checks found to the Makefiles so we can use it there too
1770 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1771
1772 dnl Translate the various configuration directories and other basic
1773 dnl information into substitutions that will end up in Makefile.config.in
1774 dnl that these configured values can be used by the makefiles
1775 if test "${prefix}" = "NONE" ; then
1776   prefix="/usr/local"
1777 fi
1778 eval LLVM_PREFIX="${prefix}";
1779 eval LLVM_BINDIR="${prefix}/bin";
1780 eval LLVM_DATADIR="${prefix}/share/llvm";
1781 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1782 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1783 eval LLVM_INCLUDEDIR="${prefix}/include";
1784 eval LLVM_INFODIR="${prefix}/info";
1785 eval LLVM_MANDIR="${prefix}/man";
1786 LLVM_CONFIGTIME=`date`
1787 AC_SUBST(LLVM_PREFIX)
1788 AC_SUBST(LLVM_BINDIR)
1789 AC_SUBST(LLVM_DATADIR)
1790 AC_SUBST(LLVM_DOCSDIR)
1791 AC_SUBST(LLVM_ETCDIR)
1792 AC_SUBST(LLVM_INCLUDEDIR)
1793 AC_SUBST(LLVM_INFODIR)
1794 AC_SUBST(LLVM_MANDIR)
1795 AC_SUBST(LLVM_CONFIGTIME)
1796
1797 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1798 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1799   LLVM_CONFIGTIME="(timestamp not enabled)"
1800 fi
1801
1802 dnl Place the various directories into the config.h file as #defines so that we
1803 dnl can know about the installation paths within LLVM.
1804 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1805                    [Installation prefix directory])
1806 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1807                    [Installation directory for binary executables])
1808 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1809                    [Installation directory for data files])
1810 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1811                    [Installation directory for documentation])
1812 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1813                    [Installation directory for config files])
1814 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1815                    [Installation directory for include files])
1816 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1817                    [Installation directory for .info files])
1818 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1819                    [Installation directory for man pages])
1820 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1821                    [Time at which LLVM was configured])
1822 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1823                    [Host triple LLVM will be executed on])
1824 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1825                    [Target triple LLVM will generate code for by default])
1826
1827 dnl Determine which bindings to build.
1828 if test "$BINDINGS_TO_BUILD" = auto ; then
1829   BINDINGS_TO_BUILD=""
1830   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1831     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1832   fi
1833 fi
1834 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1835
1836 dnl This isn't really configurey, but it avoids having to repeat the list in
1837 dnl other files.
1838 AC_SUBST(ALL_BINDINGS,ocaml)
1839
1840 dnl Do any work necessary to ensure that bindings have what they need.
1841 binding_prereqs_failed=0
1842 for a_binding in $BINDINGS_TO_BUILD ; do
1843   case "$a_binding" in
1844   ocaml)
1845     if test "x$OCAMLC" = x ; then
1846       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1847       binding_prereqs_failed=1
1848     fi
1849     if test "x$OCAMLDEP" = x ; then
1850       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1851       binding_prereqs_failed=1
1852     fi
1853     if test "x$OCAMLOPT" = x ; then
1854       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1855       dnl ocamlopt is optional!
1856     fi
1857     if test "x$with_ocaml_libdir" != xauto ; then
1858       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1859     else
1860       ocaml_stdlib="`"$OCAMLC" -where`"
1861       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1862       then
1863         # ocaml stdlib is beneath our prefix; use stdlib
1864         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1865       else
1866         # ocaml stdlib is outside our prefix; use libdir/ocaml
1867         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1868       fi
1869     fi
1870     ;;
1871   esac
1872 done
1873 if test "$binding_prereqs_failed" = 1 ; then
1874   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1875 fi
1876
1877 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1878 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1879
1880 dnl Determine linker rpath flag
1881 if test "$llvm_cv_link_use_r" = "yes" ; then
1882   RPATH="-Wl,-R"
1883 else
1884   RPATH="-Wl,-rpath"
1885 fi
1886 AC_SUBST(RPATH)
1887
1888 dnl Determine linker rdynamic flag
1889 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1890   RDYNAMIC="-rdynamic"
1891 else
1892   RDYNAMIC=""
1893 fi
1894 AC_SUBST(RDYNAMIC)
1895
1896 dnl===-----------------------------------------------------------------------===
1897 dnl===
1898 dnl=== SECTION 10: Specify the output files and generate it
1899 dnl===
1900 dnl===-----------------------------------------------------------------------===
1901
1902 dnl Configure header files
1903 dnl WARNING: dnl If you add or remove any of the following config headers, then
1904 dnl you MUST also update Makefile so that the variable FilesToConfig
1905 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1906 dnl files can be updated automatically when their *.in sources change.
1907 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1908 AH_TOP([#ifndef CONFIG_H
1909 #define CONFIG_H])
1910 AH_BOTTOM([#endif])
1911
1912 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1913 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1914 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1915 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1916 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1917
1918 dnl Configure the makefile's configuration data
1919 AC_CONFIG_FILES([Makefile.config])
1920
1921 dnl Configure the RPM spec file for LLVM
1922 AC_CONFIG_FILES([llvm.spec])
1923
1924 dnl Configure doxygen's configuration file
1925 AC_CONFIG_FILES([docs/doxygen.cfg])
1926
1927 dnl Configure clang, if present
1928 if test "${clang_src_root}" = ""; then
1929   clang_src_root="$srcdir/tools/clang"
1930 fi
1931 if test -f ${clang_src_root}/README.txt; then
1932   dnl Use variables to stay under 80 columns.
1933   configh="include/clang/Config/config.h"
1934   doxy="docs/doxygen.cfg"
1935   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1936   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1937 fi
1938
1939 dnl OCaml findlib META file
1940 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1941
1942 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1943 test "x$program_prefix" = "xNONE" && program_prefix=""
1944 AC_SUBST([program_prefix])
1945
1946
1947 dnl Do special configuration of Makefiles
1948 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1949 AC_CONFIG_MAKEFILE(Makefile)
1950 AC_CONFIG_MAKEFILE(Makefile.common)
1951 AC_CONFIG_MAKEFILE(examples/Makefile)
1952 AC_CONFIG_MAKEFILE(lib/Makefile)
1953 AC_CONFIG_MAKEFILE(runtime/Makefile)
1954 AC_CONFIG_MAKEFILE(test/Makefile)
1955 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1956 AC_CONFIG_MAKEFILE(unittests/Makefile)
1957 AC_CONFIG_MAKEFILE(tools/Makefile)
1958 AC_CONFIG_MAKEFILE(utils/Makefile)
1959 AC_CONFIG_MAKEFILE(projects/Makefile)
1960 AC_CONFIG_MAKEFILE(bindings/Makefile)
1961 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1962
1963 dnl Finally, crank out the output
1964 AC_OUTPUT