CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  15   set(cmake_3_2_USES_TERMINAL)
  16 else()
  17   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  18 endif()
  19
  20 project(LLVM)
  21
  22 # The following only works with the Ninja generator in CMake >= 3.0.
  23 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  24   "Define the maximum number of concurrent compilation jobs.")
  25 if(LLVM_PARALLEL_COMPILE_JOBS)
  26   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  27   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  28 endif()
  29
  30 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  31   "Define the maximum number of concurrent link jobs.")
  32 if(LLVM_PARALLEL_LINK_JOBS)
  33   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  34   set(CMAKE_JOB_POOL_LINK link_job_pool)
  35 endif()
  36
  37 # Add path for custom modules
  38 set(CMAKE_MODULE_PATH
  39   ${CMAKE_MODULE_PATH}
  40   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  41   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  42   )
  43
  44 set(LLVM_VERSION_MAJOR 3)
  45 set(LLVM_VERSION_MINOR 7)
  46 set(LLVM_VERSION_PATCH 0)
  47 set(LLVM_VERSION_SUFFIX svn)
  48
  49 if (NOT PACKAGE_VERSION)
  50   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  51 endif()
  52
  53 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  54
  55 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  56 if ( LLVM_USE_FOLDERS )
  57   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  58 endif()
  59
  60 include(VersionFromVCS)
  61
  62 option(LLVM_APPEND_VC_REV
  63   "Append the version control system revision id to LLVM version" OFF)
  64
  65 if( LLVM_APPEND_VC_REV )
  66   add_version_info_from_vcs(PACKAGE_VERSION)
  67 endif()
  68
  69 set(PACKAGE_NAME LLVM)
  70 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  71 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  72
  73 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  74   "Default URL where bug reports are to be submitted.")
  75
  76 # Configure CPack.
  77 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  78 set(CPACK_PACKAGE_VENDOR "LLVM")
  79 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  80 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  81 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  82 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  83 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  84 if(WIN32 AND NOT UNIX)
  85   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  86   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  87   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  88   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  89   set(CPACK_NSIS_MODIFY_PATH "ON")
  90   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  91   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  92     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  93   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  94     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  95   if( CMAKE_CL_64 )
  96     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
  97   endif()
  98 endif()
  99 include(CPack)
 100
 101 # Sanity check our source directory to make sure that we are not trying to
 102 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 103 # sure that we don't have any stray generated files lying around in the tree
 104 # (which would end up getting picked up by header search, instead of the correct
 105 # versions).
 106 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 107   message(FATAL_ERROR "In-source builds are not allowed.
 108 CMake would overwrite the makefiles distributed with LLVM.
 109 Please create a directory and run cmake from there, passing the path
 110 to this source directory as the last argument.
 111 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 112 Please delete them.")
 113 endif()
 114 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 115   file(GLOB_RECURSE
 116     tablegenned_files_on_include_dir
 117     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 118   file(GLOB_RECURSE
 119     tablegenned_files_on_lib_dir
 120     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 121   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 122     message(FATAL_ERROR "Apparently there is a previous in-source build,
 123 probably as the result of running `configure' and `make' on
 124 ${CMAKE_CURRENT_SOURCE_DIR}.
 125 This may cause problems. The suspicious files are:
 126 ${tablegenned_files_on_lib_dir}
 127 ${tablegenned_files_on_include_dir}
 128 Please clean the source directory.")
 129   endif()
 130 endif()
 131
 132 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 133
 134 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 135
 136 # They are used as destination of target generators.
 137 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 138 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 139 if(WIN32 OR CYGWIN)
 140   # DLL platform -- put DLLs into bin.
 141   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 142 else()
 143   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 144 endif()
 145
 146 # Each of them corresponds to llvm-config's.
 147 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 148 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 149 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 150 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 151 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 152
 153 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 154 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 155
 156 set(LLVM_ALL_TARGETS
 157   AArch64
 158   ARM
 159   CppBackend
 160   Hexagon
 161   Mips
 162   MSP430
 163   NVPTX
 164   PowerPC
 165   R600
 166   Sparc
 167   SystemZ
 168   X86
 169   XCore
 170   )
 171
 172 # List of targets with JIT support:
 173 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 174
 175 set(LLVM_TARGETS_TO_BUILD "all"
 176     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 177
 178 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 179   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 180
 181 option(BUILD_SHARED_LIBS
 182   "Build all libraries as shared libraries instead of static" OFF)
 183
 184 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 185 if(LLVM_ENABLE_TIMESTAMPS)
 186   set(ENABLE_TIMESTAMPS 1)
 187 endif()
 188
 189 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 190 if(LLVM_ENABLE_BACKTRACES)
 191   set(ENABLE_BACKTRACES 1)
 192 endif()
 193
 194 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 195 if(LLVM_ENABLE_CRASH_OVERRIDES)
 196   set(ENABLE_CRASH_OVERRIDES 1)
 197 endif()
 198
 199 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 200 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 201 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 202
 203 set(LLVM_TARGET_ARCH "host"
 204   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 205
 206 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 207
 208 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 209
 210 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 211
 212 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 213   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 214 endif()
 215
 216 set(LLVM_TARGETS_TO_BUILD
 217    ${LLVM_TARGETS_TO_BUILD}
 218    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 219 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 220
 221 include(AddLLVMDefinitions)
 222
 223 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 224
 225 # MSVC has a gazillion warnings with this.
 226 if( MSVC )
 227   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 228 else()
 229   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 230 endif()
 231
 232 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 233 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 234 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 235 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 236 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 237
 238 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 239   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 240 else()
 241   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 242 endif()
 243
 244 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 245        "Set to ON to force using an old, unsupported host toolchain." OFF)
 246
 247 option(LLVM_USE_INTEL_JITEVENTS
 248   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 249   OFF)
 250
 251 if( LLVM_USE_INTEL_JITEVENTS )
 252   # Verify we are on a supported platform
 253   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 254     message(FATAL_ERROR
 255       "Intel JIT API support is available on Linux and Windows only.")
 256   endif()
 257 endif( LLVM_USE_INTEL_JITEVENTS )
 258
 259 option(LLVM_USE_OPROFILE
 260   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 261
 262 # If enabled, verify we are on a platform that supports oprofile.
 263 if( LLVM_USE_OPROFILE )
 264   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 265     message(FATAL_ERROR "OProfile support is available on Linux only.")
 266   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 267 endif( LLVM_USE_OPROFILE )
 268
 269 set(LLVM_USE_SANITIZER "" CACHE STRING
 270   "Define the sanitizer used to build binaries and tests.")
 271
 272 option(LLVM_USE_SPLIT_DWARF
 273   "Use -gsplit-dwarf when compiling llvm." OFF)
 274
 275 option(WITH_POLLY "Build LLVM with Polly" ON)
 276 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 277
 278 # Define an option controlling whether we should build for 32-bit on 64-bit
 279 # platforms, where supported.
 280 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 281   # TODO: support other platforms and toolchains.
 282   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 283 endif()
 284
 285 # Define the default arguments to use with 'lit', and an option for the user to
 286 # override.
 287 set(LIT_ARGS_DEFAULT "-sv")
 288 if (MSVC OR XCODE)
 289   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 290 endif()
 291 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 292
 293 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 294 if( WIN32 AND NOT CYGWIN )
 295   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 296 endif()
 297
 298 # Define options to control the inclusion and default build behavior for
 299 # components which may not strictly be necessary (tools, examples, and tests).
 300 #
 301 # This is primarily to support building smaller or faster project files.
 302 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 303 option(LLVM_BUILD_TOOLS
 304   "Build the LLVM tools. If OFF, just generate build targets." ON)
 305
 306 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 307
 308 option(LLVM_BUILD_RUNTIME
 309   "Build the LLVM runtime libraries." ON)
 310 option(LLVM_BUILD_EXAMPLES
 311   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 312 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 313
 314 option(LLVM_BUILD_TESTS
 315   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 316 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 317
 318 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 319 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 320 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 321 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 322
 323 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 324   "Build compiler-rt as an external project." OFF)
 325
 326 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 327 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 328 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 329   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 330 endif()
 331
 332 # All options referred to from HandleLLVMOptions have to be specified
 333 # BEFORE this include, otherwise options will not be correctly set on
 334 # first cmake run
 335 include(config-ix)
 336
 337 # By default, we target the host, but this can be overridden at CMake
 338 # invocation time.
 339 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 340   "Default target for which LLVM will generate code." )
 341 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 342
 343 include(HandleLLVMOptions)
 344
 345 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 346 # FIXME: We should support systems with only Python 3, but that requires work
 347 # on LLDB.
 348 set(Python_ADDITIONAL_VERSIONS 2.7)
 349 include(FindPythonInterp)
 350 if( NOT PYTHONINTERP_FOUND )
 351   message(FATAL_ERROR
 352 "Unable to find Python interpreter, required for builds and testing.
 353
 354 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 355 endif()
 356
 357 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 358   message(FATAL_ERROR "Python 2.7 or newer is required")
 359 endif()
 360
 361 ######
 362 # LLVMBuild Integration
 363 #
 364 # We use llvm-build to generate all the data required by the CMake based
 365 # build system in one swoop:
 366 #
 367 #  - We generate a file (a CMake fragment) in the object root which contains
 368 #    all the definitions that are required by CMake.
 369 #
 370 #  - We generate the library table used by llvm-config.
 371 #
 372 #  - We generate the dependencies for the CMake fragment, so that we will
 373 #    automatically reconfigure outselves.
 374
 375 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 376 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 377   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 378 set(LLVMBUILDCMAKEFRAG
 379   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 380
 381 # Create the list of optional components that are enabled
 382 if (LLVM_USE_INTEL_JITEVENTS)
 383   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 384 endif (LLVM_USE_INTEL_JITEVENTS)
 385 if (LLVM_USE_OPROFILE)
 386   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 387 endif (LLVM_USE_OPROFILE)
 388
 389 message(STATUS "Constructing LLVMBuild project information")
 390 execute_process(
 391   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 392             --native-target "${LLVM_NATIVE_ARCH}"
 393             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 394             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 395             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 396             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 397             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 398             ERROR_VARIABLE LLVMBUILDERRORS
 399             OUTPUT_STRIP_TRAILING_WHITESPACE
 400             ERROR_STRIP_TRAILING_WHITESPACE
 401   RESULT_VARIABLE LLVMBUILDRESULT)
 402
 403 # On Win32, CMake doesn't properly handle piping the default output/error
 404 # streams into the GUI console. So, we explicitly catch and report them.
 405 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 406   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 407 endif()
 408 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 409   message(FATAL_ERROR
 410     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 411 endif()
 412
 413 # Include the generated CMake fragment. This will define properties from the
 414 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 415 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 416 # files change.
 417 include(${LLVMBUILDCMAKEFRAG})
 418
 419 ######
 420
 421 # Configure all of the various header file fragments LLVM uses which depend on
 422 # configuration variables.
 423 set(LLVM_ENUM_TARGETS "")
 424 set(LLVM_ENUM_ASM_PRINTERS "")
 425 set(LLVM_ENUM_ASM_PARSERS "")
 426 set(LLVM_ENUM_DISASSEMBLERS "")
 427 foreach(t ${LLVM_TARGETS_TO_BUILD})
 428   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 429
 430   list(FIND LLVM_ALL_TARGETS ${t} idx)
 431   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 432   if( idx LESS 0 AND idy LESS 0 )
 433     message(FATAL_ERROR "The target `${t}' does not exist.
 434     It should be one of\n${LLVM_ALL_TARGETS}")
 435   else()
 436     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 437   endif()
 438
 439   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 440   if( asmp_file )
 441     set(LLVM_ENUM_ASM_PRINTERS
 442       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 443   endif()
 444   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 445     set(LLVM_ENUM_ASM_PARSERS
 446       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 447   endif()
 448   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 449     set(LLVM_ENUM_DISASSEMBLERS
 450       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 451   endif()
 452 endforeach(t)
 453
 454 # Produce the target definition files, which provide a way for clients to easily
 455 # include various classes of targets.
 456 configure_file(
 457   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 458   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 459   )
 460 configure_file(
 461   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 462   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 463   )
 464 configure_file(
 465   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 466   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 467   )
 468 configure_file(
 469   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 470   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 471   )
 472
 473 # Configure the three LLVM configuration header files.
 474 configure_file(
 475   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 476   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 477 configure_file(
 478   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 479   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 480 configure_file(
 481   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 482   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 483
 484 # They are not referenced. See set_output_directory().
 485 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 486 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 487 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 488
 489 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 490 if (APPLE)
 491   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 492   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 493 else(UNIX)
 494   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 495     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 496     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 497       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 498       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 499     endif()
 500   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 501 endif()
 502
 503 # Work around a broken bfd ld behavior. When linking a binary with a
 504 # foo.so library, it will try to find any library that foo.so uses and
 505 # check its symbols. This is wasteful (the check was done when foo.so
 506 # was created) and can fail since it is not the dynamic linker and
 507 # doesn't know how to handle search paths correctly.
 508 if (UNIX AND NOT APPLE)
 509   set(CMAKE_EXE_LINKER_FLAGS
 510       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 511 endif()
 512
 513 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 514
 515 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 516
 517 # when crosscompiling import the executable targets from a file
 518 if(CMAKE_CROSSCOMPILING)
 519   include(CrossCompile)
 520 endif(CMAKE_CROSSCOMPILING)
 521
 522 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 523   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 524   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 525   include_directories("/usr/local/include")
 526   link_directories("/usr/local/lib")
 527 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 528
 529 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 530    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 531 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 532
 533 # Make sure we don't get -rdynamic in every binary. For those that need it,
 534 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 535 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 536
 537 include(AddLLVM)
 538 include(TableGen)
 539
 540 if( MINGW )
 541   # People report that -O3 is unreliable on MinGW. The traditional
 542   # build also uses -O2 for that reason:
 543   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 544 endif()
 545
 546 # Put this before tblgen. Else we have a circular dependence.
 547 add_subdirectory(lib/Support)
 548 add_subdirectory(lib/TableGen)
 549
 550 add_subdirectory(utils/TableGen)
 551
 552 add_subdirectory(include/llvm)
 553
 554 add_subdirectory(lib)
 555
 556 if( LLVM_INCLUDE_UTILS )
 557   add_subdirectory(utils/FileCheck)
 558   add_subdirectory(utils/PerfectShuffle)
 559   add_subdirectory(utils/count)
 560   add_subdirectory(utils/not)
 561   add_subdirectory(utils/llvm-lit)
 562   add_subdirectory(utils/yaml-bench)
 563 else()
 564   if ( LLVM_INCLUDE_TESTS )
 565     message(FATAL_ERROR "Including tests when not building utils will not work.
 566     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 567   endif()
 568 endif()
 569
 570 if(LLVM_INCLUDE_TESTS)
 571   add_subdirectory(utils/unittest)
 572 endif()
 573
 574 foreach( binding ${LLVM_BINDINGS_LIST} )
 575   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 576     add_subdirectory(bindings/${binding})
 577   endif()
 578 endforeach()
 579
 580 add_subdirectory(projects)
 581
 582 if(WITH_POLLY)
 583   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 584     set(WITH_POLLY OFF)
 585   endif()
 586 endif(WITH_POLLY)
 587
 588 if( LLVM_INCLUDE_TOOLS )
 589   add_subdirectory(tools)
 590 endif()
 591
 592 if( LLVM_INCLUDE_EXAMPLES )
 593   add_subdirectory(examples)
 594 endif()
 595
 596 if( LLVM_INCLUDE_TESTS )
 597   add_subdirectory(test)
 598   add_subdirectory(unittests)
 599   if (MSVC)
 600     # This utility is used to prevent crashing tests from calling Dr. Watson on
 601     # Windows.
 602     add_subdirectory(utils/KillTheDoctor)
 603   endif()
 604
 605   # Add a global check rule now that all subdirectories have been traversed
 606   # and we know the total set of lit testsuites.
 607   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 608   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 609   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 610   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 611   add_lit_target(check-all
 612     "Running all regression tests"
 613     ${LLVM_LIT_TESTSUITES}
 614     PARAMS ${LLVM_LIT_PARAMS}
 615     DEPENDS ${LLVM_LIT_DEPENDS}
 616     ARGS ${LLVM_LIT_EXTRA_ARGS}
 617     )
 618 endif()
 619
 620 if (LLVM_INCLUDE_DOCS)
 621   add_subdirectory(docs)
 622 endif()
 623
 624 add_subdirectory(cmake/modules)
 625
 626 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 627   install(DIRECTORY include/llvm include/llvm-c
 628     DESTINATION include
 629     COMPONENT llvm-headers
 630     FILES_MATCHING
 631     PATTERN "*.def"
 632     PATTERN "*.h"
 633     PATTERN "*.td"
 634     PATTERN "*.inc"
 635     PATTERN "LICENSE.TXT"
 636     PATTERN ".svn" EXCLUDE
 637     )
 638
 639   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 640     DESTINATION include
 641     COMPONENT llvm-headers
 642     FILES_MATCHING
 643     PATTERN "*.def"
 644     PATTERN "*.h"
 645     PATTERN "*.gen"
 646     PATTERN "*.inc"
 647     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 648     PATTERN "CMakeFiles" EXCLUDE
 649     PATTERN "config.h" EXCLUDE
 650     PATTERN ".svn" EXCLUDE
 651     )
 652
 653   if (NOT CMAKE_CONFIGURATION_TYPES)
 654     add_custom_target(installhdrs
 655                       DEPENDS ${name}
 656                       COMMAND "${CMAKE_COMMAND}"
 657                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 658                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 659   endif()
 660 endif()