CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  20   set(cmake_3_2_USES_TERMINAL)
  21 else()
  22   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  23 endif()
  24
  25 project(LLVM)
  26
  27 # The following only works with the Ninja generator in CMake >= 3.0.
  28 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  29   "Define the maximum number of concurrent compilation jobs.")
  30 if(LLVM_PARALLEL_COMPILE_JOBS)
  31   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33 endif()
  34
  35 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  36   "Define the maximum number of concurrent link jobs.")
  37 if(LLVM_PARALLEL_LINK_JOBS)
  38   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  39   set(CMAKE_JOB_POOL_LINK link_job_pool)
  40 endif()
  41
  42 # Add path for custom modules
  43 set(CMAKE_MODULE_PATH
  44   ${CMAKE_MODULE_PATH}
  45   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  46   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  47   )
  48
  49 set(LLVM_VERSION_MAJOR 3)
  50 set(LLVM_VERSION_MINOR 7)
  51 set(LLVM_VERSION_PATCH 0)
  52 set(LLVM_VERSION_SUFFIX svn)
  53
  54 if (NOT PACKAGE_VERSION)
  55   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  56 endif()
  57
  58 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  59
  60 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  61 if ( LLVM_USE_FOLDERS )
  62   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  63 endif()
  64
  65 include(VersionFromVCS)
  66
  67 option(LLVM_APPEND_VC_REV
  68   "Append the version control system revision id to LLVM version" OFF)
  69
  70 if( LLVM_APPEND_VC_REV )
  71   add_version_info_from_vcs(PACKAGE_VERSION)
  72 endif()
  73
  74 set(PACKAGE_NAME LLVM)
  75 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  76 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  77
  78 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  79   "Default URL where bug reports are to be submitted.")
  80
  81 # Configure CPack.
  82 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  83 set(CPACK_PACKAGE_VENDOR "LLVM")
  84 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  85 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  86 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  87 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  88 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  89 if(WIN32 AND NOT UNIX)
  90   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  91   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  92   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  93   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  94   set(CPACK_NSIS_MODIFY_PATH "ON")
  95   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  96   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  97     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  98   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  99     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 100   if( CMAKE_CL_64 )
 101     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 102   endif()
 103 endif()
 104 include(CPack)
 105
 106 # Sanity check our source directory to make sure that we are not trying to
 107 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 108 # sure that we don't have any stray generated files lying around in the tree
 109 # (which would end up getting picked up by header search, instead of the correct
 110 # versions).
 111 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 112   message(FATAL_ERROR "In-source builds are not allowed.
 113 CMake would overwrite the makefiles distributed with LLVM.
 114 Please create a directory and run cmake from there, passing the path
 115 to this source directory as the last argument.
 116 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 117 Please delete them.")
 118 endif()
 119 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 120   file(GLOB_RECURSE
 121     tablegenned_files_on_include_dir
 122     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 123   file(GLOB_RECURSE
 124     tablegenned_files_on_lib_dir
 125     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 126   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 127     message(FATAL_ERROR "Apparently there is a previous in-source build,
 128 probably as the result of running `configure' and `make' on
 129 ${CMAKE_CURRENT_SOURCE_DIR}.
 130 This may cause problems. The suspicious files are:
 131 ${tablegenned_files_on_lib_dir}
 132 ${tablegenned_files_on_include_dir}
 133 Please clean the source directory.")
 134   endif()
 135 endif()
 136
 137 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 138
 139 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 140
 141 # They are used as destination of target generators.
 142 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 143 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 144 if(WIN32 OR CYGWIN)
 145   # DLL platform -- put DLLs into bin.
 146   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 147 else()
 148   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 149 endif()
 150
 151 # Each of them corresponds to llvm-config's.
 152 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 153 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 154 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 155 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 156 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 157
 158 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 159 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 160
 161 set(LLVM_ALL_TARGETS
 162   AArch64
 163   ARM
 164   CppBackend
 165   Hexagon
 166   Mips
 167   MSP430
 168   NVPTX
 169   PowerPC
 170   R600
 171   Sparc
 172   SystemZ
 173   X86
 174   XCore
 175   )
 176
 177 # List of targets with JIT support:
 178 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 179
 180 set(LLVM_TARGETS_TO_BUILD "all"
 181     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 182
 183 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 184   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 185
 186 option(BUILD_SHARED_LIBS
 187   "Build all libraries as shared libraries instead of static" OFF)
 188
 189 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 190 if(LLVM_ENABLE_TIMESTAMPS)
 191   set(ENABLE_TIMESTAMPS 1)
 192 endif()
 193
 194 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 195 if(LLVM_ENABLE_BACKTRACES)
 196   set(ENABLE_BACKTRACES 1)
 197 endif()
 198
 199 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 200 if(LLVM_ENABLE_CRASH_OVERRIDES)
 201   set(ENABLE_CRASH_OVERRIDES 1)
 202 endif()
 203
 204 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 205 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 206 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 207
 208 set(LLVM_TARGET_ARCH "host"
 209   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 210
 211 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 212
 213 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 214
 215 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 216
 217 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 218   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 219 endif()
 220
 221 set(LLVM_TARGETS_TO_BUILD
 222    ${LLVM_TARGETS_TO_BUILD}
 223    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 224 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 225
 226 include(AddLLVMDefinitions)
 227
 228 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 229
 230 # MSVC has a gazillion warnings with this.
 231 if( MSVC )
 232   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 233 else()
 234   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 235 endif()
 236
 237 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 238 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 239 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 240 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 241 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 242
 243 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 244   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 245 else()
 246   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 247 endif()
 248
 249 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 250        "Set to ON to force using an old, unsupported host toolchain." OFF)
 251
 252 option(LLVM_USE_INTEL_JITEVENTS
 253   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 254   OFF)
 255
 256 if( LLVM_USE_INTEL_JITEVENTS )
 257   # Verify we are on a supported platform
 258   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 259     message(FATAL_ERROR
 260       "Intel JIT API support is available on Linux and Windows only.")
 261   endif()
 262 endif( LLVM_USE_INTEL_JITEVENTS )
 263
 264 option(LLVM_USE_OPROFILE
 265   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 266
 267 # If enabled, verify we are on a platform that supports oprofile.
 268 if( LLVM_USE_OPROFILE )
 269   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 270     message(FATAL_ERROR "OProfile support is available on Linux only.")
 271   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 272 endif( LLVM_USE_OPROFILE )
 273
 274 set(LLVM_USE_SANITIZER "" CACHE STRING
 275   "Define the sanitizer used to build binaries and tests.")
 276
 277 option(LLVM_USE_SPLIT_DWARF
 278   "Use -gsplit-dwarf when compiling llvm." OFF)
 279
 280 option(WITH_POLLY "Build LLVM with Polly" ON)
 281 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 282
 283 # Define an option controlling whether we should build for 32-bit on 64-bit
 284 # platforms, where supported.
 285 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 286   # TODO: support other platforms and toolchains.
 287   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 288 endif()
 289
 290 # Define the default arguments to use with 'lit', and an option for the user to
 291 # override.
 292 set(LIT_ARGS_DEFAULT "-sv")
 293 if (MSVC OR XCODE)
 294   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 295 endif()
 296 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 297
 298 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 299 if( WIN32 AND NOT CYGWIN )
 300   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 301 endif()
 302
 303 # Define options to control the inclusion and default build behavior for
 304 # components which may not strictly be necessary (tools, examples, and tests).
 305 #
 306 # This is primarily to support building smaller or faster project files.
 307 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 308 option(LLVM_BUILD_TOOLS
 309   "Build the LLVM tools. If OFF, just generate build targets." ON)
 310
 311 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 312
 313 option(LLVM_BUILD_RUNTIME
 314   "Build the LLVM runtime libraries." ON)
 315 option(LLVM_BUILD_EXAMPLES
 316   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 317 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 318
 319 option(LLVM_BUILD_TESTS
 320   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 321 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 322
 323 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 324 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 325 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 326 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 327
 328 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 329   "Build compiler-rt as an external project." OFF)
 330
 331 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 332 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 333 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 334   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 335 endif()
 336
 337 # All options referred to from HandleLLVMOptions have to be specified
 338 # BEFORE this include, otherwise options will not be correctly set on
 339 # first cmake run
 340 include(config-ix)
 341
 342 # By default, we target the host, but this can be overridden at CMake
 343 # invocation time.
 344 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 345   "Default target for which LLVM will generate code." )
 346 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 347
 348 include(HandleLLVMOptions)
 349
 350 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 351 # FIXME: We should support systems with only Python 3, but that requires work
 352 # on LLDB.
 353 set(Python_ADDITIONAL_VERSIONS 2.7)
 354 include(FindPythonInterp)
 355 if( NOT PYTHONINTERP_FOUND )
 356   message(FATAL_ERROR
 357 "Unable to find Python interpreter, required for builds and testing.
 358
 359 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 360 endif()
 361
 362 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 363   message(FATAL_ERROR "Python 2.7 or newer is required")
 364 endif()
 365
 366 ######
 367 # LLVMBuild Integration
 368 #
 369 # We use llvm-build to generate all the data required by the CMake based
 370 # build system in one swoop:
 371 #
 372 #  - We generate a file (a CMake fragment) in the object root which contains
 373 #    all the definitions that are required by CMake.
 374 #
 375 #  - We generate the library table used by llvm-config.
 376 #
 377 #  - We generate the dependencies for the CMake fragment, so that we will
 378 #    automatically reconfigure outselves.
 379
 380 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 381 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 382   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 383 set(LLVMBUILDCMAKEFRAG
 384   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 385
 386 # Create the list of optional components that are enabled
 387 if (LLVM_USE_INTEL_JITEVENTS)
 388   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 389 endif (LLVM_USE_INTEL_JITEVENTS)
 390 if (LLVM_USE_OPROFILE)
 391   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 392 endif (LLVM_USE_OPROFILE)
 393
 394 message(STATUS "Constructing LLVMBuild project information")
 395 execute_process(
 396   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 397             --native-target "${LLVM_NATIVE_ARCH}"
 398             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 399             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 400             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 401             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 402             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 403             ERROR_VARIABLE LLVMBUILDERRORS
 404             OUTPUT_STRIP_TRAILING_WHITESPACE
 405             ERROR_STRIP_TRAILING_WHITESPACE
 406   RESULT_VARIABLE LLVMBUILDRESULT)
 407
 408 # On Win32, CMake doesn't properly handle piping the default output/error
 409 # streams into the GUI console. So, we explicitly catch and report them.
 410 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 411   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 412 endif()
 413 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 414   message(FATAL_ERROR
 415     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 416 endif()
 417
 418 # Include the generated CMake fragment. This will define properties from the
 419 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 420 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 421 # files change.
 422 include(${LLVMBUILDCMAKEFRAG})
 423
 424 ######
 425
 426 # Configure all of the various header file fragments LLVM uses which depend on
 427 # configuration variables.
 428 set(LLVM_ENUM_TARGETS "")
 429 set(LLVM_ENUM_ASM_PRINTERS "")
 430 set(LLVM_ENUM_ASM_PARSERS "")
 431 set(LLVM_ENUM_DISASSEMBLERS "")
 432 foreach(t ${LLVM_TARGETS_TO_BUILD})
 433   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 434
 435   list(FIND LLVM_ALL_TARGETS ${t} idx)
 436   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 437   if( idx LESS 0 AND idy LESS 0 )
 438     message(FATAL_ERROR "The target `${t}' does not exist.
 439     It should be one of\n${LLVM_ALL_TARGETS}")
 440   else()
 441     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 442   endif()
 443
 444   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 445   if( asmp_file )
 446     set(LLVM_ENUM_ASM_PRINTERS
 447       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 448   endif()
 449   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 450     set(LLVM_ENUM_ASM_PARSERS
 451       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 452   endif()
 453   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 454     set(LLVM_ENUM_DISASSEMBLERS
 455       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 456   endif()
 457 endforeach(t)
 458
 459 # Produce the target definition files, which provide a way for clients to easily
 460 # include various classes of targets.
 461 configure_file(
 462   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 463   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 464   )
 465 configure_file(
 466   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 467   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 468   )
 469 configure_file(
 470   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 471   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 472   )
 473 configure_file(
 474   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 475   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 476   )
 477
 478 # Configure the three LLVM configuration header files.
 479 configure_file(
 480   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 481   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 482 configure_file(
 483   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 484   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 485 configure_file(
 486   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 487   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 488
 489 # They are not referenced. See set_output_directory().
 490 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 491 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 492 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 493
 494 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 495 if (APPLE)
 496   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 497   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 498 else(UNIX)
 499   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 500     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 501     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 502       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 503       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 504     endif()
 505   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 506 endif()
 507
 508 # Work around a broken bfd ld behavior. When linking a binary with a
 509 # foo.so library, it will try to find any library that foo.so uses and
 510 # check its symbols. This is wasteful (the check was done when foo.so
 511 # was created) and can fail since it is not the dynamic linker and
 512 # doesn't know how to handle search paths correctly.
 513 if (UNIX AND NOT APPLE)
 514   set(CMAKE_EXE_LINKER_FLAGS
 515       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 516 endif()
 517
 518 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 519
 520 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 521
 522 # when crosscompiling import the executable targets from a file
 523 if(CMAKE_CROSSCOMPILING)
 524   include(CrossCompile)
 525 endif(CMAKE_CROSSCOMPILING)
 526
 527 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 528   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 529   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 530   include_directories("/usr/local/include")
 531   link_directories("/usr/local/lib")
 532 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 533
 534 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 535    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 536 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 537
 538 # Make sure we don't get -rdynamic in every binary. For those that need it,
 539 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 540 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 541
 542 include(AddLLVM)
 543 include(TableGen)
 544
 545 if( MINGW )
 546   # People report that -O3 is unreliable on MinGW. The traditional
 547   # build also uses -O2 for that reason:
 548   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 549 endif()
 550
 551 # Put this before tblgen. Else we have a circular dependence.
 552 add_subdirectory(lib/Support)
 553 add_subdirectory(lib/TableGen)
 554
 555 add_subdirectory(utils/TableGen)
 556
 557 add_subdirectory(include/llvm)
 558
 559 add_subdirectory(lib)
 560
 561 if( LLVM_INCLUDE_UTILS )
 562   add_subdirectory(utils/FileCheck)
 563   add_subdirectory(utils/PerfectShuffle)
 564   add_subdirectory(utils/count)
 565   add_subdirectory(utils/not)
 566   add_subdirectory(utils/llvm-lit)
 567   add_subdirectory(utils/yaml-bench)
 568 else()
 569   if ( LLVM_INCLUDE_TESTS )
 570     message(FATAL_ERROR "Including tests when not building utils will not work.
 571     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 572   endif()
 573 endif()
 574
 575 if(LLVM_INCLUDE_TESTS)
 576   add_subdirectory(utils/unittest)
 577 endif()
 578
 579 foreach( binding ${LLVM_BINDINGS_LIST} )
 580   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 581     add_subdirectory(bindings/${binding})
 582   endif()
 583 endforeach()
 584
 585 add_subdirectory(projects)
 586
 587 if(WITH_POLLY)
 588   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 589     set(WITH_POLLY OFF)
 590   endif()
 591 endif(WITH_POLLY)
 592
 593 if( LLVM_INCLUDE_TOOLS )
 594   add_subdirectory(tools)
 595 endif()
 596
 597 if( LLVM_INCLUDE_EXAMPLES )
 598   add_subdirectory(examples)
 599 endif()
 600
 601 if( LLVM_INCLUDE_TESTS )
 602   add_subdirectory(test)
 603   add_subdirectory(unittests)
 604   if (MSVC)
 605     # This utility is used to prevent crashing tests from calling Dr. Watson on
 606     # Windows.
 607     add_subdirectory(utils/KillTheDoctor)
 608   endif()
 609
 610   # Add a global check rule now that all subdirectories have been traversed
 611   # and we know the total set of lit testsuites.
 612   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 613   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 614   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 615   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 616   add_lit_target(check-all
 617     "Running all regression tests"
 618     ${LLVM_LIT_TESTSUITES}
 619     PARAMS ${LLVM_LIT_PARAMS}
 620     DEPENDS ${LLVM_LIT_DEPENDS}
 621     ARGS ${LLVM_LIT_EXTRA_ARGS}
 622     )
 623 endif()
 624
 625 if (LLVM_INCLUDE_DOCS)
 626   add_subdirectory(docs)
 627 endif()
 628
 629 add_subdirectory(cmake/modules)
 630
 631 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 632   install(DIRECTORY include/llvm include/llvm-c
 633     DESTINATION include
 634     COMPONENT llvm-headers
 635     FILES_MATCHING
 636     PATTERN "*.def"
 637     PATTERN "*.h"
 638     PATTERN "*.td"
 639     PATTERN "*.inc"
 640     PATTERN "LICENSE.TXT"
 641     PATTERN ".svn" EXCLUDE
 642     )
 643
 644   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 645     DESTINATION include
 646     COMPONENT llvm-headers
 647     FILES_MATCHING
 648     PATTERN "*.def"
 649     PATTERN "*.h"
 650     PATTERN "*.gen"
 651     PATTERN "*.inc"
 652     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 653     PATTERN "CMakeFiles" EXCLUDE
 654     PATTERN "config.h" EXCLUDE
 655     PATTERN ".svn" EXCLUDE
 656     )
 657
 658   if (NOT CMAKE_CONFIGURATION_TYPES)
 659     add_custom_target(installhdrs
 660                       DEPENDS ${name}
 661                       COMMAND "${CMAKE_COMMAND}"
 662                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 663                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 664   endif()
 665 endif()