CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2 cmake_policy(SET CMP0016 NEW)
   3
   4 project(cds)
   5
   6 set(PROJECT_VERSION 2.2.0)
   7
   8 # Options
   9 option(WITH_TESTS "Build unit tests" OFF)
  10 option(WITH_TESTS_COVERAGE "Analyze test coverage using gcov (only for gcc)" OFF)
  11 option(WITH_BOOST_ATOMIC "Use boost atomics (only for boost >= 1.54)" OFF)
  12
  13 find_package(Threads REQUIRED)
  14 find_package(Boost 1.50 COMPONENTS system thread REQUIRED)
  15
  16 include_directories(${Boost_INCLUDE_DIRS})
  17
  18 if(WITH_BOOST_ATOMIC)
  19   if(${Boost_MINOR_VERSION} GREATER 53)
  20     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCDS_USE_BOOST_ATOMIC")
  21     message(STATUS "Boost version allows using of boost.atomic: activated")
  22   endif()
  23 endif(WITH_BOOST_ATOMIC)
  24
  25 if(WITH_TESTS_COVERAGE)
  26   if(CMAKE_COMPILER_IS_GNUCXX)
  27     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
  28     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
  29     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
  30     message(STATUS "Test coverage analysis: activated")
  31   else()
  32         message(WARNING "Compiler is not GNU gcc! Test coverage couldn't be analyzed")
  33   endif()
  34 endif(WITH_TESTS_COVERAGE)
  35
  36 set(CDS_SHARED_LIBRARY ${PROJECT_NAME})
  37 set(CDS_STATIC_LIBRARY ${PROJECT_NAME}-s)
  38
  39 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  40 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  41
  42 set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  43 set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
  44
  45 if(NOT CMAKE_BUILD_TYPE)
  46   set(CMAKE_BUILD_TYPE Debug CACHE STRING "Default build type to Debug" FORCE)
  47 endif()
  48
  49 message("Build type -- ${CMAKE_BUILD_TYPE}")
  50
  51 if(CMAKE_COMPILER_IS_GNUCXX)
  52   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
  53   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -pedantic -fno-strict-aliasing")
  54 # gcc 4.8: disable noise -Wunused-local-typedefs
  55   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-local-typedefs -Wno-unused-parameter")
  56 endif()
  57
  58 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_DEBUG")
  59
  60 include_directories(${CMAKE_SOURCE_DIR})
  61
  62 # Component names for separate distribution in rpms, debs etc.
  63 set(LIBRARIES_COMPONENT lib)
  64 set(HEADERS_COMPONENT devel)
  65
  66 set(SOURCES src/hp_gc.cpp
  67             src/init.cpp
  68             src/dhp_gc.cpp
  69             src/urcu_gp.cpp
  70             src/urcu_sh.cpp
  71             src/michael_heap.cpp
  72             src/topology_hpux.cpp
  73             src/topology_linux.cpp
  74             src/topology_osx.cpp
  75             src/dllmain.cpp)
  76
  77 add_library(${CDS_SHARED_LIBRARY} SHARED ${SOURCES})
  78 add_library(${CDS_STATIC_LIBRARY} STATIC ${SOURCES})
  79 target_link_libraries(${CDS_SHARED_LIBRARY} PRIVATE ${Boost_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  80 target_link_libraries(${CDS_STATIC_LIBRARY} PRIVATE ${Boost_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  81
  82 install(TARGETS ${CDS_SHARED_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
  83 install(TARGETS ${CDS_STATIC_LIBRARY} DESTINATION lib COMPONENT ${LIBRARIES_COMPONENT})
  84 install(DIRECTORY ${CMAKE_SOURCE_DIR}/cds DESTINATION include COMPONENT ${HEADERS_COMPONENT})
  85
  86 if(WITH_TESTS)
  87   enable_testing()
  88   add_subdirectory(${CMAKE_SOURCE_DIR}/tests)
  89   message(STATUS "Build tests: activated")
  90 endif(WITH_TESTS)
  91
  92 ### FOR PACKAGING in RPM, TGZ, DEB, NSYS...###############################################################################
  93 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  94 set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
  95 set(CPACK_PACKAGE_CONTACT "Max Khizhinsky <libcds-user@lists.sourceforge.net>")
  96 set(CPACK_PACKAGE_RELEASE 1)
  97 set(CPACK_PACKAGE_INSTALL_DIRECTORY "cds")
  98 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/build/cmake/description.txt")
  99 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Library of concurrent data structures")
 100 set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_PACKAGE_RELEASE}")
 101 set(DEPLOY_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}")
 102
 103 # TGZ specific
 104 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
 105
 106 # RPM specific
 107 set(CPACK_RPM_COMPONENT_INSTALL ON)
 108 set(CPACK_RPM_PACKAGE_RELEASE ${CPACK_PACKAGE_RELEASE})
 109 set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/build/cmake/post_install_script.sh")
 110 set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/build/cmake/post_uninstall_script.sh")
 111 set(CPACK_RPM_PACKAGE_URL https://github.com/khizmax/libcds)
 112 set(CPACK_RPM_PACKAGE_LICENSE GPL)
 113 set(CPACK_RPM_PACKAGE_GROUP "System Environment/Base")
 114 set(CPACK_RPM_PACKAGE_REQUIRES "boost >= 1.50")
 115 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION ${CPACK_PACKAGING_INSTALL_PREFIX})
 116 set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION /usr/local)
 117 set(CPACK_RPM_devel_PACKAGE_REQUIRES "boost >= 1.50, cds-lib = ${PROJECT_VERSION}")
 118
 119 # DEB specific
 120 set(CPACK_DEB_COMPONENT_INSTALL ON)
 121 set(CPACK_DEBIAN_PACKAGE_DEPENDS "boost (>= 1.50)")
 122 set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://github.com/khizmax/libcds")
 123 set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${CMAKE_SOURCE_DIR}/build/cmake/post_install_script.sh;;${CMAKE_SOURCE_DIR}/build/cmake/post_uninstall_script.sh;" )
 124
 125 # NSYS specific
 126 set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
 127 set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_NAME}")
 128 set(CPACK_NSIS_CONTACT ${CPACK_PACKAGE_CONTACT})
 129 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 130 set(CPACK_NSIS_MODIFY_PATH ON)
 131
 132 # Components grouping for Mac OS X and Windows installers
 133 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_GROUP "Runtime")
 134 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_GROUP "Development")
 135 set(CPACK_COMPONENT_${LIBRARIES_COMPONENT}_DISPLAY_NAME "Libraries")
 136 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DISPLAY_NAME "C++ Headers")
 137 set(CPACK_COMPONENT_${HEADERS_COMPONENT}_DEPENDS ${LIBRARIES_COMPONENT})
 138 set(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION "All of the tools you'll ever need to develop lock-free oriented software with libcds")
 139 set(CPACK_COMPONENT_GROUP_RUNTIME_DESCRIPTION "Only libcds library for runtime")
 140
 141 include(CPack)