CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 set(LLVM_VERSION_MAJOR 3)
  30 set(LLVM_VERSION_MINOR 8)
  31 set(LLVM_VERSION_PATCH 0)
  32 set(LLVM_VERSION_SUFFIX svn)
  33
  34 if (POLICY CMP0048)
  35   cmake_policy(SET CMP0048 NEW)
  36   set(cmake_3_0_PROJ_VERSION
  37     VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
  38   set(cmake_3_0_LANGUAGES LANGUAGES)
  39 endif()
  40
  41 if (NOT PACKAGE_VERSION)
  42   set(PACKAGE_VERSION
  43     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  44 endif()
  45
  46 project(LLVM
  47   ${cmake_3_0_PROJ_VERSION}
  48   ${cmake_3_0_LANGUAGES}
  49   C CXX ASM)
  50
  51 # The following only works with the Ninja generator in CMake >= 3.0.
  52 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  53   "Define the maximum number of concurrent compilation jobs.")
  54 if(LLVM_PARALLEL_COMPILE_JOBS)
  55   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  56     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  57   else()
  58     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  59     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  60   endif()
  61 endif()
  62
  63 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  64   "Define the maximum number of concurrent link jobs.")
  65 if(LLVM_PARALLEL_LINK_JOBS)
  66   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  67     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  68   else()
  69     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  70     set(CMAKE_JOB_POOL_LINK link_job_pool)
  71   endif()
  72 endif()
  73
  74 # Add path for custom modules
  75 set(CMAKE_MODULE_PATH
  76   ${CMAKE_MODULE_PATH}
  77   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  78   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  79   )
  80
  81 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  82
  83 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  84
  85 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  86 if ( LLVM_USE_FOLDERS )
  87   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  88 endif()
  89
  90 include(VersionFromVCS)
  91
  92 option(LLVM_APPEND_VC_REV
  93   "Append the version control system revision id to LLVM version" OFF)
  94
  95 if( LLVM_APPEND_VC_REV )
  96   add_version_info_from_vcs(PACKAGE_VERSION)
  97 endif()
  98
  99 set(PACKAGE_NAME LLVM)
 100 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 101 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 102
 103 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 104   "Default URL where bug reports are to be submitted.")
 105
 106 # Configure CPack.
 107 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 108 set(CPACK_PACKAGE_VENDOR "LLVM")
 109 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 110 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 111 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 112 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 113 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 114 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 115 if(WIN32 AND NOT UNIX)
 116   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 117   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 118   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 119   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 120   set(CPACK_NSIS_MODIFY_PATH "ON")
 121   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 122   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 123     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 124   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 125     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 126   if( CMAKE_CL_64 )
 127     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 128   endif()
 129 endif()
 130 include(CPack)
 131
 132 # Sanity check our source directory to make sure that we are not trying to
 133 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 134 # sure that we don't have any stray generated files lying around in the tree
 135 # (which would end up getting picked up by header search, instead of the correct
 136 # versions).
 137 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 138   message(FATAL_ERROR "In-source builds are not allowed.
 139 CMake would overwrite the makefiles distributed with LLVM.
 140 Please create a directory and run cmake from there, passing the path
 141 to this source directory as the last argument.
 142 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 143 Please delete them.")
 144 endif()
 145 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 146   file(GLOB_RECURSE
 147     tablegenned_files_on_include_dir
 148     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 149   file(GLOB_RECURSE
 150     tablegenned_files_on_lib_dir
 151     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 152   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 153     message(FATAL_ERROR "Apparently there is a previous in-source build,
 154 probably as the result of running `configure' and `make' on
 155 ${CMAKE_CURRENT_SOURCE_DIR}.
 156 This may cause problems. The suspicious files are:
 157 ${tablegenned_files_on_lib_dir}
 158 ${tablegenned_files_on_include_dir}
 159 Please clean the source directory.")
 160   endif()
 161 endif()
 162
 163 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 164
 165 if (CMAKE_BUILD_TYPE AND
 166     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 167   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 168 endif()
 169
 170 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 171
 172 # They are used as destination of target generators.
 173 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 174 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 175 if(WIN32 OR CYGWIN)
 176   # DLL platform -- put DLLs into bin.
 177   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 178 else()
 179   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 180 endif()
 181
 182 # Each of them corresponds to llvm-config's.
 183 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 184 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 185 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 186 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 187 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 188
 189 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 190 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 191
 192 set(LLVM_ALL_TARGETS
 193   AArch64
 194   AMDGPU
 195   ARM
 196   BPF
 197   CppBackend
 198   Hexagon
 199   Mips
 200   MSP430
 201   NVPTX
 202   PowerPC
 203   Sparc
 204   SystemZ
 205   X86
 206   XCore
 207   )
 208
 209 # List of targets with JIT support:
 210 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 211
 212 set(LLVM_TARGETS_TO_BUILD "all"
 213     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 214
 215 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 216   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 217
 218 option(BUILD_SHARED_LIBS
 219   "Build all libraries as shared libraries instead of static" OFF)
 220
 221 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 222 if(LLVM_ENABLE_TIMESTAMPS)
 223   set(ENABLE_TIMESTAMPS 1)
 224 endif()
 225
 226 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 227 if(LLVM_ENABLE_BACKTRACES)
 228   set(ENABLE_BACKTRACES 1)
 229 endif()
 230
 231 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 232 if(LLVM_ENABLE_CRASH_OVERRIDES)
 233   set(ENABLE_CRASH_OVERRIDES 1)
 234 endif()
 235
 236 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 237 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 238 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 239
 240 set(LLVM_TARGET_ARCH "host"
 241   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 242
 243 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 244
 245 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 246
 247 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 248
 249 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 250   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 251 endif()
 252
 253 set(LLVM_TARGETS_TO_BUILD
 254    ${LLVM_TARGETS_TO_BUILD}
 255    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 256 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 257
 258 include(AddLLVMDefinitions)
 259
 260 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 261 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 262 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 263 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 264 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 265 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 266 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 267 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 268
 269 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 270   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 271 else()
 272   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 273 endif()
 274
 275 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 276   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 277
 278 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 279        "Set to ON to force using an old, unsupported host toolchain." OFF)
 280
 281 option(LLVM_USE_INTEL_JITEVENTS
 282   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 283   OFF)
 284
 285 if( LLVM_USE_INTEL_JITEVENTS )
 286   # Verify we are on a supported platform
 287   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 288     message(FATAL_ERROR
 289       "Intel JIT API support is available on Linux and Windows only.")
 290   endif()
 291 endif( LLVM_USE_INTEL_JITEVENTS )
 292
 293 option(LLVM_USE_OPROFILE
 294   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 295
 296 # If enabled, verify we are on a platform that supports oprofile.
 297 if( LLVM_USE_OPROFILE )
 298   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 299     message(FATAL_ERROR "OProfile support is available on Linux only.")
 300   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 301 endif( LLVM_USE_OPROFILE )
 302
 303 set(LLVM_USE_SANITIZER "" CACHE STRING
 304   "Define the sanitizer used to build binaries and tests.")
 305
 306 option(LLVM_USE_SPLIT_DWARF
 307   "Use -gsplit-dwarf when compiling llvm." OFF)
 308
 309 option(WITH_POLLY "Build LLVM with Polly" ON)
 310 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 311
 312 # Define an option controlling whether we should build for 32-bit on 64-bit
 313 # platforms, where supported.
 314 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 315   # TODO: support other platforms and toolchains.
 316   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 317 endif()
 318
 319 # Define the default arguments to use with 'lit', and an option for the user to
 320 # override.
 321 set(LIT_ARGS_DEFAULT "-sv")
 322 if (MSVC_IDE OR XCODE)
 323   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 324 endif()
 325 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 326
 327 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 328 if( WIN32 AND NOT CYGWIN )
 329   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 330 endif()
 331
 332 # Define options to control the inclusion and default build behavior for
 333 # components which may not strictly be necessary (tools, examples, and tests).
 334 #
 335 # This is primarily to support building smaller or faster project files.
 336 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 337 option(LLVM_BUILD_TOOLS
 338   "Build the LLVM tools. If OFF, just generate build targets." ON)
 339
 340 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 341
 342 option(LLVM_BUILD_RUNTIME
 343   "Build the LLVM runtime libraries." ON)
 344 option(LLVM_BUILD_EXAMPLES
 345   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 346 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 347
 348 option(LLVM_BUILD_TESTS
 349   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 350 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 351 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 352
 353 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 354 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 355 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 356 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 357
 358 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 359   "Build compiler-rt as an external project." OFF)
 360
 361 # You can configure which libraries from LLVM you want to include in the
 362 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 363 # list of LLVM components. All component names handled by llvm-config are valid.
 364 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 365   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 366     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 367 endif()
 368 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 369 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_LINK_LLVM_DYLIB})
 370 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" ${LLVM_LINK_LLVM_DYLIB})
 371 set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT ON)
 372 if (LLVM_LINK_LLVM_DYLIB)
 373   set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT OFF)
 374 endif()
 375 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ${LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT})
 376 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 377   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 378 endif()
 379
 380 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 381 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 382   set(LLVM_USE_HOST_TOOLS ON)
 383 endif()
 384
 385 # All options referred to from HandleLLVMOptions have to be specified
 386 # BEFORE this include, otherwise options will not be correctly set on
 387 # first cmake run
 388 include(config-ix)
 389
 390 # By default, we target the host, but this can be overridden at CMake
 391 # invocation time.
 392 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 393   "Default target for which LLVM will generate code." )
 394 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 395
 396 include(HandleLLVMOptions)
 397
 398 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 399 # FIXME: We should support systems with only Python 3, but that requires work
 400 # on LLDB.
 401 set(Python_ADDITIONAL_VERSIONS 2.7)
 402 include(FindPythonInterp)
 403 if( NOT PYTHONINTERP_FOUND )
 404   message(FATAL_ERROR
 405 "Unable to find Python interpreter, required for builds and testing.
 406
 407 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 408 endif()
 409
 410 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 411   message(FATAL_ERROR "Python 2.7 or newer is required")
 412 endif()
 413
 414 ######
 415 # LLVMBuild Integration
 416 #
 417 # We use llvm-build to generate all the data required by the CMake based
 418 # build system in one swoop:
 419 #
 420 #  - We generate a file (a CMake fragment) in the object root which contains
 421 #    all the definitions that are required by CMake.
 422 #
 423 #  - We generate the library table used by llvm-config.
 424 #
 425 #  - We generate the dependencies for the CMake fragment, so that we will
 426 #    automatically reconfigure outselves.
 427
 428 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 429 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 430   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 431 set(LLVMBUILDCMAKEFRAG
 432   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 433
 434 # Create the list of optional components that are enabled
 435 if (LLVM_USE_INTEL_JITEVENTS)
 436   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 437 endif (LLVM_USE_INTEL_JITEVENTS)
 438 if (LLVM_USE_OPROFILE)
 439   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 440 endif (LLVM_USE_OPROFILE)
 441
 442 message(STATUS "Constructing LLVMBuild project information")
 443 execute_process(
 444   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 445             --native-target "${LLVM_NATIVE_ARCH}"
 446             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 447             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 448             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 449             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 450             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 451             ERROR_VARIABLE LLVMBUILDERRORS
 452             OUTPUT_STRIP_TRAILING_WHITESPACE
 453             ERROR_STRIP_TRAILING_WHITESPACE
 454   RESULT_VARIABLE LLVMBUILDRESULT)
 455
 456 # On Win32, CMake doesn't properly handle piping the default output/error
 457 # streams into the GUI console. So, we explicitly catch and report them.
 458 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 459   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 460 endif()
 461 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 462   message(FATAL_ERROR
 463     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 464 endif()
 465
 466 # Include the generated CMake fragment. This will define properties from the
 467 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 468 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 469 # files change.
 470 include(${LLVMBUILDCMAKEFRAG})
 471
 472 ######
 473
 474 # Configure all of the various header file fragments LLVM uses which depend on
 475 # configuration variables.
 476 set(LLVM_ENUM_TARGETS "")
 477 set(LLVM_ENUM_ASM_PRINTERS "")
 478 set(LLVM_ENUM_ASM_PARSERS "")
 479 set(LLVM_ENUM_DISASSEMBLERS "")
 480 foreach(t ${LLVM_TARGETS_TO_BUILD})
 481   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 482
 483   list(FIND LLVM_ALL_TARGETS ${t} idx)
 484   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 485   if( idx LESS 0 AND idy LESS 0 )
 486     message(FATAL_ERROR "The target `${t}' does not exist.
 487     It should be one of\n${LLVM_ALL_TARGETS}")
 488   else()
 489     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 490   endif()
 491
 492   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 493   if( asmp_file )
 494     set(LLVM_ENUM_ASM_PRINTERS
 495       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 496   endif()
 497   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 498     set(LLVM_ENUM_ASM_PARSERS
 499       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 500   endif()
 501   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 502     set(LLVM_ENUM_DISASSEMBLERS
 503       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 504   endif()
 505 endforeach(t)
 506
 507 # Produce the target definition files, which provide a way for clients to easily
 508 # include various classes of targets.
 509 configure_file(
 510   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 511   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 512   )
 513 configure_file(
 514   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 515   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 516   )
 517 configure_file(
 518   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 519   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 520   )
 521 configure_file(
 522   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 523   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 524   )
 525
 526 # Configure the three LLVM configuration header files.
 527 configure_file(
 528   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 529   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 530 configure_file(
 531   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 532   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 533 configure_file(
 534   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 535   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 536
 537 # They are not referenced. See set_output_directory().
 538 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 539 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 540 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 541
 542 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 543 if (APPLE)
 544   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 545   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 546 else(UNIX)
 547   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 548     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 549     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 550       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 551       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 552     endif()
 553   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 554 endif()
 555
 556 if(APPLE AND DARWIN_LTO_LIBRARY)
 557   set(CMAKE_EXE_LINKER_FLAGS
 558     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 559   set(CMAKE_SHARED_LINKER_FLAGS
 560     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 561   set(CMAKE_MODULE_LINKER_FLAGS
 562     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 563 endif()
 564
 565 # Work around a broken bfd ld behavior. When linking a binary with a
 566 # foo.so library, it will try to find any library that foo.so uses and
 567 # check its symbols. This is wasteful (the check was done when foo.so
 568 # was created) and can fail since it is not the dynamic linker and
 569 # doesn't know how to handle search paths correctly.
 570 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 571   set(CMAKE_EXE_LINKER_FLAGS
 572       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 573 endif()
 574
 575 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 576
 577 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 578
 579 # when crosscompiling import the executable targets from a file
 580 if(LLVM_USE_HOST_TOOLS)
 581   include(CrossCompile)
 582 endif(LLVM_USE_HOST_TOOLS)
 583 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 584 # Dummy use to avoid CMake Wraning: Manually-specified variables were not used
 585 # (this is a variable that CrossCompile sets on recursive invocations)
 586 endif()
 587
 588 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 589   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 590   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 591   include_directories("/usr/local/include")
 592   link_directories("/usr/local/lib")
 593 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 594
 595 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 596    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 597 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 598
 599 # Make sure we don't get -rdynamic in every binary. For those that need it,
 600 # use export_executable_symbols(target).
 601 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 602
 603 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 604   "Profiling data file to use when compiling in order to improve runtime performance.")
 605
 606 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 607   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 608     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 609   else()
 610     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 611   endif()
 612 endif()
 613
 614 include(AddLLVM)
 615 include(TableGen)
 616
 617 if( MINGW )
 618   # People report that -O3 is unreliable on MinGW. The traditional
 619   # build also uses -O2 for that reason:
 620   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 621 endif()
 622
 623 # Put this before tblgen. Else we have a circular dependence.
 624 add_subdirectory(lib/Support)
 625 add_subdirectory(lib/TableGen)
 626
 627 add_subdirectory(utils/TableGen)
 628
 629 add_subdirectory(include/llvm)
 630
 631 add_subdirectory(lib)
 632
 633 if( LLVM_INCLUDE_UTILS )
 634   add_subdirectory(utils/FileCheck)
 635   add_subdirectory(utils/PerfectShuffle)
 636   add_subdirectory(utils/count)
 637   add_subdirectory(utils/not)
 638   add_subdirectory(utils/llvm-lit)
 639   add_subdirectory(utils/yaml-bench)
 640 else()
 641   if ( LLVM_INCLUDE_TESTS )
 642     message(FATAL_ERROR "Including tests when not building utils will not work.
 643     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 644   endif()
 645 endif()
 646
 647 if(LLVM_INCLUDE_TESTS)
 648   add_subdirectory(utils/unittest)
 649 endif()
 650
 651 foreach( binding ${LLVM_BINDINGS_LIST} )
 652   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 653     add_subdirectory(bindings/${binding})
 654   endif()
 655 endforeach()
 656
 657 add_subdirectory(projects)
 658
 659 if(WITH_POLLY)
 660   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 661     set(WITH_POLLY OFF)
 662   endif()
 663 endif(WITH_POLLY)
 664
 665 if( LLVM_INCLUDE_TOOLS )
 666   add_subdirectory(tools)
 667 endif()
 668
 669 if( LLVM_INCLUDE_EXAMPLES )
 670   add_subdirectory(examples)
 671 endif()
 672
 673 if( LLVM_INCLUDE_TESTS )
 674   add_subdirectory(test)
 675   add_subdirectory(unittests)
 676   if (MSVC)
 677     # This utility is used to prevent crashing tests from calling Dr. Watson on
 678     # Windows.
 679     add_subdirectory(utils/KillTheDoctor)
 680   endif()
 681
 682   # Add a global check rule now that all subdirectories have been traversed
 683   # and we know the total set of lit testsuites.
 684   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 685   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 686   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 687   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 688   add_lit_target(check-all
 689     "Running all regression tests"
 690     ${LLVM_LIT_TESTSUITES}
 691     PARAMS ${LLVM_LIT_PARAMS}
 692     DEPENDS ${LLVM_LIT_DEPENDS}
 693     ARGS ${LLVM_LIT_EXTRA_ARGS}
 694     )
 695 endif()
 696
 697 if (LLVM_INCLUDE_DOCS)
 698   add_subdirectory(docs)
 699 endif()
 700
 701 add_subdirectory(cmake/modules)
 702
 703 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 704   install(DIRECTORY include/llvm include/llvm-c
 705     DESTINATION include
 706     COMPONENT llvm-headers
 707     FILES_MATCHING
 708     PATTERN "*.def"
 709     PATTERN "*.h"
 710     PATTERN "*.td"
 711     PATTERN "*.inc"
 712     PATTERN "LICENSE.TXT"
 713     PATTERN ".svn" EXCLUDE
 714     )
 715
 716   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 717     DESTINATION include
 718     COMPONENT llvm-headers
 719     FILES_MATCHING
 720     PATTERN "*.def"
 721     PATTERN "*.h"
 722     PATTERN "*.gen"
 723     PATTERN "*.inc"
 724     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 725     PATTERN "CMakeFiles" EXCLUDE
 726     PATTERN "config.h" EXCLUDE
 727     PATTERN ".svn" EXCLUDE
 728     )
 729
 730   if (NOT CMAKE_CONFIGURATION_TYPES)
 731     add_custom_target(installhdrs
 732                       DEPENDS ${name}
 733                       COMMAND "${CMAKE_COMMAND}"
 734                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 735                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 736   endif()
 737 endif()