CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 # FIXME: It may be removed when we use 2.8.12.
  11 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  12   # Invalidate a couple of keywords.
  13   set(cmake_2_8_12_INTERFACE)
  14   set(cmake_2_8_12_PRIVATE)
  15 else()
  16   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  17   set(cmake_2_8_12_INTERFACE INTERFACE)
  18   set(cmake_2_8_12_PRIVATE PRIVATE)
  19   if(POLICY CMP0022)
  20     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  21   endif()
  22 endif()
  23
  24 if (POLICY CMP0051)
  25   # CMake 3.1 and higher include generator expressions of the form
  26   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  27   # stripped everywhere that access the SOURCES property, so we just
  28   # defer to the OLD behavior of not including generator expressions
  29   # in the output for now.
  30   cmake_policy(SET CMP0051 OLD)
  31 endif()
  32
  33 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  34   set(cmake_3_2_USES_TERMINAL)
  35 else()
  36   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  37 endif()
  38
  39 project(LLVM)
  40
  41 # The following only works with the Ninja generator in CMake >= 3.0.
  42 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  43   "Define the maximum number of concurrent compilation jobs.")
  44 if(LLVM_PARALLEL_COMPILE_JOBS)
  45   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  46   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  47 endif()
  48
  49 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  50   "Define the maximum number of concurrent link jobs.")
  51 if(LLVM_PARALLEL_LINK_JOBS)
  52   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  53   set(CMAKE_JOB_POOL_LINK link_job_pool)
  54 endif()
  55
  56 # Add path for custom modules
  57 set(CMAKE_MODULE_PATH
  58   ${CMAKE_MODULE_PATH}
  59   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  60   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  61   )
  62
  63 set(LLVM_VERSION_MAJOR 3)
  64 set(LLVM_VERSION_MINOR 7)
  65 set(LLVM_VERSION_PATCH 0)
  66 set(LLVM_VERSION_SUFFIX svn)
  67
  68 if (NOT PACKAGE_VERSION)
  69   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  70 endif()
  71
  72 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  73
  74 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  75 if ( LLVM_USE_FOLDERS )
  76   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  77 endif()
  78
  79 include(VersionFromVCS)
  80
  81 option(LLVM_APPEND_VC_REV
  82   "Append the version control system revision id to LLVM version" OFF)
  83
  84 if( LLVM_APPEND_VC_REV )
  85   add_version_info_from_vcs(PACKAGE_VERSION)
  86 endif()
  87
  88 set(PACKAGE_NAME LLVM)
  89 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  90 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  91
  92 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  93   "Default URL where bug reports are to be submitted.")
  94
  95 # Configure CPack.
  96 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  97 set(CPACK_PACKAGE_VENDOR "LLVM")
  98 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  99 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 100 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 101 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 102 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 103 if(WIN32 AND NOT UNIX)
 104   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 105   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 106   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 107   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 108   set(CPACK_NSIS_MODIFY_PATH "ON")
 109   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 110   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 111     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 112   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 113     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 114   if( CMAKE_CL_64 )
 115     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 116   endif()
 117 endif()
 118 include(CPack)
 119
 120 # Sanity check our source directory to make sure that we are not trying to
 121 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 122 # sure that we don't have any stray generated files lying around in the tree
 123 # (which would end up getting picked up by header search, instead of the correct
 124 # versions).
 125 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 126   message(FATAL_ERROR "In-source builds are not allowed.
 127 CMake would overwrite the makefiles distributed with LLVM.
 128 Please create a directory and run cmake from there, passing the path
 129 to this source directory as the last argument.
 130 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 131 Please delete them.")
 132 endif()
 133 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 134   file(GLOB_RECURSE
 135     tablegenned_files_on_include_dir
 136     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 137   file(GLOB_RECURSE
 138     tablegenned_files_on_lib_dir
 139     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 140   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 141     message(FATAL_ERROR "Apparently there is a previous in-source build,
 142 probably as the result of running `configure' and `make' on
 143 ${CMAKE_CURRENT_SOURCE_DIR}.
 144 This may cause problems. The suspicious files are:
 145 ${tablegenned_files_on_lib_dir}
 146 ${tablegenned_files_on_include_dir}
 147 Please clean the source directory.")
 148   endif()
 149 endif()
 150
 151 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 152
 153 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 154
 155 # They are used as destination of target generators.
 156 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 157 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 158 if(WIN32 OR CYGWIN)
 159   # DLL platform -- put DLLs into bin.
 160   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 161 else()
 162   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 163 endif()
 164
 165 # Each of them corresponds to llvm-config's.
 166 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 167 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 168 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 169 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 170 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 171
 172 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 173 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 174
 175 set(LLVM_ALL_TARGETS
 176   AArch64
 177   ARM
 178   CppBackend
 179   Hexagon
 180   Mips
 181   MSP430
 182   NVPTX
 183   PowerPC
 184   R600
 185   Sparc
 186   SystemZ
 187   X86
 188   XCore
 189   )
 190
 191 # List of targets with JIT support:
 192 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 193
 194 set(LLVM_TARGETS_TO_BUILD "all"
 195     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 196
 197 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 198   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 199
 200 option(BUILD_SHARED_LIBS
 201   "Build all libraries as shared libraries instead of static" OFF)
 202
 203 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 204 if(LLVM_ENABLE_TIMESTAMPS)
 205   set(ENABLE_TIMESTAMPS 1)
 206 endif()
 207
 208 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 209 if(LLVM_ENABLE_BACKTRACES)
 210   set(ENABLE_BACKTRACES 1)
 211 endif()
 212
 213 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 214 if(LLVM_ENABLE_CRASH_OVERRIDES)
 215   set(ENABLE_CRASH_OVERRIDES 1)
 216 endif()
 217
 218 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 219 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 220 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 221
 222 set(LLVM_TARGET_ARCH "host"
 223   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 224
 225 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 226
 227 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 228
 229 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 230
 231 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 232   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 233 endif()
 234
 235 set(LLVM_TARGETS_TO_BUILD
 236    ${LLVM_TARGETS_TO_BUILD}
 237    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 238 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 239
 240 include(AddLLVMDefinitions)
 241
 242 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 243
 244 # MSVC has a gazillion warnings with this.
 245 if( MSVC )
 246   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 247 else()
 248   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 249 endif()
 250
 251 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 252 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 253 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 254 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 255 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 256
 257 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 258   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 259 else()
 260   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 261 endif()
 262
 263 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 264        "Set to ON to force using an old, unsupported host toolchain." OFF)
 265
 266 option(LLVM_USE_INTEL_JITEVENTS
 267   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 268   OFF)
 269
 270 if( LLVM_USE_INTEL_JITEVENTS )
 271   # Verify we are on a supported platform
 272   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 273     message(FATAL_ERROR
 274       "Intel JIT API support is available on Linux and Windows only.")
 275   endif()
 276 endif( LLVM_USE_INTEL_JITEVENTS )
 277
 278 option(LLVM_USE_OPROFILE
 279   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 280
 281 # If enabled, verify we are on a platform that supports oprofile.
 282 if( LLVM_USE_OPROFILE )
 283   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 284     message(FATAL_ERROR "OProfile support is available on Linux only.")
 285   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 286 endif( LLVM_USE_OPROFILE )
 287
 288 set(LLVM_USE_SANITIZER "" CACHE STRING
 289   "Define the sanitizer used to build binaries and tests.")
 290
 291 option(LLVM_USE_SPLIT_DWARF
 292   "Use -gsplit-dwarf when compiling llvm." OFF)
 293
 294 option(WITH_POLLY "Build LLVM with Polly" ON)
 295 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 296
 297 # Define an option controlling whether we should build for 32-bit on 64-bit
 298 # platforms, where supported.
 299 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 300   # TODO: support other platforms and toolchains.
 301   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 302 endif()
 303
 304 # Define the default arguments to use with 'lit', and an option for the user to
 305 # override.
 306 set(LIT_ARGS_DEFAULT "-sv")
 307 if (MSVC OR XCODE)
 308   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 309 endif()
 310 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 311
 312 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 313 if( WIN32 AND NOT CYGWIN )
 314   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 315 endif()
 316
 317 # Define options to control the inclusion and default build behavior for
 318 # components which may not strictly be necessary (tools, examples, and tests).
 319 #
 320 # This is primarily to support building smaller or faster project files.
 321 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 322 option(LLVM_BUILD_TOOLS
 323   "Build the LLVM tools. If OFF, just generate build targets." ON)
 324
 325 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 326
 327 option(LLVM_BUILD_RUNTIME
 328   "Build the LLVM runtime libraries." ON)
 329 option(LLVM_BUILD_EXAMPLES
 330   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 331 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 332
 333 option(LLVM_BUILD_TESTS
 334   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 335 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 336
 337 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 338 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 339 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 340 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 341
 342 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 343   "Build compiler-rt as an external project." OFF)
 344
 345 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 346 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 347 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 348   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 349 endif()
 350
 351 # All options referred to from HandleLLVMOptions have to be specified
 352 # BEFORE this include, otherwise options will not be correctly set on
 353 # first cmake run
 354 include(config-ix)
 355
 356 # By default, we target the host, but this can be overridden at CMake
 357 # invocation time.
 358 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 359   "Default target for which LLVM will generate code." )
 360 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 361
 362 include(HandleLLVMOptions)
 363
 364 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 365 # FIXME: We should support systems with only Python 3, but that requires work
 366 # on LLDB.
 367 set(Python_ADDITIONAL_VERSIONS 2.7)
 368 include(FindPythonInterp)
 369 if( NOT PYTHONINTERP_FOUND )
 370   message(FATAL_ERROR
 371 "Unable to find Python interpreter, required for builds and testing.
 372
 373 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 374 endif()
 375
 376 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 377   message(FATAL_ERROR "Python 2.7 or newer is required")
 378 endif()
 379
 380 ######
 381 # LLVMBuild Integration
 382 #
 383 # We use llvm-build to generate all the data required by the CMake based
 384 # build system in one swoop:
 385 #
 386 #  - We generate a file (a CMake fragment) in the object root which contains
 387 #    all the definitions that are required by CMake.
 388 #
 389 #  - We generate the library table used by llvm-config.
 390 #
 391 #  - We generate the dependencies for the CMake fragment, so that we will
 392 #    automatically reconfigure outselves.
 393
 394 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 395 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 396   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 397 set(LLVMBUILDCMAKEFRAG
 398   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 399
 400 # Create the list of optional components that are enabled
 401 if (LLVM_USE_INTEL_JITEVENTS)
 402   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 403 endif (LLVM_USE_INTEL_JITEVENTS)
 404 if (LLVM_USE_OPROFILE)
 405   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 406 endif (LLVM_USE_OPROFILE)
 407
 408 message(STATUS "Constructing LLVMBuild project information")
 409 execute_process(
 410   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 411             --native-target "${LLVM_NATIVE_ARCH}"
 412             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 413             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 414             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 415             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 416             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 417             ERROR_VARIABLE LLVMBUILDERRORS
 418             OUTPUT_STRIP_TRAILING_WHITESPACE
 419             ERROR_STRIP_TRAILING_WHITESPACE
 420   RESULT_VARIABLE LLVMBUILDRESULT)
 421
 422 # On Win32, CMake doesn't properly handle piping the default output/error
 423 # streams into the GUI console. So, we explicitly catch and report them.
 424 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 425   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 426 endif()
 427 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 428   message(FATAL_ERROR
 429     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 430 endif()
 431
 432 # Include the generated CMake fragment. This will define properties from the
 433 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 434 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 435 # files change.
 436 include(${LLVMBUILDCMAKEFRAG})
 437
 438 ######
 439
 440 # Configure all of the various header file fragments LLVM uses which depend on
 441 # configuration variables.
 442 set(LLVM_ENUM_TARGETS "")
 443 set(LLVM_ENUM_ASM_PRINTERS "")
 444 set(LLVM_ENUM_ASM_PARSERS "")
 445 set(LLVM_ENUM_DISASSEMBLERS "")
 446 foreach(t ${LLVM_TARGETS_TO_BUILD})
 447   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 448
 449   list(FIND LLVM_ALL_TARGETS ${t} idx)
 450   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 451   if( idx LESS 0 AND idy LESS 0 )
 452     message(FATAL_ERROR "The target `${t}' does not exist.
 453     It should be one of\n${LLVM_ALL_TARGETS}")
 454   else()
 455     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 456   endif()
 457
 458   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 459   if( asmp_file )
 460     set(LLVM_ENUM_ASM_PRINTERS
 461       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 462   endif()
 463   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 464     set(LLVM_ENUM_ASM_PARSERS
 465       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 466   endif()
 467   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 468     set(LLVM_ENUM_DISASSEMBLERS
 469       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 470   endif()
 471 endforeach(t)
 472
 473 # Produce the target definition files, which provide a way for clients to easily
 474 # include various classes of targets.
 475 configure_file(
 476   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 477   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 478   )
 479 configure_file(
 480   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 481   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 482   )
 483 configure_file(
 484   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 485   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 486   )
 487 configure_file(
 488   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 489   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 490   )
 491
 492 # Configure the three LLVM configuration header files.
 493 configure_file(
 494   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 495   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 496 configure_file(
 497   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 498   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 499 configure_file(
 500   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 501   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 502
 503 # They are not referenced. See set_output_directory().
 504 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 505 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 506 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 507
 508 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 509 if (APPLE)
 510   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 511   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 512 else(UNIX)
 513   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 514     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 515     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 516       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 517       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 518     endif()
 519   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 520 endif()
 521
 522 # Work around a broken bfd ld behavior. When linking a binary with a
 523 # foo.so library, it will try to find any library that foo.so uses and
 524 # check its symbols. This is wasteful (the check was done when foo.so
 525 # was created) and can fail since it is not the dynamic linker and
 526 # doesn't know how to handle search paths correctly.
 527 if (UNIX AND NOT APPLE)
 528   set(CMAKE_EXE_LINKER_FLAGS
 529       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 530 endif()
 531
 532 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 533
 534 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 535
 536 # when crosscompiling import the executable targets from a file
 537 if(CMAKE_CROSSCOMPILING)
 538   include(CrossCompile)
 539 endif(CMAKE_CROSSCOMPILING)
 540
 541 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 542   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 543   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 544   include_directories("/usr/local/include")
 545   link_directories("/usr/local/lib")
 546 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 547
 548 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 549    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 550 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 551
 552 # Make sure we don't get -rdynamic in every binary. For those that need it,
 553 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 554 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 555
 556 include(AddLLVM)
 557 include(TableGen)
 558
 559 if( MINGW )
 560   # People report that -O3 is unreliable on MinGW. The traditional
 561   # build also uses -O2 for that reason:
 562   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 563 endif()
 564
 565 # Put this before tblgen. Else we have a circular dependence.
 566 add_subdirectory(lib/Support)
 567 add_subdirectory(lib/TableGen)
 568
 569 add_subdirectory(utils/TableGen)
 570
 571 add_subdirectory(include/llvm)
 572
 573 add_subdirectory(lib)
 574
 575 if( LLVM_INCLUDE_UTILS )
 576   add_subdirectory(utils/FileCheck)
 577   add_subdirectory(utils/PerfectShuffle)
 578   add_subdirectory(utils/count)
 579   add_subdirectory(utils/not)
 580   add_subdirectory(utils/llvm-lit)
 581   add_subdirectory(utils/yaml-bench)
 582 else()
 583   if ( LLVM_INCLUDE_TESTS )
 584     message(FATAL_ERROR "Including tests when not building utils will not work.
 585     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 586   endif()
 587 endif()
 588
 589 if(LLVM_INCLUDE_TESTS)
 590   add_subdirectory(utils/unittest)
 591 endif()
 592
 593 foreach( binding ${LLVM_BINDINGS_LIST} )
 594   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 595     add_subdirectory(bindings/${binding})
 596   endif()
 597 endforeach()
 598
 599 add_subdirectory(projects)
 600
 601 if(WITH_POLLY)
 602   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 603     set(WITH_POLLY OFF)
 604   endif()
 605 endif(WITH_POLLY)
 606
 607 if( LLVM_INCLUDE_TOOLS )
 608   add_subdirectory(tools)
 609 endif()
 610
 611 if( LLVM_INCLUDE_EXAMPLES )
 612   add_subdirectory(examples)
 613 endif()
 614
 615 if( LLVM_INCLUDE_TESTS )
 616   add_subdirectory(test)
 617   add_subdirectory(unittests)
 618   if (MSVC)
 619     # This utility is used to prevent crashing tests from calling Dr. Watson on
 620     # Windows.
 621     add_subdirectory(utils/KillTheDoctor)
 622   endif()
 623
 624   # Add a global check rule now that all subdirectories have been traversed
 625   # and we know the total set of lit testsuites.
 626   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 627   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 628   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 629   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 630   add_lit_target(check-all
 631     "Running all regression tests"
 632     ${LLVM_LIT_TESTSUITES}
 633     PARAMS ${LLVM_LIT_PARAMS}
 634     DEPENDS ${LLVM_LIT_DEPENDS}
 635     ARGS ${LLVM_LIT_EXTRA_ARGS}
 636     )
 637 endif()
 638
 639 if (LLVM_INCLUDE_DOCS)
 640   add_subdirectory(docs)
 641 endif()
 642
 643 add_subdirectory(cmake/modules)
 644
 645 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 646   install(DIRECTORY include/llvm include/llvm-c
 647     DESTINATION include
 648     COMPONENT llvm-headers
 649     FILES_MATCHING
 650     PATTERN "*.def"
 651     PATTERN "*.h"
 652     PATTERN "*.td"
 653     PATTERN "*.inc"
 654     PATTERN "LICENSE.TXT"
 655     PATTERN ".svn" EXCLUDE
 656     )
 657
 658   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 659     DESTINATION include
 660     COMPONENT llvm-headers
 661     FILES_MATCHING
 662     PATTERN "*.def"
 663     PATTERN "*.h"
 664     PATTERN "*.gen"
 665     PATTERN "*.inc"
 666     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 667     PATTERN "CMakeFiles" EXCLUDE
 668     PATTERN "config.h" EXCLUDE
 669     PATTERN ".svn" EXCLUDE
 670     )
 671
 672   if (NOT CMAKE_CONFIGURATION_TYPES)
 673     add_custom_target(installhdrs
 674                       DEPENDS ${name}
 675                       COMMAND "${CMAKE_COMMAND}"
 676                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 677                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 678   endif()
 679 endif()