CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 set(LLVM_ALL_TARGETS
  32   Alpha
  33   ARM
  34   CBackend
  35   CellSPU
  36   CppBackend
  37   IA64
  38   Mips
  39   MSIL
  40   PIC16
  41   PowerPC
  42   Sparc
  43   X86
  44   XCore
  45   )
  46
  47 # List of targets whose asmprinters need to be forced to link
  48 # into executables on some platforms (i.e. Windows):
  49 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  50
  51 if( MSVC )
  52   set(LLVM_TARGETS_TO_BUILD X86
  53     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  54 else( MSVC )
  55   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  56     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  57 endif( MSVC )
  58
  59 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  60
  61 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  62   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  63 else()
  64   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  65 endif()
  66
  67 if( LLVM_ENABLE_ASSERTIONS )
  68   add_definitions( -D_DEBUG )
  69   # On Release builds cmake automatically defines NDEBUG, so we
  70   # explicitly undefine it:
  71   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  72     add_definitions( -UNDEBUG )
  73   endif()
  74 else()
  75   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  76     add_definitions( -DNDEBUG )
  77   endif()
  78 endif()
  79
  80 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  81   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  82 endif()
  83
  84 foreach(c ${LLVM_TARGETS_TO_BUILD})
  85   list(FIND LLVM_ALL_TARGETS ${c} idx)
  86   if( idx LESS 0 )
  87     message(FATAL_ERROR "The target `${c}' does not exists.
  88     It should be one of\n${LLVM_ALL_TARGETS}")
  89   endif()
  90 endforeach(c)
  91
  92 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  93
  94 # The USE_EXPLICIT_DEPENDENCIES variable will be TRUE to indicate that
  95 # we should use the library dependencies explicitly specified in the
  96 # CMakeLists.txt files rather than those determined by
  97 # llvm-config. This value must be true for non-make and IDE
  98 # generators.
  99 if (MSVC_IDE)
 100   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 101 elseif (XCODE)
 102   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 103 else ()
 104  set(DEFAULT_USE_EXPLICIT_DEPENDENCIES OFF)
 105 endif ()
 106
 107 option(USE_EXPLICIT_DEPENDENCIES
 108   "Use explicit dependencies instead of llvm-config"
 109   ${DEFAULT_USE_EXPLICIT_DEPENDENCIES})
 110 mark_as_advanced(USE_EXPLICIT_DEPENDENCIES)
 111
 112 # Add path for custom modules
 113 set(CMAKE_MODULE_PATH
 114   ${CMAKE_MODULE_PATH}
 115   "${LLVM_MAIN_SRC_DIR}/cmake"
 116   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 117   )
 118
 119 include(AddLLVMDefinitions)
 120
 121 if(WIN32)
 122   if(CYGWIN)
 123     set(LLVM_ON_WIN32 0)
 124     set(LLVM_ON_UNIX 1)
 125   else(CYGWIN)
 126     set(LLVM_ON_WIN32 1)
 127     set(LLVM_ON_UNIX 0)
 128   endif(CYGWIN)
 129   set(LTDL_SHLIB_EXT ".dll")
 130   set(EXEEXT ".exe")
 131   # Maximum path length is 160 for non-unicode paths
 132   set(MAXPATHLEN 160)
 133 else(WIN32)
 134   if(UNIX)
 135     set(LLVM_ON_WIN32 0)
 136     set(LLVM_ON_UNIX 1)
 137     set(LTDL_SHLIB_EXT ".so")
 138     set(EXEEXT "")
 139     # FIXME: Maximum path length is currently set to 'safe' fixed value
 140     set(MAXPATHLEN 2024)
 141   else(UNIX)
 142     MESSAGE(SEND_ERROR "Unable to determine platform")
 143   endif(UNIX)
 144 endif(WIN32)
 145
 146 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 147   set(HAVE_LLVM_CONFIG 1)
 148 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 149
 150 include(config-ix)
 151
 152 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 153
 154 set(ENABLE_PIC 0)
 155 if( LLVM_ENABLE_PIC )
 156   if( SUPPORTS_FPIC_FLAG )
 157     message(STATUS "Building with -fPIC")
 158     add_llvm_definitions(-fPIC)
 159     set(ENABLE_PIC 1)
 160  else( SUPPORTS_FPIC_FLAG )
 161     message(STATUS "Warning: -fPIC not supported.")
 162   endif()
 163 endif()
 164
 165 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 166 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 167 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 168
 169 # set(CMAKE_VERBOSE_MAKEFILE true)
 170
 171 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 172 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 173
 174 set(LLVM_PLO_FLAGS "" CACHE
 175   STRING "Flags for creating partially linked objects.")
 176
 177 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 178   # TODO: support other platforms and toolchains.
 179   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 180   if( LLVM_BUILD_32_BITS )
 181     message(STATUS "Building 32 bits executables and libraries.")
 182     add_llvm_definitions( -m32 )
 183     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 184     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 185     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 186   endif( LLVM_BUILD_32_BITS )
 187 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 188
 189 if( MSVC )
 190   # List of valid CRTs for MSVC
 191   set(MSVC_CRT
 192     MD
 193     MDd)
 194
 195   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 196   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 197   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 198   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 199   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 200   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 201
 202   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 203     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 204     if (idx LESS 0)
 205       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 206     endif (idx LESS 0)
 207     add_llvm_definitions("/${LLVM_USE_CRT}")
 208     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 209   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 210 endif( MSVC )
 211
 212 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 213
 214 include(AddLLVM)
 215 include(AddPartiallyLinkedObject)
 216 include(TableGen)
 217
 218 add_subdirectory(lib/Support)
 219 add_subdirectory(lib/System)
 220
 221 # Everything else depends on Support and System:
 222 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 223
 224 set(LLVM_TABLEGEN "tblgen" CACHE
 225   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 226 # Effective tblgen executable to be used:
 227 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 228
 229 add_subdirectory(utils/TableGen)
 230
 231 if( CMAKE_CROSSCOMPILING )
 232   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 233   include( CrossCompileLLVM )
 234 endif( CMAKE_CROSSCOMPILING )
 235
 236 add_subdirectory(include/llvm)
 237
 238 add_subdirectory(lib/VMCore)
 239 add_subdirectory(lib/CodeGen)
 240 add_subdirectory(lib/CodeGen/SelectionDAG)
 241 add_subdirectory(lib/CodeGen/AsmPrinter)
 242 add_subdirectory(lib/Bitcode/Reader)
 243 add_subdirectory(lib/Bitcode/Writer)
 244 add_subdirectory(lib/Transforms/Utils)
 245 add_subdirectory(lib/Transforms/Instrumentation)
 246 add_subdirectory(lib/Transforms/Scalar)
 247 add_subdirectory(lib/Transforms/IPO)
 248 add_subdirectory(lib/Transforms/Hello)
 249 add_subdirectory(lib/Linker)
 250 add_subdirectory(lib/Analysis)
 251 add_subdirectory(lib/Analysis/IPA)
 252
 253 foreach(t ${LLVM_TARGETS_TO_BUILD})
 254   message(STATUS "Targeting ${t}")
 255   add_subdirectory(lib/Target/${t})
 256   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 257     add_subdirectory(lib/Target/${t}/AsmPrinter)
 258   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 259 endforeach(t)
 260
 261 add_subdirectory(lib/ExecutionEngine)
 262 add_subdirectory(lib/ExecutionEngine/Interpreter)
 263 add_subdirectory(lib/ExecutionEngine/JIT)
 264 add_subdirectory(lib/Target)
 265 add_subdirectory(lib/AsmParser)
 266 add_subdirectory(lib/Debugger)
 267 add_subdirectory(lib/Archive)
 268
 269 add_subdirectory(projects)
 270 add_subdirectory(tools)
 271
 272 add_subdirectory(examples)
 273
 274 install(DIRECTORY include
 275   DESTINATION .
 276   PATTERN ".svn" EXCLUDE
 277   PATTERN "*.cmake" EXCLUDE
 278   PATTERN "*.in" EXCLUDE
 279   )
 280
 281 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 282   DESTINATION .
 283   )
 284
 285 # TODO: make and install documentation.