CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 set(LLVM_ALL_TARGETS
  32   Alpha
  33   ARM
  34   CBackend
  35   CellSPU
  36   CppBackend
  37   IA64
  38   Mips
  39   MSIL
  40   PIC16
  41   PowerPC
  42   Sparc
  43   X86
  44   XCore
  45   )
  46
  47 # List of targets whose asmprinters need to be forced to link
  48 # into executables on some platforms (i.e. Windows):
  49 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  50
  51 if( MSVC )
  52   set(LLVM_TARGETS_TO_BUILD X86
  53     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  54 else( MSVC )
  55   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  56     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  57 endif( MSVC )
  58
  59 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  60
  61 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  62   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  63 else()
  64   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  65 endif()
  66
  67 if( LLVM_ENABLE_ASSERTIONS )
  68   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  69   if( NOT MSVC )
  70     add_definitions( -D_DEBUG )
  71   endif()
  72   # On Release builds cmake automatically defines NDEBUG, so we
  73   # explicitly undefine it:
  74   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  75     add_definitions( -UNDEBUG )
  76   endif()
  77 else()
  78   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  79     add_definitions( -DNDEBUG )
  80   endif()
  81 endif()
  82
  83 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  84   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  85 endif()
  86
  87 set(LLVM_ENUM_TARGETS "")
  88 foreach(c ${LLVM_TARGETS_TO_BUILD})
  89   list(FIND LLVM_ALL_TARGETS ${c} idx)
  90   if( idx LESS 0 )
  91     message(FATAL_ERROR "The target `${c}' does not exists.
  92     It should be one of\n${LLVM_ALL_TARGETS}")
  93   else()
  94     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
  95   endif()
  96 endforeach(c)
  97
  98 # Produce llvm/Config/Targets.def
  99 configure_file(
 100   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 101   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 102   )
 103
 104 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 105
 106 # Add path for custom modules
 107 set(CMAKE_MODULE_PATH
 108   ${CMAKE_MODULE_PATH}
 109   "${LLVM_MAIN_SRC_DIR}/cmake"
 110   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 111   )
 112
 113 include(AddLLVMDefinitions)
 114
 115 if(WIN32)
 116   if(CYGWIN)
 117     set(LLVM_ON_WIN32 0)
 118     set(LLVM_ON_UNIX 1)
 119   else(CYGWIN)
 120     set(LLVM_ON_WIN32 1)
 121     set(LLVM_ON_UNIX 0)
 122   endif(CYGWIN)
 123   set(LTDL_SHLIB_EXT ".dll")
 124   set(EXEEXT ".exe")
 125   # Maximum path length is 160 for non-unicode paths
 126   set(MAXPATHLEN 160)
 127 else(WIN32)
 128   if(UNIX)
 129     set(LLVM_ON_WIN32 0)
 130     set(LLVM_ON_UNIX 1)
 131     set(LTDL_SHLIB_EXT ".so")
 132     set(EXEEXT "")
 133     # FIXME: Maximum path length is currently set to 'safe' fixed value
 134     set(MAXPATHLEN 2024)
 135   else(UNIX)
 136     MESSAGE(SEND_ERROR "Unable to determine platform")
 137   endif(UNIX)
 138 endif(WIN32)
 139
 140 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 141   set(HAVE_LLVM_CONFIG 1)
 142 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 143
 144 include(config-ix)
 145
 146 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 147
 148 set(ENABLE_PIC 0)
 149 if( LLVM_ENABLE_PIC )
 150   if( SUPPORTS_FPIC_FLAG )
 151     message(STATUS "Building with -fPIC")
 152     add_llvm_definitions(-fPIC)
 153     set(ENABLE_PIC 1)
 154  else( SUPPORTS_FPIC_FLAG )
 155     message(STATUS "Warning: -fPIC not supported.")
 156   endif()
 157 endif()
 158
 159 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 160 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 161 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 162
 163 # set(CMAKE_VERBOSE_MAKEFILE true)
 164
 165 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 166 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 167
 168 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 169   # TODO: support other platforms and toolchains.
 170   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 171   if( LLVM_BUILD_32_BITS )
 172     message(STATUS "Building 32 bits executables and libraries.")
 173     add_llvm_definitions( -m32 )
 174     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 175     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 176     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 177   endif( LLVM_BUILD_32_BITS )
 178 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 179
 180 if( MSVC )
 181   # List of valid CRTs for MSVC
 182   set(MSVC_CRT
 183     MD
 184     MDd)
 185
 186   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 187   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 188   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 189   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 190   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 191   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 192
 193   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 194     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 195     if (idx LESS 0)
 196       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 197     endif (idx LESS 0)
 198     add_llvm_definitions("/${LLVM_USE_CRT}")
 199     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 200   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 201 endif( MSVC )
 202
 203 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 204
 205 include(AddLLVM)
 206 include(TableGen)
 207
 208 add_subdirectory(lib/Support)
 209 add_subdirectory(lib/System)
 210
 211 # Everything else depends on Support and System:
 212 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 213
 214 set(LLVM_TABLEGEN "tblgen" CACHE
 215   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 216 # Effective tblgen executable to be used:
 217 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 218
 219 add_subdirectory(utils/TableGen)
 220
 221 if( CMAKE_CROSSCOMPILING )
 222   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 223   include( CrossCompileLLVM )
 224 endif( CMAKE_CROSSCOMPILING )
 225
 226 add_subdirectory(include/llvm)
 227
 228 add_subdirectory(lib/VMCore)
 229 add_subdirectory(lib/CodeGen)
 230 add_subdirectory(lib/CodeGen/SelectionDAG)
 231 add_subdirectory(lib/CodeGen/AsmPrinter)
 232 add_subdirectory(lib/Bitcode/Reader)
 233 add_subdirectory(lib/Bitcode/Writer)
 234 add_subdirectory(lib/Transforms/Utils)
 235 add_subdirectory(lib/Transforms/Instrumentation)
 236 add_subdirectory(lib/Transforms/Scalar)
 237 add_subdirectory(lib/Transforms/IPO)
 238 add_subdirectory(lib/Transforms/Hello)
 239 add_subdirectory(lib/Linker)
 240 add_subdirectory(lib/Analysis)
 241 add_subdirectory(lib/Analysis/IPA)
 242 add_subdirectory(lib/MC)
 243
 244  set(LLVM_ENUM_ASM_PRINTERS "")
 245  foreach(t ${LLVM_TARGETS_TO_BUILD})
 246   message(STATUS "Targeting ${t}")
 247   add_subdirectory(lib/Target/${t})
 248   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 249    add_subdirectory(lib/Target/${t}/AsmPrinter)
 250     set(LLVM_ENUM_ASM_PRINTERS
 251         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 252  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 253 endforeach(t)
 254
 255 # Produce llvm/Config/AsmPrinters.def
 256 configure_file(
 257   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 258   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 259   )
 260
 261 add_subdirectory(lib/ExecutionEngine)
 262 add_subdirectory(lib/ExecutionEngine/Interpreter)
 263 add_subdirectory(lib/ExecutionEngine/JIT)
 264 add_subdirectory(lib/Target)
 265 add_subdirectory(lib/AsmParser)
 266 add_subdirectory(lib/Debugger)
 267 add_subdirectory(lib/Archive)
 268
 269 add_subdirectory(projects)
 270 add_subdirectory(tools)
 271
 272 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 273 if (LLVM_EXAMPLES)
 274   add_subdirectory(examples)
 275 endif ()
 276
 277 install(DIRECTORY include
 278   DESTINATION .
 279   PATTERN ".svn" EXCLUDE
 280   PATTERN "*.cmake" EXCLUDE
 281   PATTERN "*.in" EXCLUDE
 282   )
 283
 284 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 285   DESTINATION .
 286   )
 287
 288 # TODO: make and install documentation.