CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 3)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   AArch64
  78   ARM
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   Sparc
  87   X86
  88   XCore
  89   )
  90
  91 # List of targets with JIT support:
  92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  93
  94 set(LLVM_TARGETS_TO_BUILD "all"
  95     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  96
  97 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
  98   CACHE STRING "Semicolon-separated list of experimental targets to build.")
  99
 100 option(BUILD_SHARED_LIBS
 101   "Build all libraries as shared libraries instead of static" OFF)
 102
 103 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 104 if(LLVM_ENABLE_CBE_PRINTF_A)
 105   set(ENABLE_CBE_PRINTF_A 1)
 106 endif()
 107
 108 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 109 if(LLVM_ENABLE_TIMESTAMPS)
 110   set(ENABLE_TIMESTAMPS 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 114 if(LLVM_ENABLE_BACKTRACES)
 115   set(ENABLE_BACKTRACES 1)
 116 endif()
 117
 118 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 119 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 120 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 121
 122 set(LLVM_TARGET_ARCH "host"
 123   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 124
 125 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 126
 127 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 128
 129 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 130   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 131 endif()
 132
 133 set(LLVM_TARGETS_TO_BUILD
 134    ${LLVM_TARGETS_TO_BUILD}
 135    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 136
 137 set(LLVM_ENUM_TARGETS "")
 138 foreach(c ${LLVM_TARGETS_TO_BUILD})
 139   list(FIND LLVM_ALL_TARGETS ${c} idx)
 140   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 141   if( idx LESS 0 AND idy LESS 0 )
 142     message(FATAL_ERROR "The target `${c}' does not exist.
 143     It should be one of\n${LLVM_ALL_TARGETS}")
 144   else()
 145     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 146   endif()
 147 endforeach(c)
 148
 149 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 150
 151 include(AddLLVMDefinitions)
 152
 153 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 154
 155 # MSVC has a gazillion warnings with this.
 156 if( MSVC )
 157   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 158 else( MSVC )
 159   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 160 endif()
 161
 162 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 163 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 164
 165 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 166   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 167 else()
 168   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 169 endif()
 170
 171 option(LLVM_USE_INTEL_JITEVENTS
 172   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 173   OFF)
 174
 175 if( LLVM_USE_INTEL_JITEVENTS )
 176   # Verify we are on a supported platform
 177   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 178     message(FATAL_ERROR
 179       "Intel JIT API support is available on Linux and Windows only.")
 180   endif()
 181 endif( LLVM_USE_INTEL_JITEVENTS )
 182
 183 option(LLVM_USE_OPROFILE
 184   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 185
 186 # If enabled, verify we are on a platform that supports oprofile.
 187 if( LLVM_USE_OPROFILE )
 188   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 189     message(FATAL_ERROR "OProfile support is available on Linux only.")
 190   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 191 endif( LLVM_USE_OPROFILE )
 192
 193 set(LLVM_USE_SANITIZER "" CACHE STRING
 194   "Define the sanitizer used to build binaries and tests.")
 195
 196 # Define an option controlling whether we should build for 32-bit on 64-bit
 197 # platforms, where supported.
 198 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 199   # TODO: support other platforms and toolchains.
 200   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 201 endif()
 202
 203 # Define the default arguments to use with 'lit', and an option for the user to
 204 # override.
 205 set(LIT_ARGS_DEFAULT "-sv")
 206 if (MSVC OR XCODE)
 207   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 208 endif()
 209 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 210
 211 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 212 if( WIN32 AND NOT CYGWIN )
 213   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 214 endif()
 215
 216 # Define options to control the inclusion and default build behavior for
 217 # components which may not strictly be necessary (tools, runtime, examples, and
 218 # tests).
 219 #
 220 # This is primarily to support building smaller or faster project files.
 221 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 222 option(LLVM_BUILD_TOOLS
 223   "Build the LLVM tools. If OFF, just generate build targets." ON)
 224
 225 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 226 option(LLVM_BUILD_RUNTIME
 227   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 228
 229 option(LLVM_BUILD_EXAMPLES
 230   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 231 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 232
 233 option(LLVM_BUILD_TESTS
 234   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 235 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 236
 237 # All options referred to from HandleLLVMOptions have to be specified
 238 # BEFORE this include, otherwise options will not be correctly set on
 239 # first cmake run
 240 include(config-ix)
 241
 242 # By default, we target the host, but this can be overridden at CMake
 243 # invocation time.
 244 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 245   "Default target for which LLVM will generate code." )
 246 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 247
 248 include(HandleLLVMOptions)
 249
 250 # Verify that we can find a Python interpreter,
 251 include(FindPythonInterp)
 252 if( NOT PYTHONINTERP_FOUND )
 253   message(FATAL_ERROR
 254 "Unable to find Python interpreter, required for builds and testing.
 255
 256 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 257 endif()
 258
 259 ######
 260 # LLVMBuild Integration
 261 #
 262 # We use llvm-build to generate all the data required by the CMake based
 263 # build system in one swoop:
 264 #
 265 #  - We generate a file (a CMake fragment) in the object root which contains
 266 #    all the definitions that are required by CMake.
 267 #
 268 #  - We generate the library table used by llvm-config.
 269 #
 270 #  - We generate the dependencies for the CMake fragment, so that we will
 271 #    automatically reconfigure outselves.
 272
 273 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 274 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 275   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 276 set(LLVMBUILDCMAKEFRAG
 277   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 278
 279 # Create the list of optional components that are enabled
 280 if (LLVM_USE_INTEL_JITEVENTS)
 281   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 282 endif (LLVM_USE_INTEL_JITEVENTS)
 283 if (LLVM_USE_OPROFILE)
 284   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 285 endif (LLVM_USE_OPROFILE)
 286
 287 message(STATUS "Constructing LLVMBuild project information")
 288 execute_process(
 289   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 290             --native-target "${LLVM_NATIVE_ARCH}"
 291             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 292             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 293             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 294             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 295             ERROR_VARIABLE LLVMBUILDOUTPUT
 296             ERROR_VARIABLE LLVMBUILDERRORS
 297             OUTPUT_STRIP_TRAILING_WHITESPACE
 298             ERROR_STRIP_TRAILING_WHITESPACE
 299   RESULT_VARIABLE LLVMBUILDRESULT)
 300
 301 # On Win32, CMake doesn't properly handle piping the default output/error
 302 # streams into the GUI console. So, we explicitly catch and report them.
 303 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 304   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 305 endif()
 306 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 307   message(FATAL_ERROR
 308     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 309 endif()
 310
 311 # Include the generated CMake fragment. This will define properties from the
 312 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 313 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 314 # files change.
 315 include(${LLVMBUILDCMAKEFRAG})
 316
 317 ######
 318
 319 # Configure all of the various header file fragments LLVM uses which depend on
 320 # configuration variables.
 321 set(LLVM_ENUM_ASM_PRINTERS "")
 322 set(LLVM_ENUM_ASM_PARSERS "")
 323 set(LLVM_ENUM_DISASSEMBLERS "")
 324 foreach(t ${LLVM_TARGETS_TO_BUILD})
 325   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 326   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 327   if( asmp_file )
 328     set(LLVM_ENUM_ASM_PRINTERS
 329       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 330   endif()
 331   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 332     set(LLVM_ENUM_ASM_PARSERS
 333       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 334   endif()
 335   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 336     set(LLVM_ENUM_DISASSEMBLERS
 337       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 338   endif()
 339 endforeach(t)
 340
 341 # Produce the target definition files, which provide a way for clients to easily
 342 # include various classes of targets.
 343 configure_file(
 344   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 345   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 346   )
 347 configure_file(
 348   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 349   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 350   )
 351 configure_file(
 352   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 353   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 354   )
 355 configure_file(
 356   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 357   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 358   )
 359
 360 # Configure the three LLVM configuration header files.
 361 configure_file(
 362   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 363   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 364 configure_file(
 365   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 366   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 367 configure_file(
 368   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 369   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 370
 371 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 372 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 373 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 374
 375 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 376
 377 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 378
 379 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 380   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 381   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 382   include_directories("/usr/local/include")
 383   link_directories("/usr/local/lib")
 384 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 385
 386 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 387    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 388 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 389
 390 # Make sure we don't get -rdynamic in every binary. For those that need it,
 391 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 392 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 393
 394 include(AddLLVM)
 395 include(TableGen)
 396
 397 if( MINGW )
 398   # People report that -O3 is unreliable on MinGW. The traditional
 399   # build also uses -O2 for that reason:
 400   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 401 endif()
 402
 403 # Put this before tblgen. Else we have a circular dependence.
 404 add_subdirectory(lib/Support)
 405 add_subdirectory(lib/TableGen)
 406
 407 add_subdirectory(utils/TableGen)
 408
 409 add_subdirectory(include/llvm)
 410
 411 add_subdirectory(lib)
 412
 413 add_subdirectory(utils/FileCheck)
 414 add_subdirectory(utils/FileUpdate)
 415 add_subdirectory(utils/count)
 416 add_subdirectory(utils/not)
 417 add_subdirectory(utils/llvm-lit)
 418 add_subdirectory(utils/yaml-bench)
 419
 420 add_subdirectory(projects)
 421
 422 if( LLVM_INCLUDE_TOOLS )
 423   add_subdirectory(tools)
 424 endif()
 425
 426 if( LLVM_INCLUDE_RUNTIME )
 427   add_subdirectory(runtime)
 428 endif()
 429
 430 if( LLVM_INCLUDE_EXAMPLES )
 431   add_subdirectory(examples)
 432 endif()
 433
 434 if( LLVM_INCLUDE_TESTS )
 435   add_subdirectory(test)
 436   add_subdirectory(utils/unittest)
 437   add_subdirectory(unittests)
 438   if (MSVC)
 439     # This utility is used to prevent crashing tests from calling Dr. Watson on
 440     # Windows.
 441     add_subdirectory(utils/KillTheDoctor)
 442   endif()
 443
 444   # Add a global check rule now that all subdirectories have been traversed
 445   # and we know the total set of lit testsuites.
 446   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 447   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 448   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 449   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 450   add_lit_target(check-all
 451     "Running all regression tests"
 452     ${LLVM_LIT_TESTSUITES}
 453     PARAMS ${LLVM_LIT_PARAMS}
 454     DEPENDS ${LLVM_LIT_DEPENDS}
 455     ARGS ${LLVM_LIT_EXTRA_ARGS}
 456     )
 457 endif()
 458
 459 add_subdirectory(cmake/modules)
 460
 461 install(DIRECTORY include/
 462   DESTINATION include
 463   FILES_MATCHING
 464   PATTERN "*.def"
 465   PATTERN "*.h"
 466   PATTERN "*.td"
 467   PATTERN "*.inc"
 468   PATTERN "LICENSE.TXT"
 469   PATTERN ".svn" EXCLUDE
 470   )
 471
 472 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 473   DESTINATION include
 474   FILES_MATCHING
 475   PATTERN "*.def"
 476   PATTERN "*.h"
 477   PATTERN "*.gen"
 478   PATTERN "*.inc"
 479   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 480   PATTERN "CMakeFiles" EXCLUDE
 481   PATTERN ".svn" EXCLUDE
 482   )
 483
 484 # TODO: make and install documentation.
 485
 486 set(CPACK_PACKAGE_VENDOR "LLVM")
 487 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 488 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 489 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 490 include(CPack)
 491
 492 # Workaround for MSVS10 to avoid the Dialog Hell
 493 # FIXME: This could be removed with future version of CMake.
 494 if(MSVC_VERSION EQUAL 1600)
 495   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 496   if( EXISTS "${LLVM_SLN_FILENAME}" )
 497     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 498   endif()
 499 endif()