CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  64
  65 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  66
  67 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  68 if ( LLVM_USE_FOLDERS )
  69   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  70 endif()
  71
  72 include(VersionFromVCS)
  73
  74 option(LLVM_APPEND_VC_REV
  75   "Append the version control system revision id to LLVM version" OFF)
  76
  77 if( LLVM_APPEND_VC_REV )
  78   add_version_info_from_vcs(PACKAGE_VERSION)
  79 endif()
  80
  81 set(PACKAGE_NAME LLVM)
  82 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  83 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  84
  85 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  86   "Default URL where bug reports are to be submitted.")
  87
  88 # Configure CPack.
  89 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  90 set(CPACK_PACKAGE_VENDOR "LLVM")
  91 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  92 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  93 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  94 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  95 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  96 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
  97 if(WIN32 AND NOT UNIX)
  98   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  99   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 100   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 101   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 102   set(CPACK_NSIS_MODIFY_PATH "ON")
 103   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 104   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 105     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 106   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 107     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 108   if( CMAKE_CL_64 )
 109     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 110   endif()
 111 endif()
 112 include(CPack)
 113
 114 # Sanity check our source directory to make sure that we are not trying to
 115 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 116 # sure that we don't have any stray generated files lying around in the tree
 117 # (which would end up getting picked up by header search, instead of the correct
 118 # versions).
 119 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 120   message(FATAL_ERROR "In-source builds are not allowed.
 121 CMake would overwrite the makefiles distributed with LLVM.
 122 Please create a directory and run cmake from there, passing the path
 123 to this source directory as the last argument.
 124 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 125 Please delete them.")
 126 endif()
 127 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 128   file(GLOB_RECURSE
 129     tablegenned_files_on_include_dir
 130     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 131   file(GLOB_RECURSE
 132     tablegenned_files_on_lib_dir
 133     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 134   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 135     message(FATAL_ERROR "Apparently there is a previous in-source build,
 136 probably as the result of running `configure' and `make' on
 137 ${CMAKE_CURRENT_SOURCE_DIR}.
 138 This may cause problems. The suspicious files are:
 139 ${tablegenned_files_on_lib_dir}
 140 ${tablegenned_files_on_include_dir}
 141 Please clean the source directory.")
 142   endif()
 143 endif()
 144
 145 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 146
 147 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 148
 149 # They are used as destination of target generators.
 150 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 151 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 152 if(WIN32 OR CYGWIN)
 153   # DLL platform -- put DLLs into bin.
 154   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 155 else()
 156   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 157 endif()
 158
 159 # Each of them corresponds to llvm-config's.
 160 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 161 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 162 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 163 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 164 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 165
 166 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 167 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 168
 169 set(LLVM_ALL_TARGETS
 170   AArch64
 171   ARM
 172   CppBackend
 173   Hexagon
 174   Mips
 175   MSP430
 176   NVPTX
 177   PowerPC
 178   R600
 179   Sparc
 180   SystemZ
 181   X86
 182   XCore
 183   )
 184
 185 # List of targets with JIT support:
 186 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 187
 188 set(LLVM_TARGETS_TO_BUILD "all"
 189     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 190
 191 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 192   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 193
 194 option(BUILD_SHARED_LIBS
 195   "Build all libraries as shared libraries instead of static" OFF)
 196
 197 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 198 if(LLVM_ENABLE_TIMESTAMPS)
 199   set(ENABLE_TIMESTAMPS 1)
 200 endif()
 201
 202 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 203 if(LLVM_ENABLE_BACKTRACES)
 204   set(ENABLE_BACKTRACES 1)
 205 endif()
 206
 207 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 208 if(LLVM_ENABLE_CRASH_OVERRIDES)
 209   set(ENABLE_CRASH_OVERRIDES 1)
 210 endif()
 211
 212 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 213 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 214 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 215
 216 set(LLVM_TARGET_ARCH "host"
 217   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 218
 219 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 220
 221 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 222
 223 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 224
 225 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 226   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 227 endif()
 228
 229 set(LLVM_TARGETS_TO_BUILD
 230    ${LLVM_TARGETS_TO_BUILD}
 231    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 232 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 233
 234 include(AddLLVMDefinitions)
 235
 236 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 237 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 238 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 239 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 240 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 241 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 242 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 243 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 244
 245 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 246   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 247 else()
 248   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 249 endif()
 250
 251 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 252   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 253
 254 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 255        "Set to ON to force using an old, unsupported host toolchain." OFF)
 256
 257 option(LLVM_USE_INTEL_JITEVENTS
 258   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 259   OFF)
 260
 261 if( LLVM_USE_INTEL_JITEVENTS )
 262   # Verify we are on a supported platform
 263   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 264     message(FATAL_ERROR
 265       "Intel JIT API support is available on Linux and Windows only.")
 266   endif()
 267 endif( LLVM_USE_INTEL_JITEVENTS )
 268
 269 option(LLVM_USE_OPROFILE
 270   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 271
 272 # If enabled, verify we are on a platform that supports oprofile.
 273 if( LLVM_USE_OPROFILE )
 274   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 275     message(FATAL_ERROR "OProfile support is available on Linux only.")
 276   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 277 endif( LLVM_USE_OPROFILE )
 278
 279 set(LLVM_USE_SANITIZER "" CACHE STRING
 280   "Define the sanitizer used to build binaries and tests.")
 281
 282 option(LLVM_USE_SPLIT_DWARF
 283   "Use -gsplit-dwarf when compiling llvm." OFF)
 284
 285 option(WITH_POLLY "Build LLVM with Polly" ON)
 286 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 287
 288 # Define an option controlling whether we should build for 32-bit on 64-bit
 289 # platforms, where supported.
 290 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 291   # TODO: support other platforms and toolchains.
 292   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 293 endif()
 294
 295 # Define the default arguments to use with 'lit', and an option for the user to
 296 # override.
 297 set(LIT_ARGS_DEFAULT "-sv")
 298 if (MSVC OR XCODE)
 299   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 300 endif()
 301 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 302
 303 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 304 if( WIN32 AND NOT CYGWIN )
 305   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 306 endif()
 307
 308 # Define options to control the inclusion and default build behavior for
 309 # components which may not strictly be necessary (tools, examples, and tests).
 310 #
 311 # This is primarily to support building smaller or faster project files.
 312 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 313 option(LLVM_BUILD_TOOLS
 314   "Build the LLVM tools. If OFF, just generate build targets." ON)
 315
 316 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 317
 318 option(LLVM_BUILD_RUNTIME
 319   "Build the LLVM runtime libraries." ON)
 320 option(LLVM_BUILD_EXAMPLES
 321   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 322 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 323
 324 option(LLVM_BUILD_TESTS
 325   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 326 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 327
 328 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 329 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 330 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 331 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 332
 333 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 334   "Build compiler-rt as an external project." OFF)
 335
 336 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 337 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" OFF)
 338 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 339 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 340   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 341 endif()
 342
 343 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 344 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 345   set(LLVM_USE_HOST_TOOLS ON)
 346 endif()
 347
 348 # All options referred to from HandleLLVMOptions have to be specified
 349 # BEFORE this include, otherwise options will not be correctly set on
 350 # first cmake run
 351 include(config-ix)
 352
 353 # By default, we target the host, but this can be overridden at CMake
 354 # invocation time.
 355 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 356   "Default target for which LLVM will generate code." )
 357 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 358
 359 include(HandleLLVMOptions)
 360
 361 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 362 # FIXME: We should support systems with only Python 3, but that requires work
 363 # on LLDB.
 364 set(Python_ADDITIONAL_VERSIONS 2.7)
 365 include(FindPythonInterp)
 366 if( NOT PYTHONINTERP_FOUND )
 367   message(FATAL_ERROR
 368 "Unable to find Python interpreter, required for builds and testing.
 369
 370 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 371 endif()
 372
 373 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 374   message(FATAL_ERROR "Python 2.7 or newer is required")
 375 endif()
 376
 377 ######
 378 # LLVMBuild Integration
 379 #
 380 # We use llvm-build to generate all the data required by the CMake based
 381 # build system in one swoop:
 382 #
 383 #  - We generate a file (a CMake fragment) in the object root which contains
 384 #    all the definitions that are required by CMake.
 385 #
 386 #  - We generate the library table used by llvm-config.
 387 #
 388 #  - We generate the dependencies for the CMake fragment, so that we will
 389 #    automatically reconfigure outselves.
 390
 391 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 392 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 393   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 394 set(LLVMBUILDCMAKEFRAG
 395   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 396
 397 # Create the list of optional components that are enabled
 398 if (LLVM_USE_INTEL_JITEVENTS)
 399   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 400 endif (LLVM_USE_INTEL_JITEVENTS)
 401 if (LLVM_USE_OPROFILE)
 402   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 403 endif (LLVM_USE_OPROFILE)
 404
 405 message(STATUS "Constructing LLVMBuild project information")
 406 execute_process(
 407   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 408             --native-target "${LLVM_NATIVE_ARCH}"
 409             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 410             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 411             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 412             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 413             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 414             ERROR_VARIABLE LLVMBUILDERRORS
 415             OUTPUT_STRIP_TRAILING_WHITESPACE
 416             ERROR_STRIP_TRAILING_WHITESPACE
 417   RESULT_VARIABLE LLVMBUILDRESULT)
 418
 419 # On Win32, CMake doesn't properly handle piping the default output/error
 420 # streams into the GUI console. So, we explicitly catch and report them.
 421 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 422   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 423 endif()
 424 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 425   message(FATAL_ERROR
 426     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 427 endif()
 428
 429 # Include the generated CMake fragment. This will define properties from the
 430 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 431 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 432 # files change.
 433 include(${LLVMBUILDCMAKEFRAG})
 434
 435 ######
 436
 437 # Configure all of the various header file fragments LLVM uses which depend on
 438 # configuration variables.
 439 set(LLVM_ENUM_TARGETS "")
 440 set(LLVM_ENUM_ASM_PRINTERS "")
 441 set(LLVM_ENUM_ASM_PARSERS "")
 442 set(LLVM_ENUM_DISASSEMBLERS "")
 443 foreach(t ${LLVM_TARGETS_TO_BUILD})
 444   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 445
 446   list(FIND LLVM_ALL_TARGETS ${t} idx)
 447   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 448   if( idx LESS 0 AND idy LESS 0 )
 449     message(FATAL_ERROR "The target `${t}' does not exist.
 450     It should be one of\n${LLVM_ALL_TARGETS}")
 451   else()
 452     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 453   endif()
 454
 455   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 456   if( asmp_file )
 457     set(LLVM_ENUM_ASM_PRINTERS
 458       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 459   endif()
 460   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 461     set(LLVM_ENUM_ASM_PARSERS
 462       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 463   endif()
 464   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 465     set(LLVM_ENUM_DISASSEMBLERS
 466       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 467   endif()
 468 endforeach(t)
 469
 470 # Produce the target definition files, which provide a way for clients to easily
 471 # include various classes of targets.
 472 configure_file(
 473   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 474   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 475   )
 476 configure_file(
 477   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 478   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 479   )
 480 configure_file(
 481   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 482   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 483   )
 484 configure_file(
 485   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 486   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 487   )
 488
 489 # Configure the three LLVM configuration header files.
 490 configure_file(
 491   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 492   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 493 configure_file(
 494   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 495   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 496 configure_file(
 497   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 498   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 499
 500 # They are not referenced. See set_output_directory().
 501 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 502 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 503 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 504
 505 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 506 if (APPLE)
 507   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 508   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 509 else(UNIX)
 510   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 511     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 512     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 513       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 514       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 515     endif()
 516   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 517 endif()
 518
 519 # Work around a broken bfd ld behavior. When linking a binary with a
 520 # foo.so library, it will try to find any library that foo.so uses and
 521 # check its symbols. This is wasteful (the check was done when foo.so
 522 # was created) and can fail since it is not the dynamic linker and
 523 # doesn't know how to handle search paths correctly.
 524 if (UNIX AND NOT APPLE)
 525   set(CMAKE_EXE_LINKER_FLAGS
 526       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 527 endif()
 528
 529 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 530
 531 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 532
 533 # when crosscompiling import the executable targets from a file
 534 if(LLVM_USE_HOST_TOOLS)
 535   include(CrossCompile)
 536 endif(LLVM_USE_HOST_TOOLS)
 537
 538 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 539   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 540   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 541   include_directories("/usr/local/include")
 542   link_directories("/usr/local/lib")
 543 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 544
 545 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 546    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 547 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 548
 549 # Make sure we don't get -rdynamic in every binary. For those that need it,
 550 # use export_executable_symbols(target).
 551 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 552
 553 include(AddLLVM)
 554 include(TableGen)
 555
 556 if( MINGW )
 557   # People report that -O3 is unreliable on MinGW. The traditional
 558   # build also uses -O2 for that reason:
 559   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 560 endif()
 561
 562 # Put this before tblgen. Else we have a circular dependence.
 563 add_subdirectory(lib/Support)
 564 add_subdirectory(lib/TableGen)
 565
 566 add_subdirectory(utils/TableGen)
 567
 568 add_subdirectory(include/llvm)
 569
 570 add_subdirectory(lib)
 571
 572 if( LLVM_INCLUDE_UTILS )
 573   add_subdirectory(utils/FileCheck)
 574   add_subdirectory(utils/PerfectShuffle)
 575   add_subdirectory(utils/count)
 576   add_subdirectory(utils/not)
 577   add_subdirectory(utils/llvm-lit)
 578   add_subdirectory(utils/yaml-bench)
 579 else()
 580   if ( LLVM_INCLUDE_TESTS )
 581     message(FATAL_ERROR "Including tests when not building utils will not work.
 582     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 583   endif()
 584 endif()
 585
 586 if(LLVM_INCLUDE_TESTS)
 587   add_subdirectory(utils/unittest)
 588 endif()
 589
 590 foreach( binding ${LLVM_BINDINGS_LIST} )
 591   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 592     add_subdirectory(bindings/${binding})
 593   endif()
 594 endforeach()
 595
 596 add_subdirectory(projects)
 597
 598 if(WITH_POLLY)
 599   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 600     set(WITH_POLLY OFF)
 601   endif()
 602 endif(WITH_POLLY)
 603
 604 if( LLVM_INCLUDE_TOOLS )
 605   add_subdirectory(tools)
 606 endif()
 607
 608 if( LLVM_INCLUDE_EXAMPLES )
 609   add_subdirectory(examples)
 610 endif()
 611
 612 if( LLVM_INCLUDE_TESTS )
 613   add_subdirectory(test)
 614   add_subdirectory(unittests)
 615   if (MSVC)
 616     # This utility is used to prevent crashing tests from calling Dr. Watson on
 617     # Windows.
 618     add_subdirectory(utils/KillTheDoctor)
 619   endif()
 620
 621   # Add a global check rule now that all subdirectories have been traversed
 622   # and we know the total set of lit testsuites.
 623   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 624   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 625   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 626   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 627   add_lit_target(check-all
 628     "Running all regression tests"
 629     ${LLVM_LIT_TESTSUITES}
 630     PARAMS ${LLVM_LIT_PARAMS}
 631     DEPENDS ${LLVM_LIT_DEPENDS}
 632     ARGS ${LLVM_LIT_EXTRA_ARGS}
 633     )
 634 endif()
 635
 636 if (LLVM_INCLUDE_DOCS)
 637   add_subdirectory(docs)
 638 endif()
 639
 640 add_subdirectory(cmake/modules)
 641
 642 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 643   install(DIRECTORY include/llvm include/llvm-c
 644     DESTINATION include
 645     COMPONENT llvm-headers
 646     FILES_MATCHING
 647     PATTERN "*.def"
 648     PATTERN "*.h"
 649     PATTERN "*.td"
 650     PATTERN "*.inc"
 651     PATTERN "LICENSE.TXT"
 652     PATTERN ".svn" EXCLUDE
 653     )
 654
 655   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 656     DESTINATION include
 657     COMPONENT llvm-headers
 658     FILES_MATCHING
 659     PATTERN "*.def"
 660     PATTERN "*.h"
 661     PATTERN "*.gen"
 662     PATTERN "*.inc"
 663     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 664     PATTERN "CMakeFiles" EXCLUDE
 665     PATTERN "config.h" EXCLUDE
 666     PATTERN ".svn" EXCLUDE
 667     )
 668
 669   if (NOT CMAKE_CONFIGURATION_TYPES)
 670     add_custom_target(installhdrs
 671                       DEPENDS ${name}
 672                       COMMAND "${CMAKE_COMMAND}"
 673                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 674                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 675   endif()
 676 endif()