CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  64
  65 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  66 if ( LLVM_USE_FOLDERS )
  67   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  68 endif()
  69
  70 include(VersionFromVCS)
  71
  72 option(LLVM_APPEND_VC_REV
  73   "Append the version control system revision id to LLVM version" OFF)
  74
  75 if( LLVM_APPEND_VC_REV )
  76   add_version_info_from_vcs(PACKAGE_VERSION)
  77 endif()
  78
  79 set(PACKAGE_NAME LLVM)
  80 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  81 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  82
  83 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  84   "Default URL where bug reports are to be submitted.")
  85
  86 # Configure CPack.
  87 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  88 set(CPACK_PACKAGE_VENDOR "LLVM")
  89 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  90 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  91 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  92 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  93 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  94 if(WIN32 AND NOT UNIX)
  95   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  96   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  97   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  98   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  99   set(CPACK_NSIS_MODIFY_PATH "ON")
 100   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 101   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 102     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 103   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 104     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 105   if( CMAKE_CL_64 )
 106     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 107   endif()
 108 endif()
 109 include(CPack)
 110
 111 # Sanity check our source directory to make sure that we are not trying to
 112 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 113 # sure that we don't have any stray generated files lying around in the tree
 114 # (which would end up getting picked up by header search, instead of the correct
 115 # versions).
 116 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 117   message(FATAL_ERROR "In-source builds are not allowed.
 118 CMake would overwrite the makefiles distributed with LLVM.
 119 Please create a directory and run cmake from there, passing the path
 120 to this source directory as the last argument.
 121 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 122 Please delete them.")
 123 endif()
 124 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 125   file(GLOB_RECURSE
 126     tablegenned_files_on_include_dir
 127     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 128   file(GLOB_RECURSE
 129     tablegenned_files_on_lib_dir
 130     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 131   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 132     message(FATAL_ERROR "Apparently there is a previous in-source build,
 133 probably as the result of running `configure' and `make' on
 134 ${CMAKE_CURRENT_SOURCE_DIR}.
 135 This may cause problems. The suspicious files are:
 136 ${tablegenned_files_on_lib_dir}
 137 ${tablegenned_files_on_include_dir}
 138 Please clean the source directory.")
 139   endif()
 140 endif()
 141
 142 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 143
 144 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 145
 146 # They are used as destination of target generators.
 147 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 148 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 149 if(WIN32 OR CYGWIN)
 150   # DLL platform -- put DLLs into bin.
 151   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 152 else()
 153   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 154 endif()
 155
 156 # Each of them corresponds to llvm-config's.
 157 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 158 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 159 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 160 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 161 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 162
 163 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 164 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 165
 166 set(LLVM_ALL_TARGETS
 167   AArch64
 168   ARM
 169   CppBackend
 170   Hexagon
 171   Mips
 172   MSP430
 173   NVPTX
 174   PowerPC
 175   R600
 176   Sparc
 177   SystemZ
 178   X86
 179   XCore
 180   )
 181
 182 # List of targets with JIT support:
 183 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 184
 185 set(LLVM_TARGETS_TO_BUILD "all"
 186     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 187
 188 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 189   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 190
 191 option(BUILD_SHARED_LIBS
 192   "Build all libraries as shared libraries instead of static" OFF)
 193
 194 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 195 if(LLVM_ENABLE_TIMESTAMPS)
 196   set(ENABLE_TIMESTAMPS 1)
 197 endif()
 198
 199 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 200 if(LLVM_ENABLE_BACKTRACES)
 201   set(ENABLE_BACKTRACES 1)
 202 endif()
 203
 204 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 205 if(LLVM_ENABLE_CRASH_OVERRIDES)
 206   set(ENABLE_CRASH_OVERRIDES 1)
 207 endif()
 208
 209 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 210 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 211 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 212
 213 set(LLVM_TARGET_ARCH "host"
 214   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 215
 216 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 217
 218 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 219
 220 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 221
 222 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 223   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 224 endif()
 225
 226 set(LLVM_TARGETS_TO_BUILD
 227    ${LLVM_TARGETS_TO_BUILD}
 228    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 229 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 230
 231 include(AddLLVMDefinitions)
 232
 233 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 234
 235 # MSVC has a gazillion warnings with this.
 236 if( MSVC )
 237   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 238 else()
 239   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 240 endif()
 241
 242 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 243 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 244 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 245 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 246 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 247 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 248
 249 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 250   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 251 else()
 252   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 253 endif()
 254
 255 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 256   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 257
 258 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 259        "Set to ON to force using an old, unsupported host toolchain." OFF)
 260
 261 option(LLVM_USE_INTEL_JITEVENTS
 262   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 263   OFF)
 264
 265 if( LLVM_USE_INTEL_JITEVENTS )
 266   # Verify we are on a supported platform
 267   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 268     message(FATAL_ERROR
 269       "Intel JIT API support is available on Linux and Windows only.")
 270   endif()
 271 endif( LLVM_USE_INTEL_JITEVENTS )
 272
 273 option(LLVM_USE_OPROFILE
 274   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 275
 276 # If enabled, verify we are on a platform that supports oprofile.
 277 if( LLVM_USE_OPROFILE )
 278   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 279     message(FATAL_ERROR "OProfile support is available on Linux only.")
 280   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 281 endif( LLVM_USE_OPROFILE )
 282
 283 set(LLVM_USE_SANITIZER "" CACHE STRING
 284   "Define the sanitizer used to build binaries and tests.")
 285
 286 option(LLVM_USE_SPLIT_DWARF
 287   "Use -gsplit-dwarf when compiling llvm." OFF)
 288
 289 option(WITH_POLLY "Build LLVM with Polly" ON)
 290 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 291
 292 # Define an option controlling whether we should build for 32-bit on 64-bit
 293 # platforms, where supported.
 294 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 295   # TODO: support other platforms and toolchains.
 296   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 297 endif()
 298
 299 # Define the default arguments to use with 'lit', and an option for the user to
 300 # override.
 301 set(LIT_ARGS_DEFAULT "-sv")
 302 if (MSVC OR XCODE)
 303   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 304 endif()
 305 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 306
 307 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 308 if( WIN32 AND NOT CYGWIN )
 309   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 310 endif()
 311
 312 # Define options to control the inclusion and default build behavior for
 313 # components which may not strictly be necessary (tools, examples, and tests).
 314 #
 315 # This is primarily to support building smaller or faster project files.
 316 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 317 option(LLVM_BUILD_TOOLS
 318   "Build the LLVM tools. If OFF, just generate build targets." ON)
 319
 320 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 321
 322 option(LLVM_BUILD_RUNTIME
 323   "Build the LLVM runtime libraries." ON)
 324 option(LLVM_BUILD_EXAMPLES
 325   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 326 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 327
 328 option(LLVM_BUILD_TESTS
 329   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 330 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 331
 332 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 333 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 334 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 335 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 336
 337 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 338   "Build compiler-rt as an external project." OFF)
 339
 340 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 341 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 342 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 343   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 344 endif()
 345
 346 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 347 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 348   set(LLVM_USE_HOST_TOOLS ON)
 349 endif()
 350
 351 # All options referred to from HandleLLVMOptions have to be specified
 352 # BEFORE this include, otherwise options will not be correctly set on
 353 # first cmake run
 354 include(config-ix)
 355
 356 # By default, we target the host, but this can be overridden at CMake
 357 # invocation time.
 358 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 359   "Default target for which LLVM will generate code." )
 360 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 361
 362 include(HandleLLVMOptions)
 363
 364 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 365 # FIXME: We should support systems with only Python 3, but that requires work
 366 # on LLDB.
 367 set(Python_ADDITIONAL_VERSIONS 2.7)
 368 include(FindPythonInterp)
 369 if( NOT PYTHONINTERP_FOUND )
 370   message(FATAL_ERROR
 371 "Unable to find Python interpreter, required for builds and testing.
 372
 373 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 374 endif()
 375
 376 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 377   message(FATAL_ERROR "Python 2.7 or newer is required")
 378 endif()
 379
 380 ######
 381 # LLVMBuild Integration
 382 #
 383 # We use llvm-build to generate all the data required by the CMake based
 384 # build system in one swoop:
 385 #
 386 #  - We generate a file (a CMake fragment) in the object root which contains
 387 #    all the definitions that are required by CMake.
 388 #
 389 #  - We generate the library table used by llvm-config.
 390 #
 391 #  - We generate the dependencies for the CMake fragment, so that we will
 392 #    automatically reconfigure outselves.
 393
 394 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 395 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 396   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 397 set(LLVMBUILDCMAKEFRAG
 398   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 399
 400 # Create the list of optional components that are enabled
 401 if (LLVM_USE_INTEL_JITEVENTS)
 402   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 403 endif (LLVM_USE_INTEL_JITEVENTS)
 404 if (LLVM_USE_OPROFILE)
 405   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 406 endif (LLVM_USE_OPROFILE)
 407
 408 message(STATUS "Constructing LLVMBuild project information")
 409 execute_process(
 410   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 411             --native-target "${LLVM_NATIVE_ARCH}"
 412             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 413             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 414             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 415             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 416             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 417             ERROR_VARIABLE LLVMBUILDERRORS
 418             OUTPUT_STRIP_TRAILING_WHITESPACE
 419             ERROR_STRIP_TRAILING_WHITESPACE
 420   RESULT_VARIABLE LLVMBUILDRESULT)
 421
 422 # On Win32, CMake doesn't properly handle piping the default output/error
 423 # streams into the GUI console. So, we explicitly catch and report them.
 424 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 425   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 426 endif()
 427 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 428   message(FATAL_ERROR
 429     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 430 endif()
 431
 432 # Include the generated CMake fragment. This will define properties from the
 433 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 434 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 435 # files change.
 436 include(${LLVMBUILDCMAKEFRAG})
 437
 438 ######
 439
 440 # Configure all of the various header file fragments LLVM uses which depend on
 441 # configuration variables.
 442 set(LLVM_ENUM_TARGETS "")
 443 set(LLVM_ENUM_ASM_PRINTERS "")
 444 set(LLVM_ENUM_ASM_PARSERS "")
 445 set(LLVM_ENUM_DISASSEMBLERS "")
 446 foreach(t ${LLVM_TARGETS_TO_BUILD})
 447   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 448
 449   list(FIND LLVM_ALL_TARGETS ${t} idx)
 450   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 451   if( idx LESS 0 AND idy LESS 0 )
 452     message(FATAL_ERROR "The target `${t}' does not exist.
 453     It should be one of\n${LLVM_ALL_TARGETS}")
 454   else()
 455     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 456   endif()
 457
 458   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 459   if( asmp_file )
 460     set(LLVM_ENUM_ASM_PRINTERS
 461       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 462   endif()
 463   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 464     set(LLVM_ENUM_ASM_PARSERS
 465       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 466   endif()
 467   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 468     set(LLVM_ENUM_DISASSEMBLERS
 469       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 470   endif()
 471 endforeach(t)
 472
 473 # Produce the target definition files, which provide a way for clients to easily
 474 # include various classes of targets.
 475 configure_file(
 476   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 477   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 478   )
 479 configure_file(
 480   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 481   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 482   )
 483 configure_file(
 484   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 485   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 486   )
 487 configure_file(
 488   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 489   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 490   )
 491
 492 # Configure the three LLVM configuration header files.
 493 configure_file(
 494   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 495   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 496 configure_file(
 497   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 498   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 499 configure_file(
 500   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 501   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 502
 503 # They are not referenced. See set_output_directory().
 504 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 505 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 506 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 507
 508 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 509 if (APPLE)
 510   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 511   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 512 else(UNIX)
 513   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 514     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 515     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 516       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 517       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 518     endif()
 519   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 520 endif()
 521
 522 # Work around a broken bfd ld behavior. When linking a binary with a
 523 # foo.so library, it will try to find any library that foo.so uses and
 524 # check its symbols. This is wasteful (the check was done when foo.so
 525 # was created) and can fail since it is not the dynamic linker and
 526 # doesn't know how to handle search paths correctly.
 527 if (UNIX AND NOT APPLE)
 528   set(CMAKE_EXE_LINKER_FLAGS
 529       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 530 endif()
 531
 532 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 533
 534 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 535
 536 # when crosscompiling import the executable targets from a file
 537 if(LLVM_USE_HOST_TOOLS)
 538   include(CrossCompile)
 539 endif(LLVM_USE_HOST_TOOLS)
 540
 541 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 542   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 543   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 544   include_directories("/usr/local/include")
 545   link_directories("/usr/local/lib")
 546 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 547
 548 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 549    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 550 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 551
 552 # Make sure we don't get -rdynamic in every binary. For those that need it,
 553 # use export_executable_symbols(target).
 554 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 555
 556 include(AddLLVM)
 557 include(TableGen)
 558
 559 if( MINGW )
 560   # People report that -O3 is unreliable on MinGW. The traditional
 561   # build also uses -O2 for that reason:
 562   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 563 endif()
 564
 565 # Put this before tblgen. Else we have a circular dependence.
 566 add_subdirectory(lib/Support)
 567 add_subdirectory(lib/TableGen)
 568
 569 add_subdirectory(utils/TableGen)
 570
 571 add_subdirectory(include/llvm)
 572
 573 add_subdirectory(lib)
 574
 575 if( LLVM_INCLUDE_UTILS )
 576   add_subdirectory(utils/FileCheck)
 577   add_subdirectory(utils/PerfectShuffle)
 578   add_subdirectory(utils/count)
 579   add_subdirectory(utils/not)
 580   add_subdirectory(utils/llvm-lit)
 581   add_subdirectory(utils/yaml-bench)
 582 else()
 583   if ( LLVM_INCLUDE_TESTS )
 584     message(FATAL_ERROR "Including tests when not building utils will not work.
 585     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 586   endif()
 587 endif()
 588
 589 if(LLVM_INCLUDE_TESTS)
 590   add_subdirectory(utils/unittest)
 591 endif()
 592
 593 foreach( binding ${LLVM_BINDINGS_LIST} )
 594   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 595     add_subdirectory(bindings/${binding})
 596   endif()
 597 endforeach()
 598
 599 add_subdirectory(projects)
 600
 601 if(WITH_POLLY)
 602   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 603     set(WITH_POLLY OFF)
 604   endif()
 605 endif(WITH_POLLY)
 606
 607 if( LLVM_INCLUDE_TOOLS )
 608   add_subdirectory(tools)
 609 endif()
 610
 611 if( LLVM_INCLUDE_EXAMPLES )
 612   add_subdirectory(examples)
 613 endif()
 614
 615 if( LLVM_INCLUDE_TESTS )
 616   add_subdirectory(test)
 617   add_subdirectory(unittests)
 618   if (MSVC)
 619     # This utility is used to prevent crashing tests from calling Dr. Watson on
 620     # Windows.
 621     add_subdirectory(utils/KillTheDoctor)
 622   endif()
 623
 624   # Add a global check rule now that all subdirectories have been traversed
 625   # and we know the total set of lit testsuites.
 626   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 627   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 628   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 629   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 630   add_lit_target(check-all
 631     "Running all regression tests"
 632     ${LLVM_LIT_TESTSUITES}
 633     PARAMS ${LLVM_LIT_PARAMS}
 634     DEPENDS ${LLVM_LIT_DEPENDS}
 635     ARGS ${LLVM_LIT_EXTRA_ARGS}
 636     )
 637 endif()
 638
 639 if (LLVM_INCLUDE_DOCS)
 640   add_subdirectory(docs)
 641 endif()
 642
 643 add_subdirectory(cmake/modules)
 644
 645 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 646   install(DIRECTORY include/llvm include/llvm-c
 647     DESTINATION include
 648     COMPONENT llvm-headers
 649     FILES_MATCHING
 650     PATTERN "*.def"
 651     PATTERN "*.h"
 652     PATTERN "*.td"
 653     PATTERN "*.inc"
 654     PATTERN "LICENSE.TXT"
 655     PATTERN ".svn" EXCLUDE
 656     )
 657
 658   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 659     DESTINATION include
 660     COMPONENT llvm-headers
 661     FILES_MATCHING
 662     PATTERN "*.def"
 663     PATTERN "*.h"
 664     PATTERN "*.gen"
 665     PATTERN "*.inc"
 666     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 667     PATTERN "CMakeFiles" EXCLUDE
 668     PATTERN "config.h" EXCLUDE
 669     PATTERN ".svn" EXCLUDE
 670     )
 671
 672   if (NOT CMAKE_CONFIGURATION_TYPES)
 673     add_custom_target(installhdrs
 674                       DEPENDS ${name}
 675                       COMMAND "${CMAKE_COMMAND}"
 676                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 677                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 678   endif()
 679 endif()