CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 set(LLVM_ALL_TARGETS
  32   Alpha
  33   ARM
  34   CBackend
  35   CellSPU
  36   CppBackend
  37   IA64
  38   Mips
  39   MSIL
  40   MSP430
  41   PIC16
  42   PowerPC
  43   Sparc
  44   X86
  45   XCore
  46   )
  47
  48 # List of targets whose asmprinters need to be forced to link
  49 # into executables on some platforms (i.e. Windows):
  50 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  51
  52 if( MSVC )
  53   set(LLVM_TARGETS_TO_BUILD X86
  54     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  55 else( MSVC )
  56   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  57     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  58 endif( MSVC )
  59
  60 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  61
  62 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  63   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  64 else()
  65   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  66 endif()
  67
  68 if( LLVM_ENABLE_ASSERTIONS )
  69   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  70   if( NOT MSVC )
  71     add_definitions( -D_DEBUG )
  72   endif()
  73   # On Release builds cmake automatically defines NDEBUG, so we
  74   # explicitly undefine it:
  75   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  76     add_definitions( -UNDEBUG )
  77   endif()
  78 else()
  79   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  80     add_definitions( -DNDEBUG )
  81   endif()
  82 endif()
  83
  84 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  85   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  86 endif()
  87
  88 set(LLVM_ENUM_TARGETS "")
  89 foreach(c ${LLVM_TARGETS_TO_BUILD})
  90   list(FIND LLVM_ALL_TARGETS ${c} idx)
  91   if( idx LESS 0 )
  92     message(FATAL_ERROR "The target `${c}' does not exists.
  93     It should be one of\n${LLVM_ALL_TARGETS}")
  94   else()
  95     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
  96   endif()
  97 endforeach(c)
  98
  99 # Produce llvm/Config/Targets.def
 100 configure_file(
 101   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 102   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 103   )
 104
 105 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 106
 107 # Add path for custom modules
 108 set(CMAKE_MODULE_PATH
 109   ${CMAKE_MODULE_PATH}
 110   "${LLVM_MAIN_SRC_DIR}/cmake"
 111   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 112   )
 113
 114 include(AddLLVMDefinitions)
 115
 116 if(WIN32)
 117   if(CYGWIN)
 118     set(LLVM_ON_WIN32 0)
 119     set(LLVM_ON_UNIX 1)
 120   else(CYGWIN)
 121     set(LLVM_ON_WIN32 1)
 122     set(LLVM_ON_UNIX 0)
 123   endif(CYGWIN)
 124   set(LTDL_SHLIB_EXT ".dll")
 125   set(EXEEXT ".exe")
 126   # Maximum path length is 160 for non-unicode paths
 127   set(MAXPATHLEN 160)
 128 else(WIN32)
 129   if(UNIX)
 130     set(LLVM_ON_WIN32 0)
 131     set(LLVM_ON_UNIX 1)
 132     set(LTDL_SHLIB_EXT ".so")
 133     set(EXEEXT "")
 134     # FIXME: Maximum path length is currently set to 'safe' fixed value
 135     set(MAXPATHLEN 2024)
 136   else(UNIX)
 137     MESSAGE(SEND_ERROR "Unable to determine platform")
 138   endif(UNIX)
 139 endif(WIN32)
 140
 141 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 142   set(HAVE_LLVM_CONFIG 1)
 143 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 144
 145 include(config-ix)
 146
 147 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 148
 149 set(ENABLE_PIC 0)
 150 if( LLVM_ENABLE_PIC )
 151   if( SUPPORTS_FPIC_FLAG )
 152     message(STATUS "Building with -fPIC")
 153     add_llvm_definitions(-fPIC)
 154     set(ENABLE_PIC 1)
 155  else( SUPPORTS_FPIC_FLAG )
 156     message(STATUS "Warning: -fPIC not supported.")
 157   endif()
 158 endif()
 159
 160 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 161 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 162 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 163
 164 # set(CMAKE_VERBOSE_MAKEFILE true)
 165
 166 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 167 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 168
 169 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 170   # TODO: support other platforms and toolchains.
 171   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 172   if( LLVM_BUILD_32_BITS )
 173     message(STATUS "Building 32 bits executables and libraries.")
 174     add_llvm_definitions( -m32 )
 175     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 176     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 177     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 178   endif( LLVM_BUILD_32_BITS )
 179 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 180
 181 if( MSVC )
 182   # List of valid CRTs for MSVC
 183   set(MSVC_CRT
 184     MD
 185     MDd)
 186
 187   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 188   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 189   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 190   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 191   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 192   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 193
 194   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 195     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 196     if (idx LESS 0)
 197       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 198     endif (idx LESS 0)
 199     add_llvm_definitions("/${LLVM_USE_CRT}")
 200     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 201   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 202 endif( MSVC )
 203
 204 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 205
 206 include(AddLLVM)
 207 include(TableGen)
 208
 209 add_subdirectory(lib/Support)
 210 add_subdirectory(lib/System)
 211
 212 # Everything else depends on Support and System:
 213 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 214
 215 set(LLVM_TABLEGEN "tblgen" CACHE
 216   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 217 # Effective tblgen executable to be used:
 218 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 219
 220 add_subdirectory(utils/TableGen)
 221
 222 if( CMAKE_CROSSCOMPILING )
 223   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 224   include( CrossCompileLLVM )
 225 endif( CMAKE_CROSSCOMPILING )
 226
 227 add_subdirectory(include/llvm)
 228
 229 add_subdirectory(lib/VMCore)
 230 add_subdirectory(lib/CodeGen)
 231 add_subdirectory(lib/CodeGen/SelectionDAG)
 232 add_subdirectory(lib/CodeGen/AsmPrinter)
 233 add_subdirectory(lib/Bitcode/Reader)
 234 add_subdirectory(lib/Bitcode/Writer)
 235 add_subdirectory(lib/Transforms/Utils)
 236 add_subdirectory(lib/Transforms/Instrumentation)
 237 add_subdirectory(lib/Transforms/Scalar)
 238 add_subdirectory(lib/Transforms/IPO)
 239 add_subdirectory(lib/Transforms/Hello)
 240 add_subdirectory(lib/Linker)
 241 add_subdirectory(lib/Analysis)
 242 add_subdirectory(lib/Analysis/IPA)
 243 add_subdirectory(lib/MC)
 244
 245  set(LLVM_ENUM_ASM_PRINTERS "")
 246  foreach(t ${LLVM_TARGETS_TO_BUILD})
 247   message(STATUS "Targeting ${t}")
 248   add_subdirectory(lib/Target/${t})
 249   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 250    add_subdirectory(lib/Target/${t}/AsmPrinter)
 251     set(LLVM_ENUM_ASM_PRINTERS
 252         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 253  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 254 endforeach(t)
 255
 256 # Produce llvm/Config/AsmPrinters.def
 257 configure_file(
 258   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 259   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 260   )
 261
 262 add_subdirectory(lib/ExecutionEngine)
 263 add_subdirectory(lib/ExecutionEngine/Interpreter)
 264 add_subdirectory(lib/ExecutionEngine/JIT)
 265 add_subdirectory(lib/Target)
 266 add_subdirectory(lib/AsmParser)
 267 add_subdirectory(lib/Debugger)
 268 add_subdirectory(lib/Archive)
 269
 270 add_subdirectory(projects)
 271 add_subdirectory(tools)
 272
 273 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 274 if (LLVM_EXAMPLES)
 275   add_subdirectory(examples)
 276 endif ()
 277
 278 install(DIRECTORY include
 279   DESTINATION .
 280   PATTERN ".svn" EXCLUDE
 281   PATTERN "*.cmake" EXCLUDE
 282   PATTERN "*.in" EXCLUDE
 283   )
 284
 285 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 286   DESTINATION .
 287   )
 288
 289 # TODO: make and install documentation.