folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Be sure to add any -std option to CXXFLAGS before we invoke any
  27 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  28 # before we update CXXFLAGS will not be run with the same options that we use
  29 # during the real build.
  30 STD=""
  31 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  32    STD="-std=c++0x"
  33 fi
  34 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  35    STD="-std=gnu++0x"
  36 fi
  37
  38 CXXFLAGS="$STD $CXXFLAGS"
  39
  40 # Checks for libraries.
  41 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  42              [Please install google-glog library])])
  43 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  44              [Please install google-gflags library])])
  45
  46 # check for boost libs
  47 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  48               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  49 AX_BOOST_THREAD
  50 AX_BOOST_REGEX
  51 AX_BOOST_SYSTEM
  52 AX_BOOST_FILESYSTEM
  53
  54 # Checks for header files.
  55 AC_HEADER_STDC
  56 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  57
  58 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  59                 [Couldn't find double-conversion.h, please download from \
  60                 http://code.google.com/p/double-conversion/])], [])
  61 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  62              [Please install double-conversion library])])
  63
  64 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_HEADER_STDBOOL
  68 AC_C_CONST
  69 AC_C_INLINE
  70 AC_TYPE_SIZE_T
  71 AC_HEADER_TIME
  72 AC_C_VOLATILE
  73 AC_CHECK_TYPE([__int128],
  74   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  75   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  76 AC_CHECK_TYPES([ptrdiff_t])
  77 AC_COMPILE_IFELSE(
  78   [AC_LANG_SOURCE[
  79     #pragma GCC diagnostic error "-Wattributes"
  80     extern "C" void (*test_ifunc(void))() { return 0; }
  81     void func() __attribute__((ifunc("test_ifunc")));]
  82   ],
  83   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  84   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  85 )
  86 AC_COMPILE_IFELSE(
  87   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
  88                   class D : public C { virtual void g() override {} };]],
  89   [AC_DEFINE([FINAL], [final],
  90              [Define to "final" if the compiler supports C++11 "final"])
  91    AC_DEFINE([OVERRIDE], [override],
  92              [Define to "override" if the compiler supports C++11 "override"])],
  93   [AC_DEFINE([FINAL], [],
  94              [Define to "final" if the compiler supports C++11 "final"])
  95    AC_DEFINE([OVERRIDE], [],
  96              [Define to "override" if the compiler supports C++11 "override"])]
  97 )
  98
  99 AC_COMPILE_IFELSE(
 100   [AC_LANG_SOURCE[
 101     #include <thread>
 102     #include <chrono>
 103     void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 104   [AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 105              [Define to 1 if std::this_thread::sleep_for() is defined.])])
 106
 107 AC_COMPILE_IFELSE(
 108   [AC_LANG_SOURCE[
 109     #include <cstring>
 110     static constexpr int val = strlen("foo");]],
 111   [AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 112              [Define to 1 if strlen(3) is constexpr.])])
 113
 114 AC_COMPILE_IFELSE(
 115   [AC_LANG_SOURCE[
 116     #include <type_traits>
 117     #if !_LIBCPP_VERSION
 118     #error No libc++
 119     #endif
 120     void func() {}]
 121   ],
 122   [AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])])
 123
 124 AC_COMPILE_IFELSE(
 125   [AC_LANG_SOURCE[
 126     #include <type_traits>
 127     const bool val = std::is_trivially_copyable<bool>::value;]
 128   ],
 129   [AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 130              [Define to 1 if we have a usable std::is_trivially_copyable<T>
 131               implementation.])])
 132
 133 # Figure out if we support weak symbols. If not, we will link in some null
 134 # stubs for functions that would otherwise be weak.
 135 AC_LINK_IFELSE(
 136   [AC_LANG_SOURCE[
 137     extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 138     int main(int argc, char** argv) {
 139         return configure_link_extern_weak_test == nullptr;
 140     }]
 141   ],
 142   [
 143     ac_have_weak_symbols="yes"
 144     AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 145               [Define to 1 if the linker supports weak symbols.])])
 146
 147 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty])
 148 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 149   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 150             [Define to 1 if we have cplus_demangle_v3_callback.])
 151 fi
 152
 153 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 154 # want to link with librt if necessary.
 155 AC_SEARCH_LIBS([clock_gettime], [rt],
 156   AC_DEFINE(
 157     [HAVE_CLOCK_GETTIME],
 158     [1],
 159     [Define to 1 if we support clock_gettime(2).]),
 160   [])
 161
 162 # Checks for library functions.
 163 AC_CHECK_FUNCS([getdelim \
 164                 gettimeofday \
 165                 memmove \
 166                 memset \
 167                 pow \
 168                 strerror \
 169                 pthread_yield \
 170                 rallocm \
 171                 malloc_size \
 172                 malloc_usable_size \
 173                 memrchr])
 174
 175 if test "$ac_cv_func_pthread_yield" = "no"; then
 176    AC_CHECK_HEADERS([sched.h])
 177    AC_CHECK_FUNCS([sched_yield])
 178 fi
 179
 180 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $BOOST_CPPFLAGS")
 181 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 182
 183 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 184 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 185 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 186 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS], [test "$ac_have_weak_symbols" = "yes"])
 187 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 188
 189 # Output
 190 AC_CONFIG_FILES([Makefile
 191                  test/Makefile
 192                  test/function_benchmark/Makefile])
 193 AC_OUTPUT