folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for glog and gflags
  56 # There are no symbols with C linkage, so we do a try-run
  57 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  58                 [Please install google-glog library])])
  59 AC_CACHE_CHECK(
  60   [for glog viability],
  61   [folly_cv_prog_cc_glog],
  62   [AC_RUN_IFELSE(
  63     [AC_LANG_SOURCE[
  64       #include <glog/logging.h>
  65       int main(int argc, char** argv) {
  66         google::InitGoogleLogging(argv[0]);
  67         google::ShutdownGoogleLogging();
  68         return 0;
  69       }
  70     ]],
  71     [folly_cv_prog_cc_glog=yes],
  72     [folly_cv_prog_cc_glog=no]
  73   )]
  74 )
  75
  76 if test "$folly_cv_prog_cc_glog" != "yes"; then
  77   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
  78 fi
  79
  80 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  81                 [Please install google-gflags library])])
  82 AC_CACHE_CHECK(
  83   [for gflags viability],
  84   [folly_cv_prog_cc_gflags],
  85   [AC_RUN_IFELSE(
  86     [AC_LANG_SOURCE[
  87       #include <gflags/gflags.h>
  88       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  89       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  90       int main(int argc, char** argv) {
  91         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  92       }
  93     ]],
  94     [folly_cv_prog_cc_gflags=yes],
  95     [folly_cv_prog_cc_gflags=no]
  96   )]
  97 )
  98
  99 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 100   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
 101 fi
 102
 103 AC_CHECK_LIB(ssl,
 104         SSL_ctrl,
 105         [],
 106         [AC_MSG_ERROR(["Error: libssl required"])])
 107
 108 # check for boost libs
 109 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 110               [Please install boost >= 1.51.0 (context, thread, regex, and system)])])
 111 AX_BOOST_CONTEXT
 112 AX_BOOST_THREAD
 113 AX_BOOST_REGEX
 114 AX_BOOST_SYSTEM
 115 AX_BOOST_FILESYSTEM
 116
 117 # Check for python interpreter
 118 AM_PATH_PYTHON
 119
 120 # Checks for header files.
 121 AC_HEADER_STDC
 122 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
 123
 124 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 125                 [Couldn't find double-conversion.h, please download from \
 126                  https://github.com/google/double-conversion/])], [])
 127 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 128              [Please install double-conversion library])])
 129
 130 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 131
 132 AC_CHECK_LIB([jemalloc], [xallocx])
 133
 134 # Checks for typedefs, structures, and compiler characteristics.
 135 AC_HEADER_STDBOOL
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_TYPE_SIZE_T
 139 AC_HEADER_TIME
 140 AC_C_VOLATILE
 141 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
 142 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 143
 144 AC_CACHE_CHECK(
 145   [for ifunc support],
 146   [folly_cv_prog_cc_ifunc],
 147   [AC_COMPILE_IFELSE(
 148     [AC_LANG_SOURCE[
 149       #pragma GCC diagnostic error "-Wattributes"
 150       extern "C" void (*test_ifunc(void))() { return 0; }
 151       void func() __attribute__((ifunc("test_ifunc")));]
 152     ],
 153     [folly_cv_prog_cc_ifunc=yes],
 154     [folly_cv_prog_cc_ifunc=no])])
 155
 156 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 157   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 158 fi
 159
 160 AC_CACHE_CHECK(
 161   [for final and override support],
 162   [folly_cv_c_final_override],
 163   [AC_COMPILE_IFELSE(
 164     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 165                     class D : public C { virtual void g() override {} };]],
 166     [folly_cv_c_final_override=yes],
 167     [folly_cv_c_final_override=no])])
 168
 169 if test "$folly_cv_c_final_override" = "yes"; then
 170   final_val=final
 171   override_val=override
 172 else
 173   final_val=
 174   override_val=
 175 fi
 176
 177 AC_DEFINE_UNQUOTED(
 178   [FINAL], [$final_val],
 179   [Define to "final" if the compiler supports C++11 "final"])
 180 AC_DEFINE_UNQUOTED(
 181   [OVERRIDE], [$override_val],
 182   [Define to "override" if the compiler supports C++11 "override"])
 183
 184 AC_CACHE_CHECK(
 185   [for std::this_thread::sleep_for],
 186   [folly_cv_func_this_thread_sleep_for],
 187   [AC_COMPILE_IFELSE(
 188     [AC_LANG_SOURCE[
 189       #include <thread>
 190       #include <chrono>
 191       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 192     [folly_cv_func_this_thread_sleep_for=yes],
 193     [folly_cv_func_this_thread_sleep_for=no])])
 194
 195 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 196     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 197               [Define to 1 if std::this_thread::sleep_for() is defined.])
 198 fi
 199
 200 AC_CACHE_CHECK(
 201   [for constexpr strlen],
 202   [folly_cv_func_constexpr_strlen],
 203   [AC_COMPILE_IFELSE(
 204     [AC_LANG_SOURCE[
 205       #include <cstring>
 206       static constexpr int val = strlen("foo");]],
 207     [folly_cv_func_constexpr_strlen=yes],
 208     [folly_cv_func_constexpr_strlen=no])])
 209
 210 if test "$folly_cv_func_constexpr_strlen" = yes; then
 211     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 212               [Define to 1 if strlen(3) is constexpr.])
 213 fi
 214
 215 AC_CACHE_CHECK(
 216   [for libc++],
 217   [folly_cv_lib_libcpp],
 218   [AC_COMPILE_IFELSE(
 219     [AC_LANG_SOURCE[
 220       #include <type_traits>
 221       #if !_LIBCPP_VERSION
 222       #error No libc++
 223       #endif
 224       void func() {}]
 225     ],
 226     [folly_cv_lib_libcpp=yes],
 227     [folly_cv_lib_libcpp=no])])
 228
 229 if test "$folly_cv_lib_libcpp" = yes; then
 230   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 231 fi
 232
 233 AC_CACHE_CHECK(
 234   [for usable std::is_trivially_copyable],
 235   [folly_cv_decl_std_is_trivially_copyable],
 236   [AC_COMPILE_IFELSE(
 237     [AC_LANG_SOURCE[
 238       #include <type_traits>
 239       const bool val = std::is_trivially_copyable<bool>::value;]
 240     ],
 241     [folly_cv_decl_std_is_trivially_copyable=yes],
 242     [folly_cv_decl_std_is_trivially_copyable=no])])
 243
 244 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 245   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 246             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 247              implementation.])
 248 fi
 249
 250 AC_CACHE_CHECK(
 251   [gflags namespace],
 252   [folly_cv_decl_gflags_namespace],
 253   [AC_COMPILE_IFELSE(
 254     [AC_LANG_SOURCE[
 255       #include <gflags/gflags.h>
 256       void foo() { gflags::GetArgv(); }]
 257     ],
 258     [folly_cv_decl_gflags_namespace=gflags],
 259     [AC_COMPILE_IFELSE(
 260       [AC_LANG_SOURCE[
 261         #include <gflags/gflags.h>
 262         void foo() { google::GetArgv(); }]
 263       ],
 264       [folly_cv_decl_gflags_namespace=google],
 265       [folly_cv_decl_gflags_namespace=error])])])
 266
 267 if test "$folly_cv_decl_gflags_namespace" = error; then
 268   AC_MSG_ERROR([Cannot determine gflags namespace])
 269 else
 270   AC_DEFINE_UNQUOTED(
 271     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 272     [Define to gflags namespace (usually "google" or "gflags")])
 273   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 274      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 275                [Define to 1 if the gflags namespace is not "gflags"])
 276   fi
 277 fi
 278
 279 # Figure out if we support weak symbols. If not, we will link in some null
 280 # stubs for functions that would otherwise be weak.
 281 AC_CACHE_CHECK(
 282   [for weak symbol support],
 283   [folly_cv_prog_cc_weak_symbols],
 284   [AC_LINK_IFELSE(
 285     [AC_LANG_SOURCE[
 286       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 287       int main(int argc, char** argv) {
 288           return configure_link_extern_weak_test == nullptr;
 289       }]],
 290     [folly_cv_prog_cc_weak_symbols="yes"],
 291     [folly_cv_prog_cc_weak_symbols="no"])])
 292
 293 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 294   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 295             [Define to 1 if the linker supports weak symbols.])
 296 fi
 297
 298 AC_CACHE_CHECK(
 299   [for vsnprintf reporting bad format strings],
 300   [folly_cv_prog_vsnprintf_bad_format],
 301   [AC_RUN_IFELSE(
 302     [AC_LANG_SOURCE[
 303       #include <stdio.h>
 304
 305       int main(int argc, char** argv) {
 306           char buf[256];
 307           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 308       }]],
 309     [folly_cv_prog_vsnprintf_bad_format="yes"],
 310     [folly_cv_prog_vsnprintf_bad_format="no"])])
 311
 312 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 313   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 314             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 315 fi
 316
 317 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 318 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 319   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 320             [Define to 1 if we have cplus_demangle_v3_callback.])
 321 fi
 322
 323 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 324 # want to link with librt if necessary.
 325 AC_SEARCH_LIBS([clock_gettime], [rt],
 326   AC_DEFINE(
 327     [HAVE_CLOCK_GETTIME],
 328     [1],
 329     [Define to 1 if we support clock_gettime(2).]),
 330   [])
 331
 332 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 333 # want to include pthread.h if necessary.
 334 AC_CACHE_CHECK(
 335   [for pthread_atfork support],
 336   [folly_cv_prog_cc_pthread_atfork],
 337   [AC_COMPILE_IFELSE(
 338     [AC_LANG_SOURCE[
 339       #include <pthread.h>
 340       void func() {pthread_atfork(NULL, NULL, NULL);}]
 341     ],
 342     [folly_cv_prog_cc_pthread_atfork=yes],
 343     [folly_cv_prog_cc_pthread_atfork=no])])
 344
 345 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 346   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 347 fi
 348
 349 # Checks for library functions.
 350 AC_CHECK_FUNCS([getdelim \
 351                 gettimeofday \
 352                 memmove \
 353                 memset \
 354                 pow \
 355                 strerror \
 356                 pthread_yield \
 357                 malloc_size \
 358                 malloc_usable_size \
 359                 memrchr \
 360                 pipe2])
 361
 362 if test "$ac_cv_func_pthread_yield" = "no"; then
 363    AC_CHECK_HEADERS([sched.h])
 364    AC_CHECK_FUNCS([sched_yield])
 365 fi
 366
 367 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 368 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 369 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 370 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 371
 372 # Include directory that contains "folly" so #include <folly/Foo.h> works
 373 AM_CPPFLAGS='-I$(top_srcdir)/..'
 374 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 375 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 376 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 377
 378 AC_SUBST([AM_CPPFLAGS])
 379 AC_SUBST([AM_LDFLAGS])
 380
 381 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 382 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 383 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 384 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 385                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 386 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 387
 388 # Output
 389 AC_CONFIG_FILES([Makefile
 390                  test/Makefile
 391                  test/function_benchmark/Makefile])
 392 AC_OUTPUT