CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2
   3 cmake_policy(SET CMP0016 NEW)
   4 if(POLICY CMP0042)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/build/cmake ${CMAKE_MODULE_PATH})
   9 include(TargetArch)
  10
  11 project(cds)
  12
  13 set(PROJECT_VERSION 2.3.0)
  14
  15 # Options
  16 option(WITH_TESTS "Build unit tests" OFF)
  17 option(WITH_TESTS_COVERAGE "Analyze test coverage using gcov (only for gcc)" OFF)
  18 option(WITH_BOOST_ATOMIC "Use boost atomics (only for boost >= 1.54)" OFF)
  19 option(WITH_ASAN "Build ASan+UBSan instrumented code" OFF)
  20 option(WITH_TSAN "Build TSan instrumented code" OFF)
  21 set(CMAKE_TARGET_ARCHITECTURE "" CACHE string "Target build architecture")
  22
  23 find_package(Threads)
  24
  25 if(TARGET boost::system AND TARGET boost::thread)
  26     link_libraries(boost::system boost::thread)
  27 else()
  28     find_package(Boost 1.50 COMPONENTS system thread)
  29 endif()
  30
  31 include_directories(${Boost_INCLUDE_DIRS})
  32
  33 if(NOT CMAKE_TARGET_ARCHITECTURE)
  34     target_architecture(CMAKE_TARGET_ARCHITECTURE)
  35 endif()
  36
  37 if(WITH_BOOST_ATOMIC)
  38     if(Boost_FOUND)
  39         if(${Boost_MINOR_VERSION} GREATER 53)
  40             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCDS_USE_BOOST_ATOMIC")
  41             message(STATUS "Boost version allows using of boost.atomic: activated")
  42         endif()
  43     else()
  44         if(TARGET boost::atomic)
  45             link_libraries(boost::atomic)
  46         endif()
  47     endif()
  48 endif(WITH_BOOST_ATOMIC)
  49
  50 if(WITH_ASAN)
  51     if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  52         set(CMAKE_CXX_FLAGS_DEBUG "-D_DEBUG")
  53         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG")
  54         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=address,undefined -g -DCDS_ADDRESS_SANITIZER_ENABLED -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  55         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O1 -fsanitize=address,undefined -g -DCDS_ASAN_ENABLED -fno-omit-frame-pointer -fno-optimize-sibling-calls")
  56         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,undefined -pie")
  57     else()
  58         message(WARNING "Compiler does not support AddressSanitizer")
  59     endif()
  60 endif(WITH_ASAN)
  61
  62 if(WITH_TSAN)
  63     if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  64         set(CMAKE_CXX_FLAGS_DEBUG "-D_DEBUG")
  65         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG")
  66         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  67         set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -O1 -fPIC -fsanitize=thread -g -DCDS_THREAD_SANITIZER_ENABLED -fno-omit-frame-pointer")
  68         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -pie")
  69     else()
  70         message(WARNING "Compiler does not support ThreadSanitizer")
  71     endif()
  72 endif(WITH_TSAN)
  73
  74 if(WITH_TESTS_COVERAGE)
  75     if(CMAKE_COMPILER_IS_GNUCXX)
  76         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  77         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
  78         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  79         message(STATUS "Test coverage analysis: activated")
  80     else()
  81         message(WARNING "Compiler is not GNU gcc! Test coverage couldn't be analyzed")
  82     endif()
  83 endif(WITH_TESTS_COVERAGE)
  84
  85 set(CDS_SHARED_LIBRARY ${PROJECT_NAME})
  86 set(CDS_STATIC_LIBRARY ${PROJECT_NAME}-s)
  87
  88 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  89 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  90
  91 if(CDS_BIN_DIR)
  92     set(EXECUTABLE_OUTPUT_PATH ${CDS_BIN_DIR})
  93     set(LIBRARY_OUTPUT_PATH ${CDS_BIN_DIR})
  94 else()
  95     set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  96     set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  97 endif()
  98 message(STATUS "Binary output path: ${EXECUTABLE_OUTPUT_PATH}")
  99
 100 if(NOT CMAKE_BUILD_TYPE)
 101     set(CMAKE_BUILD_TYPE Debug CACHE STRING "Default build type to Debug" FORCE)
 102 endif()
 103
 104 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 105     string(REGEX MATCHALL "-std=[^ ]+" cxx_std_found ${CMAKE_CXX_FLAGS} "dummy@rg")
 106     if(cxx_std_found)
 107         message("C++ std: ${cxx_std_found}")
 108     else()
 109         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 110         message("C++ std: -std=c++11 (default)")
 111     endif()
 112
 113     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -pedantic -fno-strict-aliasing")
 114
 115     if(CMAKE_TARGET_ARCHITECTURE STREQUAL "x86_64")
 116         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mcx16")
 117         set(LIB_SUFFIX "64")
 118
 119         # GCC-7: 128-bit atomics support is implemented via libatomic on amd64
 120         #        see https://gcc.gnu.org/ml/gcc/2017-01/msg00167.html
 121         # Maybe, it will be changed in future
 122         if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7.0.0" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0.0")
 123             set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -latomic")
 124         endif()
 125     endif()
 126
 127     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0.0")
 128         #   gcc 4.8 - 6: disable noise -Wunused-local-typedefs
 129         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-local-typedefs")
 130     endif()
 131 endif()
 132
 133 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_DEBUG")
 134
 135 message("Build type -- ${CMAKE_BUILD_TYPE}")
 136 message("Compiler version: ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}")
 137 message("System: ${CMAKE_SYSTEM_NAME} version: ${CMAKE_SYSTEM_VERSION}")
 138 message("Target architecture: ${CMAKE_TARGET_ARCHITECTURE}")
 139 if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 140     message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
 141 else()
 142     message("Compiler flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
 143 endif()
 144 message("Exe flags: ${CMAKE_EXE_LINKER_FLAGS}")
 145
 146 if(Boost_FOUND)
 147     message("Boost: ${Boost_LIB_VERSION} in ${Boost_INCLUDE_DIRS}, lib ${Boost_LIBRARY_DIRS}")
 148 else()
 149     message("Boost: Using CMake-fied boost")
 150 endif()
 151
 152 if(CMAKE_SYSTEM_NAME STREQUAL "AIX")
 153     set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> -q -c ${CMAKE_STATIC_LINKER_FLAGS} -o <TARGET> <OBJECTS>")
 154 endif()
 155
 156 include_directories(${PROJECT_SOURCE_DIR})
 157
 158 # Component names for separate distribution in rpms, debs etc.
 159 set(LIBRARIES_COMPONENT lib)
 160 set(HEADERS_COMPONENT devel)
 161
 162 set(SOURCES src/init.cpp
 163             src/hp.cpp
 164             src/dhp.cpp
 165             src/urcu_gp.cpp
 166             src/urcu_sh.cpp
 167             src/thread_data.cpp
 168             src/topology_hpux.cpp
 169             src/topology_linux.cpp
 170             src/topology_osx.cpp
 171             src/dllmain.cpp)
 172
 173 add_library(${CDS_SHARED_LIBRARY} SHARED ${SOURCES})
 174 set_target_properties(${CDS_SHARED_LIBRARY} PROPERTIES VERSION ${PROJECT_VERSION}
 175         DEBUG_POSTFIX "_d")
 176 add_library(${CDS_STATIC_LIBRARY} STATIC ${SOURCES})
 177 set_target_properties(${CDS_STATIC_LIBRARY} PROPERTIES DEBUG_POSTFIX "_d")
 178 target_link_libraries(${CDS_SHARED_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 179 target_link_libraries(${CDS_STATIC_LIBRARY} PRIVATE ${CMAKE_THREAD_LIBS_INIT})
 180
 181 install(TARGETS ${CDS_SHARED_LIBRARY} LIBRARY DESTINATION lib${LIB_SUFFIX} COMPONENT ${LIBRARIES_COMPONENT} NAMELINK_SKIP)
 182 install(TARGETS ${CDS_SHARED_LIBRARY} LIBRARY DESTINATION lib${LIB_SUFFIX} COMPONENT ${HEADERS_COMPONENT} NAMELINK_ONLY)
 183 install(TARGETS ${CDS_STATIC_LIBRARY} DESTINATION lib${LIB_SUFFIX} COMPONENT ${LIBRARIES_COMPONENT})
 184 install(DIRECTORY ${PROJECT_SOURCE_DIR}/cds DESTINATION include COMPONENT ${HEADERS_COMPONENT})
 185
 186 if(WITH_TESTS)
 187     enable_testing()
 188     add_subdirectory(${PROJECT_SOURCE_DIR}/test)
 189     message(STATUS "Build tests: activated")
 190 endif(WITH_TESTS)
 191
 192 ### FOR PACKAGING in RPM, TGZ, DEB, NSYS...###############################################################################
 193 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 194 set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
 195 set(CPACK_PACKAGE_CONTACT "Max Khizhinsky <libcds-user@lists.sourceforge.net>")
 196 set(CPACK_PACKAGE_RELEASE 1)
 197 set(CPACK_PACKAGE_INSTALL_DIRECTORY "cds")
 198 set(CPACK_PACKAGE_DESCRIPTION_FILE "${PROJECT_SOURCE_DIR}/build/cmake/description.txt")
 199 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Library of concurrent data structures")
 200 set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_PACKAGE_RELEASE}")
 201 set(DEPLOY_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}")
 202
 203 # TGZ specific
 204 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
 205
 206 # RPM specific
 207 set(CPACK_RPM_COMPONENT_INSTALL ON)
 208 set(CPACK_RPM_PACKAGE_RELEASE ${CPACK_PACKAGE_RELEASE})
 209 set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh")
 210 set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh")
 211 set(CPACK_RPM_PACKAGE_URL https://github.com/khizmax/libcds)
 212 set(CPACK_RPM_PACKAGE_LICENSE GPL)
 213 set(CPACK_RPM_PACKAGE_GROUP "System Environment/Base")
 214 set(CPACK_RPM_PACKAGE_REQUIRES "boost >= 1.50")
 215 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION ${CPACK_PACKAGING_INSTALL_PREFIX})
 216 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION /usr/local)
 217 set(CPACK_RPM_devel_PACKAGE_REQUIRES "boost >= 1.50, cds-lib = ${PROJECT_VERSION}")
 218
 219 # DEB specific
 220 set(CPACK_DEB_COMPONENT_INSTALL ON)
 221 set(CPACK_DEBIAN_PACKAGE_DEPENDS "boost (>= 1.50)")
 222 set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://github.com/khizmax/libcds")
 223 set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${PROJECT_SOURCE_DIR}/build/cmake/post_install_script.sh;;${PROJECT_SOURCE_DIR}/build/cmake/post_uninstall_script.sh;")
 224
 225 # NSYS specific
 226 set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
 227 set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_NAME}")
 228 set(CPACK_NSIS_CONTACT ${CPACK_PACKAGE_CONTACT})
 229 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 230 set(CPACK_NSIS_MODIFY_PATH ON)
 231
 232 # Components grouping for Mac OS X and Windows installers
 233 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_GROUP "Runtime")
 234 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_GROUP "Development")
 235 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_DISPLAY_NAME "Libraries")
 236 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DISPLAY_NAME "C++ Headers")
 237 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DEPENDS ${LIBRARIES_COMPONENT})
 238 set(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All of the tools you'll ever need to develop lock-free oriented software with libcds")
 239 set(CPACK_COMPONENT_GROUP_RUNTIME_DESCRIPTION "Only libcds library for runtime")
 240
 241 include(CPack)