CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 # Configure CPack.
  41 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  42 set(CPACK_PACKAGE_VENDOR "LLVM")
  43 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  44 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  45 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  46 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  47 if(WIN32 AND NOT UNIX)
  48   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  49   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  50   set(CPACK_NSIS_MODIFY_PATH "ON")
  51   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  52   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  53     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  54   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  55     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  56 endif()
  57 include(CPack)
  58
  59 # Sanity check our source directory to make sure that we are not trying to
  60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  61 # sure that we don't have any stray generated files lying around in the tree
  62 # (which would end up getting picked up by header search, instead of the correct
  63 # versions).
  64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  65   message(FATAL_ERROR "In-source builds are not allowed.
  66 CMake would overwrite the makefiles distributed with LLVM.
  67 Please create a directory and run cmake from there, passing the path
  68 to this source directory as the last argument.
  69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  70 Please delete them.")
  71 endif()
  72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  73   file(GLOB_RECURSE
  74     tablegenned_files_on_include_dir
  75     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_lib_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  79   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  80     message(FATAL_ERROR "Apparently there is a previous in-source build,
  81 probably as the result of running `configure' and `make' on
  82 ${CMAKE_CURRENT_SOURCE_DIR}.
  83 This may cause problems. The suspicious files are:
  84 ${tablegenned_files_on_lib_dir}
  85 ${tablegenned_files_on_include_dir}
  86 Please clean the source directory.")
  87   endif()
  88 endif()
  89
  90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  91
  92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  97 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  98
  99 set(LLVM_ALL_TARGETS
 100   AArch64
 101   ARM
 102   CppBackend
 103   Hexagon
 104   Mips
 105   MSP430
 106   NVPTX
 107   PowerPC
 108   R600
 109   Sparc
 110   SystemZ
 111   X86
 112   XCore
 113   )
 114
 115 # List of targets with JIT support:
 116 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 117
 118 set(LLVM_TARGETS_TO_BUILD "all"
 119     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 120
 121 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 122   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 123
 124 option(BUILD_SHARED_LIBS
 125   "Build all libraries as shared libraries instead of static" OFF)
 126
 127 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 128 if(LLVM_ENABLE_CBE_PRINTF_A)
 129   set(ENABLE_CBE_PRINTF_A 1)
 130 endif()
 131
 132 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 133 if(LLVM_ENABLE_TIMESTAMPS)
 134   set(ENABLE_TIMESTAMPS 1)
 135 endif()
 136
 137 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 138 if(LLVM_ENABLE_BACKTRACES)
 139   set(ENABLE_BACKTRACES 1)
 140 endif()
 141
 142 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 143 if(LLVM_ENABLE_CRASH_OVERRIDES)
 144   set(ENABLE_CRASH_OVERRIDES 1)
 145 endif()
 146
 147 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 148 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 149 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 150
 151 set(LLVM_TARGET_ARCH "host"
 152   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 153
 154 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 155
 156 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 157
 158 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 159
 160 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 161   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 162 endif()
 163
 164 set(LLVM_TARGETS_TO_BUILD
 165    ${LLVM_TARGETS_TO_BUILD}
 166    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 167 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 168
 169 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 170
 171 include(AddLLVMDefinitions)
 172
 173 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 174
 175 # MSVC has a gazillion warnings with this.
 176 if( MSVC )
 177   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 178 else( MSVC )
 179   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 180 endif()
 181
 182 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 183 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 184 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 185
 186 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 187   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 188 else()
 189   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 190 endif()
 191
 192 option(LLVM_USE_INTEL_JITEVENTS
 193   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 194   OFF)
 195
 196 if( LLVM_USE_INTEL_JITEVENTS )
 197   # Verify we are on a supported platform
 198   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 199     message(FATAL_ERROR
 200       "Intel JIT API support is available on Linux and Windows only.")
 201   endif()
 202 endif( LLVM_USE_INTEL_JITEVENTS )
 203
 204 option(LLVM_USE_OPROFILE
 205   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 206
 207 # If enabled, verify we are on a platform that supports oprofile.
 208 if( LLVM_USE_OPROFILE )
 209   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 210     message(FATAL_ERROR "OProfile support is available on Linux only.")
 211   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 212 endif( LLVM_USE_OPROFILE )
 213
 214 set(LLVM_USE_SANITIZER "" CACHE STRING
 215   "Define the sanitizer used to build binaries and tests.")
 216
 217 option(LLVM_USE_SPLIT_DWARF
 218   "Use -gsplit-dwarf when compiling llvm." OFF)
 219
 220 # Define an option controlling whether we should build for 32-bit on 64-bit
 221 # platforms, where supported.
 222 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 223   # TODO: support other platforms and toolchains.
 224   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 225 endif()
 226
 227 # Define the default arguments to use with 'lit', and an option for the user to
 228 # override.
 229 set(LIT_ARGS_DEFAULT "-sv")
 230 if (MSVC OR XCODE)
 231   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 232 endif()
 233 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 234
 235 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 236 if( WIN32 AND NOT CYGWIN )
 237   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 238 endif()
 239
 240 # Define options to control the inclusion and default build behavior for
 241 # components which may not strictly be necessary (tools, examples, and tests).
 242 #
 243 # This is primarily to support building smaller or faster project files.
 244 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 245 option(LLVM_BUILD_TOOLS
 246   "Build the LLVM tools. If OFF, just generate build targets." ON)
 247
 248 option(LLVM_BUILD_RUNTIME
 249   "Build the LLVM runtime libraries." ON)
 250 option(LLVM_BUILD_EXAMPLES
 251   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 252 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 253
 254 option(LLVM_BUILD_TESTS
 255   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 256 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 257
 258 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 259 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 260 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 261
 262 # All options referred to from HandleLLVMOptions have to be specified
 263 # BEFORE this include, otherwise options will not be correctly set on
 264 # first cmake run
 265 include(config-ix)
 266
 267 # By default, we target the host, but this can be overridden at CMake
 268 # invocation time.
 269 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 270   "Default target for which LLVM will generate code." )
 271 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 272
 273 include(HandleLLVMOptions)
 274
 275 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 276 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 277 include(FindPythonInterp)
 278 if( NOT PYTHONINTERP_FOUND )
 279   message(FATAL_ERROR
 280 "Unable to find Python interpreter, required for builds and testing.
 281
 282 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 283 endif()
 284
 285 ######
 286 # LLVMBuild Integration
 287 #
 288 # We use llvm-build to generate all the data required by the CMake based
 289 # build system in one swoop:
 290 #
 291 #  - We generate a file (a CMake fragment) in the object root which contains
 292 #    all the definitions that are required by CMake.
 293 #
 294 #  - We generate the library table used by llvm-config.
 295 #
 296 #  - We generate the dependencies for the CMake fragment, so that we will
 297 #    automatically reconfigure outselves.
 298
 299 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 300 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 301   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 302 set(LLVMBUILDCMAKEFRAG
 303   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 304
 305 # Create the list of optional components that are enabled
 306 if (LLVM_USE_INTEL_JITEVENTS)
 307   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 308 endif (LLVM_USE_INTEL_JITEVENTS)
 309 if (LLVM_USE_OPROFILE)
 310   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 311 endif (LLVM_USE_OPROFILE)
 312
 313 message(STATUS "Constructing LLVMBuild project information")
 314 execute_process(
 315   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 316             --native-target "${LLVM_NATIVE_ARCH}"
 317             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 318             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 319             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 320             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 321             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 322             ERROR_VARIABLE LLVMBUILDERRORS
 323             OUTPUT_STRIP_TRAILING_WHITESPACE
 324             ERROR_STRIP_TRAILING_WHITESPACE
 325   RESULT_VARIABLE LLVMBUILDRESULT)
 326
 327 # On Win32, CMake doesn't properly handle piping the default output/error
 328 # streams into the GUI console. So, we explicitly catch and report them.
 329 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 330   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 331 endif()
 332 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 333   message(FATAL_ERROR
 334     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 335 endif()
 336
 337 # Include the generated CMake fragment. This will define properties from the
 338 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 339 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 340 # files change.
 341 include(${LLVMBUILDCMAKEFRAG})
 342
 343 ######
 344
 345 # Configure all of the various header file fragments LLVM uses which depend on
 346 # configuration variables.
 347 set(LLVM_ENUM_TARGETS "")
 348 set(LLVM_ENUM_ASM_PRINTERS "")
 349 set(LLVM_ENUM_ASM_PARSERS "")
 350 set(LLVM_ENUM_DISASSEMBLERS "")
 351 foreach(t ${LLVM_TARGETS_TO_BUILD})
 352   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 353
 354   list(FIND LLVM_ALL_TARGETS ${t} idx)
 355   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 356   if( idx LESS 0 AND idy LESS 0 )
 357     message(FATAL_ERROR "The target `${t}' does not exist.
 358     It should be one of\n${LLVM_ALL_TARGETS}")
 359   else()
 360     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 361   endif()
 362
 363   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 364   if( asmp_file )
 365     set(LLVM_ENUM_ASM_PRINTERS
 366       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 367   endif()
 368   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 369     set(LLVM_ENUM_ASM_PARSERS
 370       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 371   endif()
 372   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 373     set(LLVM_ENUM_DISASSEMBLERS
 374       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 375   endif()
 376 endforeach(t)
 377
 378 # Produce the target definition files, which provide a way for clients to easily
 379 # include various classes of targets.
 380 configure_file(
 381   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 382   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 383   )
 384 configure_file(
 385   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 386   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 387   )
 388 configure_file(
 389   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 390   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 391   )
 392 configure_file(
 393   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 394   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 395   )
 396
 397 # Configure the three LLVM configuration header files.
 398 configure_file(
 399   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 400   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 401 configure_file(
 402   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 403   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 404 configure_file(
 405   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 406   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 407
 408 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 409 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 410 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 411
 412 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 413
 414 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 415
 416 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 417   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 418   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 419   include_directories("/usr/local/include")
 420   link_directories("/usr/local/lib")
 421 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 422
 423 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 424    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 425 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 426
 427 # Make sure we don't get -rdynamic in every binary. For those that need it,
 428 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 429 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 430
 431 include(AddLLVM)
 432 include(TableGen)
 433
 434 if( MINGW )
 435   # People report that -O3 is unreliable on MinGW. The traditional
 436   # build also uses -O2 for that reason:
 437   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 438 endif()
 439
 440 # Put this before tblgen. Else we have a circular dependence.
 441 add_subdirectory(lib/Support)
 442 add_subdirectory(lib/TableGen)
 443
 444 add_subdirectory(utils/TableGen)
 445
 446 add_subdirectory(include/llvm)
 447
 448 add_subdirectory(lib)
 449
 450 add_subdirectory(utils/FileCheck)
 451 add_subdirectory(utils/FileUpdate)
 452 add_subdirectory(utils/count)
 453 add_subdirectory(utils/not)
 454 add_subdirectory(utils/llvm-lit)
 455 add_subdirectory(utils/yaml-bench)
 456
 457 add_subdirectory(projects)
 458
 459 if( LLVM_INCLUDE_TOOLS )
 460   add_subdirectory(tools)
 461 endif()
 462
 463 if( LLVM_INCLUDE_EXAMPLES )
 464   add_subdirectory(examples)
 465 endif()
 466
 467 if( LLVM_INCLUDE_TESTS )
 468   add_subdirectory(test)
 469   add_subdirectory(utils/unittest)
 470   add_subdirectory(unittests)
 471   if (MSVC)
 472     # This utility is used to prevent crashing tests from calling Dr. Watson on
 473     # Windows.
 474     add_subdirectory(utils/KillTheDoctor)
 475   endif()
 476
 477   # Add a global check rule now that all subdirectories have been traversed
 478   # and we know the total set of lit testsuites.
 479   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 480   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 481   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 482   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 483   add_lit_target(check-all
 484     "Running all regression tests"
 485     ${LLVM_LIT_TESTSUITES}
 486     PARAMS ${LLVM_LIT_PARAMS}
 487     DEPENDS ${LLVM_LIT_DEPENDS}
 488     ARGS ${LLVM_LIT_EXTRA_ARGS}
 489     )
 490 endif()
 491
 492 if (LLVM_INCLUDE_DOCS)
 493   add_subdirectory(docs)
 494 endif()
 495
 496 add_subdirectory(cmake/modules)
 497
 498 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 499   install(DIRECTORY include/
 500     DESTINATION include
 501     FILES_MATCHING
 502     PATTERN "*.def"
 503     PATTERN "*.h"
 504     PATTERN "*.td"
 505     PATTERN "*.inc"
 506     PATTERN "LICENSE.TXT"
 507     PATTERN ".svn" EXCLUDE
 508     )
 509
 510   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 511     DESTINATION include
 512     FILES_MATCHING
 513     PATTERN "*.def"
 514     PATTERN "*.h"
 515     PATTERN "*.gen"
 516     PATTERN "*.inc"
 517     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 518     PATTERN "CMakeFiles" EXCLUDE
 519     PATTERN ".svn" EXCLUDE
 520     )
 521 endif()
 522
 523 # Workaround for MSVS10 to avoid the Dialog Hell
 524 # FIXME: This could be removed with future version of CMake.
 525 if(MSVC_VERSION EQUAL 1600)
 526   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 527   if( EXISTS "${LLVM_SLN_FILENAME}" )
 528     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 529   endif()
 530 endif()
 531