folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7
   8 m4_define([folly_libtool_current], [1])
   9
  10 # We assume all revisions are backwards incompatible.
  11 LT_VERSION=folly_libtool_current:0:0
  12 AC_SUBST(LT_VERSION)
  13
  14 AC_CONFIG_SRCDIR([Likely.h])
  15 AC_CONFIG_HEADERS([config.h])
  16 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18
  19 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  24 AX_CONFIG_FEATURE(
  25         [deprecated-assoc],
  26         [supports deprecated associative containers (hash_map/hash_set)],
  27         [HAVE_DEPRECATED_ASSOC],
  28         [Define if you want to support deprecated associative containers])
  29
  30 AC_PROG_INSTALL
  31 AM_PROG_LIBTOOL
  32
  33 AC_LANG([C++])
  34
  35 # Checks for programs.
  36 AC_PROG_CXX
  37 AC_PROG_CC
  38 AC_CXX_COMPILE_STDCXX_0X
  39
  40 # Be sure to add any -std option to CXXFLAGS before we invoke any
  41 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  42 # before we update CXXFLAGS will not be run with the same options that we use
  43 # during the real build.
  44 STD=""
  45 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  46    STD="-std=c++0x"
  47 fi
  48 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  49    STD="-std=gnu++0x"
  50 fi
  51
  52 CXXFLAGS="$STD $CXXFLAGS"
  53
  54 # Checks for libraries.
  55 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  56              [Please install google-glog library])])
  57 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  58              [Please install google-gflags library])])
  59
  60 # check for boost libs
  61 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  62               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  63 AX_BOOST_THREAD
  64 AX_BOOST_REGEX
  65 AX_BOOST_SYSTEM
  66 AX_BOOST_FILESYSTEM
  67
  68 # Checks for header files.
  69 AC_HEADER_STDC
  70 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  71
  72 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  73                 [Couldn't find double-conversion.h, please download from \
  74                 http://code.google.com/p/double-conversion/])], [])
  75 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  76              [Please install double-conversion library])])
  77
  78 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  79
  80 AC_CHECK_LIB([jemalloc], [rallocm])
  81
  82 # Checks for typedefs, structures, and compiler characteristics.
  83 AC_HEADER_STDBOOL
  84 AC_C_CONST
  85 AC_C_INLINE
  86 AC_TYPE_SIZE_T
  87 AC_HEADER_TIME
  88 AC_C_VOLATILE
  89 AC_CHECK_TYPE([__int128],
  90   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  91   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  92 AC_CHECK_TYPES([ptrdiff_t])
  93
  94 AC_CACHE_CHECK(
  95   [for ifunc support],
  96   [folly_cv_prog_cc_ifunc],
  97   [AC_COMPILE_IFELSE(
  98     [AC_LANG_SOURCE[
  99       #pragma GCC diagnostic error "-Wattributes"
 100       extern "C" void (*test_ifunc(void))() { return 0; }
 101       void func() __attribute__((ifunc("test_ifunc")));]
 102     ],
 103     [folly_cv_prog_cc_ifunc=yes],
 104     [folly_cv_prog_cc_ifunc=no])])
 105
 106 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 107   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 108 fi
 109
 110 AC_CACHE_CHECK(
 111   [for final and override support],
 112   [folly_cv_c_final_override],
 113   [AC_COMPILE_IFELSE(
 114     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 115                     class D : public C { virtual void g() override {} };]],
 116     [folly_cv_c_final_override=yes],
 117     [folly_cv_c_final_override=no])])
 118
 119 if test "$folly_cv_c_final_override" = "yes"; then
 120   final_val=final
 121   override_val=override
 122 else
 123   final_val=
 124   override_val=
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(
 128   [FINAL], [$final_val],
 129   [Define to "final" if the compiler supports C++11 "final"])
 130 AC_DEFINE_UNQUOTED(
 131   [OVERRIDE], [$override_val],
 132   [Define to "override" if the compiler supports C++11 "override"])
 133
 134 AC_CACHE_CHECK(
 135   [for std::this_thread::sleep_for],
 136   [folly_cv_func_this_thread_sleep_for],
 137   [AC_COMPILE_IFELSE(
 138     [AC_LANG_SOURCE[
 139       #include <thread>
 140       #include <chrono>
 141       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 142     [folly_cv_func_this_thread_sleep_for=yes],
 143     [folly_cv_func_this_thread_sleep_for=no])])
 144
 145 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 146     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 147               [Define to 1 if std::this_thread::sleep_for() is defined.])
 148 fi
 149
 150 AC_CACHE_CHECK(
 151   [for constexpr strlen],
 152   [folly_cv_func_constexpr_strlen],
 153   [AC_COMPILE_IFELSE(
 154     [AC_LANG_SOURCE[
 155       #include <cstring>
 156       static constexpr int val = strlen("foo");]],
 157     [folly_cv_func_constexpr_strlen=yes],
 158     [folly_cv_func_constexpr_strlen=no])])
 159
 160 if test "$folly_cv_func_constexpr_strlen" = yes; then
 161     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 162               [Define to 1 if strlen(3) is constexpr.])
 163 fi
 164
 165 AC_CACHE_CHECK(
 166   [for libc++],
 167   [folly_cv_lib_libcpp],
 168   [AC_COMPILE_IFELSE(
 169     [AC_LANG_SOURCE[
 170       #include <type_traits>
 171       #if !_LIBCPP_VERSION
 172       #error No libc++
 173       #endif
 174       void func() {}]
 175     ],
 176     [folly_cv_lib_libcpp=yes],
 177     [folly_cv_lib_libcpp=no])])
 178
 179 if test "$folly_cv_lib_libcpp" = yes; then
 180   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 181 fi
 182
 183 AC_CACHE_CHECK(
 184   [for usable std::is_trivially_copyable],
 185   [folly_cv_decl_std_is_trivially_copyable],
 186   [AC_COMPILE_IFELSE(
 187     [AC_LANG_SOURCE[
 188       #include <type_traits>
 189       const bool val = std::is_trivially_copyable<bool>::value;]
 190     ],
 191     [folly_cv_decl_std_is_trivially_copyable=yes],
 192     [folly_cv_decl_std_is_trivially_copyable=no])])
 193
 194 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 195   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 196             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 197              implementation.])
 198 fi
 199
 200 AC_CACHE_CHECK(
 201   [gflags namespace],
 202   [folly_cv_decl_gflags_namespace],
 203   [AC_COMPILE_IFELSE(
 204     [AC_LANG_SOURCE[
 205       #include <gflags/gflags.h>
 206       void foo() { gflags::GetArgv(); }]
 207     ],
 208     [folly_cv_decl_gflags_namespace=gflags],
 209     [AC_COMPILE_IFELSE(
 210       [AC_LANG_SOURCE[
 211         #include <gflags/gflags.h>
 212         void foo() { google::GetArgv(); }]
 213       ],
 214       [folly_cv_decl_gflags_namespace=google],
 215       [folly_cv_decl_gflags_namespace=error])])])
 216
 217 if test "$folly_cv_decl_gflags_namespace" = error; then
 218   AC_MSG_ERROR([Cannot determine gflags namespace])
 219 else
 220   AC_DEFINE_UNQUOTED(
 221     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 222     [Define to gflags namespace (usually "google" or "gflags")])
 223   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 224      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 225                [Define to 1 if the gflags namespace is not "gflags"])
 226   fi
 227 fi
 228
 229 # Figure out if we support weak symbols. If not, we will link in some null
 230 # stubs for functions that would otherwise be weak.
 231 AC_CACHE_CHECK(
 232   [for weak symbol support],
 233   [folly_cv_prog_cc_weak_symbols],
 234   [AC_LINK_IFELSE(
 235     [AC_LANG_SOURCE[
 236       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 237       int main(int argc, char** argv) {
 238           return configure_link_extern_weak_test == nullptr;
 239       }]],
 240     [folly_cv_prog_cc_weak_symbols="yes"],
 241     [folly_cv_prog_cc_weak_symbols="no"])])
 242
 243 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 244   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 245             [Define to 1 if the linker supports weak symbols.])
 246 fi
 247
 248 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 249 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 250   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 251             [Define to 1 if we have cplus_demangle_v3_callback.])
 252 fi
 253
 254 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 255 # want to link with librt if necessary.
 256 AC_SEARCH_LIBS([clock_gettime], [rt],
 257   AC_DEFINE(
 258     [HAVE_CLOCK_GETTIME],
 259     [1],
 260     [Define to 1 if we support clock_gettime(2).]),
 261   [])
 262
 263 # Checks for library functions.
 264 AC_CHECK_FUNCS([getdelim \
 265                 gettimeofday \
 266                 memmove \
 267                 memset \
 268                 pow \
 269                 strerror \
 270                 pthread_yield \
 271                 rallocm \
 272                 malloc_size \
 273                 malloc_usable_size \
 274                 memrchr])
 275
 276 if test "$ac_cv_func_pthread_yield" = "no"; then
 277    AC_CHECK_HEADERS([sched.h])
 278    AC_CHECK_FUNCS([sched_yield])
 279 fi
 280
 281 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [main]))
 282 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 283 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 284 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 285
 286 # Include directory that contains "folly" so #include <folly/Foo.h> works
 287 AM_CPPFLAGS='-I$(top_srcdir)/..'
 288 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 289 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 290 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 291
 292 AC_SUBST([AM_CPPFLAGS])
 293 AC_SUBST([AM_LDFLAGS])
 294
 295 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 296 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 297 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 298 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 299                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 300 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 301
 302 # Output
 303 AC_CONFIG_FILES([Makefile
 304                  test/Makefile
 305                  test/function_benchmark/Makefile])
 306 AC_OUTPUT