CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  20   set(cmake_3_2_USES_TERMINAL)
  21 else()
  22   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  23 endif()
  24
  25 project(LLVM)
  26
  27 # The following only works with the Ninja generator in CMake >= 3.0.
  28 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  29   "Define the maximum number of concurrent compilation jobs.")
  30 if(LLVM_PARALLEL_COMPILE_JOBS)
  31   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33 endif()
  34
  35 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  36   "Define the maximum number of concurrent link jobs.")
  37 if(LLVM_PARALLEL_LINK_JOBS)
  38   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  39   set(CMAKE_JOB_POOL_LINK link_job_pool)
  40 endif()
  41
  42 # Add path for custom modules
  43 set(CMAKE_MODULE_PATH
  44   ${CMAKE_MODULE_PATH}
  45   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  46   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  47   )
  48
  49 set(LLVM_VERSION_MAJOR 3)
  50 set(LLVM_VERSION_MINOR 6)
  51 set(LLVM_VERSION_PATCH 0)
  52
  53 if (NOT PACKAGE_VERSION)
  54   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  55 endif()
  56
  57 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  58
  59 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  60 if ( LLVM_USE_FOLDERS )
  61   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  62 endif()
  63
  64 include(VersionFromVCS)
  65
  66 option(LLVM_APPEND_VC_REV
  67   "Append the version control system revision id to LLVM version" OFF)
  68
  69 if( LLVM_APPEND_VC_REV )
  70   add_version_info_from_vcs(PACKAGE_VERSION)
  71 endif()
  72
  73 set(PACKAGE_NAME LLVM)
  74 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  75 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  76
  77 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  78   "Default URL where bug reports are to be submitted.")
  79
  80 # Configure CPack.
  81 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  82 set(CPACK_PACKAGE_VENDOR "LLVM")
  83 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  84 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  85 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  86 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  87 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  88 if(WIN32 AND NOT UNIX)
  89   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  90   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  91   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  92   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  93   set(CPACK_NSIS_MODIFY_PATH "ON")
  94   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  95   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  96     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  97   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  98     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  99 endif()
 100 include(CPack)
 101
 102 # Sanity check our source directory to make sure that we are not trying to
 103 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 104 # sure that we don't have any stray generated files lying around in the tree
 105 # (which would end up getting picked up by header search, instead of the correct
 106 # versions).
 107 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 108   message(FATAL_ERROR "In-source builds are not allowed.
 109 CMake would overwrite the makefiles distributed with LLVM.
 110 Please create a directory and run cmake from there, passing the path
 111 to this source directory as the last argument.
 112 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 113 Please delete them.")
 114 endif()
 115 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 116   file(GLOB_RECURSE
 117     tablegenned_files_on_include_dir
 118     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 119   file(GLOB_RECURSE
 120     tablegenned_files_on_lib_dir
 121     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 122   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 123     message(FATAL_ERROR "Apparently there is a previous in-source build,
 124 probably as the result of running `configure' and `make' on
 125 ${CMAKE_CURRENT_SOURCE_DIR}.
 126 This may cause problems. The suspicious files are:
 127 ${tablegenned_files_on_lib_dir}
 128 ${tablegenned_files_on_include_dir}
 129 Please clean the source directory.")
 130   endif()
 131 endif()
 132
 133 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 134
 135 # They are used as destination of target generators.
 136 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 137 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 138 if(WIN32 OR CYGWIN)
 139   # DLL platform -- put DLLs into bin.
 140   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 141 else()
 142   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 143 endif()
 144
 145 # Each of them corresponds to llvm-config's.
 146 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 147 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 148 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 149 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 150 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 151
 152 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 153 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 154 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 155
 156 set(LLVM_ALL_TARGETS
 157   AArch64
 158   ARM
 159   CppBackend
 160   Hexagon
 161   Mips
 162   MSP430
 163   NVPTX
 164   PowerPC
 165   R600
 166   Sparc
 167   SystemZ
 168   X86
 169   XCore
 170   )
 171
 172 # List of targets with JIT support:
 173 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 174
 175 set(LLVM_TARGETS_TO_BUILD "all"
 176     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 177
 178 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 179   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 180
 181 option(BUILD_SHARED_LIBS
 182   "Build all libraries as shared libraries instead of static" OFF)
 183
 184 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 185 if(LLVM_ENABLE_TIMESTAMPS)
 186   set(ENABLE_TIMESTAMPS 1)
 187 endif()
 188
 189 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 190 if(LLVM_ENABLE_BACKTRACES)
 191   set(ENABLE_BACKTRACES 1)
 192 endif()
 193
 194 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 195 if(LLVM_ENABLE_CRASH_OVERRIDES)
 196   set(ENABLE_CRASH_OVERRIDES 1)
 197 endif()
 198
 199 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 200 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 201 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 202
 203 set(LLVM_TARGET_ARCH "host"
 204   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 205
 206 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 207
 208 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 209
 210 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 211
 212 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 213   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 214 endif()
 215
 216 set(LLVM_TARGETS_TO_BUILD
 217    ${LLVM_TARGETS_TO_BUILD}
 218    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 219 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 220
 221 include(AddLLVMDefinitions)
 222
 223 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 224
 225 # MSVC has a gazillion warnings with this.
 226 if( MSVC )
 227   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 228 else()
 229   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 230 endif()
 231
 232 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 233 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 234 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 235 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 236 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 237
 238 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 239   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 240 else()
 241   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 242 endif()
 243
 244 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 245        "Set to ON to force using an old, unsupported host toolchain." OFF)
 246
 247 option(LLVM_USE_INTEL_JITEVENTS
 248   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 249   OFF)
 250
 251 if( LLVM_USE_INTEL_JITEVENTS )
 252   # Verify we are on a supported platform
 253   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 254     message(FATAL_ERROR
 255       "Intel JIT API support is available on Linux and Windows only.")
 256   endif()
 257 endif( LLVM_USE_INTEL_JITEVENTS )
 258
 259 option(LLVM_USE_OPROFILE
 260   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 261
 262 # If enabled, verify we are on a platform that supports oprofile.
 263 if( LLVM_USE_OPROFILE )
 264   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 265     message(FATAL_ERROR "OProfile support is available on Linux only.")
 266   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 267 endif( LLVM_USE_OPROFILE )
 268
 269 set(LLVM_USE_SANITIZER "" CACHE STRING
 270   "Define the sanitizer used to build binaries and tests.")
 271
 272 option(LLVM_USE_SPLIT_DWARF
 273   "Use -gsplit-dwarf when compiling llvm." OFF)
 274
 275 option(WITH_POLLY "Build LLVM with Polly" ON)
 276 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 277
 278 # Define an option controlling whether we should build for 32-bit on 64-bit
 279 # platforms, where supported.
 280 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 281   # TODO: support other platforms and toolchains.
 282   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 283 endif()
 284
 285 # Define the default arguments to use with 'lit', and an option for the user to
 286 # override.
 287 set(LIT_ARGS_DEFAULT "-sv")
 288 if (MSVC OR XCODE)
 289   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 290 endif()
 291 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 292
 293 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 294 if( WIN32 AND NOT CYGWIN )
 295   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 296 endif()
 297
 298 # Define options to control the inclusion and default build behavior for
 299 # components which may not strictly be necessary (tools, examples, and tests).
 300 #
 301 # This is primarily to support building smaller or faster project files.
 302 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 303 option(LLVM_BUILD_TOOLS
 304   "Build the LLVM tools. If OFF, just generate build targets." ON)
 305
 306 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 307
 308 option(LLVM_BUILD_RUNTIME
 309   "Build the LLVM runtime libraries." ON)
 310 option(LLVM_BUILD_EXAMPLES
 311   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 312 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 313
 314 option(LLVM_BUILD_TESTS
 315   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 316 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 317
 318 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 319 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 320 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 321 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 322
 323 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 324   "Build compiler-rt as an external project." OFF)
 325
 326 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 327 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 328 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 329   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 330 endif()
 331
 332 # All options referred to from HandleLLVMOptions have to be specified
 333 # BEFORE this include, otherwise options will not be correctly set on
 334 # first cmake run
 335 include(config-ix)
 336
 337 # By default, we target the host, but this can be overridden at CMake
 338 # invocation time.
 339 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 340   "Default target for which LLVM will generate code." )
 341 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 342
 343 include(HandleLLVMOptions)
 344
 345 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 346 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 347 include(FindPythonInterp)
 348 if( NOT PYTHONINTERP_FOUND )
 349   message(FATAL_ERROR
 350 "Unable to find Python interpreter, required for builds and testing.
 351
 352 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 353 endif()
 354
 355 ######
 356 # LLVMBuild Integration
 357 #
 358 # We use llvm-build to generate all the data required by the CMake based
 359 # build system in one swoop:
 360 #
 361 #  - We generate a file (a CMake fragment) in the object root which contains
 362 #    all the definitions that are required by CMake.
 363 #
 364 #  - We generate the library table used by llvm-config.
 365 #
 366 #  - We generate the dependencies for the CMake fragment, so that we will
 367 #    automatically reconfigure outselves.
 368
 369 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 370 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 371   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 372 set(LLVMBUILDCMAKEFRAG
 373   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 374
 375 # Create the list of optional components that are enabled
 376 if (LLVM_USE_INTEL_JITEVENTS)
 377   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 378 endif (LLVM_USE_INTEL_JITEVENTS)
 379 if (LLVM_USE_OPROFILE)
 380   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 381 endif (LLVM_USE_OPROFILE)
 382
 383 message(STATUS "Constructing LLVMBuild project information")
 384 execute_process(
 385   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 386             --native-target "${LLVM_NATIVE_ARCH}"
 387             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 388             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 389             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 390             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 391             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 392             ERROR_VARIABLE LLVMBUILDERRORS
 393             OUTPUT_STRIP_TRAILING_WHITESPACE
 394             ERROR_STRIP_TRAILING_WHITESPACE
 395   RESULT_VARIABLE LLVMBUILDRESULT)
 396
 397 # On Win32, CMake doesn't properly handle piping the default output/error
 398 # streams into the GUI console. So, we explicitly catch and report them.
 399 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 400   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 401 endif()
 402 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 403   message(FATAL_ERROR
 404     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 405 endif()
 406
 407 # Include the generated CMake fragment. This will define properties from the
 408 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 409 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 410 # files change.
 411 include(${LLVMBUILDCMAKEFRAG})
 412
 413 ######
 414
 415 # Configure all of the various header file fragments LLVM uses which depend on
 416 # configuration variables.
 417 set(LLVM_ENUM_TARGETS "")
 418 set(LLVM_ENUM_ASM_PRINTERS "")
 419 set(LLVM_ENUM_ASM_PARSERS "")
 420 set(LLVM_ENUM_DISASSEMBLERS "")
 421 foreach(t ${LLVM_TARGETS_TO_BUILD})
 422   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 423
 424   list(FIND LLVM_ALL_TARGETS ${t} idx)
 425   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 426   if( idx LESS 0 AND idy LESS 0 )
 427     message(FATAL_ERROR "The target `${t}' does not exist.
 428     It should be one of\n${LLVM_ALL_TARGETS}")
 429   else()
 430     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 431   endif()
 432
 433   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 434   if( asmp_file )
 435     set(LLVM_ENUM_ASM_PRINTERS
 436       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 437   endif()
 438   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 439     set(LLVM_ENUM_ASM_PARSERS
 440       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 441   endif()
 442   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 443     set(LLVM_ENUM_DISASSEMBLERS
 444       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 445   endif()
 446 endforeach(t)
 447
 448 # Produce the target definition files, which provide a way for clients to easily
 449 # include various classes of targets.
 450 configure_file(
 451   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 452   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 453   )
 454 configure_file(
 455   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 456   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 457   )
 458 configure_file(
 459   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 460   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 461   )
 462 configure_file(
 463   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 464   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 465   )
 466
 467 # Configure the three LLVM configuration header files.
 468 configure_file(
 469   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 470   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 471 configure_file(
 472   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 473   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 474 configure_file(
 475   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 476   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 477
 478 # They are not referenced. See set_output_directory().
 479 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 480 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 481 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 482
 483 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 484 if (APPLE)
 485   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 486   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 487 else(UNIX)
 488   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 489     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 490     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 491       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 492       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 493     endif()
 494   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 495 endif()
 496
 497 # Work around a broken bfd ld behavior. When linking a binary with a
 498 # foo.so library, it will try to find any library that foo.so uses and
 499 # check its symbols. This is wasteful (the check was done when foo.so
 500 # was created) and can fail since it is not the dynamic linker and
 501 # doesn't know how to handle search paths correctly.
 502 if (UNIX AND NOT APPLE)
 503   set(CMAKE_EXE_LINKER_FLAGS
 504       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 505 endif()
 506
 507 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 508
 509 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 510
 511 # when crosscompiling import the executable targets from a file
 512 if(CMAKE_CROSSCOMPILING)
 513   include(CrossCompile)
 514 endif(CMAKE_CROSSCOMPILING)
 515
 516 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 517   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 518   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 519   include_directories("/usr/local/include")
 520   link_directories("/usr/local/lib")
 521 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 522
 523 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 524    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 525 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 526
 527 # Make sure we don't get -rdynamic in every binary. For those that need it,
 528 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 529 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 530
 531 include(AddLLVM)
 532 include(TableGen)
 533
 534 if( MINGW )
 535   # People report that -O3 is unreliable on MinGW. The traditional
 536   # build also uses -O2 for that reason:
 537   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 538 endif()
 539
 540 # Put this before tblgen. Else we have a circular dependence.
 541 add_subdirectory(lib/Support)
 542 add_subdirectory(lib/TableGen)
 543
 544 add_subdirectory(utils/TableGen)
 545
 546 add_subdirectory(include/llvm)
 547
 548 add_subdirectory(lib)
 549
 550 if( LLVM_INCLUDE_UTILS )
 551   add_subdirectory(utils/FileCheck)
 552   add_subdirectory(utils/PerfectShuffle)
 553   add_subdirectory(utils/count)
 554   add_subdirectory(utils/not)
 555   add_subdirectory(utils/llvm-lit)
 556   add_subdirectory(utils/yaml-bench)
 557 else()
 558   if ( LLVM_INCLUDE_TESTS )
 559     message(FATAL_ERROR "Including tests when not building utils will not work.
 560     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 561   endif()
 562 endif()
 563
 564 if(LLVM_INCLUDE_TESTS)
 565   add_subdirectory(utils/unittest)
 566 endif()
 567
 568 foreach( binding ${LLVM_BINDINGS_LIST} )
 569   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 570     add_subdirectory(bindings/${binding})
 571   endif()
 572 endforeach()
 573
 574 add_subdirectory(projects)
 575
 576 if(WITH_POLLY)
 577   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 578     set(WITH_POLLY OFF)
 579   endif()
 580 endif(WITH_POLLY)
 581
 582 if( LLVM_INCLUDE_TOOLS )
 583   add_subdirectory(tools)
 584 endif()
 585
 586 if( LLVM_INCLUDE_EXAMPLES )
 587   add_subdirectory(examples)
 588 endif()
 589
 590 if( LLVM_INCLUDE_TESTS )
 591   add_subdirectory(test)
 592   add_subdirectory(unittests)
 593   if (MSVC)
 594     # This utility is used to prevent crashing tests from calling Dr. Watson on
 595     # Windows.
 596     add_subdirectory(utils/KillTheDoctor)
 597   endif()
 598
 599   # Add a global check rule now that all subdirectories have been traversed
 600   # and we know the total set of lit testsuites.
 601   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 602   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 603   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 604   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 605   add_lit_target(check-all
 606     "Running all regression tests"
 607     ${LLVM_LIT_TESTSUITES}
 608     PARAMS ${LLVM_LIT_PARAMS}
 609     DEPENDS ${LLVM_LIT_DEPENDS}
 610     ARGS ${LLVM_LIT_EXTRA_ARGS}
 611     )
 612 endif()
 613
 614 if (LLVM_INCLUDE_DOCS)
 615   add_subdirectory(docs)
 616 endif()
 617
 618 add_subdirectory(cmake/modules)
 619
 620 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 621   install(DIRECTORY include/llvm include/llvm-c
 622     DESTINATION include
 623     FILES_MATCHING
 624     PATTERN "*.def"
 625     PATTERN "*.h"
 626     PATTERN "*.td"
 627     PATTERN "*.inc"
 628     PATTERN "LICENSE.TXT"
 629     PATTERN ".svn" EXCLUDE
 630     )
 631
 632   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 633     DESTINATION include
 634     FILES_MATCHING
 635     PATTERN "*.def"
 636     PATTERN "*.h"
 637     PATTERN "*.gen"
 638     PATTERN "*.inc"
 639     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 640     PATTERN "CMakeFiles" EXCLUDE
 641     PATTERN "config.h" EXCLUDE
 642     PATTERN ".svn" EXCLUDE
 643     )
 644 endif()