CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 5)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  71   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  72   set(CPACK_NSIS_MODIFY_PATH "ON")
  73   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  74   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  76   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  77     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  78 endif()
  79 include(CPack)
  80
  81 # Sanity check our source directory to make sure that we are not trying to
  82 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  83 # sure that we don't have any stray generated files lying around in the tree
  84 # (which would end up getting picked up by header search, instead of the correct
  85 # versions).
  86 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  87   message(FATAL_ERROR "In-source builds are not allowed.
  88 CMake would overwrite the makefiles distributed with LLVM.
  89 Please create a directory and run cmake from there, passing the path
  90 to this source directory as the last argument.
  91 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  92 Please delete them.")
  93 endif()
  94 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  95   file(GLOB_RECURSE
  96     tablegenned_files_on_include_dir
  97     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  98   file(GLOB_RECURSE
  99     tablegenned_files_on_lib_dir
 100     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 101   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 102     message(FATAL_ERROR "Apparently there is a previous in-source build,
 103 probably as the result of running `configure' and `make' on
 104 ${CMAKE_CURRENT_SOURCE_DIR}.
 105 This may cause problems. The suspicious files are:
 106 ${tablegenned_files_on_lib_dir}
 107 ${tablegenned_files_on_include_dir}
 108 Please clean the source directory.")
 109   endif()
 110 endif()
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 113
 114 # They are used as destination of target generators.
 115 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 116 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 117
 118 # Each of them corresponds to llvm-config's.
 119 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 120 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 121 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 122 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 123 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 124
 125 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 126 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 127 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 128
 129 set(LLVM_ALL_TARGETS
 130   AArch64
 131   ARM
 132   CppBackend
 133   Hexagon
 134   Mips
 135   MSP430
 136   NVPTX
 137   PowerPC
 138   R600
 139   Sparc
 140   SystemZ
 141   X86
 142   XCore
 143   )
 144
 145 # List of targets with JIT support:
 146 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 147
 148 set(LLVM_TARGETS_TO_BUILD "all"
 149     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 150
 151 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 152   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 153
 154 option(BUILD_SHARED_LIBS
 155   "Build all libraries as shared libraries instead of static" OFF)
 156
 157 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 158 if(LLVM_ENABLE_TIMESTAMPS)
 159   set(ENABLE_TIMESTAMPS 1)
 160 endif()
 161
 162 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 163 if(LLVM_ENABLE_BACKTRACES)
 164   set(ENABLE_BACKTRACES 1)
 165 endif()
 166
 167 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 168 if(LLVM_ENABLE_CRASH_OVERRIDES)
 169   set(ENABLE_CRASH_OVERRIDES 1)
 170 endif()
 171
 172 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 173 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 174 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 175
 176 set(LLVM_TARGET_ARCH "host"
 177   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 178
 179 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 180
 181 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 182
 183 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 184
 185 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 186   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 187 endif()
 188
 189 set(LLVM_TARGETS_TO_BUILD
 190    ${LLVM_TARGETS_TO_BUILD}
 191    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 192 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 193
 194 include(AddLLVMDefinitions)
 195
 196 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 197
 198 # MSVC has a gazillion warnings with this.
 199 if( MSVC )
 200   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 201 else()
 202   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 203 endif()
 204
 205 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 206 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 207 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 208 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 209
 210 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 211   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 212 else()
 213   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 214 endif()
 215
 216 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 217        "Set to ON to force using an old, unsupported host toolchain." OFF)
 218
 219 option(LLVM_USE_INTEL_JITEVENTS
 220   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 221   OFF)
 222
 223 if( LLVM_USE_INTEL_JITEVENTS )
 224   # Verify we are on a supported platform
 225   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 226     message(FATAL_ERROR
 227       "Intel JIT API support is available on Linux and Windows only.")
 228   endif()
 229 endif( LLVM_USE_INTEL_JITEVENTS )
 230
 231 option(LLVM_USE_OPROFILE
 232   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 233
 234 # If enabled, verify we are on a platform that supports oprofile.
 235 if( LLVM_USE_OPROFILE )
 236   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 237     message(FATAL_ERROR "OProfile support is available on Linux only.")
 238   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 239 endif( LLVM_USE_OPROFILE )
 240
 241 set(LLVM_USE_SANITIZER "" CACHE STRING
 242   "Define the sanitizer used to build binaries and tests.")
 243
 244 option(LLVM_USE_SPLIT_DWARF
 245   "Use -gsplit-dwarf when compiling llvm." OFF)
 246
 247 option(WITH_POLLY "Build LLVM with Polly" ON)
 248 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 249
 250 # Define an option controlling whether we should build for 32-bit on 64-bit
 251 # platforms, where supported.
 252 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 253   # TODO: support other platforms and toolchains.
 254   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 255 endif()
 256
 257 # Define the default arguments to use with 'lit', and an option for the user to
 258 # override.
 259 set(LIT_ARGS_DEFAULT "-sv")
 260 if (MSVC OR XCODE)
 261   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 262 endif()
 263 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 264
 265 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 266 if( WIN32 AND NOT CYGWIN )
 267   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 268 endif()
 269
 270 # Define options to control the inclusion and default build behavior for
 271 # components which may not strictly be necessary (tools, examples, and tests).
 272 #
 273 # This is primarily to support building smaller or faster project files.
 274 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 275 option(LLVM_BUILD_TOOLS
 276   "Build the LLVM tools. If OFF, just generate build targets." ON)
 277
 278 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 279
 280 option(LLVM_BUILD_RUNTIME
 281   "Build the LLVM runtime libraries." ON)
 282 option(LLVM_BUILD_EXAMPLES
 283   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 284 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 285
 286 option(LLVM_BUILD_TESTS
 287   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 288 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 289
 290 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 291 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 292 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 293 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 294
 295 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 296   "Build compiler-rt as an external project." OFF)
 297
 298 # All options referred to from HandleLLVMOptions have to be specified
 299 # BEFORE this include, otherwise options will not be correctly set on
 300 # first cmake run
 301 include(config-ix)
 302
 303 # By default, we target the host, but this can be overridden at CMake
 304 # invocation time.
 305 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 306   "Default target for which LLVM will generate code." )
 307 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 308
 309 include(HandleLLVMOptions)
 310
 311 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 312 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 313 include(FindPythonInterp)
 314 if( NOT PYTHONINTERP_FOUND )
 315   message(FATAL_ERROR
 316 "Unable to find Python interpreter, required for builds and testing.
 317
 318 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 319 endif()
 320
 321 ######
 322 # LLVMBuild Integration
 323 #
 324 # We use llvm-build to generate all the data required by the CMake based
 325 # build system in one swoop:
 326 #
 327 #  - We generate a file (a CMake fragment) in the object root which contains
 328 #    all the definitions that are required by CMake.
 329 #
 330 #  - We generate the library table used by llvm-config.
 331 #
 332 #  - We generate the dependencies for the CMake fragment, so that we will
 333 #    automatically reconfigure outselves.
 334
 335 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 336 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 337   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 338 set(LLVMBUILDCMAKEFRAG
 339   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 340
 341 # Create the list of optional components that are enabled
 342 if (LLVM_USE_INTEL_JITEVENTS)
 343   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 344 endif (LLVM_USE_INTEL_JITEVENTS)
 345 if (LLVM_USE_OPROFILE)
 346   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 347 endif (LLVM_USE_OPROFILE)
 348
 349 message(STATUS "Constructing LLVMBuild project information")
 350 execute_process(
 351   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 352             --native-target "${LLVM_NATIVE_ARCH}"
 353             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 354             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 355             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 356             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 357             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 358             ERROR_VARIABLE LLVMBUILDERRORS
 359             OUTPUT_STRIP_TRAILING_WHITESPACE
 360             ERROR_STRIP_TRAILING_WHITESPACE
 361   RESULT_VARIABLE LLVMBUILDRESULT)
 362
 363 # On Win32, CMake doesn't properly handle piping the default output/error
 364 # streams into the GUI console. So, we explicitly catch and report them.
 365 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 366   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 367 endif()
 368 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 369   message(FATAL_ERROR
 370     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 371 endif()
 372
 373 # Include the generated CMake fragment. This will define properties from the
 374 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 375 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 376 # files change.
 377 include(${LLVMBUILDCMAKEFRAG})
 378
 379 ######
 380
 381 # Configure all of the various header file fragments LLVM uses which depend on
 382 # configuration variables.
 383 set(LLVM_ENUM_TARGETS "")
 384 set(LLVM_ENUM_ASM_PRINTERS "")
 385 set(LLVM_ENUM_ASM_PARSERS "")
 386 set(LLVM_ENUM_DISASSEMBLERS "")
 387 foreach(t ${LLVM_TARGETS_TO_BUILD})
 388   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 389
 390   list(FIND LLVM_ALL_TARGETS ${t} idx)
 391   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 392   if( idx LESS 0 AND idy LESS 0 )
 393     message(FATAL_ERROR "The target `${t}' does not exist.
 394     It should be one of\n${LLVM_ALL_TARGETS}")
 395   else()
 396     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 397   endif()
 398
 399   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 400   if( asmp_file )
 401     set(LLVM_ENUM_ASM_PRINTERS
 402       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 403   endif()
 404   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 405     set(LLVM_ENUM_ASM_PARSERS
 406       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 407   endif()
 408   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 409     set(LLVM_ENUM_DISASSEMBLERS
 410       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 411   endif()
 412 endforeach(t)
 413
 414 # Produce the target definition files, which provide a way for clients to easily
 415 # include various classes of targets.
 416 configure_file(
 417   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 418   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 419   )
 420 configure_file(
 421   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 422   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 423   )
 424 configure_file(
 425   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 426   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 427   )
 428 configure_file(
 429   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 430   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 431   )
 432
 433 # Configure the three LLVM configuration header files.
 434 configure_file(
 435   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 436   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 437 configure_file(
 438   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 439   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 440 configure_file(
 441   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 442   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 443
 444 # They are not referenced. See set_output_directory().
 445 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 446 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 447 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 448
 449 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 450 if (APPLE)
 451   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 452   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 453 else(UNIX)
 454   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 455     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 456     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 457       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 458     endif()
 459   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 460 endif()
 461
 462 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 463
 464 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 465
 466 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 467   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 468   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 469   include_directories("/usr/local/include")
 470   link_directories("/usr/local/lib")
 471 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 472
 473 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 474    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 475 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 476
 477 # Make sure we don't get -rdynamic in every binary. For those that need it,
 478 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 479 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 480
 481 include(AddLLVM)
 482 include(TableGen)
 483
 484 if( MINGW )
 485   # People report that -O3 is unreliable on MinGW. The traditional
 486   # build also uses -O2 for that reason:
 487   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 488 endif()
 489
 490 # Put this before tblgen. Else we have a circular dependence.
 491 add_subdirectory(lib/Support)
 492 add_subdirectory(lib/TableGen)
 493
 494 add_subdirectory(utils/TableGen)
 495
 496 add_subdirectory(include/llvm)
 497
 498 add_subdirectory(lib)
 499
 500 if( LLVM_INCLUDE_UTILS )
 501   add_subdirectory(utils/FileCheck)
 502   add_subdirectory(utils/PerfectShuffle)
 503   add_subdirectory(utils/count)
 504   add_subdirectory(utils/not)
 505   add_subdirectory(utils/llvm-lit)
 506   add_subdirectory(utils/yaml-bench)
 507 else()
 508   if ( LLVM_INCLUDE_TESTS )
 509     message(FATAL_ERROR "Including tests when not building utils will not work.
 510     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 511   endif()
 512 endif()
 513
 514 if(LLVM_INCLUDE_TESTS)
 515   add_subdirectory(utils/unittest)
 516 endif()
 517
 518 add_subdirectory(projects)
 519
 520 if(WITH_POLLY)
 521   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 522     set(WITH_POLLY OFF)
 523   endif()
 524 endif(WITH_POLLY)
 525
 526 if( LLVM_INCLUDE_TOOLS )
 527   add_subdirectory(tools)
 528 endif()
 529
 530 if( LLVM_INCLUDE_EXAMPLES )
 531   add_subdirectory(examples)
 532 endif()
 533
 534 if( LLVM_INCLUDE_TESTS )
 535   add_subdirectory(test)
 536   add_subdirectory(unittests)
 537   if (MSVC)
 538     # This utility is used to prevent crashing tests from calling Dr. Watson on
 539     # Windows.
 540     add_subdirectory(utils/KillTheDoctor)
 541   endif()
 542
 543   # Add a global check rule now that all subdirectories have been traversed
 544   # and we know the total set of lit testsuites.
 545   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 546   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 547   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 548   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 549   add_lit_target(check-all
 550     "Running all regression tests"
 551     ${LLVM_LIT_TESTSUITES}
 552     PARAMS ${LLVM_LIT_PARAMS}
 553     DEPENDS ${LLVM_LIT_DEPENDS}
 554     ARGS ${LLVM_LIT_EXTRA_ARGS}
 555     )
 556 endif()
 557
 558 if (LLVM_INCLUDE_DOCS)
 559   add_subdirectory(docs)
 560 endif()
 561
 562 add_subdirectory(cmake/modules)
 563
 564 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 565   install(DIRECTORY include/llvm include/llvm-c
 566     DESTINATION include
 567     FILES_MATCHING
 568     PATTERN "*.def"
 569     PATTERN "*.h"
 570     PATTERN "*.td"
 571     PATTERN "*.inc"
 572     PATTERN "LICENSE.TXT"
 573     PATTERN ".svn" EXCLUDE
 574     )
 575
 576   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 577     DESTINATION include
 578     FILES_MATCHING
 579     PATTERN "*.def"
 580     PATTERN "*.h"
 581     PATTERN "*.gen"
 582     PATTERN "*.inc"
 583     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 584     PATTERN "CMakeFiles" EXCLUDE
 585     PATTERN "config.h" EXCLUDE
 586     PATTERN ".svn" EXCLUDE
 587     )
 588 endif()