CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   AArch64
  78   ARM
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   R600
  87   Sparc
  88   SystemZ
  89   X86
  90   XCore
  91   )
  92
  93 # List of targets with JIT support:
  94 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
  95
  96 set(LLVM_TARGETS_TO_BUILD "all"
  97     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  98
  99 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 100   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 101
 102 option(BUILD_SHARED_LIBS
 103   "Build all libraries as shared libraries instead of static" OFF)
 104
 105 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 106 if(LLVM_ENABLE_CBE_PRINTF_A)
 107   set(ENABLE_CBE_PRINTF_A 1)
 108 endif()
 109
 110 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 111 if(LLVM_ENABLE_TIMESTAMPS)
 112   set(ENABLE_TIMESTAMPS 1)
 113 endif()
 114
 115 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 116 if(LLVM_ENABLE_BACKTRACES)
 117   set(ENABLE_BACKTRACES 1)
 118 endif()
 119
 120 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 121 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 122 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 123
 124 set(LLVM_TARGET_ARCH "host"
 125   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 126
 127 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 128
 129 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 130
 131 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 132   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 133 endif()
 134
 135 set(LLVM_TARGETS_TO_BUILD
 136    ${LLVM_TARGETS_TO_BUILD}
 137    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 138 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 139
 140 set(LLVM_ENUM_TARGETS "")
 141 foreach(c ${LLVM_TARGETS_TO_BUILD})
 142   list(FIND LLVM_ALL_TARGETS ${c} idx)
 143   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 144   if( idx LESS 0 AND idy LESS 0 )
 145     message(FATAL_ERROR "The target `${c}' does not exist.
 146     It should be one of\n${LLVM_ALL_TARGETS}")
 147   else()
 148     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 149   endif()
 150 endforeach(c)
 151
 152 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 153
 154 include(AddLLVMDefinitions)
 155
 156 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 157
 158 # MSVC has a gazillion warnings with this.
 159 if( MSVC )
 160   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 161 else( MSVC )
 162   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 163 endif()
 164
 165 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 166 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 167
 168 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 169   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 170 else()
 171   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 172 endif()
 173
 174 option(LLVM_USE_INTEL_JITEVENTS
 175   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 176   OFF)
 177
 178 if( LLVM_USE_INTEL_JITEVENTS )
 179   # Verify we are on a supported platform
 180   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 181     message(FATAL_ERROR
 182       "Intel JIT API support is available on Linux and Windows only.")
 183   endif()
 184 endif( LLVM_USE_INTEL_JITEVENTS )
 185
 186 option(LLVM_USE_OPROFILE
 187   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 188
 189 # If enabled, verify we are on a platform that supports oprofile.
 190 if( LLVM_USE_OPROFILE )
 191   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 192     message(FATAL_ERROR "OProfile support is available on Linux only.")
 193   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 194 endif( LLVM_USE_OPROFILE )
 195
 196 set(LLVM_USE_SANITIZER "" CACHE STRING
 197   "Define the sanitizer used to build binaries and tests.")
 198
 199 # Define an option controlling whether we should build for 32-bit on 64-bit
 200 # platforms, where supported.
 201 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 202   # TODO: support other platforms and toolchains.
 203   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 204 endif()
 205
 206 # Define the default arguments to use with 'lit', and an option for the user to
 207 # override.
 208 set(LIT_ARGS_DEFAULT "-sv")
 209 if (MSVC OR XCODE)
 210   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 211 endif()
 212 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 213
 214 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 215 if( WIN32 AND NOT CYGWIN )
 216   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 217 endif()
 218
 219 # Define options to control the inclusion and default build behavior for
 220 # components which may not strictly be necessary (tools, runtime, examples, and
 221 # tests).
 222 #
 223 # This is primarily to support building smaller or faster project files.
 224 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 225 option(LLVM_BUILD_TOOLS
 226   "Build the LLVM tools. If OFF, just generate build targets." ON)
 227
 228 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 229 option(LLVM_BUILD_RUNTIME
 230   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 231
 232 option(LLVM_BUILD_EXAMPLES
 233   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 234 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 235
 236 option(LLVM_BUILD_TESTS
 237   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 238 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 239
 240 # All options referred to from HandleLLVMOptions have to be specified
 241 # BEFORE this include, otherwise options will not be correctly set on
 242 # first cmake run
 243 include(config-ix)
 244
 245 # By default, we target the host, but this can be overridden at CMake
 246 # invocation time.
 247 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 248   "Default target for which LLVM will generate code." )
 249 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 250
 251 include(HandleLLVMOptions)
 252
 253 # Verify that we can find a Python interpreter,
 254 include(FindPythonInterp)
 255 if( NOT PYTHONINTERP_FOUND )
 256   message(FATAL_ERROR
 257 "Unable to find Python interpreter, required for builds and testing.
 258
 259 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 260 endif()
 261
 262 ######
 263 # LLVMBuild Integration
 264 #
 265 # We use llvm-build to generate all the data required by the CMake based
 266 # build system in one swoop:
 267 #
 268 #  - We generate a file (a CMake fragment) in the object root which contains
 269 #    all the definitions that are required by CMake.
 270 #
 271 #  - We generate the library table used by llvm-config.
 272 #
 273 #  - We generate the dependencies for the CMake fragment, so that we will
 274 #    automatically reconfigure outselves.
 275
 276 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 277 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 278   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 279 set(LLVMBUILDCMAKEFRAG
 280   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 281
 282 # Create the list of optional components that are enabled
 283 if (LLVM_USE_INTEL_JITEVENTS)
 284   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 285 endif (LLVM_USE_INTEL_JITEVENTS)
 286 if (LLVM_USE_OPROFILE)
 287   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 288 endif (LLVM_USE_OPROFILE)
 289
 290 message(STATUS "Constructing LLVMBuild project information")
 291 execute_process(
 292   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 293             --native-target "${LLVM_NATIVE_ARCH}"
 294             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 295             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 296             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 297             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 298             ERROR_VARIABLE LLVMBUILDOUTPUT
 299             ERROR_VARIABLE LLVMBUILDERRORS
 300             OUTPUT_STRIP_TRAILING_WHITESPACE
 301             ERROR_STRIP_TRAILING_WHITESPACE
 302   RESULT_VARIABLE LLVMBUILDRESULT)
 303
 304 # On Win32, CMake doesn't properly handle piping the default output/error
 305 # streams into the GUI console. So, we explicitly catch and report them.
 306 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 307   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 308 endif()
 309 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 310   message(FATAL_ERROR
 311     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 312 endif()
 313
 314 # Include the generated CMake fragment. This will define properties from the
 315 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 316 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 317 # files change.
 318 include(${LLVMBUILDCMAKEFRAG})
 319
 320 ######
 321
 322 # Configure all of the various header file fragments LLVM uses which depend on
 323 # configuration variables.
 324 set(LLVM_ENUM_ASM_PRINTERS "")
 325 set(LLVM_ENUM_ASM_PARSERS "")
 326 set(LLVM_ENUM_DISASSEMBLERS "")
 327 foreach(t ${LLVM_TARGETS_TO_BUILD})
 328   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 329   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 330   if( asmp_file )
 331     set(LLVM_ENUM_ASM_PRINTERS
 332       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 333   endif()
 334   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 335     set(LLVM_ENUM_ASM_PARSERS
 336       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 337   endif()
 338   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 339     set(LLVM_ENUM_DISASSEMBLERS
 340       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 341   endif()
 342 endforeach(t)
 343
 344 # Produce the target definition files, which provide a way for clients to easily
 345 # include various classes of targets.
 346 configure_file(
 347   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 348   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 349   )
 350 configure_file(
 351   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 352   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 353   )
 354 configure_file(
 355   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 356   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 357   )
 358 configure_file(
 359   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 360   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 361   )
 362
 363 # Configure the three LLVM configuration header files.
 364 configure_file(
 365   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 366   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 367 configure_file(
 368   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 369   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 370 configure_file(
 371   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 372   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 373
 374 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 375 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 376 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 377
 378 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 379
 380 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 381
 382 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 383   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 384   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 385   include_directories("/usr/local/include")
 386   link_directories("/usr/local/lib")
 387 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 388
 389 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 390    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 391 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 392
 393 # Make sure we don't get -rdynamic in every binary. For those that need it,
 394 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 395 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 396
 397 include(AddLLVM)
 398 include(TableGen)
 399
 400 if( MINGW )
 401   # People report that -O3 is unreliable on MinGW. The traditional
 402   # build also uses -O2 for that reason:
 403   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 404 endif()
 405
 406 # Put this before tblgen. Else we have a circular dependence.
 407 add_subdirectory(lib/Support)
 408 add_subdirectory(lib/TableGen)
 409
 410 add_subdirectory(utils/TableGen)
 411
 412 add_subdirectory(include/llvm)
 413
 414 add_subdirectory(lib)
 415
 416 add_subdirectory(utils/FileCheck)
 417 add_subdirectory(utils/FileUpdate)
 418 add_subdirectory(utils/count)
 419 add_subdirectory(utils/not)
 420 add_subdirectory(utils/llvm-lit)
 421 add_subdirectory(utils/yaml-bench)
 422
 423 add_subdirectory(projects)
 424
 425 if( LLVM_INCLUDE_TOOLS )
 426   add_subdirectory(tools)
 427 endif()
 428
 429 if( LLVM_INCLUDE_RUNTIME )
 430   add_subdirectory(runtime)
 431 endif()
 432
 433 if( LLVM_INCLUDE_EXAMPLES )
 434   add_subdirectory(examples)
 435 endif()
 436
 437 if( LLVM_INCLUDE_TESTS )
 438   add_subdirectory(test)
 439   add_subdirectory(utils/unittest)
 440   add_subdirectory(unittests)
 441   if (MSVC)
 442     # This utility is used to prevent crashing tests from calling Dr. Watson on
 443     # Windows.
 444     add_subdirectory(utils/KillTheDoctor)
 445   endif()
 446
 447   # Add a global check rule now that all subdirectories have been traversed
 448   # and we know the total set of lit testsuites.
 449   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 450   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 451   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 452   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 453   add_lit_target(check-all
 454     "Running all regression tests"
 455     ${LLVM_LIT_TESTSUITES}
 456     PARAMS ${LLVM_LIT_PARAMS}
 457     DEPENDS ${LLVM_LIT_DEPENDS}
 458     ARGS ${LLVM_LIT_EXTRA_ARGS}
 459     )
 460 endif()
 461
 462 add_subdirectory(cmake/modules)
 463
 464 install(DIRECTORY include/
 465   DESTINATION include
 466   FILES_MATCHING
 467   PATTERN "*.def"
 468   PATTERN "*.h"
 469   PATTERN "*.td"
 470   PATTERN "*.inc"
 471   PATTERN "LICENSE.TXT"
 472   PATTERN ".svn" EXCLUDE
 473   )
 474
 475 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 476   DESTINATION include
 477   FILES_MATCHING
 478   PATTERN "*.def"
 479   PATTERN "*.h"
 480   PATTERN "*.gen"
 481   PATTERN "*.inc"
 482   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 483   PATTERN "CMakeFiles" EXCLUDE
 484   PATTERN ".svn" EXCLUDE
 485   )
 486
 487 # TODO: make and install documentation.
 488
 489 set(CPACK_PACKAGE_VENDOR "LLVM")
 490 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 491 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 492 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 493 include(CPack)
 494
 495 # Workaround for MSVS10 to avoid the Dialog Hell
 496 # FIXME: This could be removed with future version of CMake.
 497 if(MSVC_VERSION EQUAL 1600)
 498   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 499   if( EXISTS "${LLVM_SLN_FILENAME}" )
 500     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 501   endif()
 502 endif()