CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  19
  20 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  21 if ( LLVM_USE_FOLDERS )
  22   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  23 endif()
  24
  25 include(VersionFromVCS)
  26
  27 option(LLVM_APPEND_VC_REV
  28   "Append the version control system revision id to LLVM version" OFF)
  29
  30 if( LLVM_APPEND_VC_REV )
  31   add_version_info_from_vcs(PACKAGE_VERSION)
  32 endif()
  33
  34 set(PACKAGE_NAME LLVM)
  35 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  36 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  37
  38 # Sanity check our source directory to make sure that we are not trying to
  39 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  40 # sure that we don't have any stray generated files lying around in the tree
  41 # (which would end up getting picked up by header search, instead of the correct
  42 # versions).
  43 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  44   message(FATAL_ERROR "In-source builds are not allowed.
  45 CMake would overwrite the makefiles distributed with LLVM.
  46 Please create a directory and run cmake from there, passing the path
  47 to this source directory as the last argument.
  48 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  49 Please delete them.")
  50 endif()
  51 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  52   file(GLOB_RECURSE
  53     tablegenned_files_on_include_dir
  54     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  55   file(GLOB_RECURSE
  56     tablegenned_files_on_lib_dir
  57     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  58   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  59     message(FATAL_ERROR "Apparently there is a previous in-source build,
  60 probably as the result of running `configure' and `make' on
  61 ${CMAKE_CURRENT_SOURCE_DIR}.
  62 This may cause problems. The suspicious files are:
  63 ${tablegenned_files_on_lib_dir}
  64 ${tablegenned_files_on_include_dir}
  65 Please clean the source directory.")
  66   endif()
  67 endif()
  68
  69 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  70
  71 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  72 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  73 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  74 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  75 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  76 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  77
  78 set(LLVM_ALL_TARGETS
  79   AArch64
  80   ARM
  81   CppBackend
  82   Hexagon
  83   Mips
  84   MSP430
  85   NVPTX
  86   PowerPC
  87   R600
  88   Sparc
  89   SystemZ
  90   X86
  91   XCore
  92   )
  93
  94 # List of targets with JIT support:
  95 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
  96
  97 set(LLVM_TARGETS_TO_BUILD "all"
  98     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  99
 100 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 101   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 102
 103 option(BUILD_SHARED_LIBS
 104   "Build all libraries as shared libraries instead of static" OFF)
 105
 106 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 107 if(LLVM_ENABLE_CBE_PRINTF_A)
 108   set(ENABLE_CBE_PRINTF_A 1)
 109 endif()
 110
 111 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 112 if(LLVM_ENABLE_TIMESTAMPS)
 113   set(ENABLE_TIMESTAMPS 1)
 114 endif()
 115
 116 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 117 if(LLVM_ENABLE_BACKTRACES)
 118   set(ENABLE_BACKTRACES 1)
 119 endif()
 120
 121 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 122 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 123 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 124
 125 set(LLVM_TARGET_ARCH "host"
 126   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 127
 128 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 129
 130 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 131
 132 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 133
 134 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 135   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 136 endif()
 137
 138 set(LLVM_TARGETS_TO_BUILD
 139    ${LLVM_TARGETS_TO_BUILD}
 140    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 141 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 142
 143 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 144
 145 include(AddLLVMDefinitions)
 146
 147 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 148
 149 # MSVC has a gazillion warnings with this.
 150 if( MSVC )
 151   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 152 else( MSVC )
 153   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 154 endif()
 155
 156 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 157 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 158
 159 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 160   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 161 else()
 162   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 163 endif()
 164
 165 option(LLVM_USE_INTEL_JITEVENTS
 166   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 167   OFF)
 168
 169 if( LLVM_USE_INTEL_JITEVENTS )
 170   # Verify we are on a supported platform
 171   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 172     message(FATAL_ERROR
 173       "Intel JIT API support is available on Linux and Windows only.")
 174   endif()
 175 endif( LLVM_USE_INTEL_JITEVENTS )
 176
 177 option(LLVM_USE_OPROFILE
 178   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 179
 180 # If enabled, verify we are on a platform that supports oprofile.
 181 if( LLVM_USE_OPROFILE )
 182   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 183     message(FATAL_ERROR "OProfile support is available on Linux only.")
 184   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 185 endif( LLVM_USE_OPROFILE )
 186
 187 set(LLVM_USE_SANITIZER "" CACHE STRING
 188   "Define the sanitizer used to build binaries and tests.")
 189
 190 option(LLVM_USE_SPLIT_DWARF
 191   "Use -gsplit-dwarf when compiling llvm." OFF)
 192
 193 # Define an option controlling whether we should build for 32-bit on 64-bit
 194 # platforms, where supported.
 195 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 196   # TODO: support other platforms and toolchains.
 197   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 198 endif()
 199
 200 # Define the default arguments to use with 'lit', and an option for the user to
 201 # override.
 202 set(LIT_ARGS_DEFAULT "-sv")
 203 if (MSVC OR XCODE)
 204   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 205 endif()
 206 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 207
 208 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 209 if( WIN32 AND NOT CYGWIN )
 210   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 211 endif()
 212
 213 # Define options to control the inclusion and default build behavior for
 214 # components which may not strictly be necessary (tools, runtime, examples, and
 215 # tests).
 216 #
 217 # This is primarily to support building smaller or faster project files.
 218 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 219 option(LLVM_BUILD_TOOLS
 220   "Build the LLVM tools. If OFF, just generate build targets." ON)
 221
 222 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 223 option(LLVM_BUILD_RUNTIME
 224   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 225
 226 option(LLVM_BUILD_EXAMPLES
 227   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 228 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 229
 230 option(LLVM_BUILD_TESTS
 231   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 232 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 233
 234 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 235 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 236 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 237
 238 # All options referred to from HandleLLVMOptions have to be specified
 239 # BEFORE this include, otherwise options will not be correctly set on
 240 # first cmake run
 241 include(config-ix)
 242
 243 # By default, we target the host, but this can be overridden at CMake
 244 # invocation time.
 245 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 246   "Default target for which LLVM will generate code." )
 247 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 248
 249 include(HandleLLVMOptions)
 250
 251 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 252 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 253 include(FindPythonInterp)
 254 if( NOT PYTHONINTERP_FOUND )
 255   message(FATAL_ERROR
 256 "Unable to find Python interpreter, required for builds and testing.
 257
 258 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 259 endif()
 260
 261 ######
 262 # LLVMBuild Integration
 263 #
 264 # We use llvm-build to generate all the data required by the CMake based
 265 # build system in one swoop:
 266 #
 267 #  - We generate a file (a CMake fragment) in the object root which contains
 268 #    all the definitions that are required by CMake.
 269 #
 270 #  - We generate the library table used by llvm-config.
 271 #
 272 #  - We generate the dependencies for the CMake fragment, so that we will
 273 #    automatically reconfigure outselves.
 274
 275 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 276 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 277   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 278 set(LLVMBUILDCMAKEFRAG
 279   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 280
 281 # Create the list of optional components that are enabled
 282 if (LLVM_USE_INTEL_JITEVENTS)
 283   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 284 endif (LLVM_USE_INTEL_JITEVENTS)
 285 if (LLVM_USE_OPROFILE)
 286   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 287 endif (LLVM_USE_OPROFILE)
 288
 289 message(STATUS "Constructing LLVMBuild project information")
 290 execute_process(
 291   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 292             --native-target "${LLVM_NATIVE_ARCH}"
 293             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 294             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 295             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 296             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 297             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 298             ERROR_VARIABLE LLVMBUILDERRORS
 299             OUTPUT_STRIP_TRAILING_WHITESPACE
 300             ERROR_STRIP_TRAILING_WHITESPACE
 301   RESULT_VARIABLE LLVMBUILDRESULT)
 302
 303 # On Win32, CMake doesn't properly handle piping the default output/error
 304 # streams into the GUI console. So, we explicitly catch and report them.
 305 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 306   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 307 endif()
 308 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 309   message(FATAL_ERROR
 310     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 311 endif()
 312
 313 # Include the generated CMake fragment. This will define properties from the
 314 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 315 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 316 # files change.
 317 include(${LLVMBUILDCMAKEFRAG})
 318
 319 ######
 320
 321 # Configure all of the various header file fragments LLVM uses which depend on
 322 # configuration variables.
 323 set(LLVM_ENUM_TARGETS "")
 324 set(LLVM_ENUM_ASM_PRINTERS "")
 325 set(LLVM_ENUM_ASM_PARSERS "")
 326 set(LLVM_ENUM_DISASSEMBLERS "")
 327 foreach(t ${LLVM_TARGETS_TO_BUILD})
 328   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 329
 330   list(FIND LLVM_ALL_TARGETS ${t} idx)
 331   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 332   if( idx LESS 0 AND idy LESS 0 )
 333     message(FATAL_ERROR "The target `${t}' does not exist.
 334     It should be one of\n${LLVM_ALL_TARGETS}")
 335   else()
 336     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 337   endif()
 338
 339   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 340   if( asmp_file )
 341     set(LLVM_ENUM_ASM_PRINTERS
 342       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 343   endif()
 344   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 345     set(LLVM_ENUM_ASM_PARSERS
 346       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 347   endif()
 348   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 349     set(LLVM_ENUM_DISASSEMBLERS
 350       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 351   endif()
 352 endforeach(t)
 353
 354 # Produce the target definition files, which provide a way for clients to easily
 355 # include various classes of targets.
 356 configure_file(
 357   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 358   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 359   )
 360 configure_file(
 361   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 362   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 363   )
 364 configure_file(
 365   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 366   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 367   )
 368 configure_file(
 369   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 370   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 371   )
 372
 373 # Configure the three LLVM configuration header files.
 374 configure_file(
 375   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 376   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 377 configure_file(
 378   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 379   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 380 configure_file(
 381   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 382   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 383
 384 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 385 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 386 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 387
 388 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 389
 390 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 391
 392 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 393   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 394   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 395   include_directories("/usr/local/include")
 396   link_directories("/usr/local/lib")
 397 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 398
 399 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 400    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 401 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 402
 403 # Make sure we don't get -rdynamic in every binary. For those that need it,
 404 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 405 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 406
 407 include(AddLLVM)
 408 include(TableGen)
 409
 410 if( MINGW )
 411   # People report that -O3 is unreliable on MinGW. The traditional
 412   # build also uses -O2 for that reason:
 413   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 414 endif()
 415
 416 # Put this before tblgen. Else we have a circular dependence.
 417 add_subdirectory(lib/Support)
 418 add_subdirectory(lib/TableGen)
 419
 420 add_subdirectory(utils/TableGen)
 421
 422 add_subdirectory(include/llvm)
 423
 424 add_subdirectory(lib)
 425
 426 add_subdirectory(utils/FileCheck)
 427 add_subdirectory(utils/FileUpdate)
 428 add_subdirectory(utils/count)
 429 add_subdirectory(utils/not)
 430 add_subdirectory(utils/llvm-lit)
 431 add_subdirectory(utils/yaml-bench)
 432
 433 add_subdirectory(projects)
 434
 435 if( LLVM_INCLUDE_TOOLS )
 436   add_subdirectory(tools)
 437 endif()
 438
 439 if( LLVM_INCLUDE_RUNTIME )
 440   add_subdirectory(runtime)
 441 endif()
 442
 443 if( LLVM_INCLUDE_EXAMPLES )
 444   add_subdirectory(examples)
 445 endif()
 446
 447 if( LLVM_INCLUDE_TESTS )
 448   add_subdirectory(test)
 449   add_subdirectory(utils/unittest)
 450   add_subdirectory(unittests)
 451   if (MSVC)
 452     # This utility is used to prevent crashing tests from calling Dr. Watson on
 453     # Windows.
 454     add_subdirectory(utils/KillTheDoctor)
 455   endif()
 456
 457   # Add a global check rule now that all subdirectories have been traversed
 458   # and we know the total set of lit testsuites.
 459   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 460   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 461   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 462   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 463   add_lit_target(check-all
 464     "Running all regression tests"
 465     ${LLVM_LIT_TESTSUITES}
 466     PARAMS ${LLVM_LIT_PARAMS}
 467     DEPENDS ${LLVM_LIT_DEPENDS}
 468     ARGS ${LLVM_LIT_EXTRA_ARGS}
 469     )
 470 endif()
 471
 472 if (LLVM_INCLUDE_DOCS)
 473   add_subdirectory(docs)
 474 endif()
 475
 476 add_subdirectory(cmake/modules)
 477
 478 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 479   install(DIRECTORY include/
 480     DESTINATION include
 481     FILES_MATCHING
 482     PATTERN "*.def"
 483     PATTERN "*.h"
 484     PATTERN "*.td"
 485     PATTERN "*.inc"
 486     PATTERN "LICENSE.TXT"
 487     PATTERN ".svn" EXCLUDE
 488     )
 489
 490   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 491     DESTINATION include
 492     FILES_MATCHING
 493     PATTERN "*.def"
 494     PATTERN "*.h"
 495     PATTERN "*.gen"
 496     PATTERN "*.inc"
 497     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 498     PATTERN "CMakeFiles" EXCLUDE
 499     PATTERN ".svn" EXCLUDE
 500     )
 501 endif()
 502
 503 set(CPACK_PACKAGE_VENDOR "LLVM")
 504 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 505 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 506 if( LLVM_APPEND_VC_REV )
 507   add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 508 else()
 509   set(CPACK_PACKAGE_VERSION_PATCH "svn")
 510 endif()
 511 set(CPACK_RESOURCE_FILE_LICENSE "${LLVM_MAIN_SRC_DIR}/LICENSE.TXT")
 512 if(WIN32 AND NOT UNIX)
 513   set(CPACK_PACKAGE_ICON "${LLVM_MAIN_SRC_DIR}\\\\cmake\\\\nsis_logo.bmp")
 514   set(CPACK_NSIS_MODIFY_PATH "ON")
 515 endif()
 516 include(CPack)
 517
 518 # Workaround for MSVS10 to avoid the Dialog Hell
 519 # FIXME: This could be removed with future version of CMake.
 520 if(MSVC_VERSION EQUAL 1600)
 521   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 522   if( EXISTS "${LLVM_SLN_FILENAME}" )
 523     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 524   endif()
 525 endif()