CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 # Configure CPack.
  41 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  42 set(CPACK_PACKAGE_VENDOR "LLVM")
  43 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  44 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  45 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  46 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  47 if(WIN32 AND NOT UNIX)
  48   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  49   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  50   set(CPACK_NSIS_MODIFY_PATH "ON")
  51   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  52   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  53     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  54   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  55     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  56 endif()
  57 include(CPack)
  58
  59 # Sanity check our source directory to make sure that we are not trying to
  60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  61 # sure that we don't have any stray generated files lying around in the tree
  62 # (which would end up getting picked up by header search, instead of the correct
  63 # versions).
  64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  65   message(FATAL_ERROR "In-source builds are not allowed.
  66 CMake would overwrite the makefiles distributed with LLVM.
  67 Please create a directory and run cmake from there, passing the path
  68 to this source directory as the last argument.
  69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  70 Please delete them.")
  71 endif()
  72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  73   file(GLOB_RECURSE
  74     tablegenned_files_on_include_dir
  75     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_lib_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  79   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  80     message(FATAL_ERROR "Apparently there is a previous in-source build,
  81 probably as the result of running `configure' and `make' on
  82 ${CMAKE_CURRENT_SOURCE_DIR}.
  83 This may cause problems. The suspicious files are:
  84 ${tablegenned_files_on_lib_dir}
  85 ${tablegenned_files_on_include_dir}
  86 Please clean the source directory.")
  87   endif()
  88 endif()
  89
  90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  91
  92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  97 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
  98 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  99
 100 set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 101 set(LLVM_LIBRARY_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 102
 103 set(LLVM_ALL_TARGETS
 104   AArch64
 105   ARM
 106   CppBackend
 107   Hexagon
 108   Mips
 109   MSP430
 110   NVPTX
 111   PowerPC
 112   R600
 113   Sparc
 114   SystemZ
 115   X86
 116   XCore
 117   )
 118
 119 # List of targets with JIT support:
 120 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 121
 122 set(LLVM_TARGETS_TO_BUILD "all"
 123     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 124
 125 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 126   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 127
 128 option(BUILD_SHARED_LIBS
 129   "Build all libraries as shared libraries instead of static" OFF)
 130
 131 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 132 if(LLVM_ENABLE_CBE_PRINTF_A)
 133   set(ENABLE_CBE_PRINTF_A 1)
 134 endif()
 135
 136 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 137 if(LLVM_ENABLE_TIMESTAMPS)
 138   set(ENABLE_TIMESTAMPS 1)
 139 endif()
 140
 141 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 142 if(LLVM_ENABLE_BACKTRACES)
 143   set(ENABLE_BACKTRACES 1)
 144 endif()
 145
 146 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 147 if(LLVM_ENABLE_CRASH_OVERRIDES)
 148   set(ENABLE_CRASH_OVERRIDES 1)
 149 endif()
 150
 151 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 152 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 153 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 154
 155 set(LLVM_TARGET_ARCH "host"
 156   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 157
 158 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 159
 160 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 161
 162 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 163
 164 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 165   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 166 endif()
 167
 168 set(LLVM_TARGETS_TO_BUILD
 169    ${LLVM_TARGETS_TO_BUILD}
 170    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 171 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 172
 173 include(AddLLVMDefinitions)
 174
 175 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 176
 177 # MSVC has a gazillion warnings with this.
 178 if( MSVC )
 179   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 180 else( MSVC )
 181   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 182 endif()
 183
 184 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 185 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 186 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 187 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 188
 189 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 190   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 191 else()
 192   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 193 endif()
 194
 195 option(LLVM_USE_INTEL_JITEVENTS
 196   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 197   OFF)
 198
 199 if( LLVM_USE_INTEL_JITEVENTS )
 200   # Verify we are on a supported platform
 201   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 202     message(FATAL_ERROR
 203       "Intel JIT API support is available on Linux and Windows only.")
 204   endif()
 205 endif( LLVM_USE_INTEL_JITEVENTS )
 206
 207 option(LLVM_USE_OPROFILE
 208   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 209
 210 # If enabled, verify we are on a platform that supports oprofile.
 211 if( LLVM_USE_OPROFILE )
 212   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 213     message(FATAL_ERROR "OProfile support is available on Linux only.")
 214   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 215 endif( LLVM_USE_OPROFILE )
 216
 217 set(LLVM_USE_SANITIZER "" CACHE STRING
 218   "Define the sanitizer used to build binaries and tests.")
 219
 220 option(LLVM_USE_SPLIT_DWARF
 221   "Use -gsplit-dwarf when compiling llvm." OFF)
 222
 223 # Define an option controlling whether we should build for 32-bit on 64-bit
 224 # platforms, where supported.
 225 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 226   # TODO: support other platforms and toolchains.
 227   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 228 endif()
 229
 230 # Define the default arguments to use with 'lit', and an option for the user to
 231 # override.
 232 set(LIT_ARGS_DEFAULT "-sv")
 233 if (MSVC OR XCODE)
 234   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 235 endif()
 236 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 237
 238 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 239 if( WIN32 AND NOT CYGWIN )
 240   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 241 endif()
 242
 243 # Define options to control the inclusion and default build behavior for
 244 # components which may not strictly be necessary (tools, examples, and tests).
 245 #
 246 # This is primarily to support building smaller or faster project files.
 247 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 248 option(LLVM_BUILD_TOOLS
 249   "Build the LLVM tools. If OFF, just generate build targets." ON)
 250
 251 option(LLVM_BUILD_RUNTIME
 252   "Build the LLVM runtime libraries." ON)
 253 option(LLVM_BUILD_EXAMPLES
 254   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 255 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 256
 257 option(LLVM_BUILD_TESTS
 258   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 259 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 260
 261 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 262 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 263 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 264
 265 # All options referred to from HandleLLVMOptions have to be specified
 266 # BEFORE this include, otherwise options will not be correctly set on
 267 # first cmake run
 268 include(config-ix)
 269
 270 # By default, we target the host, but this can be overridden at CMake
 271 # invocation time.
 272 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 273   "Default target for which LLVM will generate code." )
 274 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 275
 276 include(HandleLLVMOptions)
 277
 278 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 279 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 280 include(FindPythonInterp)
 281 if( NOT PYTHONINTERP_FOUND )
 282   message(FATAL_ERROR
 283 "Unable to find Python interpreter, required for builds and testing.
 284
 285 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 286 endif()
 287
 288 ######
 289 # LLVMBuild Integration
 290 #
 291 # We use llvm-build to generate all the data required by the CMake based
 292 # build system in one swoop:
 293 #
 294 #  - We generate a file (a CMake fragment) in the object root which contains
 295 #    all the definitions that are required by CMake.
 296 #
 297 #  - We generate the library table used by llvm-config.
 298 #
 299 #  - We generate the dependencies for the CMake fragment, so that we will
 300 #    automatically reconfigure outselves.
 301
 302 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 303 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 304   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 305 set(LLVMBUILDCMAKEFRAG
 306   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 307
 308 # Create the list of optional components that are enabled
 309 if (LLVM_USE_INTEL_JITEVENTS)
 310   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 311 endif (LLVM_USE_INTEL_JITEVENTS)
 312 if (LLVM_USE_OPROFILE)
 313   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 314 endif (LLVM_USE_OPROFILE)
 315
 316 message(STATUS "Constructing LLVMBuild project information")
 317 execute_process(
 318   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 319             --native-target "${LLVM_NATIVE_ARCH}"
 320             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 321             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 322             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 323             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 324             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 325             ERROR_VARIABLE LLVMBUILDERRORS
 326             OUTPUT_STRIP_TRAILING_WHITESPACE
 327             ERROR_STRIP_TRAILING_WHITESPACE
 328   RESULT_VARIABLE LLVMBUILDRESULT)
 329
 330 # On Win32, CMake doesn't properly handle piping the default output/error
 331 # streams into the GUI console. So, we explicitly catch and report them.
 332 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 333   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 334 endif()
 335 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 336   message(FATAL_ERROR
 337     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 338 endif()
 339
 340 # Include the generated CMake fragment. This will define properties from the
 341 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 342 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 343 # files change.
 344 include(${LLVMBUILDCMAKEFRAG})
 345
 346 ######
 347
 348 # Configure all of the various header file fragments LLVM uses which depend on
 349 # configuration variables.
 350 set(LLVM_ENUM_TARGETS "")
 351 set(LLVM_ENUM_ASM_PRINTERS "")
 352 set(LLVM_ENUM_ASM_PARSERS "")
 353 set(LLVM_ENUM_DISASSEMBLERS "")
 354 foreach(t ${LLVM_TARGETS_TO_BUILD})
 355   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 356
 357   list(FIND LLVM_ALL_TARGETS ${t} idx)
 358   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 359   if( idx LESS 0 AND idy LESS 0 )
 360     message(FATAL_ERROR "The target `${t}' does not exist.
 361     It should be one of\n${LLVM_ALL_TARGETS}")
 362   else()
 363     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 364   endif()
 365
 366   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 367   if( asmp_file )
 368     set(LLVM_ENUM_ASM_PRINTERS
 369       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 370   endif()
 371   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 372     set(LLVM_ENUM_ASM_PARSERS
 373       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 374   endif()
 375   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 376     set(LLVM_ENUM_DISASSEMBLERS
 377       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 378   endif()
 379 endforeach(t)
 380
 381 # Produce the target definition files, which provide a way for clients to easily
 382 # include various classes of targets.
 383 configure_file(
 384   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 385   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 386   )
 387 configure_file(
 388   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 389   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 390   )
 391 configure_file(
 392   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 393   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 394   )
 395 configure_file(
 396   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 397   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 398   )
 399
 400 # Configure the three LLVM configuration header files.
 401 configure_file(
 402   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 403   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 404 configure_file(
 405   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 406   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 407 configure_file(
 408   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 409   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 410
 411 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 412 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 413 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 414
 415 if( NOT DEFINED CMAKE_INSTALL_RPATH )
 416   set( CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 417 endif( NOT DEFINED CMAKE_INSTALL_RPATH )
 418
 419 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 420
 421 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 422
 423 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 424   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 425   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 426   include_directories("/usr/local/include")
 427   link_directories("/usr/local/lib")
 428 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 429
 430 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 431    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 432 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 433
 434 # Make sure we don't get -rdynamic in every binary. For those that need it,
 435 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 436 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 437
 438 include(AddLLVM)
 439 include(TableGen)
 440
 441 if( MINGW )
 442   # People report that -O3 is unreliable on MinGW. The traditional
 443   # build also uses -O2 for that reason:
 444   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 445 endif()
 446
 447 # Put this before tblgen. Else we have a circular dependence.
 448 add_subdirectory(lib/Support)
 449 add_subdirectory(lib/TableGen)
 450
 451 add_subdirectory(utils/TableGen)
 452
 453 add_subdirectory(include/llvm)
 454
 455 add_subdirectory(lib)
 456
 457 add_subdirectory(utils/FileCheck)
 458 add_subdirectory(utils/FileUpdate)
 459 add_subdirectory(utils/count)
 460 add_subdirectory(utils/not)
 461 add_subdirectory(utils/llvm-lit)
 462 add_subdirectory(utils/yaml-bench)
 463
 464 add_subdirectory(projects)
 465
 466 if( LLVM_INCLUDE_TOOLS )
 467   add_subdirectory(tools)
 468 endif()
 469
 470 if( LLVM_INCLUDE_EXAMPLES )
 471   add_subdirectory(examples)
 472 endif()
 473
 474 if( LLVM_INCLUDE_TESTS )
 475   add_subdirectory(test)
 476   add_subdirectory(utils/unittest)
 477   add_subdirectory(unittests)
 478   if (MSVC)
 479     # This utility is used to prevent crashing tests from calling Dr. Watson on
 480     # Windows.
 481     add_subdirectory(utils/KillTheDoctor)
 482   endif()
 483
 484   # Add a global check rule now that all subdirectories have been traversed
 485   # and we know the total set of lit testsuites.
 486   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 487   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 488   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 489   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 490   add_lit_target(check-all
 491     "Running all regression tests"
 492     ${LLVM_LIT_TESTSUITES}
 493     PARAMS ${LLVM_LIT_PARAMS}
 494     DEPENDS ${LLVM_LIT_DEPENDS}
 495     ARGS ${LLVM_LIT_EXTRA_ARGS}
 496     )
 497 endif()
 498
 499 if (LLVM_INCLUDE_DOCS)
 500   add_subdirectory(docs)
 501 endif()
 502
 503 add_subdirectory(cmake/modules)
 504
 505 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 506   install(DIRECTORY include/
 507     DESTINATION include
 508     FILES_MATCHING
 509     PATTERN "*.def"
 510     PATTERN "*.h"
 511     PATTERN "*.td"
 512     PATTERN "*.inc"
 513     PATTERN "LICENSE.TXT"
 514     PATTERN ".svn" EXCLUDE
 515     )
 516
 517   install(DIRECTORY ${LLVM_INCLUDE_DIR}/
 518     DESTINATION include
 519     FILES_MATCHING
 520     PATTERN "*.def"
 521     PATTERN "*.h"
 522     PATTERN "*.gen"
 523     PATTERN "*.inc"
 524     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 525     PATTERN "CMakeFiles" EXCLUDE
 526     PATTERN ".svn" EXCLUDE
 527     )
 528 endif()
 529
 530 # Workaround for MSVS10 to avoid the Dialog Hell
 531 # FIXME: This could be removed with future version of CMake.
 532 if(MSVC_VERSION EQUAL 1600)
 533   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 534   if( EXISTS "${LLVM_SLN_FILENAME}" )
 535     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 536   endif()
 537 endif()
 538