CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.0")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME llvm)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  29
  30 # Sanity check our source directory to make sure that we are not trying to
  31 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  32 # sure that we don't have any stray generated files lying around in the tree
  33 # (which would end up getting picked up by header search, instead of the correct
  34 # versions).
  35 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  36   message(FATAL_ERROR "In-source builds are not allowed.
  37 CMake would overwrite the makefiles distributed with LLVM.
  38 Please create a directory and run cmake from there, passing the path
  39 to this source directory as the last argument.
  40 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  41 Please delete them.")
  42 endif()
  43 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  44   file(GLOB_RECURSE
  45     tablegenned_files_on_include_dir
  46     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_lib_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  50   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  51     message(FATAL_ERROR "Apparently there is a previous in-source build,
  52 probably as the result of running `configure' and `make' on
  53 ${CMAKE_CURRENT_SOURCE_DIR}.
  54 This may cause problems. The suspicious files are:
  55 ${tablegenned_files_on_lib_dir}
  56 ${tablegenned_files_on_include_dir}
  57 Please clean the source directory.")
  58   endif()
  59 endif()
  60
  61 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  62
  63 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  64 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  65 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  66 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  67 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  68 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  69
  70 set(LLVM_ALL_TARGETS
  71   ARM
  72   CBackend
  73   CellSPU
  74   CppBackend
  75   Mips
  76   MBlaze
  77   MSP430
  78   PowerPC
  79   PTX
  80   Sparc
  81   X86
  82   XCore
  83   )
  84
  85 # List of targets with JIT support:
  86 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  87
  88 if( MSVC )
  89   set(LLVM_TARGETS_TO_BUILD X86
  90     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  91 else( MSVC )
  92   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  93     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  94 endif( MSVC )
  95
  96 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  97 if(LLVM_ENABLE_CBE_PRINTF_A)
  98   set(ENABLE_CBE_PRINTF_A 1)
  99 endif()
 100
 101 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 102 if(LLVM_ENABLE_TIMESTAMPS)
 103   set(ENABLE_TIMESTAMPS 1)
 104 endif()
 105
 106 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 107 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 108 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 109
 110 set(LLVM_TARGET_ARCH "host"
 111   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 112
 113 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 114
 115 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 116   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 117 endif()
 118
 119 set(LLVM_ENUM_TARGETS "")
 120 foreach(c ${LLVM_TARGETS_TO_BUILD})
 121   list(FIND LLVM_ALL_TARGETS ${c} idx)
 122   if( idx LESS 0 )
 123     message(FATAL_ERROR "The target `${c}' does not exist.
 124     It should be one of\n${LLVM_ALL_TARGETS}")
 125   else()
 126     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 127   endif()
 128 endforeach(c)
 129
 130 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 131
 132 include(AddLLVMDefinitions)
 133
 134 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 135
 136 # MSVC has a gazillion warnings with this.
 137 if( MSVC )
 138   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 139 else( MSVC )
 140   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 141 endif()
 142
 143 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 144 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 145
 146 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 147   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 148 else()
 149   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 150 endif()
 151
 152 # Define an option controlling whether we should build for 32-bit on 64-bit
 153 # platforms, where supported.
 154 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 155   # TODO: support other platforms and toolchains.
 156   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 157 endif()
 158
 159 # Define the default arguments to use with 'lit', and an option for the user to
 160 # override.
 161 set(LIT_ARGS_DEFAULT "-sv")
 162 if (MSVC OR XCODE)
 163   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 164 endif()
 165 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 166
 167 # On Win32/Cygwin, provide an option to specify the path to the GnuWin32 tools.
 168 if( WIN32 AND CYGWIN )
 169   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 170 endif()
 171
 172 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 173 # to use.
 174 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 175   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 176   # 2005 supports it but it is experimental.
 177   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 178     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 179 endif()
 180
 181 # Define options to control the inclusion and default build behavior for
 182 # components which may not strictly be necessary (tools, runtime, examples, and
 183 # tests).
 184 #
 185 # This is primarily to support building smaller or faster project files.
 186 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 187 option(LLVM_BUILD_TOOLS
 188   "Build the LLVM tools. If OFF, just generate build targets." ON)
 189
 190 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 191 option(LLVM_BUILD_RUNTIME
 192   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 193
 194 option(LLVM_BUILD_EXAMPLES
 195   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 196 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 197
 198 option(LLVM_BUILD_TESTS
 199   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 200 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 201
 202 # All options referred to from HandleLLVMOptions have to be specified
 203 # BEFORE this include, otherwise options will not be correctly set on
 204 # first cmake run
 205 include(config-ix)
 206 include(HandleLLVMOptions)
 207
 208 # Verify that we can find a Python interpreter,
 209 include(FindPythonInterp)
 210 if( NOT PYTHONINTERP_FOUND )
 211   message(FATAL_ERROR
 212 "Unable to find Python interpreter, required for builds and testing.
 213
 214 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 215 endif()
 216
 217 # Configure all of the various header file fragments LLVM uses which depend on
 218 # configuration variables.
 219 set(LLVM_ENUM_ASM_PRINTERS "")
 220 set(LLVM_ENUM_ASM_PARSERS "")
 221 set(LLVM_ENUM_DISASSEMBLERS "")
 222 foreach(t ${LLVM_TARGETS_TO_BUILD})
 223   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 224   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 225   if( asmp_file )
 226     set(LLVM_ENUM_ASM_PRINTERS
 227       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 228   endif()
 229   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 230     set(LLVM_ENUM_ASM_PARSERS
 231       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 232   endif()
 233   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 234     set(LLVM_ENUM_DISASSEMBLERS
 235       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 236   endif()
 237 endforeach(t)
 238
 239 # Produce the target definition files, which provide a way for clients to easily
 240 # include various classes of targets.
 241 configure_file(
 242   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 243   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 244   )
 245 configure_file(
 246   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 247   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 248   )
 249 configure_file(
 250   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 251   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 252   )
 253 configure_file(
 254   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 255   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 256   )
 257
 258 # Configure the three LLVM configuration header files.
 259 configure_file(
 260   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 261   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 262 configure_file(
 263   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 264   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 265 configure_file(
 266   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 267   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 268
 269 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 270 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 271 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 272
 273 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 274
 275 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 276
 277 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 278    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 279 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 280
 281 include(AddLLVM)
 282 include(TableGen)
 283
 284 if( MINGW )
 285   # People report that -O3 is unreliable on MinGW. The traditional
 286   # build also uses -O2 for that reason:
 287   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 288 endif()
 289
 290 # Put this before tblgen. Else we have a circular dependence.
 291 add_subdirectory(lib/Support)
 292 add_subdirectory(lib/TableGen)
 293
 294 add_subdirectory(utils/TableGen)
 295
 296 add_subdirectory(include/llvm)
 297
 298 add_subdirectory(lib)
 299
 300 add_subdirectory(utils/FileCheck)
 301 add_subdirectory(utils/FileUpdate)
 302 add_subdirectory(utils/count)
 303 add_subdirectory(utils/not)
 304 add_subdirectory(utils/llvm-lit)
 305
 306 add_subdirectory(projects)
 307
 308 if( LLVM_INCLUDE_TOOLS )
 309   add_subdirectory(tools)
 310 endif()
 311
 312 if( LLVM_INCLUDE_RUNTIME )
 313   add_subdirectory(runtime)
 314 endif()
 315
 316 if( LLVM_INCLUDE_EXAMPLES )
 317   add_subdirectory(examples)
 318 endif()
 319
 320 if( LLVM_INCLUDE_TESTS )
 321   add_subdirectory(test)
 322   add_subdirectory(utils/unittest)
 323   add_subdirectory(unittests)
 324   if (MSVC)
 325     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 326     # Windows.
 327     add_subdirectory(utils/KillTheDoctor)
 328   endif()
 329 endif()
 330
 331 add_subdirectory(cmake/modules)
 332
 333 install(DIRECTORY include/
 334   DESTINATION include
 335   FILES_MATCHING
 336   PATTERN "*.def"
 337   PATTERN "*.h"
 338   PATTERN "*.td"
 339   PATTERN "*.inc"
 340   PATTERN "LICENSE.TXT"
 341   PATTERN ".svn" EXCLUDE
 342   )
 343
 344 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 345   DESTINATION include
 346   FILES_MATCHING
 347   PATTERN "*.def"
 348   PATTERN "*.h"
 349   PATTERN "*.gen"
 350   PATTERN "*.inc"
 351   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 352   PATTERN "CMakeFiles" EXCLUDE
 353   PATTERN ".svn" EXCLUDE
 354   )
 355
 356 # TODO: make and install documentation.
 357
 358 set(CPACK_PACKAGE_VENDOR "LLVM")
 359 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 360 set(CPACK_PACKAGE_VERSION_MINOR 9)
 361 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 362 include(CPack)
 363
 364 # Workaround for MSVS10 to avoid the Dialog Hell
 365 # FIXME: This could be removed with future version of CMake.
 366 if(MSVC_VERSION EQUAL 1600)
 367   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 368   if( EXISTS "${LLVM_SLN_FILENAME}" )
 369     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 370   endif()
 371 endif()