CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  41   "Default URL where bug reports are to be submitted.")
  42
  43 # Configure CPack.
  44 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  45 set(CPACK_PACKAGE_VENDOR "LLVM")
  46 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  47 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  48 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  50 if(WIN32 AND NOT UNIX)
  51   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  52   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  53   set(CPACK_NSIS_MODIFY_PATH "ON")
  54   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  55   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  56     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  57   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  58     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  59 endif()
  60 include(CPack)
  61
  62 # Sanity check our source directory to make sure that we are not trying to
  63 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  64 # sure that we don't have any stray generated files lying around in the tree
  65 # (which would end up getting picked up by header search, instead of the correct
  66 # versions).
  67 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  68   message(FATAL_ERROR "In-source builds are not allowed.
  69 CMake would overwrite the makefiles distributed with LLVM.
  70 Please create a directory and run cmake from there, passing the path
  71 to this source directory as the last argument.
  72 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  73 Please delete them.")
  74 endif()
  75 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_include_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  79   file(GLOB_RECURSE
  80     tablegenned_files_on_lib_dir
  81     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  82   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  83     message(FATAL_ERROR "Apparently there is a previous in-source build,
  84 probably as the result of running `configure' and `make' on
  85 ${CMAKE_CURRENT_SOURCE_DIR}.
  86 This may cause problems. The suspicious files are:
  87 ${tablegenned_files_on_lib_dir}
  88 ${tablegenned_files_on_include_dir}
  89 Please clean the source directory.")
  90   endif()
  91 endif()
  92
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  94
  95 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  96 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  97 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  98 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  99 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 100 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 101 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 102
 103 set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 104 set(LLVM_LIBRARY_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 105
 106 set(LLVM_ALL_TARGETS
 107   AArch64
 108   ARM
 109   CppBackend
 110   Hexagon
 111   Mips
 112   MSP430
 113   NVPTX
 114   PowerPC
 115   R600
 116   Sparc
 117   SystemZ
 118   X86
 119   XCore
 120   )
 121
 122 # List of targets with JIT support:
 123 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 124
 125 set(LLVM_TARGETS_TO_BUILD "all"
 126     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 127
 128 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 129   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 130
 131 option(BUILD_SHARED_LIBS
 132   "Build all libraries as shared libraries instead of static" OFF)
 133
 134 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 135 if(LLVM_ENABLE_CBE_PRINTF_A)
 136   set(ENABLE_CBE_PRINTF_A 1)
 137 endif()
 138
 139 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 140 if(LLVM_ENABLE_TIMESTAMPS)
 141   set(ENABLE_TIMESTAMPS 1)
 142 endif()
 143
 144 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 145 if(LLVM_ENABLE_BACKTRACES)
 146   set(ENABLE_BACKTRACES 1)
 147 endif()
 148
 149 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 150 if(LLVM_ENABLE_CRASH_OVERRIDES)
 151   set(ENABLE_CRASH_OVERRIDES 1)
 152 endif()
 153
 154 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 155 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 156 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 157
 158 set(LLVM_TARGET_ARCH "host"
 159   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 160
 161 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 162
 163 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 164
 165 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 166
 167 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 168   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 169 endif()
 170
 171 set(LLVM_TARGETS_TO_BUILD
 172    ${LLVM_TARGETS_TO_BUILD}
 173    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 174 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 175
 176 include(AddLLVMDefinitions)
 177
 178 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 179
 180 # MSVC has a gazillion warnings with this.
 181 if( MSVC )
 182   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 183 else( MSVC )
 184   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 185 endif()
 186
 187 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 188 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 189 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 190 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 191
 192 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 193   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 194 else()
 195   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 196 endif()
 197
 198 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 199        "Set to ON to force using an old, unsupported host toolchain." OFF)
 200
 201 option(LLVM_USE_INTEL_JITEVENTS
 202   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 203   OFF)
 204
 205 if( LLVM_USE_INTEL_JITEVENTS )
 206   # Verify we are on a supported platform
 207   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 208     message(FATAL_ERROR
 209       "Intel JIT API support is available on Linux and Windows only.")
 210   endif()
 211 endif( LLVM_USE_INTEL_JITEVENTS )
 212
 213 option(LLVM_USE_OPROFILE
 214   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 215
 216 # If enabled, verify we are on a platform that supports oprofile.
 217 if( LLVM_USE_OPROFILE )
 218   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 219     message(FATAL_ERROR "OProfile support is available on Linux only.")
 220   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 221 endif( LLVM_USE_OPROFILE )
 222
 223 set(LLVM_USE_SANITIZER "" CACHE STRING
 224   "Define the sanitizer used to build binaries and tests.")
 225
 226 option(LLVM_USE_SPLIT_DWARF
 227   "Use -gsplit-dwarf when compiling llvm." OFF)
 228
 229 # Define an option controlling whether we should build for 32-bit on 64-bit
 230 # platforms, where supported.
 231 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 232   # TODO: support other platforms and toolchains.
 233   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 234 endif()
 235
 236 # Define the default arguments to use with 'lit', and an option for the user to
 237 # override.
 238 set(LIT_ARGS_DEFAULT "-sv")
 239 if (MSVC OR XCODE)
 240   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 241 endif()
 242 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 243
 244 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 245 if( WIN32 AND NOT CYGWIN )
 246   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 247 endif()
 248
 249 # Define options to control the inclusion and default build behavior for
 250 # components which may not strictly be necessary (tools, examples, and tests).
 251 #
 252 # This is primarily to support building smaller or faster project files.
 253 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 254 option(LLVM_BUILD_TOOLS
 255   "Build the LLVM tools. If OFF, just generate build targets." ON)
 256
 257 option(LLVM_BUILD_RUNTIME
 258   "Build the LLVM runtime libraries." ON)
 259 option(LLVM_BUILD_EXAMPLES
 260   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 261 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 262
 263 option(LLVM_BUILD_TESTS
 264   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 265 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 266
 267 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 268 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 269 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 270
 271 # All options referred to from HandleLLVMOptions have to be specified
 272 # BEFORE this include, otherwise options will not be correctly set on
 273 # first cmake run
 274 include(config-ix)
 275
 276 # By default, we target the host, but this can be overridden at CMake
 277 # invocation time.
 278 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 279   "Default target for which LLVM will generate code." )
 280 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 281
 282 include(HandleLLVMOptions)
 283
 284 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 285 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 286 include(FindPythonInterp)
 287 if( NOT PYTHONINTERP_FOUND )
 288   message(FATAL_ERROR
 289 "Unable to find Python interpreter, required for builds and testing.
 290
 291 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 292 endif()
 293
 294 ######
 295 # LLVMBuild Integration
 296 #
 297 # We use llvm-build to generate all the data required by the CMake based
 298 # build system in one swoop:
 299 #
 300 #  - We generate a file (a CMake fragment) in the object root which contains
 301 #    all the definitions that are required by CMake.
 302 #
 303 #  - We generate the library table used by llvm-config.
 304 #
 305 #  - We generate the dependencies for the CMake fragment, so that we will
 306 #    automatically reconfigure outselves.
 307
 308 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 309 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 310   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 311 set(LLVMBUILDCMAKEFRAG
 312   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 313
 314 # Create the list of optional components that are enabled
 315 if (LLVM_USE_INTEL_JITEVENTS)
 316   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 317 endif (LLVM_USE_INTEL_JITEVENTS)
 318 if (LLVM_USE_OPROFILE)
 319   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 320 endif (LLVM_USE_OPROFILE)
 321
 322 message(STATUS "Constructing LLVMBuild project information")
 323 execute_process(
 324   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 325             --native-target "${LLVM_NATIVE_ARCH}"
 326             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 327             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 328             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 329             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 330             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 331             ERROR_VARIABLE LLVMBUILDERRORS
 332             OUTPUT_STRIP_TRAILING_WHITESPACE
 333             ERROR_STRIP_TRAILING_WHITESPACE
 334   RESULT_VARIABLE LLVMBUILDRESULT)
 335
 336 # On Win32, CMake doesn't properly handle piping the default output/error
 337 # streams into the GUI console. So, we explicitly catch and report them.
 338 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 339   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 340 endif()
 341 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 342   message(FATAL_ERROR
 343     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 344 endif()
 345
 346 # Include the generated CMake fragment. This will define properties from the
 347 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 348 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 349 # files change.
 350 include(${LLVMBUILDCMAKEFRAG})
 351
 352 ######
 353
 354 # Configure all of the various header file fragments LLVM uses which depend on
 355 # configuration variables.
 356 set(LLVM_ENUM_TARGETS "")
 357 set(LLVM_ENUM_ASM_PRINTERS "")
 358 set(LLVM_ENUM_ASM_PARSERS "")
 359 set(LLVM_ENUM_DISASSEMBLERS "")
 360 foreach(t ${LLVM_TARGETS_TO_BUILD})
 361   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 362
 363   list(FIND LLVM_ALL_TARGETS ${t} idx)
 364   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 365   if( idx LESS 0 AND idy LESS 0 )
 366     message(FATAL_ERROR "The target `${t}' does not exist.
 367     It should be one of\n${LLVM_ALL_TARGETS}")
 368   else()
 369     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 370   endif()
 371
 372   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 373   if( asmp_file )
 374     set(LLVM_ENUM_ASM_PRINTERS
 375       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 376   endif()
 377   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 378     set(LLVM_ENUM_ASM_PARSERS
 379       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 380   endif()
 381   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 382     set(LLVM_ENUM_DISASSEMBLERS
 383       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 384   endif()
 385 endforeach(t)
 386
 387 # Produce the target definition files, which provide a way for clients to easily
 388 # include various classes of targets.
 389 configure_file(
 390   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 391   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 392   )
 393 configure_file(
 394   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 395   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 396   )
 397 configure_file(
 398   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 399   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 400   )
 401 configure_file(
 402   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 403   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 404   )
 405
 406 # Configure the three LLVM configuration header files.
 407 configure_file(
 408   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 409   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 410 configure_file(
 411   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 412   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 413 configure_file(
 414   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 415   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 416
 417 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 418 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 419 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 420
 421 if( NOT DEFINED CMAKE_INSTALL_RPATH )
 422   set( CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 423 endif( NOT DEFINED CMAKE_INSTALL_RPATH )
 424
 425 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 426
 427 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 428
 429 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 430   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 431   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 432   include_directories("/usr/local/include")
 433   link_directories("/usr/local/lib")
 434 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 435
 436 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 437    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 438 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 439
 440 # Make sure we don't get -rdynamic in every binary. For those that need it,
 441 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 442 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 443
 444 include(AddLLVM)
 445 include(TableGen)
 446
 447 if( MINGW )
 448   # People report that -O3 is unreliable on MinGW. The traditional
 449   # build also uses -O2 for that reason:
 450   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 451 endif()
 452
 453 # Put this before tblgen. Else we have a circular dependence.
 454 add_subdirectory(lib/Support)
 455 add_subdirectory(lib/TableGen)
 456
 457 add_subdirectory(utils/TableGen)
 458
 459 add_subdirectory(include/llvm)
 460
 461 add_subdirectory(lib)
 462
 463 add_subdirectory(utils/FileCheck)
 464 add_subdirectory(utils/FileUpdate)
 465 add_subdirectory(utils/count)
 466 add_subdirectory(utils/not)
 467 add_subdirectory(utils/llvm-lit)
 468 add_subdirectory(utils/yaml-bench)
 469
 470 add_subdirectory(projects)
 471
 472 if( LLVM_INCLUDE_TOOLS )
 473   add_subdirectory(tools)
 474 endif()
 475
 476 if( LLVM_INCLUDE_EXAMPLES )
 477   add_subdirectory(examples)
 478 endif()
 479
 480 if( LLVM_INCLUDE_TESTS )
 481   add_subdirectory(test)
 482   add_subdirectory(utils/unittest)
 483   add_subdirectory(unittests)
 484   if (MSVC)
 485     # This utility is used to prevent crashing tests from calling Dr. Watson on
 486     # Windows.
 487     add_subdirectory(utils/KillTheDoctor)
 488   endif()
 489
 490   # Add a global check rule now that all subdirectories have been traversed
 491   # and we know the total set of lit testsuites.
 492   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 493   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 494   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 495   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 496   add_lit_target(check-all
 497     "Running all regression tests"
 498     ${LLVM_LIT_TESTSUITES}
 499     PARAMS ${LLVM_LIT_PARAMS}
 500     DEPENDS ${LLVM_LIT_DEPENDS}
 501     ARGS ${LLVM_LIT_EXTRA_ARGS}
 502     )
 503 endif()
 504
 505 if (LLVM_INCLUDE_DOCS)
 506   add_subdirectory(docs)
 507 endif()
 508
 509 add_subdirectory(cmake/modules)
 510
 511 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 512   install(DIRECTORY include/
 513     DESTINATION include
 514     FILES_MATCHING
 515     PATTERN "*.def"
 516     PATTERN "*.h"
 517     PATTERN "*.td"
 518     PATTERN "*.inc"
 519     PATTERN "LICENSE.TXT"
 520     PATTERN ".svn" EXCLUDE
 521     )
 522
 523   install(DIRECTORY ${LLVM_INCLUDE_DIR}/
 524     DESTINATION include
 525     FILES_MATCHING
 526     PATTERN "*.def"
 527     PATTERN "*.h"
 528     PATTERN "*.gen"
 529     PATTERN "*.inc"
 530     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 531     PATTERN "CMakeFiles" EXCLUDE
 532     PATTERN ".svn" EXCLUDE
 533     )
 534 endif()
 535
 536 # Workaround for MSVS10 to avoid the Dialog Hell
 537 # FIXME: This could be removed with future version of CMake.
 538 if(MSVC_VERSION EQUAL 1600)
 539   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 540   if( EXISTS "${LLVM_SLN_FILENAME}" )
 541     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 542   endif()
 543 endif()
 544