CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29
  30 set(LLVM_ALL_TARGETS
  31   Alpha
  32   ARM
  33   CBackend
  34   CellSPU
  35   CppBackend
  36   IA64
  37   Mips
  38   MSIL
  39   PIC16
  40   PowerPC
  41   Sparc
  42   X86
  43   XCore
  44   )
  45
  46 # List of targets whose asmprinters need to be forced to link
  47 # into executables on some platforms (i.e. Windows):
  48 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  49
  50 if( MSVC )
  51   set(LLVM_TARGETS_TO_BUILD X86
  52     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  53 else( MSVC )
  54   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  55     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  56 endif( MSVC )
  57
  58 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  59
  60 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  61   option(LLVM_ENABLE_ASSERTS "Enable asserts" OFF)
  62 else()
  63   option(LLVM_ENABLE_ASSERTS "Enable asserts" ON)
  64 endif()
  65
  66 if( LLVM_ENABLE_ASSERTS )
  67   add_definitions( -D_DEBUG -UNDEBUG )
  68 endif()
  69
  70 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  71   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  72 endif()
  73
  74 foreach(c ${LLVM_TARGETS_TO_BUILD})
  75   list(FIND LLVM_ALL_TARGETS ${c} idx)
  76   if( idx LESS 0 )
  77     message(FATAL_ERROR "The target `${c}' does not exists.
  78     It should be one of\n${LLVM_ALL_TARGETS}")
  79   endif()
  80 endforeach(c)
  81
  82 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  83
  84 # Add path for custom modules
  85 set(CMAKE_MODULE_PATH
  86   ${CMAKE_MODULE_PATH}
  87   "${LLVM_MAIN_SRC_DIR}/cmake"
  88   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
  89   )
  90
  91 include(AddLLVMDefinitions)
  92
  93 if(WIN32)
  94   if(CYGWIN)
  95     set(LLVM_ON_WIN32 0)
  96     set(LLVM_ON_UNIX 1)
  97   else(CYGWIN)
  98     set(LLVM_ON_WIN32 1)
  99     set(LLVM_ON_UNIX 0)
 100   endif(CYGWIN)
 101   set(LTDL_SHLIB_EXT ".dll")
 102   set(EXEEXT ".exe")
 103   # Maximum path length is 160 for non-unicode paths
 104   set(MAXPATHLEN 160)
 105 else(WIN32)
 106   if(UNIX)
 107     set(LLVM_ON_WIN32 0)
 108     set(LLVM_ON_UNIX 1)
 109     set(LTDL_SHLIB_EXT ".so")
 110     set(EXEEXT "")
 111     # FIXME: Maximum path length is currently set to 'safe' fixed value
 112     set(MAXPATHLEN 2024)
 113   else(UNIX)
 114     MESSAGE(SEND_ERROR "Unable to determine platform")
 115   endif(UNIX)
 116 endif(WIN32)
 117
 118 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 119   set(HAVE_LLVM_CONFIG 1)
 120 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 121
 122 include(config-ix)
 123
 124 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 125
 126 if( LLVM_ENABLE_PIC )
 127   if( SUPPORTS_FPIC_FLAG )
 128     message(STATUS "Building with -fPIC")
 129     add_llvm_definitions(-fPIC)
 130   else( SUPPORTS_FPIC_FLAG )
 131     message(STATUS "Warning: -fPIC not supported.")
 132   endif()
 133 endif()
 134
 135 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 136 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 137 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 138
 139 # set(CMAKE_VERBOSE_MAKEFILE true)
 140
 141 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 142 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 143
 144 set(LLVM_PLO_FLAGS "" CACHE
 145   STRING "Flags for creating partially linked objects.")
 146
 147 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 148   # TODO: support other platforms and toolchains.
 149   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 150   if( LLVM_BUILD_32_BITS )
 151     message(STATUS "Building 32 bits executables and libraries.")
 152     add_llvm_definitions( -m32 )
 153     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 154     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 155     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 156   endif( LLVM_BUILD_32_BITS )
 157 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 158
 159 if( MSVC )
 160   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 161   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 162   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 163   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 164   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 165 endif( MSVC )
 166
 167 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 168
 169 include(AddLLVM)
 170 include(AddPartiallyLinkedObject)
 171 include(TableGen)
 172
 173 add_subdirectory(lib/Support)
 174 add_subdirectory(lib/System)
 175
 176 # Everything else depends on Support and System:
 177 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 178
 179 set(LLVM_TABLEGEN "tblgen" CACHE
 180   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 181
 182 add_subdirectory(utils/TableGen)
 183
 184 if( CMAKE_CROSSCOMPILING )
 185   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 186   include( CrossCompileLLVM )
 187 endif( CMAKE_CROSSCOMPILING )
 188
 189 add_subdirectory(include/llvm)
 190
 191 add_subdirectory(lib/VMCore)
 192 add_subdirectory(lib/CodeGen)
 193 add_subdirectory(lib/CodeGen/SelectionDAG)
 194 add_subdirectory(lib/CodeGen/AsmPrinter)
 195 add_subdirectory(lib/Bitcode/Reader)
 196 add_subdirectory(lib/Bitcode/Writer)
 197 add_subdirectory(lib/Transforms/Utils)
 198 add_subdirectory(lib/Transforms/Instrumentation)
 199 add_subdirectory(lib/Transforms/Scalar)
 200 add_subdirectory(lib/Transforms/IPO)
 201 add_subdirectory(lib/Transforms/Hello)
 202 add_subdirectory(lib/Linker)
 203 add_subdirectory(lib/Analysis)
 204 add_subdirectory(lib/Analysis/IPA)
 205
 206 foreach(t ${LLVM_TARGETS_TO_BUILD})
 207   message(STATUS "Targeting ${t}")
 208   add_subdirectory(lib/Target/${t})
 209   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 210     add_subdirectory(lib/Target/${t}/AsmPrinter)
 211   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 212 endforeach(t)
 213
 214 add_subdirectory(lib/ExecutionEngine)
 215 add_subdirectory(lib/ExecutionEngine/Interpreter)
 216 add_subdirectory(lib/ExecutionEngine/JIT)
 217 add_subdirectory(lib/Target)
 218 add_subdirectory(lib/AsmParser)
 219 add_subdirectory(lib/Debugger)
 220 add_subdirectory(lib/Archive)
 221
 222 add_subdirectory(projects)
 223 add_subdirectory(tools)
 224
 225 add_subdirectory(examples)
 226
 227 install(DIRECTORY include
 228   DESTINATION .
 229   PATTERN ".svn" EXCLUDE
 230   PATTERN "*.cmake" EXCLUDE
 231   PATTERN "*.in" EXCLUDE
 232   )
 233
 234 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 235   DESTINATION .
 236   )
 237
 238 # TODO: make and install documentation.