CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2 cmake_policy(SET CMP0016 NEW)
   3
   4 project(cds)
   5
   6 set(PROJECT_VERSION 2.1.0)
   7
   8 # Options
   9 option(WITH_TESTS "Build unit tests" OFF)
  10 option(WITH_TESTS_COVERAGE "Analyze test coverage using gcov (only for gcc)" OFF)
  11 option(WITH_BOOST_ATOMIC "Use boost atomics (only for boost >= 1.54)" OFF)
  12
  13 find_package(Threads REQUIRED)
  14 find_package(Boost 1.50 COMPONENTS system thread REQUIRED)
  15
  16 include_directories(${Boost_INCLUDE_DIRS})
  17
  18 if(WITH_BOOST_ATOMIC)
  19   if(${Boost_MINOR_VERSION} GREATER 53)
  20     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCDS_USE_BOOST_ATOMIC")
  21     message(STATUS "Boost version allows using of boost.atomic: activated")
  22   endif()
  23 endif(WITH_BOOST_ATOMIC)
  24
  25 if(WITH_TESTS_COVERAGE)
  26   if(CMAKE_COMPILER_IS_GNUCXX)
  27     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  28     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
  29     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  30     message(STATUS "Test coverage analysis: activated")
  31   else()
  32         message(WARNING "Compiler is not GNU gcc! Test coverage couldn't be analyzed")
  33   endif()
  34 endif(WITH_TESTS_COVERAGE)
  35
  36 set(CDS_SHARED_LIBRARY ${PROJECT_NAME})
  37 set(CDS_STATIC_LIBRARY ${PROJECT_NAME}-s)
  38
  39 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  40 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  41
  42 set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  43 set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  44
  45 if(NOT CMAKE_BUILD_TYPE)
  46   set(CMAKE_BUILD_TYPE Debug CACHE STRING "Default build type to Debug" FORCE)
  47 endif()
  48
  49 message("Build type -- ${CMAKE_BUILD_TYPE}")
  50
  51 if(CMAKE_COMPILER_IS_GNUCXX)
  52   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
  53   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Wno-unused-parameter -pedantic -fno-strict-aliasing")
  54 endif()
  55
  56 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_DEBUG")
  57
  58 include_directories(${CMAKE_SOURCE_DIR})
  59
  60 # Component names for separate distribution in rpms, debs etc.
  61 set(LIBRARIES_COMPONENT lib)
  62 set(HEADERS_COMPONENT devel)
  63
  64 set(SOURCES src/hp_gc.cpp
  65             src/init.cpp
  66             src/dhp_gc.cpp
  67             src/urcu_gp.cpp
  68             src/urcu_sh.cpp
  69             src/michael_heap.cpp
  70             src/topology_hpux.cpp
  71             src/topology_linux.cpp
  72             src/topology_osx.cpp
  73             src/dllmain.cpp)
  74
  75 add_library(${CDS_SHARED_LIBRARY} SHARED ${SOURCES})
  76 add_library(${CDS_STATIC_LIBRARY} STATIC ${SOURCES})
  77 target_link_libraries(${CDS_SHARED_LIBRARY} PRIVATE ${Boost_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  78 target_link_libraries(${CDS_STATIC_LIBRARY} PRIVATE ${Boost_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  79
  80 install(TARGETS ${CDS_SHARED_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
  81 install(TARGETS ${CDS_STATIC_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
  82 install(DIRECTORY ${CMAKE_SOURCE_DIR}/cds DESTINATION include COMPONENT ${HEADERS_COMPONENT})
  83
  84 if(WITH_TESTS)
  85   enable_testing()
  86   add_subdirectory(${CMAKE_SOURCE_DIR}/tests)
  87   message(STATUS "Build tests: activated")
  88 endif(WITH_TESTS)
  89
  90 ### FOR PACKAGING in RPM, TGZ, DEB, NSYS...###############################################################################
  91 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  92 set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
  93 set(CPACK_PACKAGE_CONTACT "Max Khizhinsky <libcds-user@lists.sourceforge.net>")
  94 set(CPACK_PACKAGE_RELEASE 1)
  95 set(CPACK_PACKAGE_INSTALL_DIRECTORY "cds")
  96 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/build/cmake/description.txt")
  97 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Library of concurrent data structures")
  98 set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_PACKAGE_RELEASE}")
  99 set(DEPLOY_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}")
 100
 101 # TGZ specific
 102 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
 103
 104 # RPM specific
 105 set(CPACK_RPM_COMPONENT_INSTALL ON)
 106 set(CPACK_RPM_PACKAGE_RELEASE ${CPACK_PACKAGE_RELEASE})
 107 set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/build/cmake/post_install_script.sh")
 108 set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/build/cmake/post_uninstall_script.sh")
 109 set(CPACK_RPM_PACKAGE_URL https://github.com/khizmax/libcds)
 110 set(CPACK_RPM_PACKAGE_LICENSE GPL)
 111 set(CPACK_RPM_PACKAGE_GROUP "System Environment/Base")
 112 set(CPACK_RPM_PACKAGE_REQUIRES "boost >= 1.50")
 113 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION ${CPACK_PACKAGING_INSTALL_PREFIX})
 114 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION /usr/local)
 115 set(CPACK_RPM_devel_PACKAGE_REQUIRES "boost >= 1.50, cds-lib = ${PROJECT_VERSION}")
 116
 117 # DEB specific
 118 set(CPACK_DEB_COMPONENT_INSTALL ON)
 119 set(CPACK_DEBIAN_PACKAGE_DEPENDS "boost (>= 1.50)")
 120 set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://github.com/khizmax/libcds")
 121 set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${CMAKE_SOURCE_DIR}/build/cmake/post_install_script.sh;;${CMAKE_SOURCE_DIR}/build/cmake/post_uninstall_script.sh;" )
 122
 123 # NSYS specific
 124 set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
 125 set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_NAME}")
 126 set(CPACK_NSIS_CONTACT ${CPACK_PACKAGE_CONTACT})
 127 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 128 set(CPACK_NSIS_MODIFY_PATH ON)
 129
 130 # Components grouping for Mac OS X and Windows installers
 131 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_GROUP "Runtime")
 132 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_GROUP "Development")
 133 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_DISPLAY_NAME "Libraries")
 134 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DISPLAY_NAME "C++ Headers")
 135 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DEPENDS ${LIBRARIES_COMPONENT})
 136 set(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All of the tools you'll ever need to develop lock-free oriented software with libcds")
 137 set(CPACK_COMPONENT_GROUP_RUNTIME_DESCRIPTION "Only libcds library for runtime")
 138
 139 include(CPack)