CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2 cmake_policy(SET CMP0016 NEW)
   3
   4 project(cds)
   5
   6 set(PROJECT_VERSION 2.2.0)
   7
   8 # Options
   9 option(WITH_TESTS "Build unit tests" OFF)
  10 option(WITH_TESTS_COVERAGE "Analyze test coverage using gcov (only for gcc)" OFF)
  11 option(WITH_BOOST_ATOMIC "Use boost atomics (only for boost >= 1.54)" OFF)
  12 option(WITH_ASAN "Build AddressSantinizer instrumented code" OFF)
  13 option(WITH_TSAN "Build ThreadSantinizer instrumented code" OFF)
  14
  15 find_package(Threads REQUIRED)
  16 find_package(Boost 1.50 COMPONENTS system thread REQUIRED)
  17
  18 include_directories(${Boost_INCLUDE_DIRS})
  19
  20 if(WITH_BOOST_ATOMIC)
  21   if(${Boost_MINOR_VERSION} GREATER 53)
  22     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCDS_USE_BOOST_ATOMIC")
  23     message(STATUS "Boost version allows using of boost.atomic: activated")
  24   endif()
  25 endif(WITH_BOOST_ATOMIC)
  26
  27 if(WITH_ASAN)
  28   if(CMAKE_COMPILER_IS_GNUCXX)
  29     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=address -g -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  30     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O1 -fsanitize=address -g -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  31     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address -pie")
  32   else()
  33     message(WARNING "Compiler does not support AddressSanitizer")
  34   endif()
  35 endif(WITH_ASAN)
  36
  37 if(WITH_TSAN)
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  40     set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  41     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -pie")
  42   else()
  43     message(WARNING "Compiler does not support ThreadSanitizer")
  44   endif()
  45 endif(WITH_TSAN)
  46
  47 if(WITH_TESTS_COVERAGE)
  48   if(CMAKE_COMPILER_IS_GNUCXX)
  49     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  50     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
  51     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  52     message(STATUS "Test coverage analysis: activated")
  53   else()
  54         message(WARNING "Compiler is not GNU gcc! Test coverage couldn't be analyzed")
  55   endif()
  56 endif(WITH_TESTS_COVERAGE)
  57
  58 set(CDS_SHARED_LIBRARY ${PROJECT_NAME})
  59 set(CDS_STATIC_LIBRARY ${PROJECT_NAME}-s)
  60
  61 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  62 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  63
  64 if(CDS_BIN_DIR)
  65     set(EXECUTABLE_OUTPUT_PATH ${CDS_BIN_DIR})
  66     set(LIBRARY_OUTPUT_PATH ${CDS_BIN_DIR})
  67 else()
  68     set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  69     set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  70 endif()
  71 message(STATUS "Binary output path: ${EXECUTABLE_OUTPUT_PATH}")
  72
  73 if(NOT CMAKE_BUILD_TYPE)
  74   set(CMAKE_BUILD_TYPE Debug CACHE STRING "Default build type to Debug" FORCE)
  75 endif()
  76
  77 if(CMAKE_COMPILER_IS_GNUCXX)
  78   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
  79   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -pedantic -fno-strict-aliasing")
  80 # gcc 4.8: disable noise -Wunused-local-typedefs
  81   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-local-typedefs -Wno-unused-parameter")
  82 endif()
  83
  84 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_DEBUG")
  85
  86 message("Build type -- ${CMAKE_BUILD_TYPE}")
  87 message("Compiler version: ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}")
  88 if (CMAKE_BUILD_TYPE STREQUAL "DEBUG")
  89   message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
  90 else()
  91   message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
  92 endif()
  93
  94 include_directories(${PROJECT_SOURCE_DIR})
  95
  96 # Component names for separate distribution in rpms, debs etc.
  97 set(LIBRARIES_COMPONENT lib)
  98 set(HEADERS_COMPONENT devel)
  99
 100 set(SOURCES src/hp_gc.cpp
 101             src/init.cpp
 102             src/dhp_gc.cpp
 103             src/urcu_gp.cpp
 104             src/urcu_sh.cpp
 105             src/michael_heap.cpp
 106             src/topology_hpux.cpp
 107             src/topology_linux.cpp
 108             src/topology_osx.cpp
 109             src/dllmain.cpp)
 110
 111 add_library(${CDS_SHARED_LIBRARY} SHARED ${SOURCES})
 112 set_target_properties( ${CDS_SHARED_LIBRARY} PROPERTIES VERSION ${PROJECT_VERSION})
 113 add_library(${CDS_STATIC_LIBRARY} STATIC ${SOURCES})
 114 target_link_libraries(${CDS_SHARED_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 115 target_link_libraries(${CDS_STATIC_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 116
 117 install(TARGETS ${CDS_SHARED_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
 118 install(TARGETS ${CDS_STATIC_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
 119 install(DIRECTORY ${PROJECT_SOURCE_DIR}/cds DESTINATION include COMPONENT ${HEADERS_COMPONENT})
 120
 121 if(WITH_TESTS)
 122   enable_testing()
 123   add_subdirectory(${PROJECT_SOURCE_DIR}/test)
 124   message(STATUS "Build tests: activated")
 125 endif(WITH_TESTS)
 126
 127 ### FOR PACKAGING in RPM, TGZ, DEB, NSYS...###############################################################################
 128 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 129 set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
 130 set(CPACK_PACKAGE_CONTACT "Max Khizhinsky <libcds-user@lists.sourceforge.net>")
 131 set(CPACK_PACKAGE_RELEASE 1)
 132 set(CPACK_PACKAGE_INSTALL_DIRECTORY "cds")
 133 set(CPACK_PACKAGE_DESCRIPTION_FILE "${PROJECT_SOURCE_DIR}/build/cmake/description.txt")
 134 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Library of concurrent data structures")
 135 set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_PACKAGE_RELEASE}")
 136 set(DEPLOY_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}")
 137
 138 # TGZ specific
 139 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
 140
 141 # RPM specific
 142 set(CPACK_RPM_COMPONENT_INSTALL ON)
 143 set(CPACK_RPM_PACKAGE_RELEASE ${CPACK_PACKAGE_RELEASE})
 144 set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh")
 145 set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh")
 146 set(CPACK_RPM_PACKAGE_URL https://github.com/khizmax/libcds)
 147 set(CPACK_RPM_PACKAGE_LICENSE GPL)
 148 set(CPACK_RPM_PACKAGE_GROUP "System Environment/Base")
 149 set(CPACK_RPM_PACKAGE_REQUIRES "boost >= 1.50")
 150 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION ${CPACK_PACKAGING_INSTALL_PREFIX})
 151 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION /usr/local)
 152 set(CPACK_RPM_devel_PACKAGE_REQUIRES "boost >= 1.50, cds-lib = ${PROJECT_VERSION}")
 153
 154 # DEB specific
 155 set(CPACK_DEB_COMPONENT_INSTALL ON)
 156 set(CPACK_DEBIAN_PACKAGE_DEPENDS "boost (>= 1.50)")
 157 set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://github.com/khizmax/libcds")
 158 set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh;;${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh;" )
 159
 160 # NSYS specific
 161 set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
 162 set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_NAME}")
 163 set(CPACK_NSIS_CONTACT ${CPACK_PACKAGE_CONTACT})
 164 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 165 set(CPACK_NSIS_MODIFY_PATH ON)
 166
 167 # Components grouping for Mac OS X and Windows installers
 168 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_GROUP "Runtime")
 169 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_GROUP "Development")
 170 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_DISPLAY_NAME "Libraries")
 171 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DISPLAY_NAME "C++ Headers")
 172 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DEPENDS ${LIBRARIES_COMPONENT})
 173 set(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All of the tools you'll ever need to develop lock-free oriented software with libcds")
 174 set(CPACK_COMPONENT_GROUP_RUNTIME_DESCRIPTION "Only libcds library for runtime")
 175
 176 include(CPack)