CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 6)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  71   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  72   set(CPACK_NSIS_MODIFY_PATH "ON")
  73   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  74   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  76   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  77     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  78 endif()
  79 include(CPack)
  80
  81 # Sanity check our source directory to make sure that we are not trying to
  82 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  83 # sure that we don't have any stray generated files lying around in the tree
  84 # (which would end up getting picked up by header search, instead of the correct
  85 # versions).
  86 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  87   message(FATAL_ERROR "In-source builds are not allowed.
  88 CMake would overwrite the makefiles distributed with LLVM.
  89 Please create a directory and run cmake from there, passing the path
  90 to this source directory as the last argument.
  91 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  92 Please delete them.")
  93 endif()
  94 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  95   file(GLOB_RECURSE
  96     tablegenned_files_on_include_dir
  97     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  98   file(GLOB_RECURSE
  99     tablegenned_files_on_lib_dir
 100     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 101   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 102     message(FATAL_ERROR "Apparently there is a previous in-source build,
 103 probably as the result of running `configure' and `make' on
 104 ${CMAKE_CURRENT_SOURCE_DIR}.
 105 This may cause problems. The suspicious files are:
 106 ${tablegenned_files_on_lib_dir}
 107 ${tablegenned_files_on_include_dir}
 108 Please clean the source directory.")
 109   endif()
 110 endif()
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 113
 114 # They are used as destination of target generators.
 115 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 116 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 117 if(WIN32 OR CYGWIN)
 118   # DLL platform -- put DLLs into bin.
 119   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 120 else()
 121   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 122 endif()
 123
 124 # Each of them corresponds to llvm-config's.
 125 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 126 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 127 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 128 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 129 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 130
 131 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 132 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 133 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 134
 135 set(LLVM_ALL_TARGETS
 136   AArch64
 137   ARM
 138   CppBackend
 139   Hexagon
 140   Mips
 141   MSP430
 142   NVPTX
 143   PowerPC
 144   R600
 145   Sparc
 146   SystemZ
 147   X86
 148   XCore
 149   )
 150
 151 # List of targets with JIT support:
 152 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 153
 154 set(LLVM_TARGETS_TO_BUILD "all"
 155     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 156
 157 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 158   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 159
 160 option(BUILD_SHARED_LIBS
 161   "Build all libraries as shared libraries instead of static" OFF)
 162
 163 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 164 if(LLVM_ENABLE_TIMESTAMPS)
 165   set(ENABLE_TIMESTAMPS 1)
 166 endif()
 167
 168 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 169 if(LLVM_ENABLE_BACKTRACES)
 170   set(ENABLE_BACKTRACES 1)
 171 endif()
 172
 173 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 174 if(LLVM_ENABLE_CRASH_OVERRIDES)
 175   set(ENABLE_CRASH_OVERRIDES 1)
 176 endif()
 177
 178 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 179 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 180 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 181
 182 set(LLVM_TARGET_ARCH "host"
 183   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 184
 185 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 186
 187 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 188
 189 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 190
 191 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 192   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 193 endif()
 194
 195 set(LLVM_TARGETS_TO_BUILD
 196    ${LLVM_TARGETS_TO_BUILD}
 197    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 198 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 199
 200 include(AddLLVMDefinitions)
 201
 202 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 203
 204 # MSVC has a gazillion warnings with this.
 205 if( MSVC )
 206   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 207 else()
 208   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 209 endif()
 210
 211 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 212 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 213 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 214 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 215 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 216
 217 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 218   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 219 else()
 220   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 221 endif()
 222
 223 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 224        "Set to ON to force using an old, unsupported host toolchain." OFF)
 225
 226 option(LLVM_USE_INTEL_JITEVENTS
 227   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 228   OFF)
 229
 230 if( LLVM_USE_INTEL_JITEVENTS )
 231   # Verify we are on a supported platform
 232   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 233     message(FATAL_ERROR
 234       "Intel JIT API support is available on Linux and Windows only.")
 235   endif()
 236 endif( LLVM_USE_INTEL_JITEVENTS )
 237
 238 option(LLVM_USE_OPROFILE
 239   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 240
 241 # If enabled, verify we are on a platform that supports oprofile.
 242 if( LLVM_USE_OPROFILE )
 243   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 244     message(FATAL_ERROR "OProfile support is available on Linux only.")
 245   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 246 endif( LLVM_USE_OPROFILE )
 247
 248 set(LLVM_USE_SANITIZER "" CACHE STRING
 249   "Define the sanitizer used to build binaries and tests.")
 250
 251 option(LLVM_USE_SPLIT_DWARF
 252   "Use -gsplit-dwarf when compiling llvm." OFF)
 253
 254 option(WITH_POLLY "Build LLVM with Polly" ON)
 255 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 256
 257 # Define an option controlling whether we should build for 32-bit on 64-bit
 258 # platforms, where supported.
 259 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 260   # TODO: support other platforms and toolchains.
 261   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 262 endif()
 263
 264 # Define the default arguments to use with 'lit', and an option for the user to
 265 # override.
 266 set(LIT_ARGS_DEFAULT "-sv")
 267 if (MSVC OR XCODE)
 268   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 269 endif()
 270 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 271
 272 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 273 if( WIN32 AND NOT CYGWIN )
 274   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 275 endif()
 276
 277 # Define options to control the inclusion and default build behavior for
 278 # components which may not strictly be necessary (tools, examples, and tests).
 279 #
 280 # This is primarily to support building smaller or faster project files.
 281 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 282 option(LLVM_BUILD_TOOLS
 283   "Build the LLVM tools. If OFF, just generate build targets." ON)
 284
 285 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 286
 287 option(LLVM_BUILD_RUNTIME
 288   "Build the LLVM runtime libraries." ON)
 289 option(LLVM_BUILD_EXAMPLES
 290   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 291 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 292
 293 option(LLVM_BUILD_TESTS
 294   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 295 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 296
 297 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 298 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 299 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 300 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 301
 302 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 303   "Build compiler-rt as an external project." OFF)
 304
 305 # All options referred to from HandleLLVMOptions have to be specified
 306 # BEFORE this include, otherwise options will not be correctly set on
 307 # first cmake run
 308 include(config-ix)
 309
 310 # By default, we target the host, but this can be overridden at CMake
 311 # invocation time.
 312 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 313   "Default target for which LLVM will generate code." )
 314 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 315
 316 include(HandleLLVMOptions)
 317
 318 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 319 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 320 include(FindPythonInterp)
 321 if( NOT PYTHONINTERP_FOUND )
 322   message(FATAL_ERROR
 323 "Unable to find Python interpreter, required for builds and testing.
 324
 325 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 326 endif()
 327
 328 ######
 329 # LLVMBuild Integration
 330 #
 331 # We use llvm-build to generate all the data required by the CMake based
 332 # build system in one swoop:
 333 #
 334 #  - We generate a file (a CMake fragment) in the object root which contains
 335 #    all the definitions that are required by CMake.
 336 #
 337 #  - We generate the library table used by llvm-config.
 338 #
 339 #  - We generate the dependencies for the CMake fragment, so that we will
 340 #    automatically reconfigure outselves.
 341
 342 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 343 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 344   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 345 set(LLVMBUILDCMAKEFRAG
 346   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 347
 348 # Create the list of optional components that are enabled
 349 if (LLVM_USE_INTEL_JITEVENTS)
 350   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 351 endif (LLVM_USE_INTEL_JITEVENTS)
 352 if (LLVM_USE_OPROFILE)
 353   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 354 endif (LLVM_USE_OPROFILE)
 355
 356 message(STATUS "Constructing LLVMBuild project information")
 357 execute_process(
 358   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 359             --native-target "${LLVM_NATIVE_ARCH}"
 360             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 361             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 362             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 363             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 364             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 365             ERROR_VARIABLE LLVMBUILDERRORS
 366             OUTPUT_STRIP_TRAILING_WHITESPACE
 367             ERROR_STRIP_TRAILING_WHITESPACE
 368   RESULT_VARIABLE LLVMBUILDRESULT)
 369
 370 # On Win32, CMake doesn't properly handle piping the default output/error
 371 # streams into the GUI console. So, we explicitly catch and report them.
 372 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 373   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 374 endif()
 375 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 376   message(FATAL_ERROR
 377     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 378 endif()
 379
 380 # Include the generated CMake fragment. This will define properties from the
 381 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 382 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 383 # files change.
 384 include(${LLVMBUILDCMAKEFRAG})
 385
 386 ######
 387
 388 # Configure all of the various header file fragments LLVM uses which depend on
 389 # configuration variables.
 390 set(LLVM_ENUM_TARGETS "")
 391 set(LLVM_ENUM_ASM_PRINTERS "")
 392 set(LLVM_ENUM_ASM_PARSERS "")
 393 set(LLVM_ENUM_DISASSEMBLERS "")
 394 foreach(t ${LLVM_TARGETS_TO_BUILD})
 395   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 396
 397   list(FIND LLVM_ALL_TARGETS ${t} idx)
 398   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 399   if( idx LESS 0 AND idy LESS 0 )
 400     message(FATAL_ERROR "The target `${t}' does not exist.
 401     It should be one of\n${LLVM_ALL_TARGETS}")
 402   else()
 403     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 404   endif()
 405
 406   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 407   if( asmp_file )
 408     set(LLVM_ENUM_ASM_PRINTERS
 409       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 410   endif()
 411   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 412     set(LLVM_ENUM_ASM_PARSERS
 413       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 414   endif()
 415   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 416     set(LLVM_ENUM_DISASSEMBLERS
 417       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 418   endif()
 419 endforeach(t)
 420
 421 # Produce the target definition files, which provide a way for clients to easily
 422 # include various classes of targets.
 423 configure_file(
 424   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 425   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 426   )
 427 configure_file(
 428   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 429   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 430   )
 431 configure_file(
 432   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 433   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 434   )
 435 configure_file(
 436   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 437   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 438   )
 439
 440 # Configure the three LLVM configuration header files.
 441 configure_file(
 442   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 443   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 444 configure_file(
 445   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 446   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 447 configure_file(
 448   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 449   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 450
 451 # They are not referenced. See set_output_directory().
 452 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 453 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 454 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 455
 456 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 457 if (APPLE)
 458   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 459   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 460 else(UNIX)
 461   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 462     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 463     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 464       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 465       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 466     endif()
 467   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 468 endif()
 469
 470 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 471
 472 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 473
 474 # when crosscompiling import the executable targets from a file
 475 if(CMAKE_CROSSCOMPILING)
 476   include(CrossCompile)
 477 endif(CMAKE_CROSSCOMPILING)
 478
 479 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 480   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 481   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 482   include_directories("/usr/local/include")
 483   link_directories("/usr/local/lib")
 484 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 485
 486 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 487    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 488 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 489
 490 # Make sure we don't get -rdynamic in every binary. For those that need it,
 491 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 492 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 493
 494 include(AddLLVM)
 495 include(TableGen)
 496
 497 if( MINGW )
 498   # People report that -O3 is unreliable on MinGW. The traditional
 499   # build also uses -O2 for that reason:
 500   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 501 endif()
 502
 503 # Put this before tblgen. Else we have a circular dependence.
 504 add_subdirectory(lib/Support)
 505 add_subdirectory(lib/TableGen)
 506
 507 add_subdirectory(utils/TableGen)
 508
 509 add_subdirectory(include/llvm)
 510
 511 add_subdirectory(lib)
 512
 513 if( LLVM_INCLUDE_UTILS )
 514   add_subdirectory(utils/FileCheck)
 515   add_subdirectory(utils/PerfectShuffle)
 516   add_subdirectory(utils/count)
 517   add_subdirectory(utils/not)
 518   add_subdirectory(utils/llvm-lit)
 519   add_subdirectory(utils/yaml-bench)
 520 else()
 521   if ( LLVM_INCLUDE_TESTS )
 522     message(FATAL_ERROR "Including tests when not building utils will not work.
 523     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 524   endif()
 525 endif()
 526
 527 if(LLVM_INCLUDE_TESTS)
 528   add_subdirectory(utils/unittest)
 529 endif()
 530
 531 add_subdirectory(projects)
 532
 533 if(WITH_POLLY)
 534   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 535     set(WITH_POLLY OFF)
 536   endif()
 537 endif(WITH_POLLY)
 538
 539 if( LLVM_INCLUDE_TOOLS )
 540   add_subdirectory(tools)
 541 endif()
 542
 543 if( LLVM_INCLUDE_EXAMPLES )
 544   add_subdirectory(examples)
 545 endif()
 546
 547 if( LLVM_INCLUDE_TESTS )
 548   add_subdirectory(test)
 549   add_subdirectory(unittests)
 550   if (MSVC)
 551     # This utility is used to prevent crashing tests from calling Dr. Watson on
 552     # Windows.
 553     add_subdirectory(utils/KillTheDoctor)
 554   endif()
 555
 556   # Add a global check rule now that all subdirectories have been traversed
 557   # and we know the total set of lit testsuites.
 558   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 559   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 560   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 561   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 562   add_lit_target(check-all
 563     "Running all regression tests"
 564     ${LLVM_LIT_TESTSUITES}
 565     PARAMS ${LLVM_LIT_PARAMS}
 566     DEPENDS ${LLVM_LIT_DEPENDS}
 567     ARGS ${LLVM_LIT_EXTRA_ARGS}
 568     )
 569 endif()
 570
 571 if (LLVM_INCLUDE_DOCS)
 572   add_subdirectory(docs)
 573 endif()
 574
 575 add_subdirectory(cmake/modules)
 576
 577 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 578   install(DIRECTORY include/llvm include/llvm-c
 579     DESTINATION include
 580     FILES_MATCHING
 581     PATTERN "*.def"
 582     PATTERN "*.h"
 583     PATTERN "*.td"
 584     PATTERN "*.inc"
 585     PATTERN "LICENSE.TXT"
 586     PATTERN ".svn" EXCLUDE
 587     )
 588
 589   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 590     DESTINATION include
 591     FILES_MATCHING
 592     PATTERN "*.def"
 593     PATTERN "*.h"
 594     PATTERN "*.gen"
 595     PATTERN "*.inc"
 596     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 597     PATTERN "CMakeFiles" EXCLUDE
 598     PATTERN "config.h" EXCLUDE
 599     PATTERN ".svn" EXCLUDE
 600     )
 601 endif()