CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  64
  65 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  66
  67 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  68 if ( LLVM_USE_FOLDERS )
  69   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  70 endif()
  71
  72 include(VersionFromVCS)
  73
  74 option(LLVM_APPEND_VC_REV
  75   "Append the version control system revision id to LLVM version" OFF)
  76
  77 if( LLVM_APPEND_VC_REV )
  78   add_version_info_from_vcs(PACKAGE_VERSION)
  79 endif()
  80
  81 set(PACKAGE_NAME LLVM)
  82 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  83 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  84
  85 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  86   "Default URL where bug reports are to be submitted.")
  87
  88 # Configure CPack.
  89 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  90 set(CPACK_PACKAGE_VENDOR "LLVM")
  91 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  92 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  93 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  94 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  95 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  96 if(WIN32 AND NOT UNIX)
  97   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  98   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  99   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 100   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 101   set(CPACK_NSIS_MODIFY_PATH "ON")
 102   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 103   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 104     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 105   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 106     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 107   if( CMAKE_CL_64 )
 108     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 109   endif()
 110 endif()
 111 include(CPack)
 112
 113 # Sanity check our source directory to make sure that we are not trying to
 114 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 115 # sure that we don't have any stray generated files lying around in the tree
 116 # (which would end up getting picked up by header search, instead of the correct
 117 # versions).
 118 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 119   message(FATAL_ERROR "In-source builds are not allowed.
 120 CMake would overwrite the makefiles distributed with LLVM.
 121 Please create a directory and run cmake from there, passing the path
 122 to this source directory as the last argument.
 123 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 124 Please delete them.")
 125 endif()
 126 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 127   file(GLOB_RECURSE
 128     tablegenned_files_on_include_dir
 129     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 130   file(GLOB_RECURSE
 131     tablegenned_files_on_lib_dir
 132     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 133   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 134     message(FATAL_ERROR "Apparently there is a previous in-source build,
 135 probably as the result of running `configure' and `make' on
 136 ${CMAKE_CURRENT_SOURCE_DIR}.
 137 This may cause problems. The suspicious files are:
 138 ${tablegenned_files_on_lib_dir}
 139 ${tablegenned_files_on_include_dir}
 140 Please clean the source directory.")
 141   endif()
 142 endif()
 143
 144 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 145
 146 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 147
 148 # They are used as destination of target generators.
 149 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 150 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 151 if(WIN32 OR CYGWIN)
 152   # DLL platform -- put DLLs into bin.
 153   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 154 else()
 155   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 156 endif()
 157
 158 # Each of them corresponds to llvm-config's.
 159 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 160 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 161 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 162 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 163 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 164
 165 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 166 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 167
 168 set(LLVM_ALL_TARGETS
 169   AArch64
 170   ARM
 171   CppBackend
 172   Hexagon
 173   Mips
 174   MSP430
 175   NVPTX
 176   PowerPC
 177   R600
 178   Sparc
 179   SystemZ
 180   X86
 181   XCore
 182   )
 183
 184 # List of targets with JIT support:
 185 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 186
 187 set(LLVM_TARGETS_TO_BUILD "all"
 188     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 189
 190 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 191   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 192
 193 option(BUILD_SHARED_LIBS
 194   "Build all libraries as shared libraries instead of static" OFF)
 195
 196 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 197 if(LLVM_ENABLE_TIMESTAMPS)
 198   set(ENABLE_TIMESTAMPS 1)
 199 endif()
 200
 201 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 202 if(LLVM_ENABLE_BACKTRACES)
 203   set(ENABLE_BACKTRACES 1)
 204 endif()
 205
 206 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 207 if(LLVM_ENABLE_CRASH_OVERRIDES)
 208   set(ENABLE_CRASH_OVERRIDES 1)
 209 endif()
 210
 211 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 212 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 213 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 214
 215 set(LLVM_TARGET_ARCH "host"
 216   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 217
 218 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 219
 220 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 221
 222 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 223
 224 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 225   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 226 endif()
 227
 228 set(LLVM_TARGETS_TO_BUILD
 229    ${LLVM_TARGETS_TO_BUILD}
 230    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 231 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 232
 233 include(AddLLVMDefinitions)
 234
 235 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 236
 237 # MSVC has a gazillion warnings with this.
 238 if( MSVC )
 239   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 240 else()
 241   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 242 endif()
 243
 244 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 245 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 246 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 247 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 248 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 249 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 250
 251 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 252   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 253 else()
 254   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 255 endif()
 256
 257 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 258   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 259
 260 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 261        "Set to ON to force using an old, unsupported host toolchain." OFF)
 262
 263 option(LLVM_USE_INTEL_JITEVENTS
 264   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 265   OFF)
 266
 267 if( LLVM_USE_INTEL_JITEVENTS )
 268   # Verify we are on a supported platform
 269   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 270     message(FATAL_ERROR
 271       "Intel JIT API support is available on Linux and Windows only.")
 272   endif()
 273 endif( LLVM_USE_INTEL_JITEVENTS )
 274
 275 option(LLVM_USE_OPROFILE
 276   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 277
 278 # If enabled, verify we are on a platform that supports oprofile.
 279 if( LLVM_USE_OPROFILE )
 280   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 281     message(FATAL_ERROR "OProfile support is available on Linux only.")
 282   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 283 endif( LLVM_USE_OPROFILE )
 284
 285 set(LLVM_USE_SANITIZER "" CACHE STRING
 286   "Define the sanitizer used to build binaries and tests.")
 287
 288 option(LLVM_USE_SPLIT_DWARF
 289   "Use -gsplit-dwarf when compiling llvm." OFF)
 290
 291 option(WITH_POLLY "Build LLVM with Polly" ON)
 292 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 293
 294 # Define an option controlling whether we should build for 32-bit on 64-bit
 295 # platforms, where supported.
 296 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 297   # TODO: support other platforms and toolchains.
 298   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 299 endif()
 300
 301 # Define the default arguments to use with 'lit', and an option for the user to
 302 # override.
 303 set(LIT_ARGS_DEFAULT "-sv")
 304 if (MSVC OR XCODE)
 305   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 306 endif()
 307 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 308
 309 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 310 if( WIN32 AND NOT CYGWIN )
 311   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 312 endif()
 313
 314 # Define options to control the inclusion and default build behavior for
 315 # components which may not strictly be necessary (tools, examples, and tests).
 316 #
 317 # This is primarily to support building smaller or faster project files.
 318 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 319 option(LLVM_BUILD_TOOLS
 320   "Build the LLVM tools. If OFF, just generate build targets." ON)
 321
 322 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 323
 324 option(LLVM_BUILD_RUNTIME
 325   "Build the LLVM runtime libraries." ON)
 326 option(LLVM_BUILD_EXAMPLES
 327   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 328 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 329
 330 option(LLVM_BUILD_TESTS
 331   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 332 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 333
 334 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 335 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 336 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 337 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 338
 339 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 340   "Build compiler-rt as an external project." OFF)
 341
 342 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 343 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 344 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 345   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 346 endif()
 347
 348 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 349 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 350   set(LLVM_USE_HOST_TOOLS ON)
 351 endif()
 352
 353 # All options referred to from HandleLLVMOptions have to be specified
 354 # BEFORE this include, otherwise options will not be correctly set on
 355 # first cmake run
 356 include(config-ix)
 357
 358 # By default, we target the host, but this can be overridden at CMake
 359 # invocation time.
 360 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 361   "Default target for which LLVM will generate code." )
 362 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 363
 364 include(HandleLLVMOptions)
 365
 366 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 367 # FIXME: We should support systems with only Python 3, but that requires work
 368 # on LLDB.
 369 set(Python_ADDITIONAL_VERSIONS 2.7)
 370 include(FindPythonInterp)
 371 if( NOT PYTHONINTERP_FOUND )
 372   message(FATAL_ERROR
 373 "Unable to find Python interpreter, required for builds and testing.
 374
 375 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 376 endif()
 377
 378 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 379   message(FATAL_ERROR "Python 2.7 or newer is required")
 380 endif()
 381
 382 ######
 383 # LLVMBuild Integration
 384 #
 385 # We use llvm-build to generate all the data required by the CMake based
 386 # build system in one swoop:
 387 #
 388 #  - We generate a file (a CMake fragment) in the object root which contains
 389 #    all the definitions that are required by CMake.
 390 #
 391 #  - We generate the library table used by llvm-config.
 392 #
 393 #  - We generate the dependencies for the CMake fragment, so that we will
 394 #    automatically reconfigure outselves.
 395
 396 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 397 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 398   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 399 set(LLVMBUILDCMAKEFRAG
 400   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 401
 402 # Create the list of optional components that are enabled
 403 if (LLVM_USE_INTEL_JITEVENTS)
 404   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 405 endif (LLVM_USE_INTEL_JITEVENTS)
 406 if (LLVM_USE_OPROFILE)
 407   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 408 endif (LLVM_USE_OPROFILE)
 409
 410 message(STATUS "Constructing LLVMBuild project information")
 411 execute_process(
 412   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 413             --native-target "${LLVM_NATIVE_ARCH}"
 414             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 415             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 416             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 417             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 418             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 419             ERROR_VARIABLE LLVMBUILDERRORS
 420             OUTPUT_STRIP_TRAILING_WHITESPACE
 421             ERROR_STRIP_TRAILING_WHITESPACE
 422   RESULT_VARIABLE LLVMBUILDRESULT)
 423
 424 # On Win32, CMake doesn't properly handle piping the default output/error
 425 # streams into the GUI console. So, we explicitly catch and report them.
 426 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 427   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 428 endif()
 429 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 430   message(FATAL_ERROR
 431     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 432 endif()
 433
 434 # Include the generated CMake fragment. This will define properties from the
 435 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 436 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 437 # files change.
 438 include(${LLVMBUILDCMAKEFRAG})
 439
 440 ######
 441
 442 # Configure all of the various header file fragments LLVM uses which depend on
 443 # configuration variables.
 444 set(LLVM_ENUM_TARGETS "")
 445 set(LLVM_ENUM_ASM_PRINTERS "")
 446 set(LLVM_ENUM_ASM_PARSERS "")
 447 set(LLVM_ENUM_DISASSEMBLERS "")
 448 foreach(t ${LLVM_TARGETS_TO_BUILD})
 449   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 450
 451   list(FIND LLVM_ALL_TARGETS ${t} idx)
 452   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 453   if( idx LESS 0 AND idy LESS 0 )
 454     message(FATAL_ERROR "The target `${t}' does not exist.
 455     It should be one of\n${LLVM_ALL_TARGETS}")
 456   else()
 457     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 458   endif()
 459
 460   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 461   if( asmp_file )
 462     set(LLVM_ENUM_ASM_PRINTERS
 463       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 464   endif()
 465   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 466     set(LLVM_ENUM_ASM_PARSERS
 467       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 468   endif()
 469   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 470     set(LLVM_ENUM_DISASSEMBLERS
 471       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 472   endif()
 473 endforeach(t)
 474
 475 # Produce the target definition files, which provide a way for clients to easily
 476 # include various classes of targets.
 477 configure_file(
 478   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 479   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 480   )
 481 configure_file(
 482   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 483   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 484   )
 485 configure_file(
 486   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 487   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 488   )
 489 configure_file(
 490   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 491   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 492   )
 493
 494 # Configure the three LLVM configuration header files.
 495 configure_file(
 496   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 497   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 498 configure_file(
 499   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 500   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 501 configure_file(
 502   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 503   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 504
 505 # They are not referenced. See set_output_directory().
 506 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 507 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 508 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 509
 510 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 511 if (APPLE)
 512   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 513   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 514 else(UNIX)
 515   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 516     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 517     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 518       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 519       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 520     endif()
 521   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 522 endif()
 523
 524 # Work around a broken bfd ld behavior. When linking a binary with a
 525 # foo.so library, it will try to find any library that foo.so uses and
 526 # check its symbols. This is wasteful (the check was done when foo.so
 527 # was created) and can fail since it is not the dynamic linker and
 528 # doesn't know how to handle search paths correctly.
 529 if (UNIX AND NOT APPLE)
 530   set(CMAKE_EXE_LINKER_FLAGS
 531       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 532 endif()
 533
 534 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 535
 536 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 537
 538 # when crosscompiling import the executable targets from a file
 539 if(LLVM_USE_HOST_TOOLS)
 540   include(CrossCompile)
 541 endif(LLVM_USE_HOST_TOOLS)
 542
 543 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 544   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 545   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 546   include_directories("/usr/local/include")
 547   link_directories("/usr/local/lib")
 548 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 549
 550 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 551    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 552 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 553
 554 # Make sure we don't get -rdynamic in every binary. For those that need it,
 555 # use export_executable_symbols(target).
 556 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 557
 558 include(AddLLVM)
 559 include(TableGen)
 560
 561 if( MINGW )
 562   # People report that -O3 is unreliable on MinGW. The traditional
 563   # build also uses -O2 for that reason:
 564   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 565 endif()
 566
 567 # Put this before tblgen. Else we have a circular dependence.
 568 add_subdirectory(lib/Support)
 569 add_subdirectory(lib/TableGen)
 570
 571 add_subdirectory(utils/TableGen)
 572
 573 add_subdirectory(include/llvm)
 574
 575 add_subdirectory(lib)
 576
 577 if( LLVM_INCLUDE_UTILS )
 578   add_subdirectory(utils/FileCheck)
 579   add_subdirectory(utils/PerfectShuffle)
 580   add_subdirectory(utils/count)
 581   add_subdirectory(utils/not)
 582   add_subdirectory(utils/llvm-lit)
 583   add_subdirectory(utils/yaml-bench)
 584 else()
 585   if ( LLVM_INCLUDE_TESTS )
 586     message(FATAL_ERROR "Including tests when not building utils will not work.
 587     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 588   endif()
 589 endif()
 590
 591 if(LLVM_INCLUDE_TESTS)
 592   add_subdirectory(utils/unittest)
 593 endif()
 594
 595 foreach( binding ${LLVM_BINDINGS_LIST} )
 596   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 597     add_subdirectory(bindings/${binding})
 598   endif()
 599 endforeach()
 600
 601 add_subdirectory(projects)
 602
 603 if(WITH_POLLY)
 604   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 605     set(WITH_POLLY OFF)
 606   endif()
 607 endif(WITH_POLLY)
 608
 609 if( LLVM_INCLUDE_TOOLS )
 610   add_subdirectory(tools)
 611 endif()
 612
 613 if( LLVM_INCLUDE_EXAMPLES )
 614   add_subdirectory(examples)
 615 endif()
 616
 617 if( LLVM_INCLUDE_TESTS )
 618   add_subdirectory(test)
 619   add_subdirectory(unittests)
 620   if (MSVC)
 621     # This utility is used to prevent crashing tests from calling Dr. Watson on
 622     # Windows.
 623     add_subdirectory(utils/KillTheDoctor)
 624   endif()
 625
 626   # Add a global check rule now that all subdirectories have been traversed
 627   # and we know the total set of lit testsuites.
 628   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 629   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 630   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 631   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 632   add_lit_target(check-all
 633     "Running all regression tests"
 634     ${LLVM_LIT_TESTSUITES}
 635     PARAMS ${LLVM_LIT_PARAMS}
 636     DEPENDS ${LLVM_LIT_DEPENDS}
 637     ARGS ${LLVM_LIT_EXTRA_ARGS}
 638     )
 639 endif()
 640
 641 if (LLVM_INCLUDE_DOCS)
 642   add_subdirectory(docs)
 643 endif()
 644
 645 add_subdirectory(cmake/modules)
 646
 647 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 648   install(DIRECTORY include/llvm include/llvm-c
 649     DESTINATION include
 650     COMPONENT llvm-headers
 651     FILES_MATCHING
 652     PATTERN "*.def"
 653     PATTERN "*.h"
 654     PATTERN "*.td"
 655     PATTERN "*.inc"
 656     PATTERN "LICENSE.TXT"
 657     PATTERN ".svn" EXCLUDE
 658     )
 659
 660   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 661     DESTINATION include
 662     COMPONENT llvm-headers
 663     FILES_MATCHING
 664     PATTERN "*.def"
 665     PATTERN "*.h"
 666     PATTERN "*.gen"
 667     PATTERN "*.inc"
 668     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 669     PATTERN "CMakeFiles" EXCLUDE
 670     PATTERN "config.h" EXCLUDE
 671     PATTERN ".svn" EXCLUDE
 672     )
 673
 674   if (NOT CMAKE_CONFIGURATION_TYPES)
 675     add_custom_target(installhdrs
 676                       DEPENDS ${name}
 677                       COMMAND "${CMAKE_COMMAND}"
 678                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 679                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 680   endif()
 681 endif()