CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 3)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   ARM
  78   CppBackend
  79   Hexagon
  80   Mips
  81   MBlaze
  82   MSP430
  83   NVPTX
  84   PowerPC
  85   Sparc
  86   X86
  87   XCore
  88   )
  89
  90 # List of targets with JIT support:
  91 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  92
  93 if( MSVC )
  94   set(LLVM_TARGETS_TO_BUILD X86
  95     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  96 else( MSVC )
  97   set(LLVM_TARGETS_TO_BUILD "all"
  98     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  99 endif( MSVC )
 100
 101 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 102   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 103
 104 option(BUILD_SHARED_LIBS
 105   "Build all libraries as shared libraries instead of static" OFF)
 106
 107 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 108 if(LLVM_ENABLE_CBE_PRINTF_A)
 109   set(ENABLE_CBE_PRINTF_A 1)
 110 endif()
 111
 112 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 113 if(LLVM_ENABLE_TIMESTAMPS)
 114   set(ENABLE_TIMESTAMPS 1)
 115 endif()
 116
 117 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 118 if(LLVM_ENABLE_BACKTRACES)
 119   set(ENABLE_BACKTRACES 1)
 120 endif()
 121
 122 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 123 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 124 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 125
 126 set(LLVM_TARGET_ARCH "host"
 127   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 128
 129 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 130
 131 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 132   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 133 endif()
 134
 135 set(LLVM_TARGETS_TO_BUILD
 136    ${LLVM_TARGETS_TO_BUILD}
 137    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 138
 139 set(LLVM_ENUM_TARGETS "")
 140 foreach(c ${LLVM_TARGETS_TO_BUILD})
 141   list(FIND LLVM_ALL_TARGETS ${c} idx)
 142   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 143   if( idx LESS 0 AND idy LESS 0 )
 144     message(FATAL_ERROR "The target `${c}' does not exist.
 145     It should be one of\n${LLVM_ALL_TARGETS}")
 146   else()
 147     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 148   endif()
 149 endforeach(c)
 150
 151 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 152
 153 include(AddLLVMDefinitions)
 154
 155 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 156
 157 # MSVC has a gazillion warnings with this.
 158 if( MSVC )
 159   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 160 else( MSVC )
 161   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 162 endif()
 163
 164 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 165 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 166
 167 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 168   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 169 else()
 170   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 171 endif()
 172
 173 option(LLVM_USE_INTEL_JITEVENTS
 174   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 175   OFF)
 176
 177 if( LLVM_USE_INTEL_JITEVENTS )
 178   # Verify we are on a supported platform
 179   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 180     message(FATAL_ERROR
 181       "Intel JIT API support is available on Linux and Windows only.")
 182   endif()
 183 endif( LLVM_USE_INTEL_JITEVENTS )
 184
 185 option(LLVM_USE_OPROFILE
 186   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 187
 188 # If enabled, verify we are on a platform that supports oprofile.
 189 if( LLVM_USE_OPROFILE )
 190   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 191     message(FATAL_ERROR "OProfile support is available on Linux only.")
 192   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 193 endif( LLVM_USE_OPROFILE )
 194
 195 # Define an option controlling whether we should build for 32-bit on 64-bit
 196 # platforms, where supported.
 197 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 198   # TODO: support other platforms and toolchains.
 199   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 200 endif()
 201
 202 # Define the default arguments to use with 'lit', and an option for the user to
 203 # override.
 204 set(LIT_ARGS_DEFAULT "-sv")
 205 if (MSVC OR XCODE)
 206   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 207 endif()
 208 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 209
 210 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 211 if( WIN32 AND NOT CYGWIN )
 212   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 213 endif()
 214
 215 # Define options to control the inclusion and default build behavior for
 216 # components which may not strictly be necessary (tools, runtime, examples, and
 217 # tests).
 218 #
 219 # This is primarily to support building smaller or faster project files.
 220 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 221 option(LLVM_BUILD_TOOLS
 222   "Build the LLVM tools. If OFF, just generate build targets." ON)
 223
 224 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 225 option(LLVM_BUILD_RUNTIME
 226   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 227
 228 option(LLVM_BUILD_EXAMPLES
 229   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 230 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 231
 232 option(LLVM_BUILD_TESTS
 233   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 234 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 235
 236 # All options referred to from HandleLLVMOptions have to be specified
 237 # BEFORE this include, otherwise options will not be correctly set on
 238 # first cmake run
 239 include(config-ix)
 240
 241 # By default, we target the host, but this can be overridden at CMake
 242 # invocation time.
 243 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 244   "Default target for which LLVM will generate code." )
 245 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 246
 247 include(HandleLLVMOptions)
 248
 249 # Verify that we can find a Python interpreter,
 250 include(FindPythonInterp)
 251 if( NOT PYTHONINTERP_FOUND )
 252   message(FATAL_ERROR
 253 "Unable to find Python interpreter, required for builds and testing.
 254
 255 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 256 endif()
 257
 258 ######
 259 # LLVMBuild Integration
 260 #
 261 # We use llvm-build to generate all the data required by the CMake based
 262 # build system in one swoop:
 263 #
 264 #  - We generate a file (a CMake fragment) in the object root which contains
 265 #    all the definitions that are required by CMake.
 266 #
 267 #  - We generate the library table used by llvm-config.
 268 #
 269 #  - We generate the dependencies for the CMake fragment, so that we will
 270 #    automatically reconfigure outselves.
 271
 272 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 273 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 274   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 275 set(LLVMBUILDCMAKEFRAG
 276   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 277
 278 # Create the list of optional components that are enabled
 279 if (LLVM_USE_INTEL_JITEVENTS)
 280   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 281 endif (LLVM_USE_INTEL_JITEVENTS)
 282 if (LLVM_USE_OPROFILE)
 283   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 284 endif (LLVM_USE_OPROFILE)
 285
 286 message(STATUS "Constructing LLVMBuild project information")
 287 execute_process(
 288   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 289             --native-target "${LLVM_NATIVE_ARCH}"
 290             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 291             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 292             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 293             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 294             ERROR_VARIABLE LLVMBUILDOUTPUT
 295             ERROR_VARIABLE LLVMBUILDERRORS
 296             OUTPUT_STRIP_TRAILING_WHITESPACE
 297             ERROR_STRIP_TRAILING_WHITESPACE
 298   RESULT_VARIABLE LLVMBUILDRESULT)
 299
 300 # On Win32, CMake doesn't properly handle piping the default output/error
 301 # streams into the GUI console. So, we explicitly catch and report them.
 302 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 303   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 304 endif()
 305 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 306   message(FATAL_ERROR
 307     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 308 endif()
 309
 310 # Include the generated CMake fragment. This will define properties from the
 311 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 312 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 313 # files change.
 314 include(${LLVMBUILDCMAKEFRAG})
 315
 316 ######
 317
 318 # Configure all of the various header file fragments LLVM uses which depend on
 319 # configuration variables.
 320 set(LLVM_ENUM_ASM_PRINTERS "")
 321 set(LLVM_ENUM_ASM_PARSERS "")
 322 set(LLVM_ENUM_DISASSEMBLERS "")
 323 foreach(t ${LLVM_TARGETS_TO_BUILD})
 324   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 325   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 326   if( asmp_file )
 327     set(LLVM_ENUM_ASM_PRINTERS
 328       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 329   endif()
 330   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 331     set(LLVM_ENUM_ASM_PARSERS
 332       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 333   endif()
 334   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 335     set(LLVM_ENUM_DISASSEMBLERS
 336       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 337   endif()
 338 endforeach(t)
 339
 340 # Produce the target definition files, which provide a way for clients to easily
 341 # include various classes of targets.
 342 configure_file(
 343   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 344   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 345   )
 346 configure_file(
 347   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 348   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 349   )
 350 configure_file(
 351   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 352   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 353   )
 354 configure_file(
 355   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 356   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 357   )
 358
 359 # Configure the three LLVM configuration header files.
 360 configure_file(
 361   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 362   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 363 configure_file(
 364   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 365   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 366 configure_file(
 367   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 368   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 369
 370 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 371 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 372 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 373
 374 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 375
 376 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 377
 378 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 379    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 380 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 381
 382 include(AddLLVM)
 383 include(TableGen)
 384
 385 if( MINGW )
 386   # People report that -O3 is unreliable on MinGW. The traditional
 387   # build also uses -O2 for that reason:
 388   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 389 endif()
 390
 391 # Put this before tblgen. Else we have a circular dependence.
 392 add_subdirectory(lib/Support)
 393 add_subdirectory(lib/TableGen)
 394
 395 add_subdirectory(utils/TableGen)
 396
 397 add_subdirectory(include/llvm)
 398
 399 add_subdirectory(lib)
 400
 401 add_subdirectory(utils/FileCheck)
 402 add_subdirectory(utils/FileUpdate)
 403 add_subdirectory(utils/count)
 404 add_subdirectory(utils/not)
 405 add_subdirectory(utils/llvm-lit)
 406 add_subdirectory(utils/yaml-bench)
 407 add_subdirectory(utils/obj2yaml)
 408 add_subdirectory(utils/yaml2obj)
 409
 410 add_subdirectory(projects)
 411
 412 if( LLVM_INCLUDE_TOOLS )
 413   add_subdirectory(tools)
 414 endif()
 415
 416 if( LLVM_INCLUDE_RUNTIME )
 417   add_subdirectory(runtime)
 418 endif()
 419
 420 if( LLVM_INCLUDE_EXAMPLES )
 421   add_subdirectory(examples)
 422 endif()
 423
 424 if( LLVM_INCLUDE_TESTS )
 425   add_subdirectory(test)
 426   add_subdirectory(utils/unittest)
 427   add_subdirectory(unittests)
 428   if (MSVC)
 429     # This utility is used to prevent crashing tests from calling Dr. Watson on
 430     # Windows.
 431     add_subdirectory(utils/KillTheDoctor)
 432   endif()
 433
 434   # Add a global check rule now that all subdirectories have been traversed
 435   # and we know the total set of lit testsuites.
 436   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 437   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 438   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 439   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 440   add_lit_target(check-all
 441     "Running all regression tests"
 442     ${LLVM_LIT_TESTSUITES}
 443     PARAMS ${LLVM_LIT_PARAMS}
 444     DEPENDS ${LLVM_LIT_DEPENDS}
 445     ARGS ${LLVM_LIT_EXTRA_ARGS}
 446     )
 447 endif()
 448
 449 add_subdirectory(cmake/modules)
 450
 451 install(DIRECTORY include/
 452   DESTINATION include
 453   FILES_MATCHING
 454   PATTERN "*.def"
 455   PATTERN "*.h"
 456   PATTERN "*.td"
 457   PATTERN "*.inc"
 458   PATTERN "LICENSE.TXT"
 459   PATTERN ".svn" EXCLUDE
 460   )
 461
 462 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 463   DESTINATION include
 464   FILES_MATCHING
 465   PATTERN "*.def"
 466   PATTERN "*.h"
 467   PATTERN "*.gen"
 468   PATTERN "*.inc"
 469   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 470   PATTERN "CMakeFiles" EXCLUDE
 471   PATTERN ".svn" EXCLUDE
 472   )
 473
 474 # TODO: make and install documentation.
 475
 476 set(CPACK_PACKAGE_VENDOR "LLVM")
 477 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 478 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 479 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 480 include(CPack)
 481
 482 # Workaround for MSVS10 to avoid the Dialog Hell
 483 # FIXME: This could be removed with future version of CMake.
 484 if(MSVC_VERSION EQUAL 1600)
 485   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 486   if( EXISTS "${LLVM_SLN_FILENAME}" )
 487     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 488   endif()
 489 endif()