CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 5)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MODIFY_PATH "ON")
  71   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  72   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  73     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  74   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  76 endif()
  77 include(CPack)
  78
  79 # Sanity check our source directory to make sure that we are not trying to
  80 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  81 # sure that we don't have any stray generated files lying around in the tree
  82 # (which would end up getting picked up by header search, instead of the correct
  83 # versions).
  84 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  85   message(FATAL_ERROR "In-source builds are not allowed.
  86 CMake would overwrite the makefiles distributed with LLVM.
  87 Please create a directory and run cmake from there, passing the path
  88 to this source directory as the last argument.
  89 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  90 Please delete them.")
  91 endif()
  92 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  93   file(GLOB_RECURSE
  94     tablegenned_files_on_include_dir
  95     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  96   file(GLOB_RECURSE
  97     tablegenned_files_on_lib_dir
  98     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  99   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 100     message(FATAL_ERROR "Apparently there is a previous in-source build,
 101 probably as the result of running `configure' and `make' on
 102 ${CMAKE_CURRENT_SOURCE_DIR}.
 103 This may cause problems. The suspicious files are:
 104 ${tablegenned_files_on_lib_dir}
 105 ${tablegenned_files_on_include_dir}
 106 Please clean the source directory.")
 107   endif()
 108 endif()
 109
 110 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 111
 112 # They are used as destination of target generators.
 113 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 114 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 115
 116 # Each of them corresponds to llvm-config's.
 117 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 118 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 119 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 120 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 121 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 122
 123 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 124 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 125 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 126
 127 set(LLVM_ALL_TARGETS
 128   AArch64
 129   ARM
 130   CppBackend
 131   Hexagon
 132   Mips
 133   MSP430
 134   NVPTX
 135   PowerPC
 136   R600
 137   Sparc
 138   SystemZ
 139   X86
 140   XCore
 141   )
 142
 143 # List of targets with JIT support:
 144 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 145
 146 set(LLVM_TARGETS_TO_BUILD "all"
 147     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 148
 149 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 150   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 151
 152 option(BUILD_SHARED_LIBS
 153   "Build all libraries as shared libraries instead of static" OFF)
 154
 155 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 156 if(LLVM_ENABLE_TIMESTAMPS)
 157   set(ENABLE_TIMESTAMPS 1)
 158 endif()
 159
 160 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 161 if(LLVM_ENABLE_BACKTRACES)
 162   set(ENABLE_BACKTRACES 1)
 163 endif()
 164
 165 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 166 if(LLVM_ENABLE_CRASH_OVERRIDES)
 167   set(ENABLE_CRASH_OVERRIDES 1)
 168 endif()
 169
 170 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 171 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 172 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 173
 174 set(LLVM_TARGET_ARCH "host"
 175   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 176
 177 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 178
 179 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 180
 181 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 182
 183 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 184   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 185 endif()
 186
 187 set(LLVM_TARGETS_TO_BUILD
 188    ${LLVM_TARGETS_TO_BUILD}
 189    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 190 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 191
 192 include(AddLLVMDefinitions)
 193
 194 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 195
 196 # MSVC has a gazillion warnings with this.
 197 if( MSVC )
 198   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 199 else( MSVC )
 200   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 201 endif()
 202
 203 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 204 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 205 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 206 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 207
 208 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 209   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 210 else()
 211   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 212 endif()
 213
 214 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 215        "Set to ON to force using an old, unsupported host toolchain." OFF)
 216
 217 option(LLVM_USE_INTEL_JITEVENTS
 218   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 219   OFF)
 220
 221 if( LLVM_USE_INTEL_JITEVENTS )
 222   # Verify we are on a supported platform
 223   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 224     message(FATAL_ERROR
 225       "Intel JIT API support is available on Linux and Windows only.")
 226   endif()
 227 endif( LLVM_USE_INTEL_JITEVENTS )
 228
 229 option(LLVM_USE_OPROFILE
 230   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 231
 232 # If enabled, verify we are on a platform that supports oprofile.
 233 if( LLVM_USE_OPROFILE )
 234   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 235     message(FATAL_ERROR "OProfile support is available on Linux only.")
 236   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 237 endif( LLVM_USE_OPROFILE )
 238
 239 set(LLVM_USE_SANITIZER "" CACHE STRING
 240   "Define the sanitizer used to build binaries and tests.")
 241
 242 option(LLVM_USE_SPLIT_DWARF
 243   "Use -gsplit-dwarf when compiling llvm." OFF)
 244
 245 # Define an option controlling whether we should build for 32-bit on 64-bit
 246 # platforms, where supported.
 247 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 248   # TODO: support other platforms and toolchains.
 249   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 250 endif()
 251
 252 # Define the default arguments to use with 'lit', and an option for the user to
 253 # override.
 254 set(LIT_ARGS_DEFAULT "-sv")
 255 if (MSVC OR XCODE)
 256   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 257 endif()
 258 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 259
 260 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 261 if( WIN32 AND NOT CYGWIN )
 262   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 263 endif()
 264
 265 # Define options to control the inclusion and default build behavior for
 266 # components which may not strictly be necessary (tools, examples, and tests).
 267 #
 268 # This is primarily to support building smaller or faster project files.
 269 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 270 option(LLVM_BUILD_TOOLS
 271   "Build the LLVM tools. If OFF, just generate build targets." ON)
 272
 273 option(LLVM_BUILD_RUNTIME
 274   "Build the LLVM runtime libraries." ON)
 275 option(LLVM_BUILD_EXAMPLES
 276   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 277 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 278
 279 option(LLVM_BUILD_TESTS
 280   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 281 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 282
 283 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 284 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 285 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 286
 287 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 288   "Build compiler-rt as an external project." OFF)
 289
 290 # All options referred to from HandleLLVMOptions have to be specified
 291 # BEFORE this include, otherwise options will not be correctly set on
 292 # first cmake run
 293 include(config-ix)
 294
 295 # By default, we target the host, but this can be overridden at CMake
 296 # invocation time.
 297 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 298   "Default target for which LLVM will generate code." )
 299 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 300
 301 include(HandleLLVMOptions)
 302
 303 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 304 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 305 include(FindPythonInterp)
 306 if( NOT PYTHONINTERP_FOUND )
 307   message(FATAL_ERROR
 308 "Unable to find Python interpreter, required for builds and testing.
 309
 310 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 311 endif()
 312
 313 ######
 314 # LLVMBuild Integration
 315 #
 316 # We use llvm-build to generate all the data required by the CMake based
 317 # build system in one swoop:
 318 #
 319 #  - We generate a file (a CMake fragment) in the object root which contains
 320 #    all the definitions that are required by CMake.
 321 #
 322 #  - We generate the library table used by llvm-config.
 323 #
 324 #  - We generate the dependencies for the CMake fragment, so that we will
 325 #    automatically reconfigure outselves.
 326
 327 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 328 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 329   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 330 set(LLVMBUILDCMAKEFRAG
 331   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 332
 333 # Create the list of optional components that are enabled
 334 if (LLVM_USE_INTEL_JITEVENTS)
 335   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 336 endif (LLVM_USE_INTEL_JITEVENTS)
 337 if (LLVM_USE_OPROFILE)
 338   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 339 endif (LLVM_USE_OPROFILE)
 340
 341 message(STATUS "Constructing LLVMBuild project information")
 342 execute_process(
 343   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 344             --native-target "${LLVM_NATIVE_ARCH}"
 345             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 346             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 347             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 348             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 349             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 350             ERROR_VARIABLE LLVMBUILDERRORS
 351             OUTPUT_STRIP_TRAILING_WHITESPACE
 352             ERROR_STRIP_TRAILING_WHITESPACE
 353   RESULT_VARIABLE LLVMBUILDRESULT)
 354
 355 # On Win32, CMake doesn't properly handle piping the default output/error
 356 # streams into the GUI console. So, we explicitly catch and report them.
 357 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 358   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 359 endif()
 360 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 361   message(FATAL_ERROR
 362     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 363 endif()
 364
 365 # Include the generated CMake fragment. This will define properties from the
 366 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 367 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 368 # files change.
 369 include(${LLVMBUILDCMAKEFRAG})
 370
 371 ######
 372
 373 # Configure all of the various header file fragments LLVM uses which depend on
 374 # configuration variables.
 375 set(LLVM_ENUM_TARGETS "")
 376 set(LLVM_ENUM_ASM_PRINTERS "")
 377 set(LLVM_ENUM_ASM_PARSERS "")
 378 set(LLVM_ENUM_DISASSEMBLERS "")
 379 foreach(t ${LLVM_TARGETS_TO_BUILD})
 380   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 381
 382   list(FIND LLVM_ALL_TARGETS ${t} idx)
 383   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 384   if( idx LESS 0 AND idy LESS 0 )
 385     message(FATAL_ERROR "The target `${t}' does not exist.
 386     It should be one of\n${LLVM_ALL_TARGETS}")
 387   else()
 388     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 389   endif()
 390
 391   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 392   if( asmp_file )
 393     set(LLVM_ENUM_ASM_PRINTERS
 394       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 395   endif()
 396   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 397     set(LLVM_ENUM_ASM_PARSERS
 398       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 399   endif()
 400   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 401     set(LLVM_ENUM_DISASSEMBLERS
 402       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 403   endif()
 404 endforeach(t)
 405
 406 # Produce the target definition files, which provide a way for clients to easily
 407 # include various classes of targets.
 408 configure_file(
 409   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 410   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 411   )
 412 configure_file(
 413   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 414   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 415   )
 416 configure_file(
 417   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 418   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 419   )
 420 configure_file(
 421   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 422   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 423   )
 424
 425 # Configure the three LLVM configuration header files.
 426 configure_file(
 427   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 428   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 429 configure_file(
 430   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 431   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 432 configure_file(
 433   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 434   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 435
 436 # They are not referenced. See set_output_directory().
 437 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 438 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 439 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 440
 441 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 442 if (APPLE)
 443   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 444   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 445 else(UNIX)
 446   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 447     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 448     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 449       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 450     endif()
 451   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 452 endif()
 453
 454 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 455
 456 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 457
 458 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 459   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 460   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 461   include_directories("/usr/local/include")
 462   link_directories("/usr/local/lib")
 463 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 464
 465 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 466    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 467 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 468
 469 # Make sure we don't get -rdynamic in every binary. For those that need it,
 470 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 471 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 472
 473 include(AddLLVM)
 474 include(TableGen)
 475
 476 if( MINGW )
 477   # People report that -O3 is unreliable on MinGW. The traditional
 478   # build also uses -O2 for that reason:
 479   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 480 endif()
 481
 482 # Put this before tblgen. Else we have a circular dependence.
 483 add_subdirectory(lib/Support)
 484 add_subdirectory(lib/TableGen)
 485
 486 add_subdirectory(utils/TableGen)
 487
 488 add_subdirectory(include/llvm)
 489
 490 add_subdirectory(lib)
 491
 492 add_subdirectory(utils/FileCheck)
 493 add_subdirectory(utils/FileUpdate)
 494 add_subdirectory(utils/count)
 495 add_subdirectory(utils/not)
 496 add_subdirectory(utils/llvm-lit)
 497 add_subdirectory(utils/yaml-bench)
 498
 499 if(LLVM_INCLUDE_TESTS)
 500   add_subdirectory(utils/unittest)
 501 endif()
 502
 503 add_subdirectory(projects)
 504
 505 option(WITH_POLLY "Build LLVM with Polly" ON)
 506 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 507
 508 if(WITH_POLLY)
 509   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 510     set(WITH_POLLY OFF)
 511   endif()
 512 endif(WITH_POLLY)
 513
 514 if( LLVM_INCLUDE_TOOLS )
 515   add_subdirectory(tools)
 516 endif()
 517
 518 if( LLVM_INCLUDE_EXAMPLES )
 519   add_subdirectory(examples)
 520 endif()
 521
 522 if( LLVM_INCLUDE_TESTS )
 523   add_subdirectory(test)
 524   add_subdirectory(unittests)
 525   if (MSVC)
 526     # This utility is used to prevent crashing tests from calling Dr. Watson on
 527     # Windows.
 528     add_subdirectory(utils/KillTheDoctor)
 529   endif()
 530
 531   # Add a global check rule now that all subdirectories have been traversed
 532   # and we know the total set of lit testsuites.
 533   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 534   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 535   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 536   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 537   add_lit_target(check-all
 538     "Running all regression tests"
 539     ${LLVM_LIT_TESTSUITES}
 540     PARAMS ${LLVM_LIT_PARAMS}
 541     DEPENDS ${LLVM_LIT_DEPENDS}
 542     ARGS ${LLVM_LIT_EXTRA_ARGS}
 543     )
 544 endif()
 545
 546 if (LLVM_INCLUDE_DOCS)
 547   add_subdirectory(docs)
 548 endif()
 549
 550 add_subdirectory(cmake/modules)
 551
 552 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 553   install(DIRECTORY include/llvm include/llvm-c
 554     DESTINATION include
 555     FILES_MATCHING
 556     PATTERN "*.def"
 557     PATTERN "*.h"
 558     PATTERN "*.td"
 559     PATTERN "*.inc"
 560     PATTERN "LICENSE.TXT"
 561     PATTERN ".svn" EXCLUDE
 562     )
 563
 564   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 565     DESTINATION include
 566     FILES_MATCHING
 567     PATTERN "*.def"
 568     PATTERN "*.h"
 569     PATTERN "*.gen"
 570     PATTERN "*.inc"
 571     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 572     PATTERN "CMakeFiles" EXCLUDE
 573     PATTERN ".svn" EXCLUDE
 574     )
 575 endif()