CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2
   3 cmake_policy(SET CMP0016 NEW)
   4 if(POLICY CMP0042)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/build/cmake ${CMAKE_MODULE_PATH})
   9 include(TargetArch)
  10
  11 project(cds)
  12
  13 set(PROJECT_VERSION 2.4.0)
  14
  15 # Options
  16 option(WITH_TESTS "Build unit tests" OFF)
  17 option(WITH_TESTS_COVERAGE "Analyze test coverage using gcov (only for gcc)" OFF)
  18 option(WITH_BOOST_ATOMIC "Use boost atomics (only for boost >= 1.54)" OFF)
  19 option(WITH_ASAN "Build ASan+UBSan instrumented code" OFF)
  20 option(WITH_TSAN "Build TSan instrumented code" OFF)
  21 option(ENABLE_UNIT_TEST "Enable unit test" ON)
  22 option(ENABLE_STRESS_TEST "Enable stress test" ON)
  23 set(CMAKE_TARGET_ARCHITECTURE "" CACHE string "Target build architecture")
  24
  25 find_package(Threads)
  26
  27 if(TARGET boost::system AND TARGET boost::thread)
  28     link_libraries(boost::system boost::thread)
  29 else()
  30     find_package(Boost 1.50 COMPONENTS system thread)
  31 endif()
  32
  33 include_directories(${Boost_INCLUDE_DIRS})
  34
  35 if(NOT CMAKE_TARGET_ARCHITECTURE)
  36     target_architecture(CMAKE_TARGET_ARCHITECTURE)
  37 endif()
  38
  39 if(WITH_BOOST_ATOMIC)
  40     if(Boost_FOUND)
  41         if(${Boost_MINOR_VERSION} GREATER 53)
  42             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCDS_USE_BOOST_ATOMIC")
  43             message(STATUS "Boost version allows using of boost.atomic: activated")
  44         endif()
  45     else()
  46         if(TARGET boost::atomic)
  47             link_libraries(boost::atomic)
  48         endif()
  49     endif()
  50 endif(WITH_BOOST_ATOMIC)
  51
  52 if(WITH_ASAN)
  53     if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  54         set(CMAKE_CXX_FLAGS_DEBUG "-D_DEBUG")
  55         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG")
  56         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=address,undefined -g -DCDS_ADDRESS_SANITIZER_ENABLED -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  57         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O1 -fsanitize=address,undefined -g -DCDS_ASAN_ENABLED -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  58         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,undefined -pie")
  59     else()
  60         message(WARNING "Compiler does not support AddressSanitizer")
  61     endif()
  62 endif(WITH_ASAN)
  63
  64 if(WITH_TSAN)
  65     if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  66         set(CMAKE_CXX_FLAGS_DEBUG "-D_DEBUG")
  67         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG")
  68         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  69         set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  70         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -pie")
  71     else()
  72         message(WARNING "Compiler does not support ThreadSanitizer")
  73     endif()
  74 endif(WITH_TSAN)
  75
  76 if(WITH_TESTS_COVERAGE)
  77     if(CMAKE_COMPILER_IS_GNUCXX)
  78         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  79         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
  80         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  81         message(STATUS "Test coverage analysis: activated")
  82     else()
  83         message(WARNING "Compiler is not GNU gcc! Test coverage couldn't be analyzed")
  84     endif()
  85 endif(WITH_TESTS_COVERAGE)
  86
  87 set(CDS_SHARED_LIBRARY ${PROJECT_NAME})
  88 set(CDS_STATIC_LIBRARY ${PROJECT_NAME}-s)
  89
  90 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  91 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  92
  93 if(CDS_BIN_DIR)
  94     set(EXECUTABLE_OUTPUT_PATH ${CDS_BIN_DIR})
  95     set(LIBRARY_OUTPUT_PATH ${CDS_BIN_DIR})
  96 else()
  97     set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  98     set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  99 endif()
 100 message(STATUS "Binary output path: ${EXECUTABLE_OUTPUT_PATH}")
 101
 102 if(NOT CMAKE_BUILD_TYPE)
 103     set(CMAKE_BUILD_TYPE Debug CACHE STRING "Default build type to Debug" FORCE)
 104 endif()
 105
 106 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 107     string(REGEX MATCHALL "-std=[^ ]+" cxx_std_found ${CMAKE_CXX_FLAGS} "dummy@rg")
 108     if(cxx_std_found)
 109         message("C++ std: ${cxx_std_found}")
 110     else()
 111         list(APPEND LIBCDS_PUBLIC_CXX_FLAGS "-std=c++11")
 112         message("C++ std: -std=c++11 (default)")
 113     endif()
 114
 115     list(APPEND LIBCDS_PUBLIC_CXX_FLAGS "-fno-strict-aliasing")
 116     list(APPEND LIBCDS_PRIVATE_CXX_FLAGS "-Wall" "-Wextra" "-pedantic")
 117
 118     if(CMAKE_TARGET_ARCHITECTURE STREQUAL "x86_64")
 119         list(APPEND LIBCDS_PUBLIC_CXX_FLAGS "-mcx16")
 120         set(LIB_SUFFIX "64")
 121
 122         # GCC-7: 128-bit atomics support is implemented via libatomic on amd64
 123         #        see https://gcc.gnu.org/ml/gcc/2017-01/msg00167.html
 124         # Maybe, it will be changed in future
 125         if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7.0.0" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0.0")
 126             set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -latomic")
 127         endif()
 128     endif()
 129
 130     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0.0")
 131         #   gcc 4.8 - 6: disable noise -Wunused-local-typedefs
 132         list(APPEND LIBCDS_PRIVATE_CXX_FLAGS "-Wno-unused-local-typedefs")
 133     endif()
 134 endif()
 135
 136 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_DEBUG")
 137
 138 message("Build type -- ${CMAKE_BUILD_TYPE}")
 139 message("Compiler version: ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}")
 140 message("System: ${CMAKE_SYSTEM_NAME} version: ${CMAKE_SYSTEM_VERSION}")
 141 message("Target architecture: ${CMAKE_TARGET_ARCHITECTURE}")
 142 if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 143     message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${LIBCDS_PUBLIC_CXX_FLAGS} ${LIBCDS_PRIVATE_CXX_FLAGS}")
 144 else()
 145     message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${LIBCDS_PUBLIC_CXX_FLAGS} ${LIBCDS_PRIVATE_CXX_FLAGS}")
 146 endif()
 147 message("Exe flags: ${CMAKE_EXE_LINKER_FLAGS}")
 148
 149 if(Boost_FOUND)
 150     message("Boost: ${Boost_LIB_VERSION} in ${Boost_INCLUDE_DIRS}, lib ${Boost_LIBRARY_DIRS}")
 151 else()
 152     message("Boost: Using CMake-fied boost")
 153 endif()
 154
 155 if(CMAKE_SYSTEM_NAME STREQUAL "AIX")
 156     set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> -q -c ${CMAKE_STATIC_LINKER_FLAGS} -o <TARGET> <OBJECTS>")
 157 endif()
 158
 159 # Component names for separate distribution in rpms, debs etc.
 160 set(LIBRARIES_COMPONENT lib)
 161 set(HEADERS_COMPONENT devel)
 162
 163 set(SOURCES src/init.cpp
 164             src/hp.cpp
 165             src/dhp.cpp
 166             src/urcu_gp.cpp
 167             src/urcu_sh.cpp
 168             src/thread_data.cpp
 169             src/topology_hpux.cpp
 170             src/topology_linux.cpp
 171             src/topology_osx.cpp
 172             src/dllmain.cpp)
 173
 174 add_library(${CDS_SHARED_LIBRARY} SHARED ${SOURCES})
 175 set_target_properties(${CDS_SHARED_LIBRARY} PROPERTIES VERSION ${PROJECT_VERSION}
 176         DEBUG_POSTFIX "_d")
 177 add_library(${CDS_STATIC_LIBRARY} STATIC ${SOURCES})
 178 set_target_properties(${CDS_STATIC_LIBRARY} PROPERTIES DEBUG_POSTFIX "_d")
 179 target_link_libraries(${CDS_SHARED_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 180 target_link_libraries(${CDS_STATIC_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 181 target_include_directories(${CDS_SHARED_LIBRARY} INTERFACE "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>"
 182                                                             $<INSTALL_INTERFACE:include>)
 183 target_include_directories(${CDS_STATIC_LIBRARY} INTERFACE "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>"
 184                                                             $<INSTALL_INTERFACE:include>)
 185 target_compile_options(${CDS_SHARED_LIBRARY} PUBLIC "${LIBCDS_PUBLIC_CXX_FLAGS}")
 186 target_compile_options(${CDS_STATIC_LIBRARY} PUBLIC "${LIBCDS_PUBLIC_CXX_FLAGS}")
 187 target_compile_options(${CDS_SHARED_LIBRARY} PRIVATE "${LIBCDS_PRIVATE_CXX_FLAGS}")
 188 target_compile_options(${CDS_STATIC_LIBRARY} PRIVATE "${LIBCDS_PRIVATE_CXX_FLAGS}")
 189
 190 install(TARGETS ${CDS_SHARED_LIBRARY} EXPORT LibCDSConfig LIBRARY DESTINATION lib${LIB_SUFFIX} COMPONENT ${LIBRARIES_COMPONENT} NAMELINK_SKIP)
 191 install(TARGETS ${CDS_SHARED_LIBRARY} EXPORT LibCDSConfig LIBRARY DESTINATION lib${LIB_SUFFIX} COMPONENT ${HEADERS_COMPONENT} NAMELINK_ONLY)
 192 install(TARGETS ${CDS_STATIC_LIBRARY} EXPORT LibCDSConfig DESTINATION lib${LIB_SUFFIX} COMPONENT ${LIBRARIES_COMPONENT})
 193 install(EXPORT LibCDSConfig FILE LibCDSConfig.cmake NAMESPACE LibCDS:: DESTINATION lib/cmake/LibCDS)
 194 install(DIRECTORY ${PROJECT_SOURCE_DIR}/cds DESTINATION include COMPONENT ${HEADERS_COMPONENT})
 195
 196 if(WITH_TESTS)
 197     enable_testing()
 198     add_subdirectory(${PROJECT_SOURCE_DIR}/test)
 199     message(STATUS "Build tests: activated")
 200 endif(WITH_TESTS)
 201
 202 ### FOR PACKAGING in RPM, TGZ, DEB, NSYS...###############################################################################
 203 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 204 set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
 205 set(CPACK_PACKAGE_CONTACT "Max Khizhinsky <libcds-user@lists.sourceforge.net>")
 206 set(CPACK_PACKAGE_RELEASE 1)
 207 set(CPACK_PACKAGE_INSTALL_DIRECTORY "cds")
 208 set(CPACK_PACKAGE_DESCRIPTION_FILE "${PROJECT_SOURCE_DIR}/build/cmake/description.txt")
 209 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Library of concurrent data structures")
 210 set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_PACKAGE_RELEASE}")
 211 set(DEPLOY_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}")
 212
 213 # TGZ specific
 214 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
 215
 216 # RPM specific
 217 set(CPACK_RPM_COMPONENT_INSTALL ON)
 218 set(CPACK_RPM_PACKAGE_RELEASE ${CPACK_PACKAGE_RELEASE})
 219 set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh")
 220 set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh")
 221 set(CPACK_RPM_PACKAGE_URL https://github.com/khizmax/libcds)
 222 set(CPACK_RPM_PACKAGE_LICENSE GPL)
 223 set(CPACK_RPM_PACKAGE_GROUP "System Environment/Base")
 224 set(CPACK_RPM_PACKAGE_REQUIRES "boost >= 1.50")
 225 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION ${CPACK_PACKAGING_INSTALL_PREFIX})
 226 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION /usr/local)
 227 set(CPACK_RPM_devel_PACKAGE_REQUIRES "boost >= 1.50, cds-lib = ${PROJECT_VERSION}")
 228
 229 # DEB specific
 230 set(CPACK_DEB_COMPONENT_INSTALL ON)
 231 set(CPACK_DEBIAN_PACKAGE_DEPENDS "boost (>= 1.50)")
 232 set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://github.com/khizmax/libcds")
 233 set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh;;${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh;")
 234
 235 # NSYS specific
 236 set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
 237 set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_NAME}")
 238 set(CPACK_NSIS_CONTACT ${CPACK_PACKAGE_CONTACT})
 239 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 240 set(CPACK_NSIS_MODIFY_PATH ON)
 241
 242 # Components grouping for Mac OS X and Windows installers
 243 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_GROUP "Runtime")
 244 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_GROUP "Development")
 245 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_DISPLAY_NAME "Libraries")
 246 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DISPLAY_NAME "C++ Headers")
 247 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DEPENDS ${LIBRARIES_COMPONENT})
 248 set(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All of the tools you'll ever need to develop lock-free oriented software with libcds")
 249 set(CPACK_COMPONENT_GROUP_RUNTIME_DESCRIPTION "Only libcds library for runtime")
 250
 251 include(CPack)