Have getOrCreateSubprogramDIE store the DIE for a subprogram
[oota-llvm.git] / CMakeLists.txt
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
2
3 project(LLVM)
4 cmake_minimum_required(VERSION 2.8)
5
6 # Add path for custom modules
7 set(CMAKE_MODULE_PATH
8   ${CMAKE_MODULE_PATH}
9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
11   )
12
13 set(LLVM_VERSION_MAJOR 3)
14 set(LLVM_VERSION_MINOR 2)
15
16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
17
18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
19 if ( LLVM_USE_FOLDERS )
20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
21 endif()
22
23 include(VersionFromVCS)
24
25 option(LLVM_APPEND_VC_REV
26   "Append the version control system revision id to LLVM version" OFF)
27
28 if( LLVM_APPEND_VC_REV )
29   add_version_info_from_vcs(PACKAGE_VERSION)
30 endif()
31
32 set(PACKAGE_NAME LLVM)
33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
35
36 # Sanity check our source directory to make sure that we are not trying to
37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
38 # sure that we don't have any stray generated files lying around in the tree
39 # (which would end up getting picked up by header search, instead of the correct
40 # versions).
41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
42   message(FATAL_ERROR "In-source builds are not allowed.
43 CMake would overwrite the makefiles distributed with LLVM.
44 Please create a directory and run cmake from there, passing the path
45 to this source directory as the last argument.
46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
47 Please delete them.")
48 endif()
49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
50   file(GLOB_RECURSE
51     tablegenned_files_on_include_dir
52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
53   file(GLOB_RECURSE
54     tablegenned_files_on_lib_dir
55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
57     message(FATAL_ERROR "Apparently there is a previous in-source build,
58 probably as the result of running `configure' and `make' on
59 ${CMAKE_CURRENT_SOURCE_DIR}.
60 This may cause problems. The suspicious files are:
61 ${tablegenned_files_on_lib_dir}
62 ${tablegenned_files_on_include_dir}
63 Please clean the source directory.")
64   endif()
65 endif()
66
67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
68
69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
75
76 set(LLVM_ALL_TARGETS
77   ARM
78   CellSPU
79   CppBackend
80   Hexagon
81   Mips
82   MBlaze
83   MSP430
84   NVPTX
85   PowerPC
86   Sparc
87   X86
88   XCore
89   )
90
91 # List of targets with JIT support:
92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
93
94 if( MSVC )
95   set(LLVM_TARGETS_TO_BUILD X86
96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
97 else( MSVC )
98   set(LLVM_TARGETS_TO_BUILD "all"
99     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
100 endif( MSVC )
101
102 option(BUILD_SHARED_LIBS
103   "Build all libraries as shared libraries instead of static" OFF)
104
105 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
106 if(LLVM_ENABLE_CBE_PRINTF_A)
107   set(ENABLE_CBE_PRINTF_A 1)
108 endif()
109
110 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
111 if(LLVM_ENABLE_TIMESTAMPS)
112   set(ENABLE_TIMESTAMPS 1)
113 endif()
114
115 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
116 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
117 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
118
119 set(LLVM_TARGET_ARCH "host"
120   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
121
122 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
123
124 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
125   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
126 endif()
127
128 set(LLVM_ENUM_TARGETS "")
129 foreach(c ${LLVM_TARGETS_TO_BUILD})
130   list(FIND LLVM_ALL_TARGETS ${c} idx)
131   if( idx LESS 0 )
132     message(FATAL_ERROR "The target `${c}' does not exist.
133     It should be one of\n${LLVM_ALL_TARGETS}")
134   else()
135     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
136   endif()
137 endforeach(c)
138
139 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
140
141 include(AddLLVMDefinitions)
142
143 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
144
145 # MSVC has a gazillion warnings with this.
146 if( MSVC )
147   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
148 else( MSVC )
149   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
150 endif()
151
152 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
153 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
154
155 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
156   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
157 else()
158   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
159 endif()
160
161 option(LLVM_USE_INTEL_JITEVENTS
162   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
163   OFF)
164
165 if( LLVM_USE_INTEL_JITEVENTS )
166   # Verify we are on a supported platform
167   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
168     # Directory where Intel Parallel Amplifier XE 2011 is installed.
169     if ( WIN32 )
170       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
171     else ( WIN32 )
172       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
173     endif ( WIN32 )
174
175     # Set include and library search paths for Intel JIT Events API
176     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
177
178     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
179       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
180     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
181       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
182     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
183   else()
184     message(FATAL_ERROR
185       "Intel JIT API support is available on Linux and Windows only.")
186   endif()
187 endif( LLVM_USE_INTEL_JITEVENTS )
188
189 option(LLVM_USE_OPROFILE
190   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
191
192 # If enabled, ierify we are on a platform that supports oprofile.
193 if( LLVM_USE_OPROFILE )
194   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
195     message(FATAL_ERROR "OProfile support is available on Linux only.") 
196   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
197 endif( LLVM_USE_OPROFILE )
198
199 # Define an option controlling whether we should build for 32-bit on 64-bit
200 # platforms, where supported.
201 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
202   # TODO: support other platforms and toolchains.
203   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
204 endif()
205
206 # Define the default arguments to use with 'lit', and an option for the user to
207 # override.
208 set(LIT_ARGS_DEFAULT "-sv")
209 if (MSVC OR XCODE)
210   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
211 endif()
212 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
213
214 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
215 if( WIN32 AND NOT CYGWIN )
216   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
217 endif()
218
219 # Define options to control the inclusion and default build behavior for
220 # components which may not strictly be necessary (tools, runtime, examples, and
221 # tests).
222 #
223 # This is primarily to support building smaller or faster project files.
224 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
225 option(LLVM_BUILD_TOOLS
226   "Build the LLVM tools. If OFF, just generate build targets." ON)
227
228 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
229 option(LLVM_BUILD_RUNTIME
230   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
231
232 option(LLVM_BUILD_EXAMPLES
233   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
234 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
235
236 option(LLVM_BUILD_TESTS
237   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
238 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
239
240 # All options referred to from HandleLLVMOptions have to be specified
241 # BEFORE this include, otherwise options will not be correctly set on
242 # first cmake run
243 include(config-ix)
244 include(HandleLLVMOptions)
245
246 # Verify that we can find a Python interpreter,
247 include(FindPythonInterp)
248 if( NOT PYTHONINTERP_FOUND )
249   message(FATAL_ERROR
250 "Unable to find Python interpreter, required for builds and testing.
251
252 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
253 endif()
254
255 ######
256 # LLVMBuild Integration
257 #
258 # We use llvm-build to generate all the data required by the CMake based
259 # build system in one swoop:
260 #
261 #  - We generate a file (a CMake fragment) in the object root which contains
262 #    all the definitions that are required by CMake.
263 #
264 #  - We generate the library table used by llvm-config.
265 #
266 #  - We generate the dependencies for the CMake fragment, so that we will
267 #    automatically reconfigure outselves.
268
269 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
270 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
271   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
272 set(LLVMBUILDCMAKEFRAG
273   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
274
275 # Create the list of optional components that are enabled
276 if (LLVM_USE_INTEL_JITEVENTS)
277   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
278 endif (LLVM_USE_INTEL_JITEVENTS)
279 if (LLVM_USE_OPROFILE)
280   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
281 endif (LLVM_USE_OPROFILE)
282
283 message(STATUS "Constructing LLVMBuild project information")
284 execute_process(
285   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
286             --native-target "${LLVM_NATIVE_ARCH}"
287             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
288             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
289             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
290             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
291             ERROR_VARIABLE LLVMBUILDOUTPUT
292             ERROR_VARIABLE LLVMBUILDERRORS
293             OUTPUT_STRIP_TRAILING_WHITESPACE
294             ERROR_STRIP_TRAILING_WHITESPACE
295   RESULT_VARIABLE LLVMBUILDRESULT)
296
297 # On Win32, CMake doesn't properly handle piping the default output/error
298 # streams into the GUI console. So, we explicitly catch and report them.
299 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
300   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
301 endif()
302 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
303   message(FATAL_ERROR
304     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
305 endif()
306
307 # Include the generated CMake fragment. This will define properties from the
308 # LLVMBuild files in a format which is easy to consume from CMake, and will add
309 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
310 # files change.
311 include(${LLVMBUILDCMAKEFRAG})
312
313 ######
314
315 # Configure all of the various header file fragments LLVM uses which depend on
316 # configuration variables.
317 set(LLVM_ENUM_ASM_PRINTERS "")
318 set(LLVM_ENUM_ASM_PARSERS "")
319 set(LLVM_ENUM_DISASSEMBLERS "")
320 foreach(t ${LLVM_TARGETS_TO_BUILD})
321   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
322   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
323   if( asmp_file )
324     set(LLVM_ENUM_ASM_PRINTERS
325       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
326   endif()
327   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
328     set(LLVM_ENUM_ASM_PARSERS
329       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
330   endif()
331   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
332     set(LLVM_ENUM_DISASSEMBLERS
333       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
334   endif()
335 endforeach(t)
336
337 # Produce the target definition files, which provide a way for clients to easily
338 # include various classes of targets.
339 configure_file(
340   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
341   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
342   )
343 configure_file(
344   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
345   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
346   )
347 configure_file(
348   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
349   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
350   )
351 configure_file(
352   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
353   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
354   )
355
356 # Configure the three LLVM configuration header files.
357 configure_file(
358   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
359   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
360 configure_file(
361   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
362   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
363 configure_file(
364   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
365   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
366
367 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
368 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
369 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
370
371 set(CMAKE_INCLUDE_CURRENT_DIR ON)
372
373 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
374
375 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
376    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
377 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
378
379 include(AddLLVM)
380 include(TableGen)
381
382 if( MINGW )
383   # People report that -O3 is unreliable on MinGW. The traditional
384   # build also uses -O2 for that reason:
385   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
386 endif()
387
388 # Put this before tblgen. Else we have a circular dependence.
389 add_subdirectory(lib/Support)
390 add_subdirectory(lib/TableGen)
391
392 add_subdirectory(utils/TableGen)
393
394 add_subdirectory(include/llvm)
395
396 add_subdirectory(lib)
397
398 add_subdirectory(utils/FileCheck)
399 add_subdirectory(utils/FileUpdate)
400 add_subdirectory(utils/count)
401 add_subdirectory(utils/not)
402 add_subdirectory(utils/llvm-lit)
403 add_subdirectory(utils/yaml-bench)
404
405 add_subdirectory(projects)
406
407 if( LLVM_INCLUDE_TOOLS )
408   add_subdirectory(tools)
409 endif()
410
411 if( LLVM_INCLUDE_RUNTIME )
412   add_subdirectory(runtime)
413 endif()
414
415 if( LLVM_INCLUDE_EXAMPLES )
416   add_subdirectory(examples)
417 endif()
418
419 if( LLVM_INCLUDE_TESTS )
420   add_subdirectory(test)
421   add_subdirectory(utils/unittest)
422   add_subdirectory(unittests)
423   if (MSVC)
424     # This utility is used to prevent chrashing tests from calling Dr. Watson on
425     # Windows.
426     add_subdirectory(utils/KillTheDoctor)
427   endif()
428 endif()
429
430 add_subdirectory(cmake/modules)
431
432 install(DIRECTORY include/
433   DESTINATION include
434   FILES_MATCHING
435   PATTERN "*.def"
436   PATTERN "*.h"
437   PATTERN "*.td"
438   PATTERN "*.inc"
439   PATTERN "LICENSE.TXT"
440   PATTERN ".svn" EXCLUDE
441   )
442
443 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
444   DESTINATION include
445   FILES_MATCHING
446   PATTERN "*.def"
447   PATTERN "*.h"
448   PATTERN "*.gen"
449   PATTERN "*.inc"
450   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
451   PATTERN "CMakeFiles" EXCLUDE
452   PATTERN ".svn" EXCLUDE
453   )
454
455 # TODO: make and install documentation.
456
457 set(CPACK_PACKAGE_VENDOR "LLVM")
458 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
459 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
460 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
461 include(CPack)
462
463 # Workaround for MSVS10 to avoid the Dialog Hell
464 # FIXME: This could be removed with future version of CMake.
465 if(MSVC_VERSION EQUAL 1600)
466   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
467   if( EXISTS "${LLVM_SLN_FILENAME}" )
468     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
469   endif()
470 endif()