CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 1)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  19
  20 include(VersionFromVCS)
  21
  22 option(LLVM_APPEND_VC_REV
  23   "Append the version control system revision id to LLVM version" OFF)
  24
  25 if( LLVM_APPEND_VC_REV )
  26   add_version_info_from_vcs(PACKAGE_VERSION)
  27 endif()
  28
  29 set(PACKAGE_NAME LLVM)
  30 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  31 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  32
  33 # Sanity check our source directory to make sure that we are not trying to
  34 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  35 # sure that we don't have any stray generated files lying around in the tree
  36 # (which would end up getting picked up by header search, instead of the correct
  37 # versions).
  38 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  39   message(FATAL_ERROR "In-source builds are not allowed.
  40 CMake would overwrite the makefiles distributed with LLVM.
  41 Please create a directory and run cmake from there, passing the path
  42 to this source directory as the last argument.
  43 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  44 Please delete them.")
  45 endif()
  46 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_include_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_lib_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  53   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  54     message(FATAL_ERROR "Apparently there is a previous in-source build,
  55 probably as the result of running `configure' and `make' on
  56 ${CMAKE_CURRENT_SOURCE_DIR}.
  57 This may cause problems. The suspicious files are:
  58 ${tablegenned_files_on_lib_dir}
  59 ${tablegenned_files_on_include_dir}
  60 Please clean the source directory.")
  61   endif()
  62 endif()
  63
  64 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  65
  66 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  67 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  68 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  69 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  70 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  71 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  72
  73 set(LLVM_ALL_TARGETS
  74   ARM
  75   CellSPU
  76   CppBackend
  77   Hexagon
  78   Mips
  79   MBlaze
  80   MSP430
  81   PowerPC
  82   PTX
  83   Sparc
  84   X86
  85   XCore
  86   )
  87
  88 # List of targets with JIT support:
  89 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  90
  91 if( MSVC )
  92   set(LLVM_TARGETS_TO_BUILD X86
  93     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  94 else( MSVC )
  95   set(LLVM_TARGETS_TO_BUILD "all"
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97 endif( MSVC )
  98
  99 option(BUILD_SHARED_LIBS
 100   "Build all libraries as shared libraries instead of static" OFF)
 101
 102 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 103 if(LLVM_ENABLE_CBE_PRINTF_A)
 104   set(ENABLE_CBE_PRINTF_A 1)
 105 endif()
 106
 107 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 108 if(LLVM_ENABLE_TIMESTAMPS)
 109   set(ENABLE_TIMESTAMPS 1)
 110 endif()
 111
 112 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 113 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 114 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 115
 116 set(LLVM_TARGET_ARCH "host"
 117   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 118
 119 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 120
 121 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 122   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 123 endif()
 124
 125 set(LLVM_ENUM_TARGETS "")
 126 foreach(c ${LLVM_TARGETS_TO_BUILD})
 127   list(FIND LLVM_ALL_TARGETS ${c} idx)
 128   if( idx LESS 0 )
 129     message(FATAL_ERROR "The target `${c}' does not exist.
 130     It should be one of\n${LLVM_ALL_TARGETS}")
 131   else()
 132     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 133   endif()
 134 endforeach(c)
 135
 136 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 137
 138 include(AddLLVMDefinitions)
 139
 140 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 141
 142 # MSVC has a gazillion warnings with this.
 143 if( MSVC )
 144   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 145 else( MSVC )
 146   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 147 endif()
 148
 149 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 150 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 151
 152 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 153   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 154 else()
 155   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 156 endif()
 157
 158 option(LLVM_USE_INTEL_JITEVENTS
 159   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 160   OFF)
 161
 162 if( LLVM_USE_INTEL_JITEVENTS )
 163   # Verify we are on a supported platform
 164   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 165     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 166     if ( WIN32 )
 167       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 168     else ( WIN32 )
 169       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 170     endif ( WIN32 )
 171
 172     # Set include and library search paths for Intel JIT Events API
 173     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 174
 175     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 176       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 177     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 178       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 179     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 180   else()
 181     message(FATAL_ERROR
 182       "Intel JIT API support is available on Linux and Windows only.")
 183   endif()
 184 endif( LLVM_USE_INTEL_JITEVENTS )
 185
 186 option(LLVM_USE_OPROFILE
 187   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 188
 189 # If enabled, ierify we are on a platform that supports oprofile.
 190 if( LLVM_USE_OPROFILE )
 191   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 192     message(FATAL_ERROR "OProfile support is available on Linux only.")
 193   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 194 endif( LLVM_USE_OPROFILE )
 195
 196 # Define an option controlling whether we should build for 32-bit on 64-bit
 197 # platforms, where supported.
 198 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 199   # TODO: support other platforms and toolchains.
 200   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 201 endif()
 202
 203 # Define the default arguments to use with 'lit', and an option for the user to
 204 # override.
 205 set(LIT_ARGS_DEFAULT "-sv")
 206 if (MSVC OR XCODE)
 207   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 208 endif()
 209 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 210
 211 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 212 if( WIN32 AND NOT CYGWIN )
 213   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 214 endif()
 215
 216 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 217 # to use.
 218 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 219   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 220   # 2005 supports it but it is experimental.
 221   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 222     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 223 endif()
 224
 225 # Define options to control the inclusion and default build behavior for
 226 # components which may not strictly be necessary (tools, runtime, examples, and
 227 # tests).
 228 #
 229 # This is primarily to support building smaller or faster project files.
 230 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 231 option(LLVM_BUILD_TOOLS
 232   "Build the LLVM tools. If OFF, just generate build targets." ON)
 233
 234 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 235 option(LLVM_BUILD_RUNTIME
 236   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 237
 238 option(LLVM_BUILD_EXAMPLES
 239   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 240 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 241
 242 option(LLVM_BUILD_TESTS
 243   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 244 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 245
 246 # All options referred to from HandleLLVMOptions have to be specified
 247 # BEFORE this include, otherwise options will not be correctly set on
 248 # first cmake run
 249 include(config-ix)
 250 include(HandleLLVMOptions)
 251
 252 # Verify that we can find a Python interpreter,
 253 include(FindPythonInterp)
 254 if( NOT PYTHONINTERP_FOUND )
 255   message(FATAL_ERROR
 256 "Unable to find Python interpreter, required for builds and testing.
 257
 258 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 259 endif()
 260
 261 ######
 262 # LLVMBuild Integration
 263 #
 264 # We use llvm-build to generate all the data required by the CMake based
 265 # build system in one swoop:
 266 #
 267 #  - We generate a file (a CMake fragment) in the object root which contains
 268 #    all the definitions that are required by CMake.
 269 #
 270 #  - We generate the library table used by llvm-config.
 271 #
 272 #  - We generate the dependencies for the CMake fragment, so that we will
 273 #    automatically reconfigure outselves.
 274
 275 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 276 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 277   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 278 set(LLVMBUILDCMAKEFRAG
 279   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 280 message(STATUS "Constructing LLVMBuild project information")
 281 execute_process(
 282   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 283             --native-target "${LLVM_NATIVE_ARCH}"
 284             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 285             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 286             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 287             ERROR_VARIABLE LLVMBUILDOUTPUT
 288             ERROR_VARIABLE LLVMBUILDERRORS
 289             OUTPUT_STRIP_TRAILING_WHITESPACE
 290             ERROR_STRIP_TRAILING_WHITESPACE
 291   RESULT_VARIABLE LLVMBUILDRESULT)
 292
 293 # On Win32, CMake doesn't properly handle piping the default output/error
 294 # streams into the GUI console. So, we explicitly catch and report them.
 295 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 296   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 297 endif()
 298 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 299   message(FATAL_ERROR
 300     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 301 endif()
 302
 303 # Include the generated CMake fragment. This will define properties from the
 304 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 305 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 306 # files change.
 307 include(${LLVMBUILDCMAKEFRAG})
 308
 309 ######
 310
 311 # Configure all of the various header file fragments LLVM uses which depend on
 312 # configuration variables.
 313 set(LLVM_ENUM_ASM_PRINTERS "")
 314 set(LLVM_ENUM_ASM_PARSERS "")
 315 set(LLVM_ENUM_DISASSEMBLERS "")
 316 foreach(t ${LLVM_TARGETS_TO_BUILD})
 317   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 318   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 319   if( asmp_file )
 320     set(LLVM_ENUM_ASM_PRINTERS
 321       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 322   endif()
 323   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 324     set(LLVM_ENUM_ASM_PARSERS
 325       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 326   endif()
 327   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 328     set(LLVM_ENUM_DISASSEMBLERS
 329       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 330   endif()
 331 endforeach(t)
 332
 333 # Produce the target definition files, which provide a way for clients to easily
 334 # include various classes of targets.
 335 configure_file(
 336   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 337   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 338   )
 339 configure_file(
 340   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 341   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 342   )
 343 configure_file(
 344   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 345   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 346   )
 347 configure_file(
 348   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 349   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 350   )
 351
 352 # Configure the three LLVM configuration header files.
 353 configure_file(
 354   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 355   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 356 configure_file(
 357   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 358   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 359 configure_file(
 360   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 361   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 362
 363 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 364 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 365 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 366
 367 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 368
 369 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 370
 371 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 372    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 373 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 374
 375 include(AddLLVM)
 376 include(TableGen)
 377
 378 if( MINGW )
 379   # People report that -O3 is unreliable on MinGW. The traditional
 380   # build also uses -O2 for that reason:
 381   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 382 endif()
 383
 384 # Put this before tblgen. Else we have a circular dependence.
 385 add_subdirectory(lib/Support)
 386 add_subdirectory(lib/TableGen)
 387
 388 add_subdirectory(utils/TableGen)
 389
 390 add_subdirectory(include/llvm)
 391
 392 add_subdirectory(lib)
 393
 394 add_subdirectory(utils/FileCheck)
 395 add_subdirectory(utils/FileUpdate)
 396 add_subdirectory(utils/count)
 397 add_subdirectory(utils/not)
 398 add_subdirectory(utils/llvm-lit)
 399 add_subdirectory(utils/json-bench)
 400 add_subdirectory(utils/yaml-bench)
 401
 402 add_subdirectory(projects)
 403
 404 if( LLVM_INCLUDE_TOOLS )
 405   add_subdirectory(tools)
 406 endif()
 407
 408 if( LLVM_INCLUDE_RUNTIME )
 409   add_subdirectory(runtime)
 410 endif()
 411
 412 if( LLVM_INCLUDE_EXAMPLES )
 413   add_subdirectory(examples)
 414 endif()
 415
 416 if( LLVM_INCLUDE_TESTS )
 417   add_subdirectory(test)
 418   add_subdirectory(utils/unittest)
 419   add_subdirectory(unittests)
 420   if (MSVC)
 421     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 422     # Windows.
 423     add_subdirectory(utils/KillTheDoctor)
 424   endif()
 425 endif()
 426
 427 add_subdirectory(cmake/modules)
 428
 429 install(DIRECTORY include/
 430   DESTINATION include
 431   FILES_MATCHING
 432   PATTERN "*.def"
 433   PATTERN "*.h"
 434   PATTERN "*.td"
 435   PATTERN "*.inc"
 436   PATTERN "LICENSE.TXT"
 437   PATTERN ".svn" EXCLUDE
 438   )
 439
 440 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 441   DESTINATION include
 442   FILES_MATCHING
 443   PATTERN "*.def"
 444   PATTERN "*.h"
 445   PATTERN "*.gen"
 446   PATTERN "*.inc"
 447   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 448   PATTERN "CMakeFiles" EXCLUDE
 449   PATTERN ".svn" EXCLUDE
 450   )
 451
 452 # TODO: make and install documentation.
 453
 454 set(CPACK_PACKAGE_VENDOR "LLVM")
 455 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 456 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 457 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 458 include(CPack)
 459
 460 # Workaround for MSVS10 to avoid the Dialog Hell
 461 # FIXME: This could be removed with future version of CMake.
 462 if(MSVC_VERSION EQUAL 1600)
 463   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 464   if( EXISTS "${LLVM_SLN_FILENAME}" )
 465     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 466   endif()
 467 endif()