CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM C CXX ASM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  36     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  37   else()
  38     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  39     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  40   endif()
  41 endif()
  42
  43 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  44   "Define the maximum number of concurrent link jobs.")
  45 if(LLVM_PARALLEL_LINK_JOBS)
  46   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  47     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  48   else()
  49     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  50     set(CMAKE_JOB_POOL_LINK link_job_pool)
  51   endif()
  52 endif()
  53
  54 # Add path for custom modules
  55 set(CMAKE_MODULE_PATH
  56   ${CMAKE_MODULE_PATH}
  57   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  58   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  59   )
  60
  61 set(LLVM_VERSION_MAJOR 3)
  62 set(LLVM_VERSION_MINOR 8)
  63 set(LLVM_VERSION_PATCH 0)
  64 set(LLVM_VERSION_SUFFIX svn)
  65
  66 if (NOT PACKAGE_VERSION)
  67   set(PACKAGE_VERSION
  68     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  69 endif()
  70
  71 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  72
  73 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  74
  75 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  76 if ( LLVM_USE_FOLDERS )
  77   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  78 endif()
  79
  80 include(VersionFromVCS)
  81
  82 option(LLVM_APPEND_VC_REV
  83   "Append the version control system revision id to LLVM version" OFF)
  84
  85 if( LLVM_APPEND_VC_REV )
  86   add_version_info_from_vcs(PACKAGE_VERSION)
  87 endif()
  88
  89 set(PACKAGE_NAME LLVM)
  90 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  91 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  92
  93 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  94   "Default URL where bug reports are to be submitted.")
  95
  96 # Configure CPack.
  97 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  98 set(CPACK_PACKAGE_VENDOR "LLVM")
  99 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 100 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 101 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 102 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 103 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 104 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 105 if(WIN32 AND NOT UNIX)
 106   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 107   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 108   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 109   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 110   set(CPACK_NSIS_MODIFY_PATH "ON")
 111   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 112   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 113     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 114   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 115     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 116   if( CMAKE_CL_64 )
 117     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 118   endif()
 119 endif()
 120 include(CPack)
 121
 122 # Sanity check our source directory to make sure that we are not trying to
 123 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 124 # sure that we don't have any stray generated files lying around in the tree
 125 # (which would end up getting picked up by header search, instead of the correct
 126 # versions).
 127 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 128   message(FATAL_ERROR "In-source builds are not allowed.
 129 CMake would overwrite the makefiles distributed with LLVM.
 130 Please create a directory and run cmake from there, passing the path
 131 to this source directory as the last argument.
 132 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 133 Please delete them.")
 134 endif()
 135 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 136   file(GLOB_RECURSE
 137     tablegenned_files_on_include_dir
 138     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 139   file(GLOB_RECURSE
 140     tablegenned_files_on_lib_dir
 141     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 142   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 143     message(FATAL_ERROR "Apparently there is a previous in-source build,
 144 probably as the result of running `configure' and `make' on
 145 ${CMAKE_CURRENT_SOURCE_DIR}.
 146 This may cause problems. The suspicious files are:
 147 ${tablegenned_files_on_lib_dir}
 148 ${tablegenned_files_on_include_dir}
 149 Please clean the source directory.")
 150   endif()
 151 endif()
 152
 153 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 154
 155 if (CMAKE_BUILD_TYPE AND
 156     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 157   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 158 endif()
 159
 160 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 161
 162 # They are used as destination of target generators.
 163 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 164 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 165 if(WIN32 OR CYGWIN)
 166   # DLL platform -- put DLLs into bin.
 167   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 168 else()
 169   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 170 endif()
 171
 172 # Each of them corresponds to llvm-config's.
 173 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 174 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 175 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 176 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 177 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 178
 179 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 180 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 181
 182 set(LLVM_ALL_TARGETS
 183   AArch64
 184   AMDGPU
 185   ARM
 186   BPF
 187   CppBackend
 188   Hexagon
 189   Mips
 190   MSP430
 191   NVPTX
 192   PowerPC
 193   Sparc
 194   SystemZ
 195   X86
 196   XCore
 197   )
 198
 199 # List of targets with JIT support:
 200 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 201
 202 set(LLVM_TARGETS_TO_BUILD "all"
 203     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 204
 205 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 206   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 207
 208 option(BUILD_SHARED_LIBS
 209   "Build all libraries as shared libraries instead of static" OFF)
 210
 211 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 212 if(LLVM_ENABLE_TIMESTAMPS)
 213   set(ENABLE_TIMESTAMPS 1)
 214 endif()
 215
 216 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 217 if(LLVM_ENABLE_BACKTRACES)
 218   set(ENABLE_BACKTRACES 1)
 219 endif()
 220
 221 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 222 if(LLVM_ENABLE_CRASH_OVERRIDES)
 223   set(ENABLE_CRASH_OVERRIDES 1)
 224 endif()
 225
 226 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 227 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 228 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 229
 230 set(LLVM_TARGET_ARCH "host"
 231   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 232
 233 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 234
 235 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 236
 237 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 238
 239 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 240   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 241 endif()
 242
 243 set(LLVM_TARGETS_TO_BUILD
 244    ${LLVM_TARGETS_TO_BUILD}
 245    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 246 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 247
 248 include(AddLLVMDefinitions)
 249
 250 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 251 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 252 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 253 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 254 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 255 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 256 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 257 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 258
 259 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 260   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 261 else()
 262   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 263 endif()
 264
 265 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 266   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 267
 268 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 269        "Set to ON to force using an old, unsupported host toolchain." OFF)
 270
 271 option(LLVM_USE_INTEL_JITEVENTS
 272   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 273   OFF)
 274
 275 if( LLVM_USE_INTEL_JITEVENTS )
 276   # Verify we are on a supported platform
 277   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 278     message(FATAL_ERROR
 279       "Intel JIT API support is available on Linux and Windows only.")
 280   endif()
 281 endif( LLVM_USE_INTEL_JITEVENTS )
 282
 283 option(LLVM_USE_OPROFILE
 284   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 285
 286 # If enabled, verify we are on a platform that supports oprofile.
 287 if( LLVM_USE_OPROFILE )
 288   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 289     message(FATAL_ERROR "OProfile support is available on Linux only.")
 290   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 291 endif( LLVM_USE_OPROFILE )
 292
 293 set(LLVM_USE_SANITIZER "" CACHE STRING
 294   "Define the sanitizer used to build binaries and tests.")
 295
 296 option(LLVM_USE_SPLIT_DWARF
 297   "Use -gsplit-dwarf when compiling llvm." OFF)
 298
 299 option(WITH_POLLY "Build LLVM with Polly" ON)
 300 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 301
 302 # Define an option controlling whether we should build for 32-bit on 64-bit
 303 # platforms, where supported.
 304 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 305   # TODO: support other platforms and toolchains.
 306   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 307 endif()
 308
 309 # Define the default arguments to use with 'lit', and an option for the user to
 310 # override.
 311 set(LIT_ARGS_DEFAULT "-sv")
 312 if (MSVC_IDE OR XCODE)
 313   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 314 endif()
 315 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 316
 317 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 318 if( WIN32 AND NOT CYGWIN )
 319   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 320 endif()
 321
 322 # Define options to control the inclusion and default build behavior for
 323 # components which may not strictly be necessary (tools, examples, and tests).
 324 #
 325 # This is primarily to support building smaller or faster project files.
 326 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 327 option(LLVM_BUILD_TOOLS
 328   "Build the LLVM tools. If OFF, just generate build targets." ON)
 329
 330 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 331
 332 option(LLVM_BUILD_RUNTIME
 333   "Build the LLVM runtime libraries." ON)
 334 option(LLVM_BUILD_EXAMPLES
 335   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 336 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 337
 338 option(LLVM_BUILD_TESTS
 339   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 340 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 341
 342 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 343 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 344 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 345 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 346
 347 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 348   "Build compiler-rt as an external project." OFF)
 349
 350 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 351 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_LINK_LLVM_DYLIB})
 352 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" ${LLVM_LINK_LLVM_DYLIB})
 353 set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT ON)
 354 if (LLVM_LINK_LLVM_DYLIB)
 355   set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT OFF)
 356 endif()
 357 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ${LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT})
 358 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 359   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 360 endif()
 361
 362 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 363 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 364   set(LLVM_USE_HOST_TOOLS ON)
 365 endif()
 366
 367 # All options referred to from HandleLLVMOptions have to be specified
 368 # BEFORE this include, otherwise options will not be correctly set on
 369 # first cmake run
 370 include(config-ix)
 371
 372 # By default, we target the host, but this can be overridden at CMake
 373 # invocation time.
 374 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 375   "Default target for which LLVM will generate code." )
 376 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 377
 378 include(HandleLLVMOptions)
 379
 380 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 381 # FIXME: We should support systems with only Python 3, but that requires work
 382 # on LLDB.
 383 set(Python_ADDITIONAL_VERSIONS 2.7)
 384 include(FindPythonInterp)
 385 if( NOT PYTHONINTERP_FOUND )
 386   message(FATAL_ERROR
 387 "Unable to find Python interpreter, required for builds and testing.
 388
 389 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 390 endif()
 391
 392 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 393   message(FATAL_ERROR "Python 2.7 or newer is required")
 394 endif()
 395
 396 ######
 397 # LLVMBuild Integration
 398 #
 399 # We use llvm-build to generate all the data required by the CMake based
 400 # build system in one swoop:
 401 #
 402 #  - We generate a file (a CMake fragment) in the object root which contains
 403 #    all the definitions that are required by CMake.
 404 #
 405 #  - We generate the library table used by llvm-config.
 406 #
 407 #  - We generate the dependencies for the CMake fragment, so that we will
 408 #    automatically reconfigure outselves.
 409
 410 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 411 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 412   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 413 set(LLVMBUILDCMAKEFRAG
 414   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 415
 416 # Create the list of optional components that are enabled
 417 if (LLVM_USE_INTEL_JITEVENTS)
 418   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 419 endif (LLVM_USE_INTEL_JITEVENTS)
 420 if (LLVM_USE_OPROFILE)
 421   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 422 endif (LLVM_USE_OPROFILE)
 423
 424 message(STATUS "Constructing LLVMBuild project information")
 425 execute_process(
 426   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 427             --native-target "${LLVM_NATIVE_ARCH}"
 428             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 429             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 430             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 431             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 432             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 433             ERROR_VARIABLE LLVMBUILDERRORS
 434             OUTPUT_STRIP_TRAILING_WHITESPACE
 435             ERROR_STRIP_TRAILING_WHITESPACE
 436   RESULT_VARIABLE LLVMBUILDRESULT)
 437
 438 # On Win32, CMake doesn't properly handle piping the default output/error
 439 # streams into the GUI console. So, we explicitly catch and report them.
 440 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 441   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 442 endif()
 443 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 444   message(FATAL_ERROR
 445     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 446 endif()
 447
 448 # Include the generated CMake fragment. This will define properties from the
 449 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 450 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 451 # files change.
 452 include(${LLVMBUILDCMAKEFRAG})
 453
 454 ######
 455
 456 # Configure all of the various header file fragments LLVM uses which depend on
 457 # configuration variables.
 458 set(LLVM_ENUM_TARGETS "")
 459 set(LLVM_ENUM_ASM_PRINTERS "")
 460 set(LLVM_ENUM_ASM_PARSERS "")
 461 set(LLVM_ENUM_DISASSEMBLERS "")
 462 foreach(t ${LLVM_TARGETS_TO_BUILD})
 463   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 464
 465   list(FIND LLVM_ALL_TARGETS ${t} idx)
 466   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 467   if( idx LESS 0 AND idy LESS 0 )
 468     message(FATAL_ERROR "The target `${t}' does not exist.
 469     It should be one of\n${LLVM_ALL_TARGETS}")
 470   else()
 471     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 472   endif()
 473
 474   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 475   if( asmp_file )
 476     set(LLVM_ENUM_ASM_PRINTERS
 477       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 478   endif()
 479   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 480     set(LLVM_ENUM_ASM_PARSERS
 481       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 482   endif()
 483   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 484     set(LLVM_ENUM_DISASSEMBLERS
 485       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 486   endif()
 487 endforeach(t)
 488
 489 # Produce the target definition files, which provide a way for clients to easily
 490 # include various classes of targets.
 491 configure_file(
 492   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 493   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 494   )
 495 configure_file(
 496   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 497   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 498   )
 499 configure_file(
 500   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 501   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 502   )
 503 configure_file(
 504   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 505   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 506   )
 507
 508 # Configure the three LLVM configuration header files.
 509 configure_file(
 510   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 511   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 512 configure_file(
 513   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 514   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 515 configure_file(
 516   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 517   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 518
 519 # They are not referenced. See set_output_directory().
 520 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 521 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 522 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 523
 524 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 525 if (APPLE)
 526   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 527   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 528 else(UNIX)
 529   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 530     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 531     if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 532       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 533       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 534     endif()
 535   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 536 endif()
 537
 538 # Work around a broken bfd ld behavior. When linking a binary with a
 539 # foo.so library, it will try to find any library that foo.so uses and
 540 # check its symbols. This is wasteful (the check was done when foo.so
 541 # was created) and can fail since it is not the dynamic linker and
 542 # doesn't know how to handle search paths correctly.
 543 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 544   set(CMAKE_EXE_LINKER_FLAGS
 545       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 546 endif()
 547
 548 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 549
 550 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 551
 552 # when crosscompiling import the executable targets from a file
 553 if(LLVM_USE_HOST_TOOLS)
 554   include(CrossCompile)
 555 endif(LLVM_USE_HOST_TOOLS)
 556
 557 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 558   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 559   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 560   include_directories("/usr/local/include")
 561   link_directories("/usr/local/lib")
 562 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 563
 564 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 565    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 566 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 567
 568 # Make sure we don't get -rdynamic in every binary. For those that need it,
 569 # use export_executable_symbols(target).
 570 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 571
 572 include(AddLLVM)
 573 include(TableGen)
 574
 575 if( MINGW )
 576   # People report that -O3 is unreliable on MinGW. The traditional
 577   # build also uses -O2 for that reason:
 578   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 579 endif()
 580
 581 # Put this before tblgen. Else we have a circular dependence.
 582 add_subdirectory(lib/Support)
 583 add_subdirectory(lib/TableGen)
 584
 585 add_subdirectory(utils/TableGen)
 586
 587 add_subdirectory(include/llvm)
 588
 589 add_subdirectory(lib)
 590
 591 if( LLVM_INCLUDE_UTILS )
 592   add_subdirectory(utils/FileCheck)
 593   add_subdirectory(utils/PerfectShuffle)
 594   add_subdirectory(utils/count)
 595   add_subdirectory(utils/not)
 596   add_subdirectory(utils/llvm-lit)
 597   add_subdirectory(utils/yaml-bench)
 598 else()
 599   if ( LLVM_INCLUDE_TESTS )
 600     message(FATAL_ERROR "Including tests when not building utils will not work.
 601     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 602   endif()
 603 endif()
 604
 605 if(LLVM_INCLUDE_TESTS)
 606   add_subdirectory(utils/unittest)
 607 endif()
 608
 609 foreach( binding ${LLVM_BINDINGS_LIST} )
 610   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 611     add_subdirectory(bindings/${binding})
 612   endif()
 613 endforeach()
 614
 615 add_subdirectory(projects)
 616
 617 if(WITH_POLLY)
 618   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 619     set(WITH_POLLY OFF)
 620   endif()
 621 endif(WITH_POLLY)
 622
 623 if( LLVM_INCLUDE_TOOLS )
 624   add_subdirectory(tools)
 625 endif()
 626
 627 if( LLVM_INCLUDE_EXAMPLES )
 628   add_subdirectory(examples)
 629 endif()
 630
 631 if( LLVM_INCLUDE_TESTS )
 632   add_subdirectory(test)
 633   add_subdirectory(unittests)
 634   if (MSVC)
 635     # This utility is used to prevent crashing tests from calling Dr. Watson on
 636     # Windows.
 637     add_subdirectory(utils/KillTheDoctor)
 638   endif()
 639
 640   # Add a global check rule now that all subdirectories have been traversed
 641   # and we know the total set of lit testsuites.
 642   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 643   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 644   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 645   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 646   add_lit_target(check-all
 647     "Running all regression tests"
 648     ${LLVM_LIT_TESTSUITES}
 649     PARAMS ${LLVM_LIT_PARAMS}
 650     DEPENDS ${LLVM_LIT_DEPENDS}
 651     ARGS ${LLVM_LIT_EXTRA_ARGS}
 652     )
 653 endif()
 654
 655 if (LLVM_INCLUDE_DOCS)
 656   add_subdirectory(docs)
 657 endif()
 658
 659 add_subdirectory(cmake/modules)
 660
 661 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 662   install(DIRECTORY include/llvm include/llvm-c
 663     DESTINATION include
 664     COMPONENT llvm-headers
 665     FILES_MATCHING
 666     PATTERN "*.def"
 667     PATTERN "*.h"
 668     PATTERN "*.td"
 669     PATTERN "*.inc"
 670     PATTERN "LICENSE.TXT"
 671     PATTERN ".svn" EXCLUDE
 672     )
 673
 674   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 675     DESTINATION include
 676     COMPONENT llvm-headers
 677     FILES_MATCHING
 678     PATTERN "*.def"
 679     PATTERN "*.h"
 680     PATTERN "*.gen"
 681     PATTERN "*.inc"
 682     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 683     PATTERN "CMakeFiles" EXCLUDE
 684     PATTERN "config.h" EXCLUDE
 685     PATTERN ".svn" EXCLUDE
 686     )
 687
 688   if (NOT CMAKE_CONFIGURATION_TYPES)
 689     add_custom_target(installhdrs
 690                       DEPENDS ${name}
 691                       COMMAND "${CMAKE_COMMAND}"
 692                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 693                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 694   endif()
 695 endif()