CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 5)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  71   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  72   set(CPACK_NSIS_MODIFY_PATH "ON")
  73   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  74   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  76   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  77     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  78 endif()
  79 include(CPack)
  80
  81 # Sanity check our source directory to make sure that we are not trying to
  82 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  83 # sure that we don't have any stray generated files lying around in the tree
  84 # (which would end up getting picked up by header search, instead of the correct
  85 # versions).
  86 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  87   message(FATAL_ERROR "In-source builds are not allowed.
  88 CMake would overwrite the makefiles distributed with LLVM.
  89 Please create a directory and run cmake from there, passing the path
  90 to this source directory as the last argument.
  91 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  92 Please delete them.")
  93 endif()
  94 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  95   file(GLOB_RECURSE
  96     tablegenned_files_on_include_dir
  97     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  98   file(GLOB_RECURSE
  99     tablegenned_files_on_lib_dir
 100     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 101   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 102     message(FATAL_ERROR "Apparently there is a previous in-source build,
 103 probably as the result of running `configure' and `make' on
 104 ${CMAKE_CURRENT_SOURCE_DIR}.
 105 This may cause problems. The suspicious files are:
 106 ${tablegenned_files_on_lib_dir}
 107 ${tablegenned_files_on_include_dir}
 108 Please clean the source directory.")
 109   endif()
 110 endif()
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 113
 114 # They are used as destination of target generators.
 115 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 116 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 117
 118 # Each of them corresponds to llvm-config's.
 119 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 120 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 121 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 122 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 123 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 124
 125 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 126 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 127 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 128
 129 set(LLVM_ALL_TARGETS
 130   AArch64
 131   ARM
 132   CppBackend
 133   Hexagon
 134   Mips
 135   MSP430
 136   NVPTX
 137   PowerPC
 138   R600
 139   Sparc
 140   SystemZ
 141   X86
 142   XCore
 143   )
 144
 145 # List of targets with JIT support:
 146 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 147
 148 set(LLVM_TARGETS_TO_BUILD "all"
 149     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 150
 151 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 152   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 153
 154 option(BUILD_SHARED_LIBS
 155   "Build all libraries as shared libraries instead of static" OFF)
 156
 157 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 158 if(LLVM_ENABLE_TIMESTAMPS)
 159   set(ENABLE_TIMESTAMPS 1)
 160 endif()
 161
 162 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 163 if(LLVM_ENABLE_BACKTRACES)
 164   set(ENABLE_BACKTRACES 1)
 165 endif()
 166
 167 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 168 if(LLVM_ENABLE_CRASH_OVERRIDES)
 169   set(ENABLE_CRASH_OVERRIDES 1)
 170 endif()
 171
 172 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 173 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 174 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 175
 176 set(LLVM_TARGET_ARCH "host"
 177   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 178
 179 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 180
 181 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 182
 183 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 184
 185 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 186   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 187 endif()
 188
 189 set(LLVM_TARGETS_TO_BUILD
 190    ${LLVM_TARGETS_TO_BUILD}
 191    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 192 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 193
 194 include(AddLLVMDefinitions)
 195
 196 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 197
 198 # MSVC has a gazillion warnings with this.
 199 if( MSVC )
 200   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 201 else( MSVC )
 202   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 203 endif()
 204
 205 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 206 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 207 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 208 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 209
 210 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 211   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 212 else()
 213   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 214 endif()
 215
 216 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 217        "Set to ON to force using an old, unsupported host toolchain." OFF)
 218
 219 option(LLVM_USE_INTEL_JITEVENTS
 220   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 221   OFF)
 222
 223 if( LLVM_USE_INTEL_JITEVENTS )
 224   # Verify we are on a supported platform
 225   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 226     message(FATAL_ERROR
 227       "Intel JIT API support is available on Linux and Windows only.")
 228   endif()
 229 endif( LLVM_USE_INTEL_JITEVENTS )
 230
 231 option(LLVM_USE_OPROFILE
 232   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 233
 234 # If enabled, verify we are on a platform that supports oprofile.
 235 if( LLVM_USE_OPROFILE )
 236   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 237     message(FATAL_ERROR "OProfile support is available on Linux only.")
 238   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 239 endif( LLVM_USE_OPROFILE )
 240
 241 set(LLVM_USE_SANITIZER "" CACHE STRING
 242   "Define the sanitizer used to build binaries and tests.")
 243
 244 option(LLVM_USE_SPLIT_DWARF
 245   "Use -gsplit-dwarf when compiling llvm." OFF)
 246
 247 # Define an option controlling whether we should build for 32-bit on 64-bit
 248 # platforms, where supported.
 249 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 250   # TODO: support other platforms and toolchains.
 251   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 252 endif()
 253
 254 # Define the default arguments to use with 'lit', and an option for the user to
 255 # override.
 256 set(LIT_ARGS_DEFAULT "-sv")
 257 if (MSVC OR XCODE)
 258   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 259 endif()
 260 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 261
 262 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 263 if( WIN32 AND NOT CYGWIN )
 264   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 265 endif()
 266
 267 # Define options to control the inclusion and default build behavior for
 268 # components which may not strictly be necessary (tools, examples, and tests).
 269 #
 270 # This is primarily to support building smaller or faster project files.
 271 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 272 option(LLVM_BUILD_TOOLS
 273   "Build the LLVM tools. If OFF, just generate build targets." ON)
 274
 275 option(LLVM_BUILD_RUNTIME
 276   "Build the LLVM runtime libraries." ON)
 277 option(LLVM_BUILD_EXAMPLES
 278   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 279 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 280
 281 option(LLVM_BUILD_TESTS
 282   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 283 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 284
 285 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 286 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 287 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 288
 289 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 290   "Build compiler-rt as an external project." OFF)
 291
 292 # All options referred to from HandleLLVMOptions have to be specified
 293 # BEFORE this include, otherwise options will not be correctly set on
 294 # first cmake run
 295 include(config-ix)
 296
 297 # By default, we target the host, but this can be overridden at CMake
 298 # invocation time.
 299 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 300   "Default target for which LLVM will generate code." )
 301 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 302
 303 include(HandleLLVMOptions)
 304
 305 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 306 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 307 include(FindPythonInterp)
 308 if( NOT PYTHONINTERP_FOUND )
 309   message(FATAL_ERROR
 310 "Unable to find Python interpreter, required for builds and testing.
 311
 312 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 313 endif()
 314
 315 ######
 316 # LLVMBuild Integration
 317 #
 318 # We use llvm-build to generate all the data required by the CMake based
 319 # build system in one swoop:
 320 #
 321 #  - We generate a file (a CMake fragment) in the object root which contains
 322 #    all the definitions that are required by CMake.
 323 #
 324 #  - We generate the library table used by llvm-config.
 325 #
 326 #  - We generate the dependencies for the CMake fragment, so that we will
 327 #    automatically reconfigure outselves.
 328
 329 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 330 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 331   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 332 set(LLVMBUILDCMAKEFRAG
 333   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 334
 335 # Create the list of optional components that are enabled
 336 if (LLVM_USE_INTEL_JITEVENTS)
 337   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 338 endif (LLVM_USE_INTEL_JITEVENTS)
 339 if (LLVM_USE_OPROFILE)
 340   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 341 endif (LLVM_USE_OPROFILE)
 342
 343 message(STATUS "Constructing LLVMBuild project information")
 344 execute_process(
 345   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 346             --native-target "${LLVM_NATIVE_ARCH}"
 347             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 348             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 349             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 350             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 351             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 352             ERROR_VARIABLE LLVMBUILDERRORS
 353             OUTPUT_STRIP_TRAILING_WHITESPACE
 354             ERROR_STRIP_TRAILING_WHITESPACE
 355   RESULT_VARIABLE LLVMBUILDRESULT)
 356
 357 # On Win32, CMake doesn't properly handle piping the default output/error
 358 # streams into the GUI console. So, we explicitly catch and report them.
 359 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 360   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 361 endif()
 362 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 363   message(FATAL_ERROR
 364     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 365 endif()
 366
 367 # Include the generated CMake fragment. This will define properties from the
 368 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 369 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 370 # files change.
 371 include(${LLVMBUILDCMAKEFRAG})
 372
 373 ######
 374
 375 # Configure all of the various header file fragments LLVM uses which depend on
 376 # configuration variables.
 377 set(LLVM_ENUM_TARGETS "")
 378 set(LLVM_ENUM_ASM_PRINTERS "")
 379 set(LLVM_ENUM_ASM_PARSERS "")
 380 set(LLVM_ENUM_DISASSEMBLERS "")
 381 foreach(t ${LLVM_TARGETS_TO_BUILD})
 382   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 383
 384   list(FIND LLVM_ALL_TARGETS ${t} idx)
 385   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 386   if( idx LESS 0 AND idy LESS 0 )
 387     message(FATAL_ERROR "The target `${t}' does not exist.
 388     It should be one of\n${LLVM_ALL_TARGETS}")
 389   else()
 390     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 391   endif()
 392
 393   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 394   if( asmp_file )
 395     set(LLVM_ENUM_ASM_PRINTERS
 396       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 397   endif()
 398   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 399     set(LLVM_ENUM_ASM_PARSERS
 400       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 401   endif()
 402   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 403     set(LLVM_ENUM_DISASSEMBLERS
 404       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 405   endif()
 406 endforeach(t)
 407
 408 # Produce the target definition files, which provide a way for clients to easily
 409 # include various classes of targets.
 410 configure_file(
 411   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 412   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 413   )
 414 configure_file(
 415   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 416   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 417   )
 418 configure_file(
 419   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 420   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 421   )
 422 configure_file(
 423   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 424   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 425   )
 426
 427 # Configure the three LLVM configuration header files.
 428 configure_file(
 429   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 430   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 431 configure_file(
 432   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 433   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 434 configure_file(
 435   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 436   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 437
 438 # They are not referenced. See set_output_directory().
 439 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 440 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 441 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 442
 443 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 444 if (APPLE)
 445   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 446   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 447 else(UNIX)
 448   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 449     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 450     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 451       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 452     endif()
 453   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 454 endif()
 455
 456 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 457
 458 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 459
 460 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 461   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 462   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 463   include_directories("/usr/local/include")
 464   link_directories("/usr/local/lib")
 465 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 466
 467 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 468    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 469 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 470
 471 # Make sure we don't get -rdynamic in every binary. For those that need it,
 472 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 473 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 474
 475 include(AddLLVM)
 476 include(TableGen)
 477
 478 if( MINGW )
 479   # People report that -O3 is unreliable on MinGW. The traditional
 480   # build also uses -O2 for that reason:
 481   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 482 endif()
 483
 484 # Put this before tblgen. Else we have a circular dependence.
 485 add_subdirectory(lib/Support)
 486 add_subdirectory(lib/TableGen)
 487
 488 add_subdirectory(utils/TableGen)
 489
 490 add_subdirectory(include/llvm)
 491
 492 add_subdirectory(lib)
 493
 494 add_subdirectory(utils/FileCheck)
 495 add_subdirectory(utils/FileUpdate)
 496 add_subdirectory(utils/count)
 497 add_subdirectory(utils/not)
 498 add_subdirectory(utils/llvm-lit)
 499 add_subdirectory(utils/yaml-bench)
 500
 501 if(LLVM_INCLUDE_TESTS)
 502   add_subdirectory(utils/unittest)
 503 endif()
 504
 505 add_subdirectory(projects)
 506
 507 option(WITH_POLLY "Build LLVM with Polly" ON)
 508 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 509
 510 if(WITH_POLLY)
 511   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 512     set(WITH_POLLY OFF)
 513   endif()
 514 endif(WITH_POLLY)
 515
 516 if( LLVM_INCLUDE_TOOLS )
 517   add_subdirectory(tools)
 518 endif()
 519
 520 if( LLVM_INCLUDE_EXAMPLES )
 521   add_subdirectory(examples)
 522 endif()
 523
 524 if( LLVM_INCLUDE_TESTS )
 525   add_subdirectory(test)
 526   add_subdirectory(unittests)
 527   if (MSVC)
 528     # This utility is used to prevent crashing tests from calling Dr. Watson on
 529     # Windows.
 530     add_subdirectory(utils/KillTheDoctor)
 531   endif()
 532
 533   # Add a global check rule now that all subdirectories have been traversed
 534   # and we know the total set of lit testsuites.
 535   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 536   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 537   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 538   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 539   add_lit_target(check-all
 540     "Running all regression tests"
 541     ${LLVM_LIT_TESTSUITES}
 542     PARAMS ${LLVM_LIT_PARAMS}
 543     DEPENDS ${LLVM_LIT_DEPENDS}
 544     ARGS ${LLVM_LIT_EXTRA_ARGS}
 545     )
 546 endif()
 547
 548 if (LLVM_INCLUDE_DOCS)
 549   add_subdirectory(docs)
 550 endif()
 551
 552 add_subdirectory(cmake/modules)
 553
 554 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 555   install(DIRECTORY include/llvm include/llvm-c
 556     DESTINATION include
 557     FILES_MATCHING
 558     PATTERN "*.def"
 559     PATTERN "*.h"
 560     PATTERN "*.td"
 561     PATTERN "*.inc"
 562     PATTERN "LICENSE.TXT"
 563     PATTERN ".svn" EXCLUDE
 564     )
 565
 566   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 567     DESTINATION include
 568     FILES_MATCHING
 569     PATTERN "*.def"
 570     PATTERN "*.h"
 571     PATTERN "*.gen"
 572     PATTERN "*.inc"
 573     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 574     PATTERN "CMakeFiles" EXCLUDE
 575     PATTERN ".svn" EXCLUDE
 576     )
 577 endif()