CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 3)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   AArch64
  78   ARM
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   Sparc
  87   X86
  88   XCore
  89   )
  90
  91 # List of targets with JIT support:
  92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  93
  94 set(LLVM_TARGETS_TO_BUILD "all"
  95     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  96
  97 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
  98   CACHE STRING "Semicolon-separated list of experimental targets to build.")
  99
 100 option(BUILD_SHARED_LIBS
 101   "Build all libraries as shared libraries instead of static" OFF)
 102
 103 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 104 if(LLVM_ENABLE_CBE_PRINTF_A)
 105   set(ENABLE_CBE_PRINTF_A 1)
 106 endif()
 107
 108 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 109 if(LLVM_ENABLE_TIMESTAMPS)
 110   set(ENABLE_TIMESTAMPS 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 114 if(LLVM_ENABLE_BACKTRACES)
 115   set(ENABLE_BACKTRACES 1)
 116 endif()
 117
 118 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 119 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 120 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 121
 122 set(LLVM_TARGET_ARCH "host"
 123   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 124
 125 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 126
 127 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 128   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 129 endif()
 130
 131 set(LLVM_TARGETS_TO_BUILD
 132    ${LLVM_TARGETS_TO_BUILD}
 133    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 134
 135 set(LLVM_ENUM_TARGETS "")
 136 foreach(c ${LLVM_TARGETS_TO_BUILD})
 137   list(FIND LLVM_ALL_TARGETS ${c} idx)
 138   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 139   if( idx LESS 0 AND idy LESS 0 )
 140     message(FATAL_ERROR "The target `${c}' does not exist.
 141     It should be one of\n${LLVM_ALL_TARGETS}")
 142   else()
 143     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 144   endif()
 145 endforeach(c)
 146
 147 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 148
 149 include(AddLLVMDefinitions)
 150
 151 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 152
 153 # MSVC has a gazillion warnings with this.
 154 if( MSVC )
 155   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 156 else( MSVC )
 157   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 158 endif()
 159
 160 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 161 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 162
 163 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 164   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 165 else()
 166   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 167 endif()
 168
 169 option(LLVM_USE_INTEL_JITEVENTS
 170   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 171   OFF)
 172
 173 if( LLVM_USE_INTEL_JITEVENTS )
 174   # Verify we are on a supported platform
 175   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 176     message(FATAL_ERROR
 177       "Intel JIT API support is available on Linux and Windows only.")
 178   endif()
 179 endif( LLVM_USE_INTEL_JITEVENTS )
 180
 181 option(LLVM_USE_OPROFILE
 182   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 183
 184 # If enabled, verify we are on a platform that supports oprofile.
 185 if( LLVM_USE_OPROFILE )
 186   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 187     message(FATAL_ERROR "OProfile support is available on Linux only.")
 188   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 189 endif( LLVM_USE_OPROFILE )
 190
 191 set(LLVM_USE_SANITIZER "" CACHE STRING
 192   "Define the sanitizer used to build binaries and tests.")
 193
 194 # Define an option controlling whether we should build for 32-bit on 64-bit
 195 # platforms, where supported.
 196 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 197   # TODO: support other platforms and toolchains.
 198   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 199 endif()
 200
 201 # Define the default arguments to use with 'lit', and an option for the user to
 202 # override.
 203 set(LIT_ARGS_DEFAULT "-sv")
 204 if (MSVC OR XCODE)
 205   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 206 endif()
 207 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 208
 209 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 210 if( WIN32 AND NOT CYGWIN )
 211   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 212 endif()
 213
 214 # Define options to control the inclusion and default build behavior for
 215 # components which may not strictly be necessary (tools, runtime, examples, and
 216 # tests).
 217 #
 218 # This is primarily to support building smaller or faster project files.
 219 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 220 option(LLVM_BUILD_TOOLS
 221   "Build the LLVM tools. If OFF, just generate build targets." ON)
 222
 223 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 224 option(LLVM_BUILD_RUNTIME
 225   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 226
 227 option(LLVM_BUILD_EXAMPLES
 228   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 229 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 230
 231 option(LLVM_BUILD_TESTS
 232   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 233 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 234
 235 # All options referred to from HandleLLVMOptions have to be specified
 236 # BEFORE this include, otherwise options will not be correctly set on
 237 # first cmake run
 238 include(config-ix)
 239
 240 # By default, we target the host, but this can be overridden at CMake
 241 # invocation time.
 242 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 243   "Default target for which LLVM will generate code." )
 244 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 245
 246 include(HandleLLVMOptions)
 247
 248 # Verify that we can find a Python interpreter,
 249 include(FindPythonInterp)
 250 if( NOT PYTHONINTERP_FOUND )
 251   message(FATAL_ERROR
 252 "Unable to find Python interpreter, required for builds and testing.
 253
 254 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 255 endif()
 256
 257 ######
 258 # LLVMBuild Integration
 259 #
 260 # We use llvm-build to generate all the data required by the CMake based
 261 # build system in one swoop:
 262 #
 263 #  - We generate a file (a CMake fragment) in the object root which contains
 264 #    all the definitions that are required by CMake.
 265 #
 266 #  - We generate the library table used by llvm-config.
 267 #
 268 #  - We generate the dependencies for the CMake fragment, so that we will
 269 #    automatically reconfigure outselves.
 270
 271 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 272 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 273   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 274 set(LLVMBUILDCMAKEFRAG
 275   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 276
 277 # Create the list of optional components that are enabled
 278 if (LLVM_USE_INTEL_JITEVENTS)
 279   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 280 endif (LLVM_USE_INTEL_JITEVENTS)
 281 if (LLVM_USE_OPROFILE)
 282   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 283 endif (LLVM_USE_OPROFILE)
 284
 285 message(STATUS "Constructing LLVMBuild project information")
 286 execute_process(
 287   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 288             --native-target "${LLVM_NATIVE_ARCH}"
 289             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 290             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 291             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 292             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 293             ERROR_VARIABLE LLVMBUILDOUTPUT
 294             ERROR_VARIABLE LLVMBUILDERRORS
 295             OUTPUT_STRIP_TRAILING_WHITESPACE
 296             ERROR_STRIP_TRAILING_WHITESPACE
 297   RESULT_VARIABLE LLVMBUILDRESULT)
 298
 299 # On Win32, CMake doesn't properly handle piping the default output/error
 300 # streams into the GUI console. So, we explicitly catch and report them.
 301 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 302   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 303 endif()
 304 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 305   message(FATAL_ERROR
 306     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 307 endif()
 308
 309 # Include the generated CMake fragment. This will define properties from the
 310 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 311 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 312 # files change.
 313 include(${LLVMBUILDCMAKEFRAG})
 314
 315 ######
 316
 317 # Configure all of the various header file fragments LLVM uses which depend on
 318 # configuration variables.
 319 set(LLVM_ENUM_ASM_PRINTERS "")
 320 set(LLVM_ENUM_ASM_PARSERS "")
 321 set(LLVM_ENUM_DISASSEMBLERS "")
 322 foreach(t ${LLVM_TARGETS_TO_BUILD})
 323   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 324   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 325   if( asmp_file )
 326     set(LLVM_ENUM_ASM_PRINTERS
 327       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 328   endif()
 329   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 330     set(LLVM_ENUM_ASM_PARSERS
 331       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 332   endif()
 333   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 334     set(LLVM_ENUM_DISASSEMBLERS
 335       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 336   endif()
 337 endforeach(t)
 338
 339 # Produce the target definition files, which provide a way for clients to easily
 340 # include various classes of targets.
 341 configure_file(
 342   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 343   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 344   )
 345 configure_file(
 346   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 347   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 348   )
 349 configure_file(
 350   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 351   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 352   )
 353 configure_file(
 354   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 355   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 356   )
 357
 358 # Configure the three LLVM configuration header files.
 359 configure_file(
 360   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 361   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 362 configure_file(
 363   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 364   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 365 configure_file(
 366   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 367   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 368
 369 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 370 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 371 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 372
 373 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 374
 375 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 376
 377 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 378   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 379   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 380   include_directories("/usr/local/include")
 381   link_directories("/usr/local/lib")
 382 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 383
 384 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 385    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 386 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 387
 388 # Make sure we don't get -rdynamic in every binary. For those that need it,
 389 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 390 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 391
 392 include(AddLLVM)
 393 include(TableGen)
 394
 395 if( MINGW )
 396   # People report that -O3 is unreliable on MinGW. The traditional
 397   # build also uses -O2 for that reason:
 398   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 399 endif()
 400
 401 # Put this before tblgen. Else we have a circular dependence.
 402 add_subdirectory(lib/Support)
 403 add_subdirectory(lib/TableGen)
 404
 405 add_subdirectory(utils/TableGen)
 406
 407 add_subdirectory(include/llvm)
 408
 409 add_subdirectory(lib)
 410
 411 add_subdirectory(utils/FileCheck)
 412 add_subdirectory(utils/FileUpdate)
 413 add_subdirectory(utils/count)
 414 add_subdirectory(utils/not)
 415 add_subdirectory(utils/llvm-lit)
 416 add_subdirectory(utils/yaml-bench)
 417
 418 add_subdirectory(projects)
 419
 420 if( LLVM_INCLUDE_TOOLS )
 421   add_subdirectory(tools)
 422 endif()
 423
 424 if( LLVM_INCLUDE_RUNTIME )
 425   add_subdirectory(runtime)
 426 endif()
 427
 428 if( LLVM_INCLUDE_EXAMPLES )
 429   add_subdirectory(examples)
 430 endif()
 431
 432 if( LLVM_INCLUDE_TESTS )
 433   add_subdirectory(test)
 434   add_subdirectory(utils/unittest)
 435   add_subdirectory(unittests)
 436   if (MSVC)
 437     # This utility is used to prevent crashing tests from calling Dr. Watson on
 438     # Windows.
 439     add_subdirectory(utils/KillTheDoctor)
 440   endif()
 441
 442   # Add a global check rule now that all subdirectories have been traversed
 443   # and we know the total set of lit testsuites.
 444   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 445   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 446   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 447   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 448   add_lit_target(check-all
 449     "Running all regression tests"
 450     ${LLVM_LIT_TESTSUITES}
 451     PARAMS ${LLVM_LIT_PARAMS}
 452     DEPENDS ${LLVM_LIT_DEPENDS}
 453     ARGS ${LLVM_LIT_EXTRA_ARGS}
 454     )
 455 endif()
 456
 457 add_subdirectory(cmake/modules)
 458
 459 install(DIRECTORY include/
 460   DESTINATION include
 461   FILES_MATCHING
 462   PATTERN "*.def"
 463   PATTERN "*.h"
 464   PATTERN "*.td"
 465   PATTERN "*.inc"
 466   PATTERN "LICENSE.TXT"
 467   PATTERN ".svn" EXCLUDE
 468   )
 469
 470 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 471   DESTINATION include
 472   FILES_MATCHING
 473   PATTERN "*.def"
 474   PATTERN "*.h"
 475   PATTERN "*.gen"
 476   PATTERN "*.inc"
 477   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 478   PATTERN "CMakeFiles" EXCLUDE
 479   PATTERN ".svn" EXCLUDE
 480   )
 481
 482 # TODO: make and install documentation.
 483
 484 set(CPACK_PACKAGE_VENDOR "LLVM")
 485 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 486 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 487 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 488 include(CPack)
 489
 490 # Workaround for MSVS10 to avoid the Dialog Hell
 491 # FIXME: This could be removed with future version of CMake.
 492 if(MSVC_VERSION EQUAL 1600)
 493   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 494   if( EXISTS "${LLVM_SLN_FILENAME}" )
 495     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 496   endif()
 497 endif()