CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 2)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   ARM
  78   CellSPU
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   Sparc
  87   X86
  88   XCore
  89   )
  90
  91 # List of targets with JIT support:
  92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  93
  94 if( MSVC )
  95   set(LLVM_TARGETS_TO_BUILD X86
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97 else( MSVC )
  98   set(LLVM_TARGETS_TO_BUILD "all"
  99     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 100 endif( MSVC )
 101
 102 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 103   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 104
 105 option(BUILD_SHARED_LIBS
 106   "Build all libraries as shared libraries instead of static" OFF)
 107
 108 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 109 if(LLVM_ENABLE_CBE_PRINTF_A)
 110   set(ENABLE_CBE_PRINTF_A 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 114 if(LLVM_ENABLE_TIMESTAMPS)
 115   set(ENABLE_TIMESTAMPS 1)
 116 endif()
 117
 118 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 119 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 120 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 121
 122 set(LLVM_TARGET_ARCH "host"
 123   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 124
 125 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 126
 127 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 128   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 129 endif()
 130
 131 set(LLVM_TARGETS_TO_BUILD
 132    ${LLVM_TARGETS_TO_BUILD}
 133    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 134
 135 set(LLVM_ENUM_TARGETS "")
 136 foreach(c ${LLVM_TARGETS_TO_BUILD})
 137   list(FIND LLVM_ALL_TARGETS ${c} idx)
 138   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 139   if( idx LESS 0 AND idy LESS 0 )
 140     message(FATAL_ERROR "The target `${c}' does not exist.
 141     It should be one of\n${LLVM_ALL_TARGETS}")
 142   else()
 143     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 144   endif()
 145 endforeach(c)
 146
 147 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 148
 149 include(AddLLVMDefinitions)
 150
 151 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 152
 153 # MSVC has a gazillion warnings with this.
 154 if( MSVC )
 155   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 156 else( MSVC )
 157   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 158 endif()
 159
 160 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 161 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 162
 163 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 164   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 165 else()
 166   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 167 endif()
 168
 169 option(LLVM_USE_INTEL_JITEVENTS
 170   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 171   OFF)
 172
 173 if( LLVM_USE_INTEL_JITEVENTS )
 174   # Verify we are on a supported platform
 175   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 176     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 177     if ( WIN32 )
 178       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 179     else ( WIN32 )
 180       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 181     endif ( WIN32 )
 182
 183     # Set include and library search paths for Intel JIT Events API
 184     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 185
 186     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 187       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 188     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 189       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 190     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 191   else()
 192     message(FATAL_ERROR
 193       "Intel JIT API support is available on Linux and Windows only.")
 194   endif()
 195 endif( LLVM_USE_INTEL_JITEVENTS )
 196
 197 option(LLVM_USE_OPROFILE
 198   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 199
 200 # If enabled, ierify we are on a platform that supports oprofile.
 201 if( LLVM_USE_OPROFILE )
 202   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 203     message(FATAL_ERROR "OProfile support is available on Linux only.")
 204   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 205 endif( LLVM_USE_OPROFILE )
 206
 207 # Define an option controlling whether we should build for 32-bit on 64-bit
 208 # platforms, where supported.
 209 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 210   # TODO: support other platforms and toolchains.
 211   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 212 endif()
 213
 214 # Define the default arguments to use with 'lit', and an option for the user to
 215 # override.
 216 set(LIT_ARGS_DEFAULT "-sv")
 217 if (MSVC OR XCODE)
 218   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 219 endif()
 220 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 221
 222 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 223 if( WIN32 AND NOT CYGWIN )
 224   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 225 endif()
 226
 227 # Define options to control the inclusion and default build behavior for
 228 # components which may not strictly be necessary (tools, runtime, examples, and
 229 # tests).
 230 #
 231 # This is primarily to support building smaller or faster project files.
 232 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 233 option(LLVM_BUILD_TOOLS
 234   "Build the LLVM tools. If OFF, just generate build targets." ON)
 235
 236 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 237 option(LLVM_BUILD_RUNTIME
 238   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 239
 240 option(LLVM_BUILD_EXAMPLES
 241   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 242 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 243
 244 option(LLVM_BUILD_TESTS
 245   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 246 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 247
 248 # All options referred to from HandleLLVMOptions have to be specified
 249 # BEFORE this include, otherwise options will not be correctly set on
 250 # first cmake run
 251 include(config-ix)
 252
 253 # By default, we target the host, but this can be overridden at CMake
 254 # invocation time.
 255 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 256   "Default target for which LLVM will generate code." )
 257 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}" CACHE STRING
 258   "Default target for which LLVM will generate code." )
 259
 260 include(HandleLLVMOptions)
 261
 262 # Verify that we can find a Python interpreter,
 263 include(FindPythonInterp)
 264 if( NOT PYTHONINTERP_FOUND )
 265   message(FATAL_ERROR
 266 "Unable to find Python interpreter, required for builds and testing.
 267
 268 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 269 endif()
 270
 271 ######
 272 # LLVMBuild Integration
 273 #
 274 # We use llvm-build to generate all the data required by the CMake based
 275 # build system in one swoop:
 276 #
 277 #  - We generate a file (a CMake fragment) in the object root which contains
 278 #    all the definitions that are required by CMake.
 279 #
 280 #  - We generate the library table used by llvm-config.
 281 #
 282 #  - We generate the dependencies for the CMake fragment, so that we will
 283 #    automatically reconfigure outselves.
 284
 285 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 286 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 287   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 288 set(LLVMBUILDCMAKEFRAG
 289   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 290
 291 # Create the list of optional components that are enabled
 292 if (LLVM_USE_INTEL_JITEVENTS)
 293   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 294 endif (LLVM_USE_INTEL_JITEVENTS)
 295 if (LLVM_USE_OPROFILE)
 296   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 297 endif (LLVM_USE_OPROFILE)
 298
 299 message(STATUS "Constructing LLVMBuild project information")
 300 execute_process(
 301   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 302             --native-target "${LLVM_NATIVE_ARCH}"
 303             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 304             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 305             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 306             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 307             ERROR_VARIABLE LLVMBUILDOUTPUT
 308             ERROR_VARIABLE LLVMBUILDERRORS
 309             OUTPUT_STRIP_TRAILING_WHITESPACE
 310             ERROR_STRIP_TRAILING_WHITESPACE
 311   RESULT_VARIABLE LLVMBUILDRESULT)
 312
 313 # On Win32, CMake doesn't properly handle piping the default output/error
 314 # streams into the GUI console. So, we explicitly catch and report them.
 315 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 316   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 317 endif()
 318 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 319   message(FATAL_ERROR
 320     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 321 endif()
 322
 323 # Include the generated CMake fragment. This will define properties from the
 324 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 325 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 326 # files change.
 327 include(${LLVMBUILDCMAKEFRAG})
 328
 329 ######
 330
 331 # Configure all of the various header file fragments LLVM uses which depend on
 332 # configuration variables.
 333 set(LLVM_ENUM_ASM_PRINTERS "")
 334 set(LLVM_ENUM_ASM_PARSERS "")
 335 set(LLVM_ENUM_DISASSEMBLERS "")
 336 foreach(t ${LLVM_TARGETS_TO_BUILD})
 337   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 338   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 339   if( asmp_file )
 340     set(LLVM_ENUM_ASM_PRINTERS
 341       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 342   endif()
 343   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 344     set(LLVM_ENUM_ASM_PARSERS
 345       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 346   endif()
 347   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 348     set(LLVM_ENUM_DISASSEMBLERS
 349       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 350   endif()
 351 endforeach(t)
 352
 353 # Produce the target definition files, which provide a way for clients to easily
 354 # include various classes of targets.
 355 configure_file(
 356   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 357   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 358   )
 359 configure_file(
 360   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 361   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 362   )
 363 configure_file(
 364   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 365   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 366   )
 367 configure_file(
 368   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 369   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 370   )
 371
 372 # Configure the three LLVM configuration header files.
 373 configure_file(
 374   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 375   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 376 configure_file(
 377   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 378   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 379 configure_file(
 380   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 381   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 382
 383 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 384 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 385 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 386
 387 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 388
 389 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 390
 391 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 392    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 393 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 394
 395 include(AddLLVM)
 396 include(TableGen)
 397
 398 if( MINGW )
 399   # People report that -O3 is unreliable on MinGW. The traditional
 400   # build also uses -O2 for that reason:
 401   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 402 endif()
 403
 404 # Put this before tblgen. Else we have a circular dependence.
 405 add_subdirectory(lib/Support)
 406 add_subdirectory(lib/TableGen)
 407
 408 add_subdirectory(utils/TableGen)
 409
 410 add_subdirectory(include/llvm)
 411
 412 add_subdirectory(lib)
 413
 414 add_subdirectory(utils/FileCheck)
 415 add_subdirectory(utils/FileUpdate)
 416 add_subdirectory(utils/count)
 417 add_subdirectory(utils/not)
 418 add_subdirectory(utils/llvm-lit)
 419 add_subdirectory(utils/yaml-bench)
 420 add_subdirectory(utils/obj2yaml)
 421 add_subdirectory(utils/yaml2obj)
 422
 423 add_subdirectory(projects)
 424
 425 if( LLVM_INCLUDE_TOOLS )
 426   add_subdirectory(tools)
 427 endif()
 428
 429 if( LLVM_INCLUDE_RUNTIME )
 430   add_subdirectory(runtime)
 431 endif()
 432
 433 if( LLVM_INCLUDE_EXAMPLES )
 434   add_subdirectory(examples)
 435 endif()
 436
 437 if( LLVM_INCLUDE_TESTS )
 438   add_subdirectory(test)
 439   add_subdirectory(utils/unittest)
 440   add_subdirectory(unittests)
 441   if (MSVC)
 442     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 443     # Windows.
 444     add_subdirectory(utils/KillTheDoctor)
 445   endif()
 446
 447   # Add a global check rule now that all subdirectories have been traversed
 448   # and we know the total set of lit testsuites.
 449   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 450   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 451   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 452   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 453   add_lit_target(check-all
 454     "Running all regression tests"
 455     ${LLVM_LIT_TESTSUITES}
 456     PARAMS ${LLVM_LIT_PARAMS}
 457     DEPENDS ${LLVM_LIT_DEPENDS}
 458     ARGS ${LLVM_LIT_EXTRA_ARGS}
 459     )
 460 endif()
 461
 462 add_subdirectory(cmake/modules)
 463
 464 install(DIRECTORY include/
 465   DESTINATION include
 466   FILES_MATCHING
 467   PATTERN "*.def"
 468   PATTERN "*.h"
 469   PATTERN "*.td"
 470   PATTERN "*.inc"
 471   PATTERN "LICENSE.TXT"
 472   PATTERN ".svn" EXCLUDE
 473   )
 474
 475 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 476   DESTINATION include
 477   FILES_MATCHING
 478   PATTERN "*.def"
 479   PATTERN "*.h"
 480   PATTERN "*.gen"
 481   PATTERN "*.inc"
 482   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 483   PATTERN "CMakeFiles" EXCLUDE
 484   PATTERN ".svn" EXCLUDE
 485   )
 486
 487 # TODO: make and install documentation.
 488
 489 set(CPACK_PACKAGE_VENDOR "LLVM")
 490 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 491 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 492 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 493 include(CPack)
 494
 495 # Workaround for MSVS10 to avoid the Dialog Hell
 496 # FIXME: This could be removed with future version of CMake.
 497 if(MSVC_VERSION EQUAL 1600)
 498   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 499   if( EXISTS "${LLVM_SLN_FILENAME}" )
 500     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 501   endif()
 502 endif()