folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_HEADER_STDBOOL
 186 AC_C_CONST
 187 AC_C_INLINE
 188 AC_TYPE_SIZE_T
 189 AC_HEADER_TIME
 190 AC_C_VOLATILE
 191 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 192     [folly_cv_prog_cc_int128=no])
 193 if test "$folly_cv_prog_cc_int128" = "yes"; then
 194   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 195   AC_CACHE_CHECK(
 196     [for __int128 type traits],
 197     [folly_cv_prog_cc_int128traits],
 198     [AC_COMPILE_IFELSE(
 199       [AC_LANG_SOURCE([[
 200 #include <type_traits>
 201 static_assert(
 202   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 203   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 204       ]])],
 205       [folly_cv_prog_cc_int128traits=yes],
 206       [folly_cv_prog_cc_int128traits=no])
 207     ])
 208   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 209     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 210   fi
 211 fi
 212
 213 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 214
 215 AC_CACHE_CHECK(
 216   [for ifunc support],
 217   [folly_cv_prog_cc_ifunc],
 218   [AC_COMPILE_IFELSE(
 219     [AC_LANG_SOURCE[
 220       #pragma GCC diagnostic error "-Wattributes"
 221       extern "C" void (*test_ifunc(void))() { return 0; }
 222       void func() __attribute__((ifunc("test_ifunc")));]
 223     ],
 224     [folly_cv_prog_cc_ifunc=yes],
 225     [folly_cv_prog_cc_ifunc=no])])
 226
 227 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 228   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 229 fi
 230
 231 AC_CACHE_CHECK(
 232   [for final and override support],
 233   [folly_cv_c_final_override],
 234   [AC_COMPILE_IFELSE(
 235     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 236                     class D : public C { virtual void g() override {} };]],
 237     [folly_cv_c_final_override=yes],
 238     [folly_cv_c_final_override=no])])
 239
 240 if test "$folly_cv_c_final_override" = "yes"; then
 241   final_val=final
 242   override_val=override
 243 else
 244   final_val=
 245   override_val=
 246 fi
 247
 248 AC_DEFINE_UNQUOTED(
 249   [FINAL], [$final_val],
 250   [Define to "final" if the compiler supports C++11 "final"])
 251 AC_DEFINE_UNQUOTED(
 252   [OVERRIDE], [$override_val],
 253   [Define to "override" if the compiler supports C++11 "override"])
 254
 255 AC_CACHE_CHECK(
 256   [for std::this_thread::sleep_for],
 257   [folly_cv_func_this_thread_sleep_for],
 258   [AC_COMPILE_IFELSE(
 259     [AC_LANG_SOURCE[
 260       #include <thread>
 261       #include <chrono>
 262       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 263     [folly_cv_func_this_thread_sleep_for=yes],
 264     [folly_cv_func_this_thread_sleep_for=no])])
 265
 266 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 267     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 268               [Define to 1 if std::this_thread::sleep_for() is defined.])
 269 fi
 270
 271 AC_CACHE_CHECK(
 272   [for constexpr strlen],
 273   [folly_cv_func_constexpr_strlen],
 274   [AC_COMPILE_IFELSE(
 275     [AC_LANG_SOURCE[
 276       #include <cstring>
 277       static constexpr int val = strlen("foo");]],
 278     [folly_cv_func_constexpr_strlen=yes],
 279     [folly_cv_func_constexpr_strlen=no])])
 280
 281 if test "$folly_cv_func_constexpr_strlen" = yes; then
 282     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 283               [Define to 1 if strlen(3) is constexpr.])
 284 fi
 285
 286 AC_CACHE_CHECK(
 287   [for libc++],
 288   [folly_cv_lib_libcpp],
 289   [AC_COMPILE_IFELSE(
 290     [AC_LANG_SOURCE[
 291       #include <type_traits>
 292       #if !_LIBCPP_VERSION
 293       #error No libc++
 294       #endif
 295       void func() {}]
 296     ],
 297     [folly_cv_lib_libcpp=yes],
 298     [folly_cv_lib_libcpp=no])])
 299
 300 if test "$folly_cv_lib_libcpp" = yes; then
 301   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 302 fi
 303
 304 AC_CACHE_CHECK(
 305   [for c++11 atomic support without GNU Atomic library],
 306   [folly_cv_lib_libatomic],
 307   [AC_LINK_IFELSE(
 308     [AC_LANG_SOURCE[
 309       #include <atomic>
 310       int main() {
 311         struct Test { int val; };
 312         std::atomic<Test> s;
 313         s.is_lock_free();
 314       }
 315     ]],
 316     [folly_cv_lib_libatomic=yes],
 317     [folly_cv_lib_libatomic=no])])
 318
 319 if test "$folly_cv_lib_libatomic" = no; then
 320   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 321                   [Please install the GNU Atomic library])])
 322 fi
 323
 324 AC_CACHE_CHECK(
 325   [for liblinux-vdso support],
 326   [folly_cv_lib_liblinux_vdso],
 327   [AC_RUN_IFELSE(
 328     [AC_LANG_PROGRAM[
 329       #include <dlfcn.h>
 330       int main() {
 331         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 332         if (h == nullptr) {
 333           return -1;
 334         }
 335         dlclose(h);
 336         return 0;
 337       }
 338     ]],
 339     [folly_cv_lib_liblinux_vdso=yes],
 340     [folly_cv_lib_liblinux_vdso=no])])
 341
 342 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 343   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 344 fi
 345
 346 AC_CACHE_CHECK(
 347   [for usable std::is_trivially_copyable],
 348   [folly_cv_decl_std_is_trivially_copyable],
 349   [AC_COMPILE_IFELSE(
 350     [AC_LANG_SOURCE[
 351       #include <type_traits>
 352       const bool val = std::is_trivially_copyable<bool>::value;]
 353     ],
 354     [folly_cv_decl_std_is_trivially_copyable=yes],
 355     [folly_cv_decl_std_is_trivially_copyable=no])])
 356
 357 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 358   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 359             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 360              implementation.])
 361 fi
 362
 363 AC_CACHE_CHECK(
 364   [gflags namespace],
 365   [folly_cv_decl_gflags_namespace],
 366   [AC_COMPILE_IFELSE(
 367     [AC_LANG_SOURCE[
 368       #include <gflags/gflags.h>
 369       void foo() { gflags::GetArgv(); }]
 370     ],
 371     [folly_cv_decl_gflags_namespace=gflags],
 372     [AC_COMPILE_IFELSE(
 373       [AC_LANG_SOURCE[
 374         #include <gflags/gflags.h>
 375         void foo() { google::GetArgv(); }]
 376       ],
 377       [folly_cv_decl_gflags_namespace=google],
 378       [folly_cv_decl_gflags_namespace=error])])])
 379
 380 if test "$folly_cv_decl_gflags_namespace" = error; then
 381   AC_MSG_ERROR([Cannot determine gflags namespace])
 382 else
 383   AC_DEFINE_UNQUOTED(
 384     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 385     [Define to gflags namespace (usually "google" or "gflags")])
 386   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 387      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 388                [Define to 1 if the gflags namespace is not "gflags"])
 389   fi
 390 fi
 391
 392 # Figure out if we support weak symbols. If not, we will link in some null
 393 # stubs for functions that would otherwise be weak.
 394 AC_CACHE_CHECK(
 395   [for weak symbol support],
 396   [folly_cv_prog_cc_weak_symbols],
 397   [AC_LINK_IFELSE(
 398     [AC_LANG_SOURCE[
 399       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 400       int main(int argc, char** argv) {
 401           return configure_link_extern_weak_test == nullptr;
 402       }]],
 403     [folly_cv_prog_cc_weak_symbols="yes"],
 404     [folly_cv_prog_cc_weak_symbols="no"])])
 405
 406 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 407   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 408             [Define to 1 if the linker supports weak symbols.])
 409 fi
 410
 411
 412 # Figure out if we support wchar well
 413 AC_CACHE_CHECK(
 414   [for wchar support],
 415   [folly_cv_prog_cc_wchar_support],
 416   [AC_RUN_IFELSE(
 417     [AC_LANG_SOURCE[
 418       #include <cstddef>
 419       #include <cwchar>
 420
 421       int main(int argc, char** argv) {
 422         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 423       }
 424     ]],
 425     [folly_cv_prog_cc_wchar_support=yes],
 426     [folly_cv_prog_cc_wchar_support=no])])
 427
 428 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 429   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 430 fi
 431
 432 # Figure out whether the architecture supports unaligned accesses
 433 AC_CACHE_CHECK(
 434   [for unaligned access support],
 435   [folly_cv_prog_cc_unaligned_access],
 436   [AC_RUN_IFELSE(
 437     [AC_LANG_SOURCE[
 438       int main(int argc, char** argv) {
 439         char buf[64] = {0};
 440         unsigned long *ptr = (unsigned long *)(buf + 1);
 441         *ptr = 0xdeadbeef;
 442         return (*ptr & 0xff) == 0xef ? 0 : 1;
 443       }
 444     ]],
 445     [folly_cv_prog_cc_unaligned_access=yes],
 446     [folly_cv_prog_cc_unaligned_access=no])])
 447
 448 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 449   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 450 fi
 451
 452 AC_CACHE_CHECK(
 453   [for vsnprintf reporting bad format strings],
 454   [folly_cv_prog_vsnprintf_bad_format],
 455   [AC_RUN_IFELSE(
 456     [AC_LANG_SOURCE[
 457       #include <stdio.h>
 458
 459       int main(int argc, char** argv) {
 460           char buf[256];
 461           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 462       }]],
 463     [folly_cv_prog_vsnprintf_bad_format="yes"],
 464     [folly_cv_prog_vsnprintf_bad_format="no"])])
 465
 466 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 467   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 468             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 469 fi
 470
 471 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 472 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 473   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 474             [Define to 1 if we have cplus_demangle_v3_callback.])
 475 fi
 476
 477 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 478 # want to link with librt if necessary.
 479 AC_SEARCH_LIBS([clock_gettime], [rt],
 480   AC_DEFINE(
 481     [HAVE_CLOCK_GETTIME],
 482     [1],
 483     [Define to 1 if we support clock_gettime(2).]),
 484   [])
 485
 486 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 487 # want to include pthread.h if necessary.
 488 AC_CACHE_CHECK(
 489   [for pthread_atfork support],
 490   [folly_cv_prog_cc_pthread_atfork],
 491   [AC_COMPILE_IFELSE(
 492     [AC_LANG_SOURCE[
 493       #include <pthread.h>
 494       void func() {pthread_atfork(NULL, NULL, NULL);}]
 495     ],
 496     [folly_cv_prog_cc_pthread_atfork=yes],
 497     [folly_cv_prog_cc_pthread_atfork=no])])
 498
 499 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 500   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 501 fi
 502
 503 # Check for XSI-compatible strerror_r as default implementation
 504 AC_CACHE_CHECK(
 505   [for XSI style strerror_r support],
 506   [folly_cv_prog_cc_xsi_strerror_r],
 507   [AC_RUN_IFELSE(
 508     [AC_LANG_SOURCE[
 509       #include <string.h>
 510       #include <errno.h>
 511       int main(int argc, char** argv) {
 512         char buf[1024];
 513         buf[0] = 0;
 514         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 515         return ret;
 516       }
 517     ]],
 518     [folly_cv_prog_cc_xsi_strerror_r=yes],
 519     [folly_cv_prog_cc_xsi_strerror_r=no])])
 520
 521 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 522   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 523 fi
 524
 525 AC_CACHE_CHECK(
 526   [for ext/random and __gnu_cxx::sfmt19937],
 527   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 528   [AC_COMPILE_IFELSE(
 529     [AC_LANG_SOURCE[
 530       #include <ext/random>
 531       int main(int argc, char** argv) {
 532         __gnu_cxx::sfmt19937 rng;
 533         return 0;
 534       }
 535     ]],
 536     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 537     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 538
 539 AC_CACHE_CHECK(
 540   [for VLA (variable-length array) support],
 541   [folly_cv_prog_cc_have_vla],
 542   [AC_COMPILE_IFELSE(
 543     [AC_LANG_SOURCE[
 544       int main(int argc, char** argv) {
 545         unsigned size = argc;
 546         char data[size];
 547         return 0;
 548       }
 549     ]],
 550     [folly_cv_prog_cc_have_vla=yes],
 551     [folly_cv_prog_cc_have_vla=no])])
 552
 553 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 554 AC_DEFINE_UNQUOTED(
 555   [HAVE_VLA],
 556   [$have_vla],
 557   [Define to 1 if the compiler has VLA (variable-length array) support,
 558    otherwise define to 0])
 559
 560 # Checks for library functions.
 561 AC_CHECK_FUNCS([getdelim \
 562                 gettimeofday \
 563                 memmove \
 564                 memset \
 565                 pow \
 566                 strerror \
 567                 malloc_size \
 568                 malloc_usable_size \
 569                 memrchr \
 570                 pipe2 \
 571                 preadv \
 572                 pwritev \
 573               ])
 574
 575 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 576 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 577 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 578 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 579 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 580 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 581
 582 AC_ARG_ENABLE([follytestmain],
 583    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 584    [follytestmain=${enableval}], [follytestmain=no])
 585
 586 use_follytestmain=yes
 587 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 588 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 589 # Check whether we have both the library and the header
 590 have_libdwarf=no
 591 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 592 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 593
 594
 595 AC_ARG_ENABLE([mobile],
 596    AS_HELP_STRING([--enable-mobile],
 597                   [enables using main function from folly for tests]),
 598                   [mobile=${enableval}], [mobile=no])
 599 AS_IF([test "x${mobile}" = "xyes"], [
 600     AC_DEFINE([MOBILE], [1],
 601               [Define to 1 for compiler guards for mobile targets.])
 602 ])
 603
 604 # Include directory that contains "folly" so #include <folly/Foo.h> works
 605 AM_CPPFLAGS='-I$(top_srcdir)/..'
 606 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 607 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 608 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 609 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 610 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 611
 612 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 613
 614 AC_SUBST([AM_CPPFLAGS])
 615 AC_SUBST([AM_LDFLAGS])
 616
 617 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 618 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 619 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 620 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 621 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 622 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 623                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 624 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 625 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 626                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 627 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 628 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 629 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 630
 631 # remove pkg-config deps from dependent libraries
 632 # (at least for pkg-config file purposes)
 633 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 634
 635 # Output
 636 AC_CONFIG_FILES([Makefile
 637                  libfolly.pc
 638                  test/Makefile
 639                  test/function_benchmark/Makefile
 640                  experimental/Makefile
 641                  experimental/symbolizer/Makefile
 642                  init/Makefile])
 643 AC_OUTPUT